New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
wet_dry.F90 in NEMO/branches/2020/dev_r13296_HPC-07_mocavero_mpi3/src/OCE/DYN – NEMO

source: NEMO/branches/2020/dev_r13296_HPC-07_mocavero_mpi3/src/OCE/DYN/wet_dry.F90 @ 13630

Last change on this file since 13630 was 13630, checked in by mocavero, 3 years ago

Add neighborhood collectives calls in the NEMO src - ticket #2496

  • Property svn:keywords set to Id
File size: 19.9 KB
Line 
1MODULE wet_dry
2
3   !! includes updates to namelist namwad for diagnostic outputs of ROMS wetting and drying
4
5   !!==============================================================================
6   !!                       ***  MODULE  wet_dry  ***
7   !! Wetting and drying includes initialisation routine and routines to
8   !! compute and apply flux limiters and preserve water depth positivity
9   !! only effects if wetting/drying is on (ln_wd_il == .true. or ln_wd_dl==.true. )
10   !!==============================================================================
11   !! History :  3.6  ! 2014-09  ((H.Liu)  Original code
12   !!                 ! will add the runoff and periodic BC case later
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   wad_init      : initialisation of wetting and drying
17   !!   wad_lmt       : horizontal flux limiter and limited velocity when wetting and drying happens
18   !!   wad_lmt_bt    : same as wad_lmt for the barotropic stepping (dynspg_ts)
19   !!----------------------------------------------------------------------
20   USE oce            ! ocean dynamics and tracers
21   USE dom_oce        ! ocean space and time domain
22   USE sbc_oce  , ONLY: ln_rnf   ! surface boundary condition: ocean
23   USE sbcrnf         ! river runoff
24   !
25   USE in_out_manager ! I/O manager
26   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
27   USE lib_mpp        ! MPP library
28   USE timing         ! timing of the main modules
29
30   IMPLICIT NONE
31   PRIVATE
32
33   !! * Substitutions
34#  include "do_loop_substitute.h90"
35#  include "domzgr_substitute.h90"
36   !!----------------------------------------------------------------------
37   !! critical depths,filters, limiters,and masks for  Wetting and Drying
38   !! ---------------------------------------------------------------------
39
40   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:) ::   wdmask   !: u- and v- limiter
41   !                                                           !  (can include negative depths)
42   REAL(wp), PUBLIC, ALLOCATABLE, DIMENSION(:,:) ::   wdramp, wdrampu, wdrampv !: for hpg limiting
43
44   LOGICAL,  PUBLIC  ::   ln_wd_il    !: Wetting/drying il activation switch (T:on,F:off)
45   LOGICAL,  PUBLIC  ::   ln_wd_dl    !: Wetting/drying dl activation switch (T:on,F:off)
46   REAL(wp), PUBLIC  ::   rn_wdmin0   !: depth at which wetting/drying starts
47   REAL(wp), PUBLIC  ::   rn_wdmin1   !: minimum water depth on dried cells
48   REAL(wp), PUBLIC  ::   r_rn_wdmin1 !: 1/minimum water depth on dried cells
49   REAL(wp), PUBLIC  ::   rn_wdmin2   !: tolerance of minimum water depth on dried cells
50   REAL(wp), PUBLIC  ::   rn_wd_sbcdep   !: Depth at which to taper sbc fluxes
51   REAL(wp), PUBLIC  ::   rn_wd_sbcfra   !: Fraction of SBC at taper depth
52   REAL(wp), PUBLIC  ::   rn_wdld     !: land elevation below which wetting/drying will be considered
53   INTEGER , PUBLIC  ::   nn_wdit     !: maximum number of iteration for W/D limiter
54   LOGICAL,  PUBLIC  ::   ln_wd_dl_bc !: DL scheme: True implies 3D velocities are set to the barotropic values at points
55                                      !: where the flow is from wet points on less than half the barotropic sub-steps 
56   LOGICAL,  PUBLIC  ::  ln_wd_dl_rmp !: use a ramp for the dl flux limiter between 2 rn_wdmin1 and rn_wdmin1 (rather than a cut-off at rn_wdmin1)     
57   REAL(wp), PUBLIC  ::   ssh_ref     !: height of z=0 with respect to the geoid;
58
59   LOGICAL,  PUBLIC  ::   ll_wd = .FALSE. !: Wetting/drying activation switch (ln_wd_il or ln_wd_dl) <- default def if wad_init not called
60
61   PUBLIC   wad_init                  ! initialisation routine called by step.F90
62   PUBLIC   wad_lmt                   ! routine called by sshwzv.F90
63   PUBLIC   wad_lmt_bt                ! routine called by dynspg_ts.F90
64
65   !! * Substitutions
66   !!----------------------------------------------------------------------
67CONTAINS
68
69   SUBROUTINE wad_init
70      !!----------------------------------------------------------------------
71      !!                     ***  ROUTINE wad_init  ***
72      !!                   
73      !! ** Purpose :   read wetting and drying namelist and print the variables.
74      !!
75      !! ** input   : - namwad namelist
76      !!----------------------------------------------------------------------
77      INTEGER  ::   ios, ierr   ! Local integer
78      !!
79      NAMELIST/namwad/ ln_wd_il, ln_wd_dl   , rn_wdmin0, rn_wdmin1, rn_wdmin2, rn_wdld,   &
80         &             nn_wdit , ln_wd_dl_bc, ln_wd_dl_rmp, rn_wd_sbcdep,rn_wd_sbcfra
81      !!----------------------------------------------------------------------
82      !
83      READ  ( numnam_ref, namwad, IOSTAT = ios, ERR = 905)
84905   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namwad in reference namelist' ) 
85      READ  ( numnam_cfg, namwad, IOSTAT = ios, ERR = 906)
86906   IF( ios >  0 )   CALL ctl_nam ( ios , 'namwad in configuration namelist' )
87      IF(lwm) WRITE ( numond, namwad )
88      !
89      IF( rn_wd_sbcfra>=1 )   CALL ctl_stop( 'STOP', 'rn_wd_sbcfra >=1 : must be < 1' )
90      IF(lwp) THEN                  ! control print
91         WRITE(numout,*)
92         WRITE(numout,*) 'wad_init : Wetting and drying initialization through namelist read'
93         WRITE(numout,*) '~~~~~~~~'
94         WRITE(numout,*) '   Namelist namwad'
95         WRITE(numout,*) '      Logical for Iter Lim wd option   ln_wd_il     = ', ln_wd_il
96         WRITE(numout,*) '      Logical for Dir. Lim wd option   ln_wd_dl     = ', ln_wd_dl
97         WRITE(numout,*) '      Depth at which wet/drying starts rn_wdmin0    = ', rn_wdmin0
98         WRITE(numout,*) '      Minimum wet depth on dried cells rn_wdmin1    = ', rn_wdmin1
99         WRITE(numout,*) '      Tolerance of min wet depth       rn_wdmin2    = ', rn_wdmin2
100         WRITE(numout,*) '      land elevation threshold         rn_wdld      = ', rn_wdld
101         WRITE(numout,*) '      Max iteration for W/D limiter    nn_wdit      = ', nn_wdit
102         WRITE(numout,*) '      T => baroclinic u,v=0 at dry pts: ln_wd_dl_bc = ', ln_wd_dl_bc     
103         WRITE(numout,*) '      use a ramp for rwd limiter:  ln_wd_dl_rwd_rmp = ', ln_wd_dl_rmp
104         WRITE(numout,*) '      cut off depth sbc for wd   rn_wd_sbcdep       = ', rn_wd_sbcdep
105         WRITE(numout,*) '      fraction to start sbc wgt rn_wd_sbcfra        = ', rn_wd_sbcfra
106      ENDIF
107      IF( .NOT. ln_read_cfg ) THEN
108         IF(lwp) WRITE(numout,*) '      No configuration file so seting ssh_ref to zero  '
109         ssh_ref=0._wp
110      ENDIF
111
112      r_rn_wdmin1 = 1 / rn_wdmin1
113      IF( ln_wd_il .OR. ln_wd_dl ) THEN
114         ll_wd = .TRUE.
115         ALLOCATE( wdmask(jpi,jpj),   STAT=ierr )
116         ALLOCATE( wdramp(jpi,jpj), wdrampu(jpi,jpj), wdrampv(jpi,jpj), STAT=ierr ) 
117         IF( ierr /= 0 ) CALL ctl_stop('STOP', 'wad_init : Array allocation error')
118      ENDIF
119      !
120   END SUBROUTINE wad_init
121
122
123   SUBROUTINE wad_lmt( psshb1, psshemp, z2dt, Kmm, puu, pvv )
124      !!----------------------------------------------------------------------
125      !!                  ***  ROUTINE wad_lmt  ***
126      !!                   
127      !! ** Purpose :   generate flux limiters for wetting/drying
128      !!
129      !! ** Method  : - Prevent negative depth occurring (Not ready for Agrif)
130      !!
131      !! ** Action  : - calculate flux limiter and W/D flag
132      !!----------------------------------------------------------------------
133      REAL(wp), DIMENSION(:,:)            , INTENT(inout) ::   psshb1
134      REAL(wp), DIMENSION(:,:)            , INTENT(in   ) ::   psshemp
135      REAL(wp)                            , INTENT(in   ) ::   z2dt
136      INTEGER                             , INTENT(in   ) ::   Kmm       ! time level index
137      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::   puu, pvv  ! velocity arrays
138      !
139      INTEGER  ::   ji, jj, jk, jk1     ! dummy loop indices
140      INTEGER  ::   jflag               ! local scalar
141      REAL(wp) ::   zcoef, zdep1, zdep2 ! local scalars
142      REAL(wp) ::   zzflxp, zzflxn      ! local scalars
143      REAL(wp) ::   zdepwd              ! local scalar, always wet cell depth
144      REAL(wp) ::   ztmp                ! local scalars
145      REAL(wp),  DIMENSION(jpi,jpj) ::   zwdlmtu, zwdlmtv   ! W/D flux limiters
146      REAL(wp),  DIMENSION(jpi,jpj) ::   zflxp  ,  zflxn    ! local 2D workspace
147      REAL(wp),  DIMENSION(jpi,jpj) ::   zflxu  ,  zflxv    ! local 2D workspace
148      REAL(wp),  DIMENSION(jpi,jpj) ::   zflxu1 , zflxv1    ! local 2D workspace
149      !!----------------------------------------------------------------------
150      IF( ln_timing )   CALL timing_start('wad_lmt')      !
151      !
152      DO jk = 1, jpkm1
153         puu(:,:,jk,Kmm) = puu(:,:,jk,Kmm) * zwdlmtu(:,:) 
154         pvv(:,:,jk,Kmm) = pvv(:,:,jk,Kmm) * zwdlmtv(:,:) 
155      END DO
156      jflag  = 0
157      zdepwd = 50._wp      ! maximum depth on which that W/D could possibly happen
158      !
159      zflxp(:,:)   = 0._wp
160      zflxn(:,:)   = 0._wp
161      zflxu(:,:)   = 0._wp
162      zflxv(:,:)   = 0._wp
163      !
164      zwdlmtu(:,:) = 1._wp
165      zwdlmtv(:,:) = 1._wp
166      !
167      DO jk = 1, jpkm1     ! Horizontal Flux in u and v direction
168         zflxu(:,:) = zflxu(:,:) + e3u(:,:,jk,Kmm) * puu(:,:,jk,Kmm) * umask(:,:,jk)
169         zflxv(:,:) = zflxv(:,:) + e3v(:,:,jk,Kmm) * pvv(:,:,jk,Kmm) * vmask(:,:,jk)
170      END DO
171      zflxu(:,:) = zflxu(:,:) * e2u(:,:)
172      zflxv(:,:) = zflxv(:,:) * e1v(:,:)
173      !
174      wdmask(:,:) = 1._wp
175      DO_2D( 0, 1, 0, 1 )
176         !
177         IF( tmask(ji,jj,1)        < 0.5_wp )   CYCLE    ! we don't care about land cells
178         IF( ht_0(ji,jj) - ssh_ref > zdepwd )   CYCLE    ! and cells which are unlikely to dry
179         !
180         zflxp(ji,jj) = MAX( zflxu(ji,jj) , 0._wp ) - MIN( zflxu(ji-1,jj  ) , 0._wp )   &
181            &         + MAX( zflxv(ji,jj) , 0._wp ) - MIN( zflxv(ji,  jj-1) , 0._wp ) 
182         zflxn(ji,jj) = MIN( zflxu(ji,jj) , 0._wp ) - MAX( zflxu(ji-1,jj  ) , 0._wp )   &
183            &         + MIN( zflxv(ji,jj) , 0._wp ) - MAX( zflxv(ji,  jj-1) , 0._wp ) 
184         !
185         zdep2 = ht_0(ji,jj) + psshb1(ji,jj) - rn_wdmin1
186         IF( zdep2 <= 0._wp ) THEN     ! add more safty, but not necessary
187            psshb1(ji,jj) = rn_wdmin1 - ht_0(ji,jj)
188            IF(zflxu(ji,  jj) > 0._wp) zwdlmtu(ji  ,jj) = 0._wp
189            IF(zflxu(ji-1,jj) < 0._wp) zwdlmtu(ji-1,jj) = 0._wp
190            IF(zflxv(ji,  jj) > 0._wp) zwdlmtv(ji  ,jj) = 0._wp
191            IF(zflxv(ji,jj-1) < 0._wp) zwdlmtv(ji,jj-1) = 0._wp 
192            wdmask(ji,jj) = 0._wp
193         END IF
194      END_2D
195      !
196      !           ! HPG limiter from jholt
197      wdramp(:,:) = min((ht_0(:,:) + psshb1(:,:) - rn_wdmin1)/(rn_wdmin0 - rn_wdmin1),1.0_wp)
198      !jth assume don't need a lbc_lnk here
199      DO_2D( 1, 0, 1, 0 )
200         wdrampu(ji,jj) = MIN( wdramp(ji,jj) , wdramp(ji+1,jj) )
201         wdrampv(ji,jj) = MIN( wdramp(ji,jj) , wdramp(ji,jj+1) )
202      END_2D
203      !           ! end HPG limiter
204      !
205      !
206      DO jk1 = 1, nn_wdit + 1      !==  start limiter iterations  ==!
207         !
208         zflxu1(:,:) = zflxu(:,:) * zwdlmtu(:,:)
209         zflxv1(:,:) = zflxv(:,:) * zwdlmtv(:,:)
210         jflag = 0     ! flag indicating if any further iterations are needed
211         !
212         DO_2D( 0, 1, 0, 1 )
213            IF( tmask(ji, jj, 1) < 0.5_wp )   CYCLE
214            IF( ht_0(ji,jj)      > zdepwd )   CYCLE
215            !
216            ztmp = e1e2t(ji,jj)
217            !
218            zzflxp = MAX( zflxu1(ji,jj) , 0._wp ) - MIN( zflxu1(ji-1,jj  ) , 0._wp)   &
219               &   + MAX( zflxv1(ji,jj) , 0._wp ) - MIN( zflxv1(ji,  jj-1) , 0._wp) 
220            zzflxn = MIN( zflxu1(ji,jj) , 0._wp ) - MAX( zflxu1(ji-1,jj  ) , 0._wp)   &
221               &   + MIN( zflxv1(ji,jj) , 0._wp ) - MAX( zflxv1(ji,  jj-1) , 0._wp) 
222            !
223            zdep1 = (zzflxp + zzflxn) * z2dt / ztmp
224            zdep2 = ht_0(ji,jj) + psshb1(ji,jj) - rn_wdmin1 - z2dt * psshemp(ji,jj)
225            !
226            IF( zdep1 > zdep2 ) THEN
227               wdmask(ji, jj) = 0._wp
228               zcoef = ( ( zdep2 - rn_wdmin2 ) * ztmp - zzflxn * z2dt ) / ( zflxp(ji,jj) * z2dt )
229               !zcoef = ( ( zdep2 - rn_wdmin2 ) * ztmp - zzflxn * z2dt ) / ( zzflxp * z2dt )
230               ! flag if the limiter has been used but stop flagging if the only
231               ! changes have zeroed the coefficient since further iterations will
232               ! not change anything
233               IF( zcoef > 0._wp ) THEN   ;   jflag = 1 
234               ELSE                       ;   zcoef = 0._wp
235               ENDIF
236               IF( jk1 > nn_wdit )   zcoef = 0._wp
237               IF( zflxu1(ji  ,jj  ) > 0._wp )   zwdlmtu(ji  ,jj  ) = zcoef
238               IF( zflxu1(ji-1,jj  ) < 0._wp )   zwdlmtu(ji-1,jj  ) = zcoef
239               IF( zflxv1(ji  ,jj  ) > 0._wp )   zwdlmtv(ji  ,jj  ) = zcoef
240               IF( zflxv1(ji  ,jj-1) < 0._wp )   zwdlmtv(ji  ,jj-1) = zcoef
241            ENDIF
242         END_2D
243#if defined key_mpi3
244         CALL lbc_lnk_nc_multi( 'wet_dry', zwdlmtu, 'U', 1.0_wp, zwdlmtv, 'V', 1.0_wp )
245#else
246         CALL lbc_lnk_multi( 'wet_dry', zwdlmtu, 'U', 1.0_wp, zwdlmtv, 'V', 1.0_wp )
247#endif
248         !
249         CALL mpp_max('wet_dry', jflag)   !max over the global domain
250         !
251         IF( jflag == 0 )   EXIT
252         !
253      END DO  ! jk1 loop
254      !
255      DO jk = 1, jpkm1
256         puu(:,:,jk,Kmm) = puu(:,:,jk,Kmm) * zwdlmtu(:,:) 
257         pvv(:,:,jk,Kmm) = pvv(:,:,jk,Kmm) * zwdlmtv(:,:) 
258      END DO
259      uu_b(:,:,Kmm) = uu_b(:,:,Kmm) * zwdlmtu(:, :)
260      vv_b(:,:,Kmm) = vv_b(:,:,Kmm) * zwdlmtv(:, :)
261      !
262!!gm TO BE SUPPRESSED ?  these lbc_lnk are useless since zwdlmtu and zwdlmtv are defined everywhere !
263#if defined key_mpi3
264      CALL lbc_lnk_nc_multi( 'wet_dry', puu(:,:,:,Kmm)  , 'U', -1.0_wp, pvv(:,:,:,Kmm)  , 'V', -1.0_wp )
265      CALL lbc_lnk_nc_multi( 'wet_dry', uu_b(:,:,Kmm), 'U', -1.0_wp, vv_b(:,:,Kmm), 'V', -1.0_wp )
266#else
267      CALL lbc_lnk_multi( 'wet_dry', puu(:,:,:,Kmm)  , 'U', -1.0_wp, pvv(:,:,:,Kmm)  , 'V', -1.0_wp )
268      CALL lbc_lnk_multi( 'wet_dry', uu_b(:,:,Kmm), 'U', -1.0_wp, vv_b(:,:,Kmm), 'V', -1.0_wp )
269#endif
270!!gm
271      !
272      IF(jflag == 1 .AND. lwp)   WRITE(numout,*) 'Need more iterations in wad_lmt!!!'
273      !
274      !IF( ln_rnf      )   CALL sbc_rnf_div( hdiv )          ! runoffs (update hdiv field)
275      !
276      IF( ln_timing )   CALL timing_stop('wad_lmt')      !
277      !
278   END SUBROUTINE wad_lmt
279
280
281   SUBROUTINE wad_lmt_bt( zflxu, zflxv, sshn_e, zssh_frc, rDt_e )
282      !!----------------------------------------------------------------------
283      !!                  ***  ROUTINE wad_lmt  ***
284      !!                   
285      !! ** Purpose :   limiting flux in the barotropic stepping (dynspg_ts)
286      !!
287      !! ** Method  : - Prevent negative depth occurring (Not ready for Agrif)
288      !!
289      !! ** Action  : - calculate flux limiter and W/D flag
290      !!----------------------------------------------------------------------
291      REAL(wp)                , INTENT(in   ) ::   rDt_e    ! ocean time-step index
292      REAL(wp), DIMENSION(:,:), INTENT(inout) ::   zflxu,  zflxv, sshn_e, zssh_frc 
293      !
294      INTEGER  ::   ji, jj, jk, jk1     ! dummy loop indices
295      INTEGER  ::   jflag               ! local integer
296      REAL(wp) ::   z2dt
297      REAL(wp) ::   zcoef, zdep1, zdep2 ! local scalars
298      REAL(wp) ::   zzflxp, zzflxn      ! local scalars
299      REAL(wp) ::   zdepwd              ! local scalar, always wet cell depth
300      REAL(wp) ::   ztmp                ! local scalars
301      REAL(wp), DIMENSION(jpi,jpj) ::   zwdlmtu, zwdlmtv         !: W/D flux limiters
302      REAL(wp), DIMENSION(jpi,jpj) ::   zflxp,  zflxn            ! local 2D workspace
303      REAL(wp), DIMENSION(jpi,jpj) ::   zflxu1, zflxv1           ! local 2D workspace
304      !!----------------------------------------------------------------------
305      IF( ln_timing )   CALL timing_start('wad_lmt_bt')      !
306      !
307      jflag  = 0
308      zdepwd = 50._wp   ! maximum depth that ocean cells can have W/D processes
309      !
310      z2dt = rDt_e   
311      !
312      zflxp(:,:)   = 0._wp
313      zflxn(:,:)   = 0._wp
314      zwdlmtu(:,:) = 1._wp
315      zwdlmtv(:,:) = 1._wp
316      !
317      DO_2D( 0, 1, 0, 1 )      ! Horizontal Flux in u and v direction
318         !
319         IF( tmask(ji, jj, 1 ) < 0.5_wp) CYCLE   ! we don't care about land cells
320         IF( ht_0(ji,jj) > zdepwd )      CYCLE   ! and cells which are unlikely to dry
321         !
322         zflxp(ji,jj) = MAX( zflxu(ji,jj) , 0._wp ) - MIN( zflxu(ji-1,jj  ) , 0._wp )   &
323            &         + MAX( zflxv(ji,jj) , 0._wp ) - MIN( zflxv(ji,  jj-1) , 0._wp ) 
324         zflxn(ji,jj) = MIN( zflxu(ji,jj) , 0._wp ) - MAX( zflxu(ji-1,jj  ) , 0._wp )   &
325            &         + MIN( zflxv(ji,jj) , 0._wp ) - MAX( zflxv(ji,  jj-1) , 0._wp ) 
326         !
327         zdep2 = ht_0(ji,jj) + sshn_e(ji,jj) - rn_wdmin1
328         IF( zdep2 <= 0._wp ) THEN  !add more safety, but not necessary
329           sshn_e(ji,jj) = rn_wdmin1 - ht_0(ji,jj)
330           IF( zflxu(ji  ,jj  ) > 0._wp)   zwdlmtu(ji  ,jj  ) = 0._wp
331           IF( zflxu(ji-1,jj  ) < 0._wp)   zwdlmtu(ji-1,jj  ) = 0._wp
332           IF( zflxv(ji  ,jj  ) > 0._wp)   zwdlmtv(ji  ,jj  ) = 0._wp
333           IF( zflxv(ji  ,jj-1) < 0._wp)   zwdlmtv(ji  ,jj-1) = 0._wp 
334         ENDIF
335      END_2D
336      !
337      DO jk1 = 1, nn_wdit + 1      !! start limiter iterations
338         !
339         zflxu1(:,:) = zflxu(:,:) * zwdlmtu(:,:)
340         zflxv1(:,:) = zflxv(:,:) * zwdlmtv(:,:)
341         jflag = 0     ! flag indicating if any further iterations are needed
342         !
343         DO_2D( 0, 1, 0, 1 )
344            !
345            IF( tmask(ji, jj, 1 ) < 0.5_wp )   CYCLE
346            IF( ht_0(ji,jj)       > zdepwd )   CYCLE
347            !
348            ztmp = e1e2t(ji,jj)
349            !
350            zzflxp = max(zflxu1(ji,jj), 0._wp) - min(zflxu1(ji-1,jj),   0._wp)   &
351               &   + max(zflxv1(ji,jj), 0._wp) - min(zflxv1(ji,  jj-1), 0._wp) 
352            zzflxn = min(zflxu1(ji,jj), 0._wp) - max(zflxu1(ji-1,jj),   0._wp)   &
353               &   + min(zflxv1(ji,jj), 0._wp) - max(zflxv1(ji,  jj-1), 0._wp) 
354       
355            zdep1 = (zzflxp + zzflxn) * z2dt / ztmp
356            zdep2 = ht_0(ji,jj) + sshn_e(ji,jj) - rn_wdmin1 - z2dt * zssh_frc(ji,jj)
357       
358            IF(zdep1 > zdep2) THEN
359              zcoef = ( ( zdep2 - rn_wdmin2 ) * ztmp - zzflxn * z2dt ) / ( zflxp(ji,jj) * z2dt )
360              !zcoef = ( ( zdep2 - rn_wdmin2 ) * ztmp - zzflxn * z2dt ) / ( zzflxp * z2dt )
361              ! flag if the limiter has been used but stop flagging if the only
362              ! changes have zeroed the coefficient since further iterations will
363              ! not change anything
364              IF( zcoef > 0._wp ) THEN
365                 jflag = 1 
366              ELSE
367                 zcoef = 0._wp
368              ENDIF
369              IF(jk1 > nn_wdit) zcoef = 0._wp
370              IF(zflxu1(ji,  jj) > 0._wp) zwdlmtu(ji  ,jj) = zcoef
371              IF(zflxu1(ji-1,jj) < 0._wp) zwdlmtu(ji-1,jj) = zcoef
372              IF(zflxv1(ji,  jj) > 0._wp) zwdlmtv(ji  ,jj) = zcoef
373              IF(zflxv1(ji,jj-1) < 0._wp) zwdlmtv(ji,jj-1) = zcoef
374            END IF
375         END_2D
376         !
377#if defined key_mpi3
378         CALL lbc_lnk_nc_multi( 'wet_dry', zwdlmtu, 'U', 1.0_wp, zwdlmtv, 'V', 1.0_wp )
379#else
380         CALL lbc_lnk_multi( 'wet_dry', zwdlmtu, 'U', 1.0_wp, zwdlmtv, 'V', 1.0_wp )
381#endif
382         !
383         CALL mpp_max('wet_dry', jflag)   !max over the global domain
384         !
385         IF(jflag == 0)   EXIT
386         !
387      END DO  ! jk1 loop
388      !
389      zflxu(:,:) = zflxu(:,:) * zwdlmtu(:, :) 
390      zflxv(:,:) = zflxv(:,:) * zwdlmtv(:, :) 
391      !
392!!gm THIS lbc_lnk is useless since it is already done at the end of the jk1-loop
393#if defined key_mpi3
394      CALL lbc_lnk_nc_multi( 'wet_dry', zflxu, 'U', -1.0_wp, zflxv, 'V', -1.0_wp )
395#else
396      CALL lbc_lnk_multi( 'wet_dry', zflxu, 'U', -1.0_wp, zflxv, 'V', -1.0_wp )
397#endif
398!!gm end
399      !
400      IF( jflag == 1 .AND. lwp )   WRITE(numout,*) 'Need more iterations in wad_lmt_bt!!!'
401      !
402      !IF( ln_rnf      )   CALL sbc_rnf_div( hdiv )          ! runoffs (update hdiv field)
403      !
404      IF( ln_timing )   CALL timing_stop('wad_lmt_bt')      !
405      !
406   END SUBROUTINE wad_lmt_bt
407
408   !!==============================================================================
409END MODULE wet_dry
Note: See TracBrowser for help on using the repository browser.