New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icbini.F90 in NEMO/branches/2020/dev_r13296_HPC-07_mocavero_mpi3/src/OCE/ICB – NEMO

source: NEMO/branches/2020/dev_r13296_HPC-07_mocavero_mpi3/src/OCE/ICB/icbini.F90 @ 13630

Last change on this file since 13630 was 13630, checked in by mocavero, 3 years ago

Add neighborhood collectives calls in the NEMO src - ticket #2496

  • Property svn:keywords set to Id
File size: 23.8 KB
Line 
1MODULE icbini
2   !!======================================================================
3   !!                       ***  MODULE  icbini  ***
4   !! Icebergs:  initialise variables for iceberg tracking
5   !!======================================================================
6   !! History :   -   !  2010-01  (T. Martin & A. Adcroft)  Original code
7   !!            3.3  !  2011-03  (G. Madec)  Part conversion to NEMO form ; Removal of mapping from another grid
8   !!             -   !  2011-04  (S. Alderson)  Split into separate modules ; Restore restart routines
9   !!             -   !  2011-05  (S. Alderson)  generate_test_icebergs restored ; new forcing arrays with extra halo ;
10   !!             -   !                          north fold exchange arrays added
11   !!----------------------------------------------------------------------
12   !!----------------------------------------------------------------------
13   !!   icb_init     : initialise icebergs
14   !!   icb_ini_gen  : generate test icebergs
15   !!   icb_nam      : read iceberg namelist
16   !!----------------------------------------------------------------------
17   USE dom_oce        ! ocean domain
18   USE in_out_manager ! IO routines and numout in particular
19   USE lib_mpp        ! mpi library and lk_mpp in particular
20   USE sbc_oce        ! ocean  : surface boundary condition
21   USE sbc_ice        ! sea-ice: surface boundary condition
22   USE iom            ! IOM library
23   USE fldread        ! field read
24   USE lbclnk         ! lateral boundary condition - MPP link
25   !
26   USE icb_oce        ! define iceberg arrays
27   USE icbutl         ! iceberg utility routines
28   USE icbrst         ! iceberg restart routines
29   USE icbtrj         ! iceberg trajectory I/O routines
30   USE icbdia         ! iceberg budget routines
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   icb_init  ! routine called in nemogcm.F90 module
36
37   CHARACTER(len=100)                                 ::   cn_dir = './'   !: Root directory for location of icb files
38   TYPE(FLD_N)                                        ::   sn_icb          !: information about the calving file to be read
39   TYPE(FLD), PUBLIC, ALLOCATABLE     , DIMENSION(:)  ::   sf_icb          !: structure: file information, fields read
40                                                                           !: used in icbini and icbstp
41   !! * Substitutions
42#  include "do_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
45   !! $Id$
46   !! Software governed by the CeCILL license (see ./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE icb_init( pdt, kt )
51      !!----------------------------------------------------------------------
52      !!                  ***  ROUTINE dom_init  ***
53      !!
54      !! ** Purpose :   iceberg initialization.
55      !!
56      !! ** Method  : - read the iceberg namelist
57      !!              - find non-overlapping processor interior since we can only
58      !!                have one instance of a particular iceberg
59      !!              - calculate the destinations for north fold exchanges
60      !!              - setup either test icebergs or calving file
61      !!----------------------------------------------------------------------
62      REAL(wp), INTENT(in) ::   pdt   ! iceberg time-step (rn_Dt*nn_fsbc)
63      INTEGER , INTENT(in) ::   kt    ! time step number
64      !
65      INTEGER ::   ji, jj, jn               ! dummy loop indices
66      INTEGER ::   i1, i2, i3               ! local integers
67      INTEGER ::   ii, inum, ivar           !   -       -
68      INTEGER ::   istat1, istat2, istat3   !   -       -
69      CHARACTER(len=300) ::   cl_sdist      ! local character
70      !!----------------------------------------------------------------------
71      !
72      CALL icb_nam               ! Read and print namelist parameters
73      !
74      IF( .NOT. ln_icebergs )   RETURN
75
76      !                          ! allocate gridded fields
77      IF( icb_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'icb_alloc : unable to allocate arrays' )
78      !
79      !                          ! initialised variable with extra haloes to zero
80      uo_e(:,:) = 0._wp   ;   vo_e(:,:) = 0._wp   ;
81      ua_e(:,:) = 0._wp   ;   va_e(:,:) = 0._wp   ;
82      ff_e(:,:) = 0._wp   ;   tt_e(:,:) = 0._wp   ;
83      fr_e(:,:) = 0._wp   ;   ss_e(:,:) = 0._wp   ;
84#if defined key_si3
85      hi_e(:,:) = 0._wp   ;
86      ui_e(:,:) = 0._wp   ;   vi_e(:,:) = 0._wp   ;
87#endif
88      ssh_e(:,:) = 0._wp  ; 
89      !
90      !                          ! open ascii output file or files for iceberg status information
91      !                          ! note that we choose to do this on all processors since we cannot
92      !                          ! predict where icebergs will be ahead of time
93      IF( nn_verbose_level > 0) THEN
94         CALL ctl_opn( numicb, 'icebergs.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
95      ENDIF
96
97      ! set parameters (mostly from namelist)
98      !
99      berg_dt         = pdt
100      first_width (:) = SQRT(  rn_initial_mass(:) / ( rn_LoW_ratio * rn_rho_bergs * rn_initial_thickness(:) )  )
101      first_length(:) = rn_LoW_ratio * first_width(:)
102
103      berg_grid%calving      (:,:)   = 0._wp
104      berg_grid%calving_hflx (:,:)   = 0._wp
105      berg_grid%stored_heat  (:,:)   = 0._wp
106      berg_grid%floating_melt(:,:)   = 0._wp
107      berg_grid%maxclass     (:,:)   = nclasses
108      berg_grid%stored_ice   (:,:,:) = 0._wp
109      berg_grid%tmp          (:,:)   = 0._wp
110      src_calving            (:,:)   = 0._wp
111      src_calving_hflx       (:,:)   = 0._wp
112
113      !                          ! domain for icebergs
114      IF( lk_mpp .AND. jpni == 1 )   CALL ctl_stop( 'icbinit: having ONE processor in x currently does not work' )
115      ! NB: the issue here is simply that cyclic east-west boundary condition have not been coded in mpp case
116      ! for the north fold we work out which points communicate by asking
117      ! lbc_lnk to pass processor number (valid even in single processor case)
118      ! borrow src_calving arrays for this
119      !
120      ! pack i and j together using a scaling of a power of 10
121      nicbpack = 10000
122      IF( jpiglo >= nicbpack )   CALL ctl_stop( 'icbini: processor index packing failure' )
123      nicbfldproc(:) = -1
124
125      DO_2D( 1, 1, 1, 1 )
126         src_calving_hflx(ji,jj) = narea
127         src_calving     (ji,jj) = nicbpack * mjg(jj) + mig(ji)
128      END_2D
129#if defined key_mpi3
130      CALL lbc_lnk_nc_multi( 'icbini', src_calving_hflx, 'T', 1._wp )
131      CALL lbc_lnk_nc_multi( 'icbini', src_calving     , 'T', 1._wp )
132#else
133      CALL lbc_lnk( 'icbini', src_calving_hflx, 'T', 1._wp )
134      CALL lbc_lnk( 'icbini', src_calving     , 'T', 1._wp )
135#endif
136
137      ! work out interior of processor from exchange array
138      ! first entry with narea for this processor is left hand interior index
139      ! last  entry                               is right hand interior index
140      jj = jpj/2
141      nicbdi = -1
142      nicbei = -1
143      DO ji = 1, jpi
144         i3 = INT( src_calving(ji,jj) )
145         i2 = INT( i3/nicbpack )
146         i1 = i3 - i2*nicbpack
147         i3 = INT( src_calving_hflx(ji,jj) )
148         IF( i1 == mig(ji) .AND. i3 == narea ) THEN
149            IF( nicbdi < 0 ) THEN   ;   nicbdi = ji
150            ELSE                    ;   nicbei = ji
151            ENDIF
152         ENDIF
153      END DO
154      !
155      ! repeat for j direction
156      ji = jpi/2
157      nicbdj = -1
158      nicbej = -1
159      DO jj = 1, jpj
160         i3 = INT( src_calving(ji,jj) )
161         i2 = INT( i3/nicbpack )
162         i1 = i3 - i2*nicbpack
163         i3 = INT( src_calving_hflx(ji,jj) )
164         IF( i2 == mjg(jj) .AND. i3 == narea ) THEN
165            IF( nicbdj < 0 ) THEN   ;   nicbdj = jj
166            ELSE                    ;   nicbej = jj
167            ENDIF
168         ENDIF
169      END DO
170      !   
171      ! special for east-west boundary exchange we save the destination index
172      i1 = MAX( nicbdi-1, 1)
173      i3 = INT( src_calving(i1,jpj/2) )
174      jj = INT( i3/nicbpack )
175      ricb_left = REAL( i3 - nicbpack*jj, wp )
176      i1 = MIN( nicbei+1, jpi )
177      i3 = INT( src_calving(i1,jpj/2) )
178      jj = INT( i3/nicbpack )
179      ricb_right = REAL( i3 - nicbpack*jj, wp )
180     
181      ! north fold
182      IF( npolj > 0 ) THEN
183         !
184         ! icebergs in row nicbej+1 get passed across fold
185         nicbfldpts(:)  = INT( src_calving(:,nicbej+1) )
186         nicbflddest(:) = INT( src_calving_hflx(:,nicbej+1) )
187         !
188         ! work out list of unique processors to talk to
189         ! pack them into a fixed size array where empty slots are marked by a -1
190         DO ji = nicbdi, nicbei
191            ii = nicbflddest(ji)
192            IF( ii .GT. 0 ) THEN     ! Needed because land suppression can mean
193                                     ! that unused points are not set in edge haloes
194               DO jn = 1, jpni
195                  ! work along array until we find an empty slot
196                  IF( nicbfldproc(jn) == -1 ) THEN
197                     nicbfldproc(jn) = ii
198                     EXIT                             !!gm EXIT should be avoided: use DO WHILE expression instead
199                  ENDIF
200                  ! before we find an empty slot, we may find processor number is already here so we exit
201                  IF( nicbfldproc(jn) == ii ) EXIT
202               END DO
203            ENDIF
204         END DO
205      ENDIF
206      !
207      IF( nn_verbose_level > 0) THEN
208         WRITE(numicb,*) 'processor ', narea
209         WRITE(numicb,*) 'jpi, jpj   ', jpi, jpj
210         WRITE(numicb,*) 'Nis0, Nie0 ', Nis0, Nie0
211         WRITE(numicb,*) 'Njs0, Nje0 ', Njs0, Nje0
212         WRITE(numicb,*) 'berg i interior ', nicbdi, nicbei
213         WRITE(numicb,*) 'berg j interior ', nicbdj, nicbej
214         WRITE(numicb,*) 'berg left       ', ricb_left
215         WRITE(numicb,*) 'berg right      ', ricb_right
216         jj = jpj/2
217         WRITE(numicb,*) "central j line:"
218         WRITE(numicb,*) "i processor"
219         WRITE(numicb,*) (INT(src_calving_hflx(ji,jj)), ji=1,jpi)
220         WRITE(numicb,*) "i point"
221         WRITE(numicb,*) (INT(src_calving(ji,jj)), ji=1,jpi)
222         ji = jpi/2
223         WRITE(numicb,*) "central i line:"
224         WRITE(numicb,*) "j processor"
225         WRITE(numicb,*) (INT(src_calving_hflx(ji,jj)), jj=1,jpj)
226         WRITE(numicb,*) "j point"
227         WRITE(numicb,*) (INT(src_calving(ji,jj)), jj=1,jpj)
228         IF( npolj > 0 ) THEN
229            WRITE(numicb,*) 'north fold destination points '
230            WRITE(numicb,*) nicbfldpts
231            WRITE(numicb,*) 'north fold destination procs  '
232            WRITE(numicb,*) nicbflddest
233            WRITE(numicb,*) 'north fold destination proclist  '
234            WRITE(numicb,*) nicbfldproc
235         ENDIF
236         CALL flush(numicb)
237      ENDIF
238     
239      src_calving     (:,:) = 0._wp
240      src_calving_hflx(:,:) = 0._wp
241
242      ! definition of extended surface masked needed by icb_bilin_h
243      tmask_e(:,:) = 0._wp   ;   tmask_e(1:jpi,1:jpj) = tmask(:,:,1)
244      umask_e(:,:) = 0._wp   ;   umask_e(1:jpi,1:jpj) = umask(:,:,1)
245      vmask_e(:,:) = 0._wp   ;   vmask_e(1:jpi,1:jpj) = vmask(:,:,1)
246      CALL lbc_lnk_icb( 'icbini', tmask_e, 'T', +1._wp, 1, 1 )
247      CALL lbc_lnk_icb( 'icbini', umask_e, 'T', +1._wp, 1, 1 )
248      CALL lbc_lnk_icb( 'icbini', vmask_e, 'T', +1._wp, 1, 1 )
249      !
250      ! assign each new iceberg with a unique number constructed from the processor number
251      ! and incremented by the total number of processors
252      num_bergs(:) = 0
253      num_bergs(1) = narea - jpnij
254
255      ! when not generating test icebergs we need to setup calving file
256      IF( nn_test_icebergs < 0 .OR. ln_use_calving ) THEN
257         !
258         ! maximum distribution class array does not change in time so read it once
259         cl_sdist = TRIM( cn_dir )//TRIM( sn_icb%clname )
260         CALL iom_open ( cl_sdist, inum )                              ! open file
261         ivar = iom_varid( inum, 'maxclass', ldstop=.FALSE. )
262         IF( ivar > 0 ) THEN
263            CALL iom_get  ( inum, jpdom_global, 'maxclass', src_calving )   ! read the max distribution array
264            berg_grid%maxclass(:,:) = INT( src_calving )
265            src_calving(:,:) = 0._wp
266         ENDIF
267         CALL iom_close( inum )                                     ! close file
268         !
269         IF( nn_verbose_level > 0) THEN
270            WRITE(numicb,*)
271            WRITE(numicb,*) '          calving read in a file'
272         ENDIF
273         ALLOCATE( sf_icb(1), STAT=istat1 )         ! Create sf_icb structure (calving)
274         ALLOCATE( sf_icb(1)%fnow(jpi,jpj,1), STAT=istat2 )
275         ALLOCATE( sf_icb(1)%fdta(jpi,jpj,1,2), STAT=istat3 )
276         IF( istat1+istat2+istat3 > 0 ) THEN
277            CALL ctl_stop( 'sbc_icb: unable to allocate sf_icb structure' )   ;   RETURN
278         ENDIF
279         !                                          ! fill sf_icb with the namelist (sn_icb) and control print
280         CALL fld_fill( sf_icb, (/ sn_icb /), cn_dir, 'icb_init', 'read calving data', 'namicb' )
281         !
282      ENDIF
283
284      IF( .NOT.ln_rstart ) THEN
285         IF( nn_test_icebergs > 0 )   CALL icb_ini_gen()
286      ELSE
287         IF( nn_test_icebergs > 0 ) THEN
288            CALL icb_ini_gen()
289         ELSE
290            CALL icb_rst_read()
291            l_restarted_bergs = .TRUE.
292         ENDIF
293      ENDIF
294      !
295      IF( nn_sample_rate .GT. 0 ) CALL icb_trj_init( nitend )
296      !
297      CALL icb_dia_init()
298      !
299      IF( nn_verbose_level >= 2 )   CALL icb_utl_print('icb_init, initial status', nit000-1)
300      !
301   END SUBROUTINE icb_init
302
303
304   SUBROUTINE icb_ini_gen()
305      !!----------------------------------------------------------------------
306      !!                  ***  ROUTINE icb_ini_gen  ***
307      !!
308      !! ** Purpose :   iceberg generation
309      !!
310      !! ** Method  : - at each grid point of the test box supplied in the namelist
311      !!                generate an iceberg in one class determined by the value of
312      !!                parameter nn_test_icebergs
313      !!----------------------------------------------------------------------
314      INTEGER                         ::   ji, jj, ibergs
315      TYPE(iceberg)                   ::   localberg ! NOT a pointer but an actual local variable
316      TYPE(point)                     ::   localpt
317      INTEGER                         ::   iyr, imon, iday, ihr, imin, isec
318      INTEGER                         ::   iberg
319      !!----------------------------------------------------------------------
320
321      ! For convenience
322      iberg = nn_test_icebergs
323
324      ! call get_date(Time, iyr, imon, iday, ihr, imin, isec)
325      ! Convert nemo time variables from dom_oce into local versions
326      iyr  = nyear
327      imon = nmonth
328      iday = nday
329      ihr = INT(nsec_day/3600)
330      imin = INT((nsec_day-ihr*3600)/60)
331      isec = nsec_day - ihr*3600 - imin*60
332
333      ! no overlap for icebergs since we want only one instance of each across the whole domain
334      ! so restrict area of interest
335      ! use tmask here because tmask_i has been doctored on one side of the north fold line
336
337      DO jj = nicbdj, nicbej
338         DO ji = nicbdi, nicbei
339            IF( tmask(ji,jj,1) > 0._wp        .AND.                                       &
340                rn_test_box(1) < glamt(ji,jj) .AND. glamt(ji,jj) < rn_test_box(2) .AND.   &
341                rn_test_box(3) < gphit(ji,jj) .AND. gphit(ji,jj) < rn_test_box(4) ) THEN
342               localberg%mass_scaling = rn_mass_scaling(iberg)
343               localpt%xi = REAL( mig(ji), wp )
344               localpt%yj = REAL( mjg(jj), wp )
345               localpt%lon = icb_utl_bilin(glamt, localpt%xi, localpt%yj, 'T' )
346               localpt%lat = icb_utl_bilin(gphit, localpt%xi, localpt%yj, 'T' )
347               localpt%mass      = rn_initial_mass     (iberg)
348               localpt%thickness = rn_initial_thickness(iberg)
349               localpt%width  = first_width (iberg)
350               localpt%length = first_length(iberg)
351               localpt%year = iyr
352               localpt%day = REAL(iday,wp)+(REAL(ihr,wp)+REAL(imin,wp)/60._wp)/24._wp
353               localpt%mass_of_bits = 0._wp
354               localpt%heat_density = 0._wp
355               localpt%uvel = 0._wp
356               localpt%vvel = 0._wp
357               CALL icb_utl_incr()
358               localberg%number(:) = num_bergs(:)
359               call icb_utl_add(localberg, localpt)
360            ENDIF
361         END DO
362      END DO
363      !
364      ibergs = icb_utl_count()
365      CALL mpp_sum('icbini', ibergs)
366      IF( nn_verbose_level > 0) THEN
367         WRITE(numicb,'(a,i6,a)') 'diamonds, icb_ini_gen: ',ibergs,' were generated'
368      ENDIF
369      !
370   END SUBROUTINE icb_ini_gen
371
372
373   SUBROUTINE icb_nam
374      !!----------------------------------------------------------------------
375      !!                     ***  ROUTINE icb_nam  ***
376      !!
377      !! ** Purpose :   read iceberg namelist and print the variables.
378      !!
379      !! ** input   : - namberg namelist
380      !!----------------------------------------------------------------------
381      INTEGER  ::   jn      ! dummy loop indices
382      INTEGER  ::   ios     ! Local integer output status for namelist read
383      REAL(wp) ::   zfact   ! local scalar
384      !
385      NAMELIST/namberg/ ln_icebergs    , ln_bergdia     , nn_sample_rate      , rn_initial_mass      ,   &
386         &              rn_distribution, rn_mass_scaling, rn_initial_thickness, nn_verbose_write     ,   &
387         &              rn_rho_bergs   , rn_LoW_ratio   , nn_verbose_level    , ln_operator_splitting,   &
388         &              rn_bits_erosion_fraction        , rn_sicn_shift       , ln_passive_mode      ,   &
389         &              ln_time_average_weight          , nn_test_icebergs    , rn_test_box          ,   &
390         &              ln_use_calving , rn_speed_limit , cn_dir, sn_icb      ,                          &
391         &              cn_icbrst_indir, cn_icbrst_in   , cn_icbrst_outdir    , cn_icbrst_out
392      !!----------------------------------------------------------------------
393
394#if defined key_agrif
395      IF(lwp) THEN
396         WRITE(numout,*)
397         WRITE(numout,*) 'icb_nam : AGRIF is not compatible with namelist namberg :  '
398         WRITE(numout,*) '~~~~~~~   definition of rn_initial_mass(nclasses) with nclasses as PARAMETER '
399         WRITE(numout,*)
400         WRITE(numout,*) '   ==>>>   force  NO icebergs used. The namelist namberg is not read'
401      ENDIF
402      ln_icebergs = .false.     
403      RETURN
404#else
405      IF(lwp) THEN
406         WRITE(numout,*)
407         WRITE(numout,*) 'icb_nam : iceberg initialization through namberg namelist read'
408         WRITE(numout,*) '~~~~~~~~ '
409      ENDIF
410#endif   
411      !                             !==  read namelist  ==!
412      READ  ( numnam_ref, namberg, IOSTAT = ios, ERR = 901)
413901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namberg in reference namelist' )
414      READ  ( numnam_cfg, namberg, IOSTAT = ios, ERR = 902 )
415902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namberg in configuration namelist' )
416      IF(lwm) WRITE ( numond, namberg )
417      !
418      IF(lwp) WRITE(numout,*)
419      IF( ln_icebergs ) THEN
420         IF(lwp) WRITE(numout,*) '   ==>>>   icebergs are used'
421      ELSE
422         IF(lwp) WRITE(numout,*) '   ==>>>   No icebergs used'
423         RETURN
424      ENDIF
425      !
426      IF( nn_test_icebergs > nclasses ) THEN
427         IF(lwp) WRITE(numout,*)
428         IF(lwp) WRITE(numout,*) '   ==>>>   Resetting of nn_test_icebergs to ', nclasses
429         nn_test_icebergs = nclasses
430      ENDIF
431      !
432      IF( nn_test_icebergs < 0 .AND. .NOT. ln_use_calving ) THEN
433         IF(lwp) WRITE(numout,*)
434         IF(lwp) WRITE(numout,*) '   ==>>>   Resetting ln_use_calving to .true. since we are not using test icebergs'
435         ln_use_calving = .true.
436      ENDIF
437      !
438      IF(lwp) THEN                  ! control print
439         WRITE(numout,*)
440         WRITE(numout,*) 'icb_nam : iceberg initialization through namberg namelist read'
441         WRITE(numout,*) '~~~~~~~~ '
442         WRITE(numout,*) '   Calculate budgets                                            ln_bergdia       = ', ln_bergdia
443         WRITE(numout,*) '   Period between sampling of position for trajectory storage   nn_sample_rate = ', nn_sample_rate
444         WRITE(numout,*) '   Mass thresholds between iceberg classes (kg)                 rn_initial_mass     ='
445         DO jn = 1, nclasses
446            WRITE(numout,'(a,f15.2)') '                                                                ', rn_initial_mass(jn)
447         ENDDO
448         WRITE(numout,*) '   Fraction of calving to apply to this class (non-dim)         rn_distribution     ='
449         DO jn = 1, nclasses
450            WRITE(numout,'(a,f10.4)') '                                                                ', rn_distribution(jn)
451         END DO
452         WRITE(numout,*) '   Ratio between effective and real iceberg mass (non-dim)      rn_mass_scaling     = '
453         DO jn = 1, nclasses
454            WRITE(numout,'(a,f10.2)') '                                                                ', rn_mass_scaling(jn)
455         END DO
456         WRITE(numout,*) '   Total thickness of newly calved bergs (m)                    rn_initial_thickness = '
457         DO jn = 1, nclasses
458            WRITE(numout,'(a,f10.2)') '                                                                ', rn_initial_thickness(jn)
459         END DO
460         WRITE(numout,*) '   Timesteps between verbose messages                           nn_verbose_write    = ', nn_verbose_write
461
462         WRITE(numout,*) '   Density of icebergs                           rn_rho_bergs  = ', rn_rho_bergs
463         WRITE(numout,*) '   Initial ratio L/W for newly calved icebergs   rn_LoW_ratio  = ', rn_LoW_ratio
464         WRITE(numout,*) '   Turn on more verbose output                          level  = ', nn_verbose_level
465         WRITE(numout,*) '   Use first order operator splitting for thermodynamics    ',   &
466            &                    'use_operator_splitting = ', ln_operator_splitting
467         WRITE(numout,*) '   Fraction of erosion melt flux to divert to bergy bits    ',   &
468            &                    'bits_erosion_fraction = ', rn_bits_erosion_fraction
469
470         WRITE(numout,*) '   Shift of sea-ice concentration in erosion flux modulation ',   &
471            &                    '(0<sicn_shift<1)    rn_sicn_shift  = ', rn_sicn_shift
472         WRITE(numout,*) '   Do not add freshwater flux from icebergs to ocean                ',   &
473            &                    '                  passive_mode            = ', ln_passive_mode
474         WRITE(numout,*) '   Time average the weight on the ocean   time_average_weight       = ', ln_time_average_weight
475         WRITE(numout,*) '   Create icebergs in absence of a restart file   nn_test_icebergs  = ', nn_test_icebergs
476         WRITE(numout,*) '                   in lon/lat box                                   = ', rn_test_box
477         WRITE(numout,*) '   Use calving data even if nn_test_icebergs > 0    ln_use_calving  = ', ln_use_calving
478         WRITE(numout,*) '   CFL speed limit for a berg            speed_limit                = ', rn_speed_limit
479         WRITE(numout,*) '   Writing Iceberg status information to icebergs.stat file        '
480      ENDIF
481      !
482      ! ensure that the sum of berg input distribution is equal to one
483      zfact = SUM( rn_distribution )
484      IF( zfact /= 1._wp .AND. 0_wp /= zfact ) THEN
485         rn_distribution(:) = rn_distribution(:) / zfact
486         IF(lwp) THEN
487            WRITE(numout,*)
488            WRITE(numout,*) '      ==>>> CAUTION:    sum of berg input distribution = ', zfact
489            WRITE(numout,*) '            *******     redistribution has been rescaled'
490            WRITE(numout,*) '                        updated berg distribution is :'
491            DO jn = 1, nclasses
492               WRITE(numout,'(a,f10.4)') '                                   ',rn_distribution(jn)
493            END DO
494         ENDIF
495      ENDIF
496      IF( MINVAL( rn_distribution(:) ) < 0._wp ) THEN
497         CALL ctl_stop( 'icb_nam: a negative rn_distribution value encountered ==>> change your namelist namberg' )
498      ENDIF
499      !
500   END SUBROUTINE icb_nam
501
502   !!======================================================================
503END MODULE icbini
Note: See TracBrowser for help on using the repository browser.