source: NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/TRA/traadv.F90 @ 13516

Last change on this file since 13516 was 13516, checked in by hadcv, 7 months ago

Tiling for tra_adv

  • Property svn:keywords set to Id
File size: 18.7 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            3.6  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!            3.7  !  2014-05  (G. Madec)  Add 2nd/4th order cases for CEN and FCT schemes
10   !!             -   !  2014-12  (G. Madec) suppression of cross land advection option
11   !!            3.6  !  2015-06  (E. Clementi) Addition of Stokes drift in case of wave coupling
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv       : compute ocean tracer advection trend
16   !!   tra_adv_init  : control the different options of advection scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   ! TEMP: This change not necessary after trd_tra is tiled and extended haloes development
21   USE domain, ONLY : dom_tile
22   USE domvvl         ! variable vertical scale factors
23   USE sbcwave        ! wave module
24   USE sbc_oce        ! surface boundary condition: ocean
25   USE traadv_cen     ! centered scheme            (tra_adv_cen  routine)
26   USE traadv_fct     ! FCT      scheme            (tra_adv_fct  routine)
27   USE traadv_mus     ! MUSCL    scheme            (tra_adv_mus  routine)
28   USE traadv_ubs     ! UBS      scheme            (tra_adv_ubs  routine)
29   USE traadv_qck     ! QUICKEST scheme            (tra_adv_qck  routine)
30   USE tramle         ! Mixed Layer Eddy transport (tra_mle_trp  routine)
31   USE ldftra         ! Eddy Induced transport     (ldf_eiv_trp  routine)
32   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
33   USE trd_oce        ! trends: ocean variables
34   USE trdtra         ! trends manager: tracers
35   USE diaptr         ! Poleward heat transport
36   !
37   USE in_out_manager ! I/O manager
38   USE iom            ! I/O module
39   USE prtctl         ! Print control
40   USE lib_mpp        ! MPP library
41   USE timing         ! Timing
42
43   IMPLICIT NONE
44   PRIVATE
45
46   PUBLIC   tra_adv        ! called by step.F90
47   PUBLIC   tra_adv_init   ! called by nemogcm.F90
48
49   !                            !!* Namelist namtra_adv *
50   LOGICAL ::   ln_traadv_OFF    ! no advection on T and S
51   LOGICAL ::   ln_traadv_cen    ! centered scheme flag
52   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
53   LOGICAL ::   ln_traadv_fct    ! FCT scheme flag
54   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
55   LOGICAL ::   ln_traadv_mus    ! MUSCL scheme flag
56   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
57   LOGICAL ::   ln_traadv_ubs    ! UBS scheme flag
58   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
59   LOGICAL ::   ln_traadv_qck    ! QUICKEST scheme flag
60
61   INTEGER ::   nadv             ! choice of the type of advection scheme
62   !                             ! associated indices:
63   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
64   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
65   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
66   INTEGER, PARAMETER ::   np_MUS     = 3   ! MUSCL scheme
67   INTEGER, PARAMETER ::   np_UBS     = 4   ! 3rd order Upstream Biased Scheme
68   INTEGER, PARAMETER ::   np_QCK     = 5   ! QUICK scheme
69
70   !! * Substitutions
71#  include "do_loop_substitute.h90"
72#  include "domzgr_substitute.h90"
73   !!----------------------------------------------------------------------
74   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
75   !! $Id$
76   !! Software governed by the CeCILL license (see ./LICENSE)
77   !!----------------------------------------------------------------------
78CONTAINS
79
80   SUBROUTINE tra_adv( kt, Kbb, Kmm, pts, Krhs )
81      !!----------------------------------------------------------------------
82      !!                  ***  ROUTINE tra_adv  ***
83      !!
84      !! ** Purpose :   compute the ocean tracer advection trend.
85      !!
86      !! ** Method  : - Update (uu(:,:,:,Krhs),vv(:,:,:,Krhs)) with the advection term following nadv
87      !!----------------------------------------------------------------------
88      INTEGER                                  , INTENT(in)    :: kt             ! ocean time-step index
89      INTEGER                                  , INTENT(in)    :: Kbb, Kmm, Krhs ! time level indices
90      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts            ! active tracers and RHS of tracer equation
91      !
92      ! TEMP: This change not necessary after trd_tra is tiled
93      INTEGER ::   itile
94      INTEGER ::   ji, jj, jk   ! dummy loop index
95      ! TEMP: This change not necessary and can be ST_2D(nn_hls) if using XIOS (subdomain support)
96      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE :: zuu, zvv, zww   ! 3D workspace
97      ! TEMP: This change not necessary after trd_tra is tiled
98      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE :: ztrdt, ztrds
99      ! TEMP: This change not necessary after extra haloes development
100      LOGICAL :: lskip
101      !!----------------------------------------------------------------------
102      !
103      IF( ln_timing )   CALL timing_start('tra_adv')
104      !
105      lskip = .FALSE.
106
107      ! TEMP: These changes not necessary if using XIOS (subdomain support)
108      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
109         ALLOCATE( zuu(jpi,jpj,jpk), zvv(jpi,jpj,jpk), zww(jpi,jpj,jpk) )
110         ! TEMP: This can be ST_2D(nn_hls) after trd_tra is tiled
111         IF( l_trdtra ) ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
112      ENDIF
113
114      ! TEMP: These changes not necessary after extra haloes development (lbc_lnk removed from tra_adv_*, ldf_eiv_dia)
115      IF( nadv /= np_CEN .OR. (nadv == np_CEN .AND. nn_cen_h == 4) .OR. ln_ldfeiv_dia )  THEN
116         IF( ln_tile ) THEN
117            IF( ntile == 1 ) THEN
118               CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )
119            ELSE
120               lskip = .TRUE.
121            ENDIF
122         ENDIF
123      ENDIF
124      IF( .NOT. lskip ) THEN
125
126         ! TEMP: This change not necessary after trd_tra is tiled
127         itile = ntile
128         !                                         !==  effective transport  ==!
129         ! TODO: NOT TESTED- requires waves
130         IF( ln_wave .AND. ln_sdw )  THEN
131            DO_3D( 1, 1, 1, 1, 1, jpkm1 )
132               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * ( uu(ji,jj,jk,Kmm) + usd(ji,jj,jk) )
133               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * ( vv(ji,jj,jk,Kmm) + vsd(ji,jj,jk) )
134               zww(ji,jj,jk) = e1e2t(ji,jj)                     * ( ww(ji,jj,jk)     + wsd(ji,jj,jk) )
135            END_3D
136         ELSE
137            DO_3D( 1, 1, 1, 1, 1, jpkm1 )
138               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * uu(ji,jj,jk,Kmm)               ! eulerian transport only
139               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * vv(ji,jj,jk,Kmm)
140               zww(ji,jj,jk) = e1e2t(ji,jj)                     * ww(ji,jj,jk)
141            END_3D
142         ENDIF
143         !
144         ! TODO: NOT TESTED- requires ztilde
145         IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                ! add z-tilde and/or vvl corrections
146            DO_3D( 1, 1, 1, 1, 1, jpkm1 )
147               zuu(ji,jj,jk) = zuu(ji,jj,jk) + un_td(ji,jj,jk)
148               zvv(ji,jj,jk) = zvv(ji,jj,jk) + vn_td(ji,jj,jk)
149            END_3D
150         ENDIF
151         !
152         DO_2D( 1, 1, 1, 1 )
153            zuu(ji,jj,jpk) = 0._wp                                                      ! no transport trough the bottom
154            zvv(ji,jj,jpk) = 0._wp
155            zww(ji,jj,jpk) = 0._wp
156         END_2D
157         !
158         ! TEMP: These changes not necessary if using XIOS (subdomain support)
159         IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   &
160            &              CALL ldf_eiv_trp( kt, nit000, zuu(ST_2D(nn_hls),:), zvv(ST_2D(nn_hls),:), zww(ST_2D(nn_hls),:), &
161            &                                'TRA', Kmm, Krhs )   ! add the eiv transport (if necessary)
162         !
163         IF( ln_mle    )   CALL tra_mle_trp( kt, nit000, zuu(ST_2D(nn_hls),:), zvv(ST_2D(nn_hls),:), zww(ST_2D(nn_hls),:), &
164            &                                'TRA', Kmm       )   ! add the mle transport (if necessary)
165         !
166         ! TEMP: This change not necessary if using XIOS (subdomain support)
167         IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only on the last tile
168            CALL iom_put( "uocetr_eff", zuu )                                        ! output effective transport
169            CALL iom_put( "vocetr_eff", zvv )
170            CALL iom_put( "wocetr_eff", zww )
171         ENDIF
172         !
173   !!gm ???
174         ! TEMP: This change not necessary if using XIOS (subdomain support)
175         CALL dia_ptr( kt, Kmm, zvv(ST_2D(nn_hls),:) )                                    ! diagnose the effective MSF
176   !!gm ???
177         !
178
179         IF( l_trdtra )   THEN                    !* Save ta and sa trends
180            DO_3D( 0, 0, 0, 0, 1, jpk )
181               ztrdt(ji,jj,jk) = pts(ji,jj,jk,jp_tem,Krhs)
182               ztrds(ji,jj,jk) = pts(ji,jj,jk,jp_sal,Krhs)
183            END_3D
184         ENDIF
185         !
186         SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
187         !
188         CASE ( np_CEN )                                 ! Centered scheme : 2nd / 4th order
189            CALL tra_adv_cen    ( kt, nit000, 'TRA',         zuu, zvv, zww, Kmm, pts, jpts, Krhs, nn_cen_h, nn_cen_v )
190         CASE ( np_FCT )                                 ! FCT scheme      : 2nd / 4th order
191            CALL tra_adv_fct    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_fct_h, nn_fct_v )
192         CASE ( np_MUS )                                 ! MUSCL
193            CALL tra_adv_mus    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, ln_mus_ups )
194         CASE ( np_UBS )                                 ! UBS
195            CALL tra_adv_ubs    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_ubs_v   )
196         CASE ( np_QCK )                                 ! QUICKEST
197            CALL tra_adv_qck    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs )
198         !
199         END SELECT
200         !
201         ! TEMP: These changes not necessary after trd_tra is tiled
202         IF( l_trdtra )   THEN                      ! save the advective trends for further diagnostics
203            DO_3D( 0, 0, 0, 0, 1, jpk )
204               ztrdt(ji,jj,jk) = pts(ji,jj,jk,jp_tem,Krhs) - ztrdt(ji,jj,jk)
205               ztrds(ji,jj,jk) = pts(ji,jj,jk,jp_sal,Krhs) - ztrds(ji,jj,jk)
206            END_3D
207
208            IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only for the full domain
209               IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )         ! Use full domain
210
211               ! TODO: TO BE TILED- trd_tra
212               CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_totad, ztrdt )
213               CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_totad, ztrds )
214               DEALLOCATE( ztrdt, ztrds )
215
216               IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = itile )     ! Revert to tile domain
217            ENDIF
218         ENDIF
219
220         ! TEMP: This change not necessary after extra haloes development (lbc_lnk removed from tra_adv_*, ldf_eiv_dia)
221         IF( ln_tile .AND. ntile == 0 ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 1 )
222
223      ENDIF
224      !                                              ! print mean trends (used for debugging)
225      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Krhs), clinfo1=' adv  - Ta: ', mask1=tmask, &
226         &                                  tab3d_2=pts(:,:,:,jp_sal,Krhs), clinfo2=       ' Sa: ', mask2=tmask, &
227         &                                  clinfo3='tra' )
228
229      ! TEMP: This change not necessary if using XIOS (subdomain support)
230      IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only for the full domain
231         DEALLOCATE( zuu, zvv, zww )
232      ENDIF
233      !
234      IF( ln_timing )   CALL timing_stop( 'tra_adv' )
235      !
236   END SUBROUTINE tra_adv
237
238
239   SUBROUTINE tra_adv_init
240      !!---------------------------------------------------------------------
241      !!                  ***  ROUTINE tra_adv_init  ***
242      !!               
243      !! ** Purpose :   Control the consistency between namelist options for
244      !!              tracer advection schemes and set nadv
245      !!----------------------------------------------------------------------
246      INTEGER ::   ioptio, ios   ! Local integers
247      !
248      NAMELIST/namtra_adv/ ln_traadv_OFF,                        &   ! No advection
249         &                 ln_traadv_cen , nn_cen_h, nn_cen_v,   &   ! CEN
250         &                 ln_traadv_fct , nn_fct_h, nn_fct_v,   &   ! FCT
251         &                 ln_traadv_mus , ln_mus_ups,           &   ! MUSCL
252         &                 ln_traadv_ubs ,           nn_ubs_v,   &   ! UBS
253         &                 ln_traadv_qck                             ! QCK
254      !!----------------------------------------------------------------------
255      !
256      !                                !==  Namelist  ==!
257      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
258901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_adv in reference namelist' )
259      !
260      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
261902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_adv in configuration namelist' )
262      IF(lwm) WRITE( numond, namtra_adv )
263      !
264      IF(lwp) THEN                           ! Namelist print
265         WRITE(numout,*)
266         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
267         WRITE(numout,*) '~~~~~~~~~~~~'
268         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
269         WRITE(numout,*) '      No advection on T & S                     ln_traadv_OFF = ', ln_traadv_OFF
270         WRITE(numout,*) '      centered scheme                           ln_traadv_cen = ', ln_traadv_cen
271         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
272         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
273         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_traadv_fct = ', ln_traadv_fct
274         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
275         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
276         WRITE(numout,*) '      MUSCL scheme                              ln_traadv_mus = ', ln_traadv_mus
277         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
278         WRITE(numout,*) '      UBS scheme                                ln_traadv_ubs = ', ln_traadv_ubs
279         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
280         WRITE(numout,*) '      QUICKEST scheme                           ln_traadv_qck = ', ln_traadv_qck
281      ENDIF
282      !
283      !                                !==  Parameter control & set nadv ==!
284      ioptio = 0                       
285      IF( ln_traadv_OFF ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_NO_adv   ;   ENDIF
286      IF( ln_traadv_cen ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_CEN      ;   ENDIF
287      IF( ln_traadv_fct ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_FCT      ;   ENDIF
288      IF( ln_traadv_mus ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_MUS      ;   ENDIF
289      IF( ln_traadv_ubs ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_UBS      ;   ENDIF
290      IF( ln_traadv_qck ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_QCK      ;   ENDIF
291      !
292      IF( ioptio /= 1 )   CALL ctl_stop( 'tra_adv_init: Choose ONE advection option in namelist namtra_adv' )
293      !
294      IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &          ! Centered
295                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
296        CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
297      ENDIF
298      IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &          ! FCT
299                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
300        CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
301      ENDIF
302      IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN     ! UBS
303        CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
304      ENDIF
305      IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
306         CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
307      ENDIF
308      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
309         IF(  ln_traadv_cen .AND. nn_cen_v == 4    .OR.   &                            ! NO 4th order with ISF
310            & ln_traadv_fct .AND. nn_fct_v == 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
311      ENDIF
312      !
313      !                                !==  Print the choice  ==! 
314      IF(lwp) THEN
315         WRITE(numout,*)
316         SELECT CASE ( nadv )
317         CASE( np_NO_adv  )   ;   WRITE(numout,*) '   ==>>>   NO T-S advection'
318         CASE( np_CEN     )   ;   WRITE(numout,*) '   ==>>>   CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
319            &                                                                        ' Vertical   order: ', nn_cen_v
320         CASE( np_FCT     )   ;   WRITE(numout,*) '   ==>>>   FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
321            &                                                                        ' Vertical   order: ', nn_fct_v
322         CASE( np_MUS     )   ;   WRITE(numout,*) '   ==>>>   MUSCL    scheme is used'
323         CASE( np_UBS     )   ;   WRITE(numout,*) '   ==>>>   UBS      scheme is used'
324         CASE( np_QCK     )   ;   WRITE(numout,*) '   ==>>>   QUICKEST scheme is used'
325         END SELECT
326      ENDIF
327      !
328      CALL tra_mle_init            !== initialisation of the Mixed Layer Eddy parametrisation (MLE)  ==!
329      !
330   END SUBROUTINE tra_adv_init
331
332  !!======================================================================
333END MODULE traadv
Note: See TracBrowser for help on using the repository browser.