New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_cen.F90 in NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/TRA/traadv_cen.F90 @ 13551

Last change on this file since 13551 was 13551, checked in by hadcv, 4 years ago

#2365: Replace trd_tra workarounds with ctl_warn if using tiling
  • Property svn:keywords set to Id
File size: 10.2 KB
Line 
1MODULE traadv_cen
2   !!======================================================================
3   !!                     ***  MODULE  traadv_cen  ***
4   !! Ocean  tracers:   advective trend (2nd/4th order centered)
5   !!======================================================================
6   !! History :  3.7  ! 2014-05  (G. Madec)  original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   tra_adv_cen   : update the tracer trend with the advection trends using a centered or scheme (2nd or 4th order)
11   !!                   NB: on the vertical it is actually a 4th order COMPACT scheme which is used
12   !!----------------------------------------------------------------------
13   USE dom_oce        ! ocean space and time domain
14   USE eosbn2         ! equation of state
15   USE traadv_fct     ! acces to routine interp_4th_cpt
16   USE trd_oce        ! trends: ocean variables
17   USE trdtra         ! trends manager: tracers
18   USE diaptr         ! poleward transport diagnostics
19   USE diaar5         ! AR5 diagnostics
20   !
21   USE in_out_manager ! I/O manager
22   USE iom            ! IOM library
23   USE trc_oce        ! share passive tracers/Ocean variables
24   USE lib_mpp        ! MPP library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   tra_adv_cen   ! called by traadv.F90
30   
31   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
32
33   LOGICAL ::   l_trd   ! flag to compute trends
34   LOGICAL ::   l_ptr   ! flag to compute poleward transport
35   LOGICAL ::   l_hst   ! flag to compute heat/salt transport
36
37   !! * Substitutions
38#  include "do_loop_substitute.h90"
39#  include "domzgr_substitute.h90"
40   !!----------------------------------------------------------------------
41   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
42   !! $Id$
43   !! Software governed by the CeCILL license (see ./LICENSE)
44   !!----------------------------------------------------------------------
45CONTAINS
46
47   SUBROUTINE tra_adv_cen( kt, kit000, cdtype, pU, pV, pW,     &
48      &                    Kmm, pt, kjpt, Krhs, kn_cen_h, kn_cen_v ) 
49      !!----------------------------------------------------------------------
50      !!                  ***  ROUTINE tra_adv_cen  ***
51      !!                 
52      !! ** Purpose :   Compute the now trend due to the advection of tracers
53      !!      and add it to the general trend of passive tracer equations.
54      !!
55      !! ** Method  :   The advection is evaluated by a 2nd or 4th order scheme
56      !!               using now fields (leap-frog scheme).
57      !!       kn_cen_h = 2  ==>> 2nd order centered scheme on the horizontal
58      !!                = 4  ==>> 4th order    -        -       -      -
59      !!       kn_cen_v = 2  ==>> 2nd order centered scheme on the vertical
60      !!                = 4  ==>> 4th order COMPACT  scheme     -      -
61      !!
62      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
63      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
64      !!             - poleward advective heat and salt transport (l_diaptr=T)
65      !!----------------------------------------------------------------------
66      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
67      INTEGER                                  , INTENT(in   ) ::   Kmm, Krhs       ! ocean time level indices
68      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
69      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
70      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
71      INTEGER                                  , INTENT(in   ) ::   kn_cen_h        ! =2/4 (2nd or 4th order scheme)
72      INTEGER                                  , INTENT(in   ) ::   kn_cen_v        ! =2/4 (2nd or 4th order scheme)
73      ! TEMP: This can be ST_2D(nn_hls) if using XIOS (subdomain support)
74      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
75      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
76      !
77      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
78      INTEGER  ::   ierr             ! local integer
79      REAL(wp) ::   zC2t_u, zC2t_v   ! local scalars
80      REAL(wp), DIMENSION(ST_2D(nn_hls),jpk) ::   zwx, zwy, zwz, ztu, ztv, ztw, zltu, zltv
81      !!----------------------------------------------------------------------
82      !
83      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
84         IF( kt == kit000 )  THEN
85            IF(lwp) WRITE(numout,*)
86            IF(lwp) WRITE(numout,*) 'tra_adv_cen : centered advection scheme on ', cdtype, ' order h/v =', kn_cen_h,'/', kn_cen_v
87            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
88         ENDIF
89         !                          ! set local switches
90         l_trd = .FALSE.
91         l_hst = .FALSE.
92         l_ptr = .FALSE.
93         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )       l_trd = .TRUE.
94         IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) )  )    l_ptr = .TRUE.
95         IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
96            &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
97      ENDIF
98      !
99      !                   
100      zwz(:,:, 1 ) = 0._wp       ! surface & bottom vertical flux set to zero for all tracers
101      zwz(:,:,jpk) = 0._wp
102      !
103      DO jn = 1, kjpt            !==  loop over the tracers  ==!
104         !
105         SELECT CASE( kn_cen_h )       !--  Horizontal fluxes  --!
106         !
107         CASE(  2  )                         !* 2nd order centered
108            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
109               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm) )
110               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm) )
111            END_3D
112            !
113         CASE(  4  )                         !* 4th order centered
114            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
115            zltv(:,:,jpk) = 0._wp
116            DO jk = 1, jpkm1                 ! Laplacian
117               DO_2D( 1, 0, 1, 0 )
118                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
119                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
120               END_2D
121               DO_2D( 0, 0, 0, 0 )
122                  zltu(ji,jj,jk) = ztu(ji,jj,jk) + ztu(ji-1,jj,jk)
123                  zltv(ji,jj,jk) = ztv(ji,jj,jk) + ztv(ji,jj-1,jk)
124               END_2D
125            END DO
126            CALL lbc_lnk_multi( 'traadv_cen', zltu, 'T', 1. , zltv, 'T', 1. )   ! Lateral boundary cond. (unchanged sgn)
127            !
128            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
129               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! C2 interpolation of T at u- & v-points (x2)
130               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
131               !                                                  ! C4 fluxes
132               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + r1_6 * (zltu(ji,jj,jk) - zltu(ji+1,jj,jk)) )
133               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + r1_6 * (zltv(ji,jj,jk) - zltv(ji,jj+1,jk)) )
134            END_3D
135            !
136         CASE DEFAULT
137            CALL ctl_stop( 'traadv_fct: wrong value for nn_fct' )
138         END SELECT
139         !
140         SELECT CASE( kn_cen_v )       !--  Vertical fluxes  --!   (interior)
141         !
142         CASE(  2  )                         !* 2nd order centered
143            DO_3D( 0, 0, 0, 0, 2, jpk )
144               zwz(ji,jj,jk) = 0.5 * pW(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) ) * wmask(ji,jj,jk)
145            END_3D
146            !
147         CASE(  4  )                         !* 4th order compact
148            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )      ! ztw = interpolated value of T at w-point
149            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
150               zwz(ji,jj,jk) = pW(ji,jj,jk) * ztw(ji,jj,jk) * wmask(ji,jj,jk)
151            END_3D
152            !
153         END SELECT
154         !
155         IF( ln_linssh ) THEN                !* top value   (linear free surf. only as zwz is multiplied by wmask)
156            ! TODO: NOT TESTED- requires isf
157            IF( ln_isfcav ) THEN                  ! ice-shelf cavities (top of the ocean)
158               DO_2D( 1, 1, 1, 1 )
159                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kmm) 
160               END_2D
161            ELSE                                   ! no ice-shelf cavities (only ocean surface)
162               DO_2D( 1, 1, 1, 1 )
163                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kmm)
164               END_2D
165            ENDIF
166         ENDIF
167         !               
168         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
169            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs)    &
170               &             - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )    &
171               &                + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )    &
172               &                + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1)  ) &
173               &                * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
174         END_3D
175         !                             ! trend diagnostics
176         IF( l_trd ) THEN
177            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, zwx, pU, pt(:,:,:,jn,Kmm) )
178            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, zwy, pV, pt(:,:,:,jn,Kmm) )
179            CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, zwz, pW, pt(:,:,:,jn,Kmm) )
180         ENDIF
181         !                                 ! "Poleward" heat and salt transports
182         IF( l_ptr )   CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
183         !                                 !  heat and salt transport
184         IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
185         !
186      END DO
187      !
188   END SUBROUTINE tra_adv_cen
189   
190   !!======================================================================
191END MODULE traadv_cen
Note: See TracBrowser for help on using the repository browser.