New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
isfcav.F90 in NEMO/branches/2020/dev_r13296_HPC-07_mocavero_mpi3/src/OCE/ISF – NEMO

source: NEMO/branches/2020/dev_r13296_HPC-07_mocavero_mpi3/src/OCE/ISF/isfcav.F90 @ 13630

Last change on this file since 13630 was 13630, checked in by mocavero, 4 years ago

Add neighborhood collectives calls in the NEMO src - ticket #2496
File size: 10.3 KB
Line 
1MODULE isfcav
2   !!======================================================================
3   !!                       ***  MODULE  isfcav  ***
4   !! Ice shelf cavity module :  update ice shelf melting under ice
5   !!                            shelf
6   !!======================================================================
7   !! History :  3.2  !  2011-02  (C.Harris  ) Original code isf cav
8   !!            3.4  !  2013-03  (P. Mathiot) Merging + parametrization
9   !!            4.1  !  2019-09  (P. Mathiot) Split ice shelf cavity and ice shelf parametrisation
10   !!----------------------------------------------------------------------
11
12   !!----------------------------------------------------------------------
13   !!   isf_cav       : update ice shelf melting under ice shelf
14   !!----------------------------------------------------------------------
15   USE isf_oce        ! ice shelf public variables
16   !
17   USE isfrst   , ONLY: isfrst_write, isfrst_read ! ice shelf restart read/write subroutine
18   USE isfutils , ONLY: debug          ! ice shelf debug subroutine
19   USE isftbl   , ONLY: isf_tbl        ! ice shelf top boundary layer properties subroutine
20   USE isfcavmlt, ONLY: isfcav_mlt     ! ice shelf melt formulation subroutine
21   USE isfcavgam, ONLY: isfcav_gammats ! ice shelf melt exchange coeficient subroutine
22   USE isfdiags , ONLY: isf_diags_flx  ! ice shelf diags subroutine
23   !
24   USE oce      , ONLY: ts                              ! ocean tracers
25   USE par_oce  , ONLY: jpi,jpj                         ! ocean space and time domain
26   USE phycst   , ONLY: grav,rho0,rho0_rcp,r1_rho0_rcp  ! physical constants
27   USE eosbn2   , ONLY: ln_teos10                       ! use ln_teos10 or not
28   !
29   USE in_out_manager ! I/O manager
30   USE iom            ! I/O library
31   USE fldread        ! read input field at current time step
32   USE lbclnk         ! lbclnk
33
34   IMPLICIT NONE
35
36   PRIVATE
37
38   PUBLIC   isf_cav, isf_cav_init ! routine called in isfmlt
39
40   !!----------------------------------------------------------------------
41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
42   !! $Id: sbcisf.F90 10536 2019-01-16 19:21:09Z mathiot $
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE isf_cav( kt, Kmm, ptsc, pqfwf )
48      !!---------------------------------------------------------------------
49      !!                     ***  ROUTINE isf_cav  ***
50      !!
51      !! ** Purpose :   handle surface boundary condition under ice shelf
52      !!
53      !! ** Method  :   based on Mathiot et al. (2017)
54      !!
55      !! ** Action  :   - compute geometry of the Losch top bournary layer (see Losch et al. 2008)
56      !!                - depending on the chooses option
57      !!                   - compute temperature/salt in the tbl
58      !!                   - compute exchange coeficient
59      !!                   - compute heat and fwf fluxes
60      !!                   - output
61      !!---------------------------------------------------------------------
62      !!-------------------------- OUT --------------------------------------
63      REAL(wp), DIMENSION(jpi,jpj)     , INTENT(inout) :: pqfwf  ! ice shelf melt (>0 out)
64      REAL(wp), DIMENSION(jpi,jpj,jpts), INTENT(inout) :: ptsc   ! T & S ice shelf cavity contents
65      !!-------------------------- IN  --------------------------------------
66      INTEGER, INTENT(in) ::   Kmm  ! ocean time level index
67      INTEGER, INTENT(in) ::   kt   ! ocean time step
68      !!---------------------------------------------------------------------
69      LOGICAL :: lit
70      INTEGER :: nit
71      REAL(wp) :: zerr
72      REAL(wp), DIMENSION(jpi,jpj) :: zqlat, zqoce, zqhc, zqh  ! heat fluxes
73      REAL(wp), DIMENSION(jpi,jpj) :: zqoce_b                  !
74      REAL(wp), DIMENSION(jpi,jpj) :: zgammat, zgammas         ! exchange coeficient
75      REAL(wp), DIMENSION(jpi,jpj) :: zttbl, zstbl             ! temp. and sal. in top boundary layer
76      !!---------------------------------------------------------------------
77      !
78      ! compute T/S/U/V for the top boundary layer
79      CALL isf_tbl(Kmm, ts(:,:,:,jp_tem,Kmm), zttbl(:,:),'T', misfkt_cav, rhisf_tbl_cav, misfkb_cav, rfrac_tbl_cav )
80      CALL isf_tbl(Kmm, ts(:,:,:,jp_sal,Kmm), zstbl(:,:),'T', misfkt_cav, rhisf_tbl_cav, misfkb_cav, rfrac_tbl_cav )
81      !
82      ! output T/S/U/V for the top boundary layer
83      CALL iom_put('ttbl_cav',zttbl(:,:) * mskisf_cav(:,:))
84      CALL iom_put('stbl'    ,zstbl(:,:) * mskisf_cav(:,:))
85      !
86      ! initialisation
87      IF (TRIM(cn_gammablk) == 'vel_stab' ) zqoce_b (:,:) = ptsc(:,:,jp_tem) * rho0_rcp ! last time step total heat fluxes (to speed up convergence)
88      !
89      ! compute ice shelf melting
90      nit = 1 ; lit = .TRUE.
91      DO WHILE ( lit )    ! maybe just a constant number of iteration as in blk_core is fine
92         !
93         ! compute gammat everywhere (2d)
94         ! useless if melt specified
95         IF ( TRIM(cn_isfcav_mlt) .NE. 'spe' ) THEN
96            CALL isfcav_gammats( Kmm, zttbl, zstbl, zqoce  , pqfwf,  &
97               &                                    zgammat, zgammas )
98         END IF
99         !   
100         ! compute tfrz, latent heat and melt (2d)
101         CALL isfcav_mlt(kt, zgammat, zgammas, zttbl, zstbl, &
102            &                         zqhc   , zqoce, pqfwf  )
103         !
104         ! define if we need to iterate
105         SELECT CASE ( cn_gammablk )
106         CASE ( 'spe','vel' )
107            ! no convergence needed
108            lit = .FALSE.
109         CASE ( 'vel_stab' )
110            ! compute error between 2 iterations
111            zerr = MAXVAL(ABS(zqoce(:,:) - zqoce_b(:,:)))
112            !
113            ! define if iteration needed
114            IF (nit >= 100) THEN              ! too much iteration
115               CALL ctl_stop( 'STOP', 'isf_cav: vel_stab gamma formulation had too many iterations ...' )
116            ELSE IF ( zerr <= 0.01_wp ) THEN  ! convergence is achieve
117               lit = .FALSE.
118            ELSE                              ! converge is not yet achieve
119               nit = nit + 1
120               zqoce_b(:,:) = zqoce(:,:)
121            END IF
122         END SELECT
123         !
124      END DO
125      !
126      ! compute heat and water flux ( > 0 out )
127      pqfwf(:,:) = pqfwf(:,:) * mskisf_cav(:,:)
128      zqoce(:,:) = zqoce(:,:) * mskisf_cav(:,:)
129      zqhc (:,:) = zqhc(:,:)  * mskisf_cav(:,:)
130      !
131      ! compute heat content flux ( > 0 out )
132      zqlat(:,:) = - pqfwf(:,:) * rLfusisf    ! 2d latent heat flux (W/m2)
133      !
134      ! total heat flux ( >0 out )
135      zqh(:,:) = ( zqhc (:,:) + zqoce(:,:) )
136      !
137      ! lbclnk on melt
138#if defined key_mpi3
139      CALL lbc_lnk_nc_multi( 'isfmlt', zqh, 'T', 1.0_wp, pqfwf, 'T', 1.0_wp)
140#else
141      CALL lbc_lnk_multi( 'isfmlt', zqh, 'T', 1.0_wp, pqfwf, 'T', 1.0_wp)
142#endif
143      !
144      ! output fluxes
145      CALL isf_diags_flx( Kmm, misfkt_cav, misfkb_cav, rhisf_tbl_cav, rfrac_tbl_cav, 'cav', pqfwf, zqoce, zqlat, zqhc)
146      !
147      ! set temperature content
148      ptsc(:,:,jp_tem) = - zqh(:,:) * r1_rho0_rcp
149      !
150      ! write restart variables (qoceisf, qhcisf, fwfisf for now and before)
151      IF (lrst_oce) CALL isfrst_write(kt, 'cav', ptsc, pqfwf)
152      !
153      IF ( ln_isfdebug ) THEN
154         CALL debug('isf_cav: ptsc T',ptsc(:,:,1))
155         CALL debug('isf_cav: ptsc S',ptsc(:,:,2))
156         CALL debug('isf_cav: pqfwf fwf',pqfwf(:,:))
157      END IF
158      !
159   END SUBROUTINE isf_cav
160
161   SUBROUTINE isf_cav_init
162      !!---------------------------------------------------------------------
163      !!                  ***  ROUTINE isf_cav_init ***
164      !!
165      !! ** Purpose : initialisation of variable needed to compute melt under an ice shelf
166      !!
167      !!----------------------------------------------------------------------
168      INTEGER :: ierr
169      !!---------------------------------------------------------------------
170      !
171      !==============
172      ! 0: allocation
173      !==============
174      !
175      CALL isf_alloc_cav()
176      !
177      !==================
178      ! 1: initialisation
179      !==================
180      !
181      ! top and bottom level of the 'top boundary layer'
182      misfkt_cav(:,:)    = mikt(:,:) ; misfkb_cav(:,:)    = 1
183      !
184      ! thickness of 'tbl' and fraction of bottom cell affected by 'tbl'
185      rhisf_tbl_cav(:,:) = 0.0_wp    ; rfrac_tbl_cav(:,:) = 0.0_wp
186      !
187      ! cavity mask
188      mskisf_cav(:,:)    = (1._wp - tmask(:,:,1)) * ssmask(:,:)
189      !
190      !================
191      ! 2: read restart
192      !================
193      !
194      ! read cav variable from restart
195      IF ( ln_rstart ) CALL isfrst_read('cav', risf_cav_tsc, fwfisf_cav, risf_cav_tsc_b, fwfisf_cav_b)
196      !
197      !==========================================
198      ! 3: specific allocation and initialisation (depending of scheme choice)
199      !==========================================
200      !
201      SELECT CASE ( TRIM(cn_isfcav_mlt) )
202      CASE( 'spe' )
203
204         ALLOCATE( sf_isfcav_fwf(1), STAT=ierr )
205         ALLOCATE( sf_isfcav_fwf(1)%fnow(jpi,jpj,1), sf_isfcav_fwf(1)%fdta(jpi,jpj,1,2) )
206         CALL fld_fill( sf_isfcav_fwf, (/ sn_isfcav_fwf /), cn_isfdir, 'isf_cav_init', 'read fresh water flux isf data', 'namisf' )
207
208         IF(lwp) WRITE(numout,*)
209         IF(lwp) WRITE(numout,*) '  ==>> The ice shelf melt inside the cavity is read from forcing files'
210
211      CASE( '2eq' )
212         IF(lwp) WRITE(numout,*)
213         IF(lwp) WRITE(numout,*) '  ==>> The original ISOMIP melt formulation is used to compute melt under the ice shelves'
214
215      CASE( '3eq' )
216         ! coeficient for linearisation of potential tfreez
217         ! Crude approximation for pressure (but commonly used)
218         IF ( ln_teos10 ) THEN   ! linearisation from Jourdain et al. (2017)
219            risf_lamb1 =-0.0564_wp
220            risf_lamb2 = 0.0773_wp
221            risf_lamb3 =-7.8633e-8 * grav * rho0
222         ELSE                  ! linearisation from table 4 (Asay-Davis et al., 2015)
223            risf_lamb1 =-0.0573_wp
224            risf_lamb2 = 0.0832_wp
225            risf_lamb3 =-7.5300e-8 * grav * rho0
226         ENDIF
227
228         IF(lwp) WRITE(numout,*)
229         IF(lwp) WRITE(numout,*) '  ==>> The 3 equations melt formulation is used to compute melt under the ice shelves'
230
231      CASE DEFAULT
232         CALL ctl_stop(' cn_isfcav_mlt method unknown (spe, 2eq, 3eq), check namelist')
233      END SELECT
234      !
235   END SUBROUTINE isf_cav_init
236
237END MODULE isfcav
Note: See TracBrowser for help on using the repository browser.