New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynzdf.F90 in NEMO/branches/2020/dev_r13333_KERNEL-08_techene_gm_HPG_SPG/src/OCE/DYN – NEMO

source: NEMO/branches/2020/dev_r13333_KERNEL-08_techene_gm_HPG_SPG/src/OCE/DYN/dynzdf.F90 @ 13362

Last change on this file since 13362 was 13295, checked in by acc, 4 years ago

Replace do-loop macros in the trunk with alternative forms with greater flexibility for extra halo applications. This alters a lot of routines but does not change any behaviour or results. do_loop_substitute.h90 is greatly simplified by this change. SETTE results are identical to those with the previous revision

  • Property svn:keywords set to Id
File size: 24.5 KB
Line 
1MODULE dynzdf
2   !!==============================================================================
3   !!                 ***  MODULE  dynzdf  ***
4   !! Ocean dynamics :  vertical component of the momentum mixing trend
5   !!==============================================================================
6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase
8   !!            4.0  !  2017-06  (G. Madec) remove the explicit time-stepping option + avm at t-point
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   dyn_zdf       : compute the after velocity through implicit calculation of vertical mixing
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE phycst         ! physical constants
16   USE dom_oce        ! ocean space and time domain variables
17   USE sbc_oce        ! surface boundary condition: ocean
18   USE zdf_oce        ! ocean vertical physics variables
19   USE zdfdrg         ! vertical physics: top/bottom drag coef.
20   USE dynadv    ,ONLY: ln_dynadv_vec    ! dynamics: advection form
21   USE dynldf_iso,ONLY: akzu, akzv       ! dynamics: vertical component of rotated lateral mixing
22   USE ldfdyn         ! lateral diffusion: eddy viscosity coef. and type of operator
23   USE trd_oce        ! trends: ocean variables
24   USE trddyn         ! trend manager: dynamics
25   !
26   USE in_out_manager ! I/O manager
27   USE lib_mpp        ! MPP library
28   USE prtctl         ! Print control
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   dyn_zdf   !  routine called by step.F90
35
36   REAL(wp) ::  r_vvl     ! non-linear free surface indicator: =0 if ln_linssh=T, =1 otherwise
37
38   !! * Substitutions
39#  include "do_loop_substitute.h90"
40#  include "domzgr_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47   
48   SUBROUTINE dyn_zdf( kt, Kbb, Kmm, Krhs, puu, pvv, Kaa )
49      !!----------------------------------------------------------------------
50      !!                  ***  ROUTINE dyn_zdf  ***
51      !!
52      !! ** Purpose :   compute the trend due to the vert. momentum diffusion
53      !!              together with the Leap-Frog time stepping using an
54      !!              implicit scheme.
55      !!
56      !! ** Method  :  - Leap-Frog time stepping on all trends but the vertical mixing
57      !!         u(after) =         u(before) + 2*dt *       u(rhs)                vector form or linear free surf.
58      !!         u(after) = ( e3u_b*u(before) + 2*dt * e3u_n*u(rhs) ) / e3u_after   otherwise
59      !!               - update the after velocity with the implicit vertical mixing.
60      !!      This requires to solver the following system:
61      !!         u(after) = u(after) + 1/e3u_after  dk+1[ mi(avm) / e3uw_after dk[ua] ]
62      !!      with the following surface/top/bottom boundary condition:
63      !!      surface: wind stress input (averaged over kt-1/2 & kt+1/2)
64      !!      top & bottom : top stress (iceshelf-ocean) & bottom stress (cf zdfdrg.F90)
65      !!
66      !! ** Action :   (puu(:,:,:,Kaa),pvv(:,:,:,Kaa))   after velocity
67      !!---------------------------------------------------------------------
68      INTEGER                             , INTENT( in )  ::  kt                  ! ocean time-step index
69      INTEGER                             , INTENT( in )  ::  Kbb, Kmm, Krhs, Kaa ! ocean time level indices
70      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv            ! ocean velocities and RHS of momentum equation
71      !
72      INTEGER  ::   ji, jj, jk         ! dummy loop indices
73      INTEGER  ::   iku, ikv           ! local integers
74      REAL(wp) ::   zzwi, ze3ua, zdt   ! local scalars
75      REAL(wp) ::   zzws, ze3va        !   -      -
76      REAL(wp) ::   z1_e3ua, z1_e3va   !   -      -
77      REAL(wp) ::   zWu , zWv          !   -      -
78      REAL(wp) ::   zWui, zWvi         !   -      -
79      REAL(wp) ::   zWus, zWvs         !   -      -
80      REAL(wp), DIMENSION(jpi,jpj,jpk)        ::  zwi, zwd, zws   ! 3D workspace
81      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdu, ztrdv   !  -      -
82      !!---------------------------------------------------------------------
83      !
84      IF( ln_timing )   CALL timing_start('dyn_zdf')
85      !
86      IF( kt == nit000 ) THEN       !* initialization
87         IF(lwp) WRITE(numout,*)
88         IF(lwp) WRITE(numout,*) 'dyn_zdf_imp : vertical momentum diffusion implicit operator'
89         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
90         !
91         If( ln_linssh ) THEN   ;    r_vvl = 0._wp    ! non-linear free surface indicator
92         ELSE                   ;    r_vvl = 1._wp
93         ENDIF
94      ENDIF
95      !                             !* explicit top/bottom drag case
96      IF( .NOT.ln_drgimp )   CALL zdf_drg_exp( kt, Kmm, puu(:,:,:,Kbb), pvv(:,:,:,Kbb), puu(:,:,:,Krhs), pvv(:,:,:,Krhs) )  ! add top/bottom friction trend to (puu(Kaa),pvv(Kaa))
97      !
98      !
99      IF( l_trddyn )   THEN         !* temporary save of ta and sa trends
100         ALLOCATE( ztrdu(jpi,jpj,jpk), ztrdv(jpi,jpj,jpk) ) 
101         ztrdu(:,:,:) = puu(:,:,:,Krhs)
102         ztrdv(:,:,:) = pvv(:,:,:,Krhs)
103      ENDIF
104      !
105      !              !==  RHS: Leap-Frog time stepping on all trends but the vertical mixing  ==!   (put in puu(:,:,:,Kaa),pvv(:,:,:,Kaa))
106      !
107      !                    ! time stepping except vertical diffusion
108      IF( ln_dynadv_vec .OR. ln_linssh ) THEN   ! applied on velocity
109         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
110            puu(ji,jj,jk,Kaa) = ( puu(ji,jj,jk,Kbb) + rDt * puu(ji,jj,jk,Krhs) ) * umask(ji,jj,jk)
111            pvv(ji,jj,jk,Kaa) = ( pvv(ji,jj,jk,Kbb) + rDt * pvv(ji,jj,jk,Krhs) ) * vmask(ji,jj,jk)
112         END_3D
113      ELSE                                      ! applied on thickness weighted velocity
114         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
115            puu(ji,jj,jk,Kaa) = (         e3u(ji,jj,jk,Kbb) * puu(ji,jj,jk,Kbb )  &
116               &                  + rDt * e3u(ji,jj,jk,Kmm) * puu(ji,jj,jk,Krhs)  ) &
117               &                        / e3u(ji,jj,jk,Kaa) * umask(ji,jj,jk)
118            pvv(ji,jj,jk,Kaa) = (         e3v(ji,jj,jk,Kbb) * pvv(ji,jj,jk,Kbb )  &
119               &                  + rDt * e3v(ji,jj,jk,Kmm) * pvv(ji,jj,jk,Krhs)  ) &
120               &                        / e3v(ji,jj,jk,Kaa) * vmask(ji,jj,jk)
121         END_3D
122      ENDIF
123      !                    ! add top/bottom friction
124      !     With split-explicit free surface, barotropic stress is treated explicitly Update velocities at the bottom.
125      !     J. Chanut: The bottom stress is computed considering after barotropic velocities, which does
126      !                not lead to the effective stress seen over the whole barotropic loop.
127      !     G. Madec : in linear free surface, e3u(:,:,:,Kaa) = e3u(:,:,:,Kmm) = e3u_0, so systematic use of e3u(:,:,:,Kaa)
128      IF( ln_drgimp .AND. ln_dynspg_ts ) THEN
129         DO_3D( 0, 0, 0, 0, 1, jpkm1 )      ! remove barotropic velocities
130            puu(ji,jj,jk,Kaa) = ( puu(ji,jj,jk,Kaa) - uu_b(ji,jj,Kaa) ) * umask(ji,jj,jk)
131            pvv(ji,jj,jk,Kaa) = ( pvv(ji,jj,jk,Kaa) - vv_b(ji,jj,Kaa) ) * vmask(ji,jj,jk)
132         END_3D
133         DO_2D( 0, 0, 0, 0 )
134            iku = mbku(ji,jj)         ! ocean bottom level at u- and v-points
135            ikv = mbkv(ji,jj)         ! (deepest ocean u- and v-points)
136            ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,iku,Kmm)    &
137               &             + r_vvl   * e3u(ji,jj,iku,Kaa)
138            ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,ikv,Kmm)    &
139               &             + r_vvl   * e3v(ji,jj,ikv,Kaa)
140            puu(ji,jj,iku,Kaa) = puu(ji,jj,iku,Kaa) + rDt * 0.5*( rCdU_bot(ji+1,jj)+rCdU_bot(ji,jj) ) * uu_b(ji,jj,Kaa) / ze3ua
141            pvv(ji,jj,ikv,Kaa) = pvv(ji,jj,ikv,Kaa) + rDt * 0.5*( rCdU_bot(ji,jj+1)+rCdU_bot(ji,jj) ) * vv_b(ji,jj,Kaa) / ze3va
142         END_2D
143         IF( ln_isfcav ) THEN    ! Ocean cavities (ISF)
144            DO_2D( 0, 0, 0, 0 )
145               iku = miku(ji,jj)         ! top ocean level at u- and v-points
146               ikv = mikv(ji,jj)         ! (first wet ocean u- and v-points)
147               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,iku,Kmm)    &
148                  &             + r_vvl   * e3u(ji,jj,iku,Kaa)
149               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,ikv,Kmm)    &
150                  &             + r_vvl   * e3v(ji,jj,ikv,Kaa)
151               puu(ji,jj,iku,Kaa) = puu(ji,jj,iku,Kaa) + rDt * 0.5*( rCdU_top(ji+1,jj)+rCdU_top(ji,jj) ) * uu_b(ji,jj,Kaa) / ze3ua
152               pvv(ji,jj,ikv,Kaa) = pvv(ji,jj,ikv,Kaa) + rDt * 0.5*( rCdU_top(ji,jj+1)+rCdU_top(ji,jj) ) * vv_b(ji,jj,Kaa) / ze3va
153            END_2D
154         END IF
155      ENDIF
156      !
157      !              !==  Vertical diffusion on u  ==!
158      !
159      !                    !* Matrix construction
160      zdt = rDt * 0.5
161      IF( ln_zad_Aimp ) THEN   !!
162         SELECT CASE( nldf_dyn )
163         CASE( np_lap_i )           ! rotated lateral mixing: add its vertical mixing (akzu)
164            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
165               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,jk,Kmm)    &
166                  &             + r_vvl   * e3u(ji,jj,jk,Kaa)   ! after scale factor at U-point
167               zzwi = - zdt * ( avm(ji+1,jj,jk  ) + avm(ji,jj,jk  ) + akzu(ji,jj,jk  ) )   &
168                  &         / ( ze3ua * e3uw(ji,jj,jk  ,Kmm) ) * wumask(ji,jj,jk  )
169               zzws = - zdt * ( avm(ji+1,jj,jk+1) + avm(ji,jj,jk+1) + akzu(ji,jj,jk+1) )   &
170                  &         / ( ze3ua * e3uw(ji,jj,jk+1,Kmm) ) * wumask(ji,jj,jk+1)
171               zWui = ( wi(ji,jj,jk  ) + wi(ji+1,jj,jk  ) ) / ze3ua
172               zWus = ( wi(ji,jj,jk+1) + wi(ji+1,jj,jk+1) ) / ze3ua
173               zwi(ji,jj,jk) = zzwi + zdt * MIN( zWui, 0._wp ) 
174               zws(ji,jj,jk) = zzws - zdt * MAX( zWus, 0._wp )
175               zwd(ji,jj,jk) = 1._wp - zzwi - zzws + zdt * ( MAX( zWui, 0._wp ) - MIN( zWus, 0._wp ) )
176            END_3D
177         CASE DEFAULT               ! iso-level lateral mixing
178            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
179               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,jk,Kmm)    &    ! after scale factor at U-point
180                  &             + r_vvl   * e3u(ji,jj,jk,Kaa)
181               zzwi = - zdt * ( avm(ji+1,jj,jk  ) + avm(ji,jj,jk  ) )   &
182                  &         / ( ze3ua * e3uw(ji,jj,jk  ,Kmm) ) * wumask(ji,jj,jk  )
183               zzws = - zdt * ( avm(ji+1,jj,jk+1) + avm(ji,jj,jk+1) )   &
184                  &         / ( ze3ua * e3uw(ji,jj,jk+1,Kmm) ) * wumask(ji,jj,jk+1)
185               zWui = ( wi(ji,jj,jk  ) + wi(ji+1,jj,jk  ) ) / ze3ua
186               zWus = ( wi(ji,jj,jk+1) + wi(ji+1,jj,jk+1) ) / ze3ua
187               zwi(ji,jj,jk) = zzwi + zdt * MIN( zWui, 0._wp )
188               zws(ji,jj,jk) = zzws - zdt * MAX( zWus, 0._wp )
189               zwd(ji,jj,jk) = 1._wp - zzwi - zzws + zdt * ( MAX( zWui, 0._wp ) - MIN( zWus, 0._wp ) )
190            END_3D
191         END SELECT
192         DO_2D( 0, 0, 0, 0 )
193            zwi(ji,jj,1) = 0._wp
194            ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,1,Kmm)    &
195               &             + r_vvl   * e3u(ji,jj,1,Kaa)
196            zzws = - zdt * ( avm(ji+1,jj,2) + avm(ji  ,jj,2) )   &
197               &         / ( ze3ua * e3uw(ji,jj,2,Kmm) ) * wumask(ji,jj,2)
198            zWus = ( wi(ji  ,jj,2) +  wi(ji+1,jj,2) ) / ze3ua
199            zws(ji,jj,1 ) = zzws - zdt * MAX( zWus, 0._wp )
200            zwd(ji,jj,1 ) = 1._wp - zzws - zdt * ( MIN( zWus, 0._wp ) )
201         END_2D
202      ELSE
203         SELECT CASE( nldf_dyn )
204         CASE( np_lap_i )           ! rotated lateral mixing: add its vertical mixing (akzu)
205            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
206               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,jk,Kmm)    &
207                  &             + r_vvl   * e3u(ji,jj,jk,Kaa)   ! after scale factor at U-point
208               zzwi = - zdt * ( avm(ji+1,jj,jk  ) + avm(ji,jj,jk  ) + akzu(ji,jj,jk  ) )   &
209                  &         / ( ze3ua * e3uw(ji,jj,jk  ,Kmm) ) * wumask(ji,jj,jk  )
210               zzws = - zdt * ( avm(ji+1,jj,jk+1) + avm(ji,jj,jk+1) + akzu(ji,jj,jk+1) )   &
211                  &         / ( ze3ua * e3uw(ji,jj,jk+1,Kmm) ) * wumask(ji,jj,jk+1)
212               zwi(ji,jj,jk) = zzwi
213               zws(ji,jj,jk) = zzws
214               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
215            END_3D
216         CASE DEFAULT               ! iso-level lateral mixing
217            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
218               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,jk,Kmm)    &
219                  &             + r_vvl   * e3u(ji,jj,jk,Kaa)   ! after scale factor at U-point
220               zzwi = - zdt * ( avm(ji+1,jj,jk  ) + avm(ji,jj,jk  ) )    &
221                  &         / ( ze3ua * e3uw(ji,jj,jk  ,Kmm) ) * wumask(ji,jj,jk  )
222               zzws = - zdt * ( avm(ji+1,jj,jk+1) + avm(ji,jj,jk+1) )    &
223                  &         / ( ze3ua * e3uw(ji,jj,jk+1,Kmm) ) * wumask(ji,jj,jk+1)
224               zwi(ji,jj,jk) = zzwi
225               zws(ji,jj,jk) = zzws
226               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
227            END_3D
228         END SELECT
229         DO_2D( 0, 0, 0, 0 )
230            zwi(ji,jj,1) = 0._wp
231            zwd(ji,jj,1) = 1._wp - zws(ji,jj,1)
232         END_2D
233      ENDIF
234      !
235      !
236      !              !==  Apply semi-implicit bottom friction  ==!
237      !
238      !     Only needed for semi-implicit bottom friction setup. The explicit
239      !     bottom friction has been included in "u(v)a" which act as the R.H.S
240      !     column vector of the tri-diagonal matrix equation
241      !
242      IF ( ln_drgimp ) THEN      ! implicit bottom friction
243         DO_2D( 0, 0, 0, 0 )
244            iku = mbku(ji,jj)       ! ocean bottom level at u- and v-points
245            ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,iku,Kmm)    &
246               &             + r_vvl   * e3u(ji,jj,iku,Kaa)   ! after scale factor at T-point
247            zwd(ji,jj,iku) = zwd(ji,jj,iku) - rDt * 0.5*( rCdU_bot(ji+1,jj)+rCdU_bot(ji,jj) ) / ze3ua
248         END_2D
249         IF ( ln_isfcav ) THEN   ! top friction (always implicit)
250            DO_2D( 0, 0, 0, 0 )
251               !!gm   top Cd is masked (=0 outside cavities) no need of test on mik>=2  ==>> it has been suppressed
252               iku = miku(ji,jj)       ! ocean top level at u- and v-points
253               ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,iku,Kmm)    &
254                  &             + r_vvl   * e3u(ji,jj,iku,Kaa)   ! after scale factor at T-point
255               zwd(ji,jj,iku) = zwd(ji,jj,iku) - rDt * 0.5*( rCdU_top(ji+1,jj)+rCdU_top(ji,jj) ) / ze3ua
256            END_2D
257         END IF
258      ENDIF
259      !
260      ! Matrix inversion starting from the first level
261      !-----------------------------------------------------------------------
262      !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
263      !
264      !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
265      !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
266      !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
267      !        (        ...               )( ...  ) ( ...  )
268      !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
269      !
270      !   m is decomposed in the product of an upper and a lower triangular matrix
271      !   The 3 diagonal terms are in 2d arrays: zwd, zws, zwi
272      !   The solution (the after velocity) is in puu(:,:,:,Kaa)
273      !-----------------------------------------------------------------------
274      !
275      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
276         zwd(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwd(ji,jj,jk-1)
277      END_3D
278      !
279      DO_2D( 0, 0, 0, 0 )
280         ze3ua =  ( 1._wp - r_vvl ) * e3u(ji,jj,1,Kmm)    &
281            &             + r_vvl   * e3u(ji,jj,1,Kaa) 
282         puu(ji,jj,1,Kaa) = puu(ji,jj,1,Kaa) + rDt * 0.5_wp * ( utau_b(ji,jj) + utau(ji,jj) )   &
283            &                                      / ( ze3ua * rho0 ) * umask(ji,jj,1) 
284      END_2D
285      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
286         puu(ji,jj,jk,Kaa) = puu(ji,jj,jk,Kaa) - zwi(ji,jj,jk) / zwd(ji,jj,jk-1) * puu(ji,jj,jk-1,Kaa)
287      END_3D
288      !
289      DO_2D( 0, 0, 0, 0 )
290         puu(ji,jj,jpkm1,Kaa) = puu(ji,jj,jpkm1,Kaa) / zwd(ji,jj,jpkm1)
291      END_2D
292      DO_3DS( 0, 0, 0, 0, jpk-2, 1, -1 )
293         puu(ji,jj,jk,Kaa) = ( puu(ji,jj,jk,Kaa) - zws(ji,jj,jk) * puu(ji,jj,jk+1,Kaa) ) / zwd(ji,jj,jk)
294      END_3D
295      !
296      !              !==  Vertical diffusion on v  ==!
297      !
298      !                       !* Matrix construction
299      zdt = rDt * 0.5
300      IF( ln_zad_Aimp ) THEN   !!
301         SELECT CASE( nldf_dyn )
302         CASE( np_lap_i )           ! rotated lateral mixing: add its vertical mixing (akzv)
303            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
304               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,jk,Kmm)    &
305                  &             + r_vvl   * e3v(ji,jj,jk,Kaa)   ! after scale factor at V-point
306               zzwi = - zdt * ( avm(ji,jj+1,jk  ) + avm(ji,jj,jk  ) + akzv(ji,jj,jk  ) )   &
307                  &         / ( ze3va * e3vw(ji,jj,jk  ,Kmm) ) * wvmask(ji,jj,jk  )
308               zzws = - zdt * ( avm(ji,jj+1,jk+1) + avm(ji,jj,jk+1) + akzv(ji,jj,jk+1) )   &
309                  &         / ( ze3va * e3vw(ji,jj,jk+1,Kmm) ) * wvmask(ji,jj,jk+1)
310               zWvi = ( wi(ji,jj,jk  ) + wi(ji,jj+1,jk  ) ) / ze3va
311               zWvs = ( wi(ji,jj,jk+1) + wi(ji,jj+1,jk+1) ) / ze3va
312               zwi(ji,jj,jk) = zzwi + zdt * MIN( zWvi, 0._wp )
313               zws(ji,jj,jk) = zzws - zdt * MAX( zWvs, 0._wp )
314               zwd(ji,jj,jk) = 1._wp - zzwi - zzws - zdt * ( - MAX( zWvi, 0._wp ) + MIN( zWvs, 0._wp ) )
315            END_3D
316         CASE DEFAULT               ! iso-level lateral mixing
317            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
318               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,jk,Kmm)    &
319                  &             + r_vvl   * e3v(ji,jj,jk,Kaa)   ! after scale factor at V-point
320               zzwi = - zdt * ( avm(ji,jj+1,jk  ) + avm(ji,jj,jk  ) )    &
321                  &         / ( ze3va * e3vw(ji,jj,jk  ,Kmm) ) * wvmask(ji,jj,jk  )
322               zzws = - zdt * ( avm(ji,jj+1,jk+1) + avm(ji,jj,jk+1) )    &
323                  &         / ( ze3va * e3vw(ji,jj,jk+1,Kmm) ) * wvmask(ji,jj,jk+1)
324               zWvi = ( wi(ji,jj,jk  ) + wi(ji,jj+1,jk  ) ) / ze3va
325               zWvs = ( wi(ji,jj,jk+1) + wi(ji,jj+1,jk+1) ) / ze3va
326               zwi(ji,jj,jk) = zzwi  + zdt * MIN( zWvi, 0._wp )
327               zws(ji,jj,jk) = zzws  - zdt * MAX( zWvs, 0._wp )
328               zwd(ji,jj,jk) = 1._wp - zzwi - zzws - zdt * ( - MAX( zWvi, 0._wp ) + MIN( zWvs, 0._wp ) )
329            END_3D
330         END SELECT
331         DO_2D( 0, 0, 0, 0 )
332            zwi(ji,jj,1) = 0._wp
333            ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,1,Kmm)    &
334               &             + r_vvl   * e3v(ji,jj,1,Kaa)
335            zzws = - zdt * ( avm(ji,jj+1,2) + avm(ji,jj,2) )    &
336               &         / ( ze3va * e3vw(ji,jj,2,Kmm) ) * wvmask(ji,jj,2)
337            zWvs = ( wi(ji,jj  ,2) +  wi(ji,jj+1,2) ) / ze3va
338            zws(ji,jj,1 ) = zzws - zdt * MAX( zWvs, 0._wp )
339            zwd(ji,jj,1 ) = 1._wp - zzws - zdt * ( MIN( zWvs, 0._wp ) )
340         END_2D
341      ELSE
342         SELECT CASE( nldf_dyn )
343         CASE( np_lap_i )           ! rotated lateral mixing: add its vertical mixing (akzu)
344            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
345               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,jk,Kmm)    &
346                  &             + r_vvl   * e3v(ji,jj,jk,Kaa)   ! after scale factor at V-point
347               zzwi = - zdt * ( avm(ji,jj+1,jk  ) + avm(ji,jj,jk  ) + akzv(ji,jj,jk  ) )   &
348                  &         / ( ze3va * e3vw(ji,jj,jk  ,Kmm) ) * wvmask(ji,jj,jk  )
349               zzws = - zdt * ( avm(ji,jj+1,jk+1) + avm(ji,jj,jk+1) + akzv(ji,jj,jk+1) )   &
350                  &         / ( ze3va * e3vw(ji,jj,jk+1,Kmm) ) * wvmask(ji,jj,jk+1)
351               zwi(ji,jj,jk) = zzwi
352               zws(ji,jj,jk) = zzws
353               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
354            END_3D
355         CASE DEFAULT               ! iso-level lateral mixing
356            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
357               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,jk,Kmm)    &
358                  &             + r_vvl   * e3v(ji,jj,jk,Kaa)   ! after scale factor at V-point
359               zzwi = - zdt * ( avm(ji,jj+1,jk  ) + avm(ji,jj,jk  ) )    &
360                  &         / ( ze3va * e3vw(ji,jj,jk  ,Kmm) ) * wvmask(ji,jj,jk  )
361               zzws = - zdt * ( avm(ji,jj+1,jk+1) + avm(ji,jj,jk+1) )    &
362                  &         / ( ze3va * e3vw(ji,jj,jk+1,Kmm) ) * wvmask(ji,jj,jk+1)
363               zwi(ji,jj,jk) = zzwi
364               zws(ji,jj,jk) = zzws
365               zwd(ji,jj,jk) = 1._wp - zzwi - zzws
366            END_3D
367         END SELECT
368         DO_2D( 0, 0, 0, 0 )
369            zwi(ji,jj,1) = 0._wp
370            zwd(ji,jj,1) = 1._wp - zws(ji,jj,1)
371         END_2D
372      ENDIF
373      !
374      !              !==  Apply semi-implicit top/bottom friction  ==!
375      !
376      !     Only needed for semi-implicit bottom friction setup. The explicit
377      !     bottom friction has been included in "u(v)a" which act as the R.H.S
378      !     column vector of the tri-diagonal matrix equation
379      !
380      IF( ln_drgimp ) THEN
381         DO_2D( 0, 0, 0, 0 )
382            ikv = mbkv(ji,jj)       ! (deepest ocean u- and v-points)
383            ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,ikv,Kmm)    &
384               &             + r_vvl   * e3v(ji,jj,ikv,Kaa)   ! after scale factor at T-point
385            zwd(ji,jj,ikv) = zwd(ji,jj,ikv) - rDt * 0.5*( rCdU_bot(ji,jj+1)+rCdU_bot(ji,jj) ) / ze3va           
386         END_2D
387         IF ( ln_isfcav ) THEN
388            DO_2D( 0, 0, 0, 0 )
389               ikv = mikv(ji,jj)       ! (first wet ocean u- and v-points)
390               ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,ikv,Kmm)    &
391                  &             + r_vvl   * e3v(ji,jj,ikv,Kaa)   ! after scale factor at T-point
392               zwd(ji,jj,ikv) = zwd(ji,jj,ikv) - rDt * 0.5*( rCdU_top(ji,jj+1)+rCdU_top(ji,jj) ) / ze3va
393            END_2D
394         ENDIF
395      ENDIF
396
397      ! Matrix inversion
398      !-----------------------------------------------------------------------
399      !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
400      !
401      !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
402      !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
403      !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
404      !        (        ...               )( ...  ) ( ...  )
405      !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
406      !
407      !   m is decomposed in the product of an upper and lower triangular matrix
408      !   The 3 diagonal terms are in 2d arrays: zwd, zws, zwi
409      !   The solution (after velocity) is in 2d array va
410      !-----------------------------------------------------------------------
411      !
412      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
413         zwd(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwd(ji,jj,jk-1)
414      END_3D
415      !
416      DO_2D( 0, 0, 0, 0 )
417         ze3va =  ( 1._wp - r_vvl ) * e3v(ji,jj,1,Kmm)    &
418            &             + r_vvl   * e3v(ji,jj,1,Kaa) 
419         pvv(ji,jj,1,Kaa) = pvv(ji,jj,1,Kaa) + rDt * 0.5_wp * ( vtau_b(ji,jj) + vtau(ji,jj) )   &
420            &                                      / ( ze3va * rho0 ) * vmask(ji,jj,1) 
421      END_2D
422      DO_3D( 0, 0, 0, 0, 2, jpkm1 )
423         pvv(ji,jj,jk,Kaa) = pvv(ji,jj,jk,Kaa) - zwi(ji,jj,jk) / zwd(ji,jj,jk-1) * pvv(ji,jj,jk-1,Kaa)
424      END_3D
425      !
426      DO_2D( 0, 0, 0, 0 )
427         pvv(ji,jj,jpkm1,Kaa) = pvv(ji,jj,jpkm1,Kaa) / zwd(ji,jj,jpkm1)
428      END_2D
429      DO_3DS( 0, 0, 0, 0, jpk-2, 1, -1 )
430         pvv(ji,jj,jk,Kaa) = ( pvv(ji,jj,jk,Kaa) - zws(ji,jj,jk) * pvv(ji,jj,jk+1,Kaa) ) / zwd(ji,jj,jk)
431      END_3D
432      !
433      IF( l_trddyn )   THEN                      ! save the vertical diffusive trends for further diagnostics
434         ztrdu(:,:,:) = ( puu(:,:,:,Kaa) - puu(:,:,:,Kbb) ) / rDt - ztrdu(:,:,:)
435         ztrdv(:,:,:) = ( pvv(:,:,:,Kaa) - pvv(:,:,:,Kbb) ) / rDt - ztrdv(:,:,:)
436         CALL trd_dyn( ztrdu, ztrdv, jpdyn_zdf, kt, Kmm )
437         DEALLOCATE( ztrdu, ztrdv ) 
438      ENDIF
439      !                                          ! print mean trends (used for debugging)
440      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Kaa), clinfo1=' zdf  - Ua: ', mask1=umask,               &
441         &                                  tab3d_2=pvv(:,:,:,Kaa), clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
442         !
443      IF( ln_timing )   CALL timing_stop('dyn_zdf')
444      !
445   END SUBROUTINE dyn_zdf
446
447   !!==============================================================================
448END MODULE dynzdf
Note: See TracBrowser for help on using the repository browser.