New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv.F90 in NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/TRA/traadv.F90 @ 13551

Last change on this file since 13551 was 13551, checked in by hadcv, 4 years ago

#2365: Replace trd_tra workarounds with ctl_warn if using tiling
  • Property svn:keywords set to Id
File size: 17.8 KB
Line 
1MODULE traadv
2   !!==============================================================================
3   !!                       ***  MODULE  traadv  ***
4   !! Ocean active tracers:  advection trend
5   !!==============================================================================
6   !! History :  2.0  !  2005-11  (G. Madec)  Original code
7   !!            3.3  !  2010-09  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
8   !!            3.6  !  2011-06  (G. Madec)  Addition of Mixed Layer Eddy parameterisation
9   !!            3.7  !  2014-05  (G. Madec)  Add 2nd/4th order cases for CEN and FCT schemes
10   !!             -   !  2014-12  (G. Madec) suppression of cross land advection option
11   !!            3.6  !  2015-06  (E. Clementi) Addition of Stokes drift in case of wave coupling
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv       : compute ocean tracer advection trend
16   !!   tra_adv_init  : control the different options of advection scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE dom_oce        ! ocean space and time domain
20   ! TEMP: This change not necessary after trd_tra is tiled and extended haloes development
21   USE domain, ONLY : dom_tile
22   USE domvvl         ! variable vertical scale factors
23   USE sbcwave        ! wave module
24   USE sbc_oce        ! surface boundary condition: ocean
25   USE traadv_cen     ! centered scheme            (tra_adv_cen  routine)
26   USE traadv_fct     ! FCT      scheme            (tra_adv_fct  routine)
27   USE traadv_mus     ! MUSCL    scheme            (tra_adv_mus  routine)
28   USE traadv_ubs     ! UBS      scheme            (tra_adv_ubs  routine)
29   USE traadv_qck     ! QUICKEST scheme            (tra_adv_qck  routine)
30   USE tramle         ! Mixed Layer Eddy transport (tra_mle_trp  routine)
31   USE ldftra         ! Eddy Induced transport     (ldf_eiv_trp  routine)
32   USE ldfslp         ! Lateral diffusion: slopes of neutral surfaces
33   USE trd_oce        ! trends: ocean variables
34   USE trdtra         ! trends manager: tracers
35   USE diaptr         ! Poleward heat transport
36   !
37   USE in_out_manager ! I/O manager
38   USE iom            ! I/O module
39   USE prtctl         ! Print control
40   USE lib_mpp        ! MPP library
41   USE timing         ! Timing
42
43   IMPLICIT NONE
44   PRIVATE
45
46   PUBLIC   tra_adv        ! called by step.F90
47   PUBLIC   tra_adv_init   ! called by nemogcm.F90
48
49   !                            !!* Namelist namtra_adv *
50   LOGICAL ::   ln_traadv_OFF    ! no advection on T and S
51   LOGICAL ::   ln_traadv_cen    ! centered scheme flag
52   INTEGER ::      nn_cen_h, nn_cen_v   ! =2/4 : horizontal and vertical choices of the order of CEN scheme
53   LOGICAL ::   ln_traadv_fct    ! FCT scheme flag
54   INTEGER ::      nn_fct_h, nn_fct_v   ! =2/4 : horizontal and vertical choices of the order of FCT scheme
55   LOGICAL ::   ln_traadv_mus    ! MUSCL scheme flag
56   LOGICAL ::      ln_mus_ups           ! use upstream scheme in vivcinity of river mouths
57   LOGICAL ::   ln_traadv_ubs    ! UBS scheme flag
58   INTEGER ::      nn_ubs_v             ! =2/4 : vertical choice of the order of UBS scheme
59   LOGICAL ::   ln_traadv_qck    ! QUICKEST scheme flag
60
61   INTEGER ::   nadv             ! choice of the type of advection scheme
62   !                             ! associated indices:
63   INTEGER, PARAMETER ::   np_NO_adv  = 0   ! no T-S advection
64   INTEGER, PARAMETER ::   np_CEN     = 1   ! 2nd/4th order centered scheme
65   INTEGER, PARAMETER ::   np_FCT     = 2   ! 2nd/4th order Flux Corrected Transport scheme
66   INTEGER, PARAMETER ::   np_MUS     = 3   ! MUSCL scheme
67   INTEGER, PARAMETER ::   np_UBS     = 4   ! 3rd order Upstream Biased Scheme
68   INTEGER, PARAMETER ::   np_QCK     = 5   ! QUICK scheme
69
70   !! * Substitutions
71#  include "do_loop_substitute.h90"
72#  include "domzgr_substitute.h90"
73   !!----------------------------------------------------------------------
74   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
75   !! $Id$
76   !! Software governed by the CeCILL license (see ./LICENSE)
77   !!----------------------------------------------------------------------
78CONTAINS
79
80   SUBROUTINE tra_adv( kt, Kbb, Kmm, pts, Krhs )
81      !!----------------------------------------------------------------------
82      !!                  ***  ROUTINE tra_adv  ***
83      !!
84      !! ** Purpose :   compute the ocean tracer advection trend.
85      !!
86      !! ** Method  : - Update (uu(:,:,:,Krhs),vv(:,:,:,Krhs)) with the advection term following nadv
87      !!----------------------------------------------------------------------
88      INTEGER                                  , INTENT(in)    :: kt             ! ocean time-step index
89      INTEGER                                  , INTENT(in)    :: Kbb, Kmm, Krhs ! time level indices
90      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts            ! active tracers and RHS of tracer equation
91      !
92      INTEGER ::   ji, jj, jk   ! dummy loop index
93      ! TEMP: This change not necessary and can be ST_2D(nn_hls) if using XIOS (subdomain support)
94      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE :: zuu, zvv, zww   ! 3D workspace
95      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE :: ztrdt, ztrds
96      ! TEMP: This change not necessary after extra haloes development
97      LOGICAL :: lskip
98      !!----------------------------------------------------------------------
99      !
100      IF( ln_timing )   CALL timing_start('tra_adv')
101      !
102      lskip = .FALSE.
103
104      ! TEMP: These changes not necessary if using XIOS (subdomain support)
105      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
106         ALLOCATE( zuu(jpi,jpj,jpk), zvv(jpi,jpj,jpk), zww(jpi,jpj,jpk) )
107      ENDIF
108
109      ! TEMP: These changes not necessary after extra haloes development (lbc_lnk removed from tra_adv_*)
110      IF( nadv /= np_CEN .OR. (nadv == np_CEN .AND. nn_cen_h == 4) .OR. ln_ldfeiv_dia )  THEN
111         IF( ln_tile ) THEN
112            IF( ntile == 1 ) THEN
113               CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )
114            ELSE
115               lskip = .TRUE.
116            ENDIF
117         ENDIF
118      ENDIF
119      IF( .NOT. lskip ) THEN
120         !                                         !==  effective transport  ==!
121         ! TODO: NOT TESTED- requires waves
122         IF( ln_wave .AND. ln_sdw )  THEN
123            DO_3D( 1, 1, 1, 1, 1, jpkm1 )
124               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * ( uu(ji,jj,jk,Kmm) + usd(ji,jj,jk) )
125               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * ( vv(ji,jj,jk,Kmm) + vsd(ji,jj,jk) )
126               zww(ji,jj,jk) = e1e2t(ji,jj)                     * ( ww(ji,jj,jk)     + wsd(ji,jj,jk) )
127            END_3D
128         ELSE
129            DO_3D( 1, 1, 1, 1, 1, jpkm1 )
130               zuu(ji,jj,jk) = e2u  (ji,jj) * e3u(ji,jj,jk,Kmm) * uu(ji,jj,jk,Kmm)               ! eulerian transport only
131               zvv(ji,jj,jk) = e1v  (ji,jj) * e3v(ji,jj,jk,Kmm) * vv(ji,jj,jk,Kmm)
132               zww(ji,jj,jk) = e1e2t(ji,jj)                     * ww(ji,jj,jk)
133            END_3D
134         ENDIF
135         !
136         ! TODO: NOT TESTED- requires ztilde
137         IF( ln_vvl_ztilde .OR. ln_vvl_layer ) THEN                                ! add z-tilde and/or vvl corrections
138            DO_3D( 1, 1, 1, 1, 1, jpkm1 )
139               zuu(ji,jj,jk) = zuu(ji,jj,jk) + un_td(ji,jj,jk)
140               zvv(ji,jj,jk) = zvv(ji,jj,jk) + vn_td(ji,jj,jk)
141            END_3D
142         ENDIF
143         !
144         DO_2D( 1, 1, 1, 1 )
145            zuu(ji,jj,jpk) = 0._wp                                                      ! no transport trough the bottom
146            zvv(ji,jj,jpk) = 0._wp
147            zww(ji,jj,jpk) = 0._wp
148         END_2D
149         !
150         ! TEMP: These changes not necessary if using XIOS (subdomain support)
151         IF( ln_ldfeiv .AND. .NOT. ln_traldf_triad )   &
152            &              CALL ldf_eiv_trp( kt, nit000, zuu(ST_2D(nn_hls),:), zvv(ST_2D(nn_hls),:), zww(ST_2D(nn_hls),:), &
153            &                                'TRA', Kmm, Krhs )   ! add the eiv transport (if necessary)
154         !
155         IF( ln_mle    )   CALL tra_mle_trp( kt, nit000, zuu(ST_2D(nn_hls),:), zvv(ST_2D(nn_hls),:), zww(ST_2D(nn_hls),:), &
156            &                                'TRA', Kmm       )   ! add the mle transport (if necessary)
157         !
158         ! TEMP: This change not necessary if using XIOS (subdomain support)
159         IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only on the last tile
160            CALL iom_put( "uocetr_eff", zuu )                                        ! output effective transport
161            CALL iom_put( "vocetr_eff", zvv )
162            CALL iom_put( "wocetr_eff", zww )
163         ENDIF
164         !
165   !!gm ???
166         ! TEMP: This change not necessary if using XIOS (subdomain support)
167         CALL dia_ptr( kt, Kmm, zvv(ST_2D(nn_hls),:) )                                    ! diagnose the effective MSF
168   !!gm ???
169         !
170
171         IF( l_trdtra )   THEN                    !* Save ta and sa trends
172            ALLOCATE( ztrdt(jpi,jpj,jpk), ztrds(jpi,jpj,jpk) )
173            ztrdt(:,:,:) = pts(:,:,:,jp_tem,Krhs)
174            ztrds(:,:,:) = pts(:,:,:,jp_sal,Krhs)
175         ENDIF
176         !
177         SELECT CASE ( nadv )                      !==  compute advection trend and add it to general trend  ==!
178         !
179         CASE ( np_CEN )                                 ! Centered scheme : 2nd / 4th order
180            CALL tra_adv_cen    ( kt, nit000, 'TRA',         zuu, zvv, zww, Kmm, pts, jpts, Krhs, nn_cen_h, nn_cen_v )
181         CASE ( np_FCT )                                 ! FCT scheme      : 2nd / 4th order
182            CALL tra_adv_fct    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_fct_h, nn_fct_v )
183         CASE ( np_MUS )                                 ! MUSCL
184            CALL tra_adv_mus    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, ln_mus_ups )
185         CASE ( np_UBS )                                 ! UBS
186            CALL tra_adv_ubs    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs, nn_ubs_v   )
187         CASE ( np_QCK )                                 ! QUICKEST
188            CALL tra_adv_qck    ( kt, nit000, 'TRA', rDt, zuu, zvv, zww, Kbb, Kmm, pts, jpts, Krhs )
189         !
190         END SELECT
191         !
192         IF( l_trdtra )   THEN                      ! save the advective trends for further diagnostics
193            DO jk = 1, jpkm1
194               ztrdt(:,:,jk) = pts(:,:,jk,jp_tem,Krhs) - ztrdt(:,:,jk)
195               ztrds(:,:,jk) = pts(:,:,jk,jp_sal,Krhs) - ztrds(:,:,jk)
196            END DO
197            CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_totad, ztrdt )
198            CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_totad, ztrds )
199            DEALLOCATE( ztrdt, ztrds )
200         ENDIF
201
202         ! TEMP: This change not necessary after extra haloes development (lbc_lnk removed from tra_adv_*)
203         IF( ln_tile .AND. ntile == 0 ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 1 )
204
205      ENDIF
206      !                                              ! print mean trends (used for debugging)
207      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Krhs), clinfo1=' adv  - Ta: ', mask1=tmask, &
208         &                                  tab3d_2=pts(:,:,:,jp_sal,Krhs), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
209
210      ! TEMP: This change not necessary if using XIOS (subdomain support)
211      IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only for the full domain
212         DEALLOCATE( zuu, zvv, zww )
213      ENDIF
214      !
215      IF( ln_timing )   CALL timing_stop( 'tra_adv' )
216      !
217   END SUBROUTINE tra_adv
218
219
220   SUBROUTINE tra_adv_init
221      !!---------------------------------------------------------------------
222      !!                  ***  ROUTINE tra_adv_init  ***
223      !!               
224      !! ** Purpose :   Control the consistency between namelist options for
225      !!              tracer advection schemes and set nadv
226      !!----------------------------------------------------------------------
227      INTEGER ::   ioptio, ios   ! Local integers
228      !
229      NAMELIST/namtra_adv/ ln_traadv_OFF,                        &   ! No advection
230         &                 ln_traadv_cen , nn_cen_h, nn_cen_v,   &   ! CEN
231         &                 ln_traadv_fct , nn_fct_h, nn_fct_v,   &   ! FCT
232         &                 ln_traadv_mus , ln_mus_ups,           &   ! MUSCL
233         &                 ln_traadv_ubs ,           nn_ubs_v,   &   ! UBS
234         &                 ln_traadv_qck                             ! QCK
235      !!----------------------------------------------------------------------
236      !
237      !                                !==  Namelist  ==!
238      READ  ( numnam_ref, namtra_adv, IOSTAT = ios, ERR = 901)
239901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_adv in reference namelist' )
240      !
241      READ  ( numnam_cfg, namtra_adv, IOSTAT = ios, ERR = 902 )
242902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_adv in configuration namelist' )
243      IF(lwm) WRITE( numond, namtra_adv )
244      !
245      IF(lwp) THEN                           ! Namelist print
246         WRITE(numout,*)
247         WRITE(numout,*) 'tra_adv_init : choice/control of the tracer advection scheme'
248         WRITE(numout,*) '~~~~~~~~~~~~'
249         WRITE(numout,*) '   Namelist namtra_adv : chose a advection scheme for tracers'
250         WRITE(numout,*) '      No advection on T & S                     ln_traadv_OFF = ', ln_traadv_OFF
251         WRITE(numout,*) '      centered scheme                           ln_traadv_cen = ', ln_traadv_cen
252         WRITE(numout,*) '            horizontal 2nd/4th order               nn_cen_h   = ', nn_fct_h
253         WRITE(numout,*) '            vertical   2nd/4th order               nn_cen_v   = ', nn_fct_v
254         WRITE(numout,*) '      Flux Corrected Transport scheme           ln_traadv_fct = ', ln_traadv_fct
255         WRITE(numout,*) '            horizontal 2nd/4th order               nn_fct_h   = ', nn_fct_h
256         WRITE(numout,*) '            vertical   2nd/4th order               nn_fct_v   = ', nn_fct_v
257         WRITE(numout,*) '      MUSCL scheme                              ln_traadv_mus = ', ln_traadv_mus
258         WRITE(numout,*) '            + upstream scheme near river mouths    ln_mus_ups = ', ln_mus_ups
259         WRITE(numout,*) '      UBS scheme                                ln_traadv_ubs = ', ln_traadv_ubs
260         WRITE(numout,*) '            vertical   2nd/4th order               nn_ubs_v   = ', nn_ubs_v
261         WRITE(numout,*) '      QUICKEST scheme                           ln_traadv_qck = ', ln_traadv_qck
262      ENDIF
263      !
264      !                                !==  Parameter control & set nadv ==!
265      ioptio = 0                       
266      IF( ln_traadv_OFF ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_NO_adv   ;   ENDIF
267      IF( ln_traadv_cen ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_CEN      ;   ENDIF
268      IF( ln_traadv_fct ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_FCT      ;   ENDIF
269      IF( ln_traadv_mus ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_MUS      ;   ENDIF
270      IF( ln_traadv_ubs ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_UBS      ;   ENDIF
271      IF( ln_traadv_qck ) THEN   ;   ioptio = ioptio + 1   ;   nadv = np_QCK      ;   ENDIF
272      !
273      IF( ioptio /= 1 )   CALL ctl_stop( 'tra_adv_init: Choose ONE advection option in namelist namtra_adv' )
274      !
275      IF( ln_traadv_cen .AND. ( nn_cen_h /= 2 .AND. nn_cen_h /= 4 )   &          ! Centered
276                        .AND. ( nn_cen_v /= 2 .AND. nn_cen_v /= 4 )   ) THEN
277        CALL ctl_stop( 'tra_adv_init: CEN scheme, choose 2nd or 4th order' )
278      ENDIF
279      IF( ln_traadv_fct .AND. ( nn_fct_h /= 2 .AND. nn_fct_h /= 4 )   &          ! FCT
280                        .AND. ( nn_fct_v /= 2 .AND. nn_fct_v /= 4 )   ) THEN
281        CALL ctl_stop( 'tra_adv_init: FCT scheme, choose 2nd or 4th order' )
282      ENDIF
283      IF( ln_traadv_ubs .AND. ( nn_ubs_v /= 2 .AND. nn_ubs_v /= 4 )   ) THEN     ! UBS
284        CALL ctl_stop( 'tra_adv_init: UBS scheme, choose 2nd or 4th order' )
285      ENDIF
286      IF( ln_traadv_ubs .AND. nn_ubs_v == 4 ) THEN
287         CALL ctl_warn( 'tra_adv_init: UBS scheme, only 2nd FCT scheme available on the vertical. It will be used' )
288      ENDIF
289      IF( ln_isfcav ) THEN                                                       ! ice-shelf cavities
290         IF(  ln_traadv_cen .AND. nn_cen_v == 4    .OR.   &                            ! NO 4th order with ISF
291            & ln_traadv_fct .AND. nn_fct_v == 4   )   CALL ctl_stop( 'tra_adv_init: 4th order COMPACT scheme not allowed with ISF' )
292      ENDIF
293      !
294      !                                !==  Print the choice  ==! 
295      IF(lwp) THEN
296         WRITE(numout,*)
297         SELECT CASE ( nadv )
298         CASE( np_NO_adv  )   ;   WRITE(numout,*) '   ==>>>   NO T-S advection'
299         CASE( np_CEN     )   ;   WRITE(numout,*) '   ==>>>   CEN      scheme is used. Horizontal order: ', nn_cen_h,   &
300            &                                                                        ' Vertical   order: ', nn_cen_v
301         CASE( np_FCT     )   ;   WRITE(numout,*) '   ==>>>   FCT      scheme is used. Horizontal order: ', nn_fct_h,   &
302            &                                                                        ' Vertical   order: ', nn_fct_v
303         CASE( np_MUS     )   ;   WRITE(numout,*) '   ==>>>   MUSCL    scheme is used'
304         CASE( np_UBS     )   ;   WRITE(numout,*) '   ==>>>   UBS      scheme is used'
305         CASE( np_QCK     )   ;   WRITE(numout,*) '   ==>>>   QUICKEST scheme is used'
306         END SELECT
307      ENDIF
308      !
309      CALL tra_mle_init            !== initialisation of the Mixed Layer Eddy parametrisation (MLE)  ==!
310      !
311   END SUBROUTINE tra_adv_init
312
313  !!======================================================================
314END MODULE traadv
Note: See TracBrowser for help on using the repository browser.