source: NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/TRA/traadv_fct.F90 @ 13516

Last change on this file since 13516 was 13516, checked in by hadcv, 7 months ago

Tiling for tra_adv

  • Property svn:keywords set to Id
File size: 35.2 KB
Line 
1MODULE traadv_fct
2   !!==============================================================================
3   !!                       ***  MODULE  traadv_fct  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend (2nd/4th order Flux Corrected Transport method)
5   !!==============================================================================
6   !! History :  3.7  !  2015-09  (L. Debreu, G. Madec)  original code (inspired from traadv_tvd.F90)
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!  tra_adv_fct    : update the tracer trend with a 3D advective trends using a 2nd or 4th order FCT scheme
11   !!                   with sub-time-stepping in the vertical direction
12   !!  nonosc         : compute monotonic tracer fluxes by a non-oscillatory algorithm
13   !!  interp_4th_cpt : 4th order compact scheme for the vertical component of the advection
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and active tracers
16   USE dom_oce        ! ocean space and time domain
17   ! TEMP: This change not necessary after trd_tra is tiled
18   USE domain, ONLY : dom_tile
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE trd_oce        ! trends: ocean variables
21   USE trdtra         ! tracers trends
22   USE diaptr         ! poleward transport diagnostics
23   USE diaar5         ! AR5 diagnostics
24   USE phycst  , ONLY : rho0_rcp
25   USE zdf_oce , ONLY : ln_zad_Aimp
26   !
27   USE in_out_manager ! I/O manager
28   USE iom            !
29   USE lib_mpp        ! MPP library
30   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
31   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   tra_adv_fct        ! called by traadv.F90
37   PUBLIC   interp_4th_cpt     ! called by traadv_cen.F90
38
39   LOGICAL  ::   l_trd   ! flag to compute trends
40   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
41   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
42   REAL(wp) ::   r1_6 = 1._wp / 6._wp   ! =1/6
43
44   !                                        ! tridiag solver associated indices:
45   INTEGER, PARAMETER ::   np_NH   = 0   ! Neumann homogeneous boundary condition
46   INTEGER, PARAMETER ::   np_CEN2 = 1   ! 2nd order centered  boundary condition
47
48   !! * Substitutions
49#  include "do_loop_substitute.h90"
50#  include "domzgr_substitute.h90"
51   !!----------------------------------------------------------------------
52   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
53   !! $Id$
54   !! Software governed by the CeCILL license (see ./LICENSE)
55   !!----------------------------------------------------------------------
56CONTAINS
57
58   SUBROUTINE tra_adv_fct( kt, kit000, cdtype, p2dt, pU, pV, pW,       &
59      &                    Kbb, Kmm, pt, kjpt, Krhs, kn_fct_h, kn_fct_v )
60      !!----------------------------------------------------------------------
61      !!                  ***  ROUTINE tra_adv_fct  ***
62      !!
63      !! **  Purpose :   Compute the now trend due to total advection of tracers
64      !!               and add it to the general trend of tracer equations
65      !!
66      !! **  Method  : - 2nd or 4th FCT scheme on the horizontal direction
67      !!               (choice through the value of kn_fct)
68      !!               - on the vertical the 4th order is a compact scheme
69      !!               - corrected flux (monotonic correction)
70      !!
71      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
72      !!             - send trends to trdtra module for further diagnostics (l_trdtra=T)
73      !!             - poleward advective heat and salt transport (ln_diaptr=T)
74      !!----------------------------------------------------------------------
75      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
76      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
77      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
78      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
79      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
80      INTEGER                                  , INTENT(in   ) ::   kn_fct_h        ! order of the FCT scheme (=2 or 4)
81      INTEGER                                  , INTENT(in   ) ::   kn_fct_v        ! order of the FCT scheme (=2 or 4)
82      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
83      ! TEMP: This can be ST_2D(nn_hls) after trd_tra is tiled
84      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
85      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
86      !
87      INTEGER  ::   ji, jj, jk, jn                           ! dummy loop indices 
88      ! TEMP: This change not necessary after trd_tra is tiled
89      INTEGER  ::   itile
90      REAL(wp) ::   ztra                                     ! local scalar
91      REAL(wp) ::   zfp_ui, zfp_vj, zfp_wk, zC2t_u, zC4t_u   !   -      -
92      REAL(wp) ::   zfm_ui, zfm_vj, zfm_wk, zC2t_v, zC4t_v   !   -      -
93      REAL(wp), DIMENSION(ST_2D(nn_hls),jpk)        ::   zwi, zwx, zwy, zwz, ztu, ztv, zltu, zltv, ztw
94      ! TEMP: This change not necessary after trd_tra is tiled
95      REAL(wp), DIMENSION(:,:,:), SAVE, ALLOCATABLE ::   ztrdx, ztrdy, ztrdz
96      REAL(wp), DIMENSION(:,:,:)      , ALLOCATABLE ::   zptry
97      REAL(wp), DIMENSION(:,:,:)      , ALLOCATABLE ::   zwinf, zwdia, zwsup
98      LOGICAL  ::   ll_zAimp                                 ! flag to apply adaptive implicit vertical advection
99      !!----------------------------------------------------------------------
100      ! TEMP: This change not necessary after trd_tra is tiled
101      itile = ntile
102      !
103      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
104         IF( kt == kit000 )  THEN
105            IF(lwp) WRITE(numout,*)
106            IF(lwp) WRITE(numout,*) 'tra_adv_fct : FCT advection scheme on ', cdtype
107            IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
108         ENDIF
109      !! -- init to 0
110      zwi(:,:,:) = 0._wp
111      zwx(:,:,:) = 0._wp
112      zwy(:,:,:) = 0._wp
113      zwz(:,:,:) = 0._wp
114      ztu(:,:,:) = 0._wp
115      ztv(:,:,:) = 0._wp
116      zltu(:,:,:) = 0._wp
117      zltv(:,:,:) = 0._wp
118      ztw(:,:,:) = 0._wp
119         !
120         l_trd = .FALSE.            ! set local switches
121         l_hst = .FALSE.
122         l_ptr = .FALSE.
123         ll_zAimp = .FALSE.
124         IF( ( cdtype == 'TRA' .AND. l_trdtra  ) .OR. ( cdtype =='TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
125         IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) ) )    l_ptr = .TRUE.
126         IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR.  &
127            &                         iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )  l_hst = .TRUE.
128         !
129         ! TEMP: This can be ST_2D(nn_hls) after trd_tra is tiled
130         IF( kt == kit000 .AND. (l_trd .OR. l_hst) )  THEN
131            ALLOCATE( ztrdx(jpi,jpj,jpk), ztrdy(jpi,jpj,jpk), ztrdz(jpi,jpj,jpk) )
132         ENDIF
133      ENDIF
134      !
135      IF( l_ptr ) THEN 
136         ALLOCATE( zptry(ST_2D(nn_hls),jpk) )
137         zptry(:,:,:) = 0._wp
138      ENDIF
139      !                          ! surface & bottom value : flux set to zero one for all
140      zwz(:,:, 1 ) = 0._wp           
141      zwx(:,:,jpk) = 0._wp   ;   zwy(:,:,jpk) = 0._wp    ;    zwz(:,:,jpk) = 0._wp
142      !
143      zwi(:,:,:) = 0._wp       
144      !
145      ! If adaptive vertical advection, check if it is needed on this PE at this time
146      IF( ln_zad_Aimp ) THEN
147         IF( MAXVAL( ABS( wi(ST_2D(nn_hls),:) ) ) > 0._wp ) ll_zAimp = .TRUE.
148      END IF
149      ! If active adaptive vertical advection, build tridiagonal matrix
150      IF( ll_zAimp ) THEN
151         ALLOCATE(zwdia(ST_2D(nn_hls),jpk), zwinf(ST_2D(nn_hls),jpk), zwsup(ST_2D(nn_hls),jpk))
152         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
153            zwdia(ji,jj,jk) =  1._wp + p2dt * ( MAX( wi(ji,jj,jk) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )   &
154            &                               / e3t(ji,jj,jk,Krhs)
155            zwinf(ji,jj,jk) =  p2dt * MIN( wi(ji,jj,jk  ) , 0._wp ) / e3t(ji,jj,jk,Krhs)
156            zwsup(ji,jj,jk) = -p2dt * MAX( wi(ji,jj,jk+1) , 0._wp ) / e3t(ji,jj,jk,Krhs)
157         END_3D
158      END IF
159      !
160      DO jn = 1, kjpt            !==  loop over the tracers  ==!
161         !
162         !        !==  upstream advection with initial mass fluxes & intermediate update  ==!
163         !                    !* upstream tracer flux in the i and j direction
164         DO_3D( 1, 0, 1, 0, 1, jpkm1 )
165            ! upstream scheme
166            zfp_ui = pU(ji,jj,jk) + ABS( pU(ji,jj,jk) )
167            zfm_ui = pU(ji,jj,jk) - ABS( pU(ji,jj,jk) )
168            zfp_vj = pV(ji,jj,jk) + ABS( pV(ji,jj,jk) )
169            zfm_vj = pV(ji,jj,jk) - ABS( pV(ji,jj,jk) )
170            zwx(ji,jj,jk) = 0.5 * ( zfp_ui * pt(ji,jj,jk,jn,Kbb) + zfm_ui * pt(ji+1,jj  ,jk,jn,Kbb) )
171            zwy(ji,jj,jk) = 0.5 * ( zfp_vj * pt(ji,jj,jk,jn,Kbb) + zfm_vj * pt(ji  ,jj+1,jk,jn,Kbb) )
172         END_3D
173         !                    !* upstream tracer flux in the k direction *!
174         DO_3D( 1, 1, 1, 1, 2, jpkm1 )
175            zfp_wk = pW(ji,jj,jk) + ABS( pW(ji,jj,jk) )
176            zfm_wk = pW(ji,jj,jk) - ABS( pW(ji,jj,jk) )
177            zwz(ji,jj,jk) = 0.5 * ( zfp_wk * pt(ji,jj,jk,jn,Kbb) + zfm_wk * pt(ji,jj,jk-1,jn,Kbb) ) * wmask(ji,jj,jk)
178         END_3D
179         IF( ln_linssh ) THEN    ! top ocean value (only in linear free surface as zwz has been w-masked)
180            ! TODO: NOT TESTED- requires isf
181            IF( ln_isfcav ) THEN             ! top of the ice-shelf cavities and at the ocean surface
182               DO_2D( 1, 1, 1, 1 )
183                  zwz(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)   ! linear free surface
184               END_2D
185            ELSE                             ! no cavities: only at the ocean surface
186               DO_2D( 1, 1, 1, 1 )
187                  zwz(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
188               END_2D
189            ENDIF
190         ENDIF
191         !               
192         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
193            !                             ! total intermediate advective trends
194            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
195               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
196               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
197            !                             ! update and guess with monotonic sheme
198            pt(ji,jj,jk,jn,Krhs) =                   pt(ji,jj,jk,jn,Krhs) +       ztra   &
199               &                                  / e3t(ji,jj,jk,Kmm ) * tmask(ji,jj,jk)
200            zwi(ji,jj,jk)    = ( e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * ztra ) &
201               &                                  / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
202         END_3D
203         
204         IF ( ll_zAimp ) THEN
205            CALL tridia_solver( zwdia, zwsup, zwinf, zwi, zwi , 0 )
206            !
207            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp ;
208            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
209               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
210               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
211               ztw(ji,jj,jk) =  0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
212               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! update vertical fluxes
213            END_3D
214            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
215               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
216                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
217            END_3D
218            !
219         END IF
220         !               
221         ! TEMP: This change not necessary after trd_tra is tiled
222         IF( l_trd .OR. l_hst )  THEN             ! trend diagnostics (contribution of upstream fluxes)
223            DO_3D( 1, 0, 1, 0, 1, jpk )
224               ztrdx(ji,jj,jk) = zwx(ji,jj,jk)   ;   ztrdy(ji,jj,jk) = zwy(ji,jj,jk)   ;   ztrdz(ji,jj,jk) = zwz(ji,jj,jk)
225            END_3D
226         END IF
227         !                             ! "Poleward" heat and salt transports (contribution of upstream fluxes)
228         IF( l_ptr )   zptry(:,:,:) = zwy(:,:,:) 
229         !
230         !        !==  anti-diffusive flux : high order minus low order  ==!
231         !
232         SELECT CASE( kn_fct_h )    !* horizontal anti-diffusive fluxes
233         !
234         CASE(  2  )                   !- 2nd order centered
235            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
236               zwx(ji,jj,jk) = 0.5_wp * pU(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj,jk,jn,Kmm) ) - zwx(ji,jj,jk)
237               zwy(ji,jj,jk) = 0.5_wp * pV(ji,jj,jk) * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj+1,jk,jn,Kmm) ) - zwy(ji,jj,jk)
238            END_3D
239            !
240         CASE(  4  )                   !- 4th order centered
241            zltu(:,:,jpk) = 0._wp            ! Bottom value : flux set to zero
242            zltv(:,:,jpk) = 0._wp
243            DO jk = 1, jpkm1                 ! Laplacian
244               DO_2D( 1, 0, 1, 0 )
245                  ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
246                  ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
247               END_2D
248               DO_2D( 0, 0, 0, 0 )
249                  zltu(ji,jj,jk) = (  ztu(ji,jj,jk) + ztu(ji-1,jj,jk)  ) * r1_6
250                  zltv(ji,jj,jk) = (  ztv(ji,jj,jk) + ztv(ji,jj-1,jk)  ) * r1_6
251               END_2D
252            END DO
253            CALL lbc_lnk_multi( 'traadv_fct', zltu, 'T', 1.0_wp , zltv, 'T', 1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
254            !
255            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
256               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points
257               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
258               !                                                  ! C4 minus upstream advective fluxes
259               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * ( zC2t_u + zltu(ji,jj,jk) - zltu(ji+1,jj,jk) ) - zwx(ji,jj,jk)
260               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * ( zC2t_v + zltv(ji,jj,jk) - zltv(ji,jj+1,jk) ) - zwy(ji,jj,jk)
261            END_3D
262            !
263         CASE(  41 )                   !- 4th order centered       ==>>   !!gm coding attempt   need to be tested
264            ztu(:,:,jpk) = 0._wp             ! Bottom value : flux set to zero
265            ztv(:,:,jpk) = 0._wp
266            DO_3D( 1, 0, 1, 0, 1, jpkm1 )
267               ztu(ji,jj,jk) = ( pt(ji+1,jj  ,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * umask(ji,jj,jk)
268               ztv(ji,jj,jk) = ( pt(ji  ,jj+1,jk,jn,Kmm) - pt(ji,jj,jk,jn,Kmm) ) * vmask(ji,jj,jk)
269            END_3D
270            CALL lbc_lnk_multi( 'traadv_fct', ztu, 'U', -1.0_wp , ztv, 'V', -1.0_wp )   ! Lateral boundary cond. (unchanged sgn)
271            !
272            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
273               zC2t_u = pt(ji,jj,jk,jn,Kmm) + pt(ji+1,jj  ,jk,jn,Kmm)   ! 2 x C2 interpolation of T at u- & v-points (x2)
274               zC2t_v = pt(ji,jj,jk,jn,Kmm) + pt(ji  ,jj+1,jk,jn,Kmm)
275               !                                                  ! C4 interpolation of T at u- & v-points (x2)
276               zC4t_u =  zC2t_u + r1_6 * ( ztu(ji-1,jj  ,jk) - ztu(ji+1,jj  ,jk) )
277               zC4t_v =  zC2t_v + r1_6 * ( ztv(ji  ,jj-1,jk) - ztv(ji  ,jj+1,jk) )
278               !                                                  ! C4 minus upstream advective fluxes
279               zwx(ji,jj,jk) =  0.5_wp * pU(ji,jj,jk) * zC4t_u - zwx(ji,jj,jk)
280               zwy(ji,jj,jk) =  0.5_wp * pV(ji,jj,jk) * zC4t_v - zwy(ji,jj,jk)
281            END_3D
282            !
283         END SELECT
284         !                     
285         SELECT CASE( kn_fct_v )    !* vertical anti-diffusive fluxes (w-masked interior values)
286         !
287         CASE(  2  )                   !- 2nd order centered
288            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
289               zwz(ji,jj,jk) =  (  pW(ji,jj,jk) * 0.5_wp * ( pt(ji,jj,jk,jn,Kmm) + pt(ji,jj,jk-1,jn,Kmm) )   &
290                  &              - zwz(ji,jj,jk)  ) * wmask(ji,jj,jk)
291            END_3D
292            !
293         CASE(  4  )                   !- 4th order COMPACT
294            CALL interp_4th_cpt( pt(:,:,:,jn,Kmm) , ztw )   ! zwt = COMPACT interpolation of T at w-point
295            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
296               zwz(ji,jj,jk) = ( pW(ji,jj,jk) * ztw(ji,jj,jk) - zwz(ji,jj,jk) ) * wmask(ji,jj,jk)
297            END_3D
298            !
299         END SELECT
300         IF( ln_linssh ) THEN    ! top ocean value: high order = upstream  ==>>  zwz=0
301            zwz(:,:,1) = 0._wp   ! only ocean surface as interior zwz values have been w-masked
302         ENDIF
303         !         
304         IF ( ll_zAimp ) THEN
305            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
306               !                             ! total intermediate advective trends
307               ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
308                  &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
309                  &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
310               ztw(ji,jj,jk)  = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
311            END_3D
312            !
313            CALL tridia_solver( zwdia, zwsup, zwinf, ztw, ztw , 0 )
314            !
315            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
316               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
317               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
318               zwz(ji,jj,jk) =  zwz(ji,jj,jk) + 0.5 * e1e2t(ji,jj) * ( zfp_wk * ztw(ji,jj,jk) + zfm_wk * ztw(ji,jj,jk-1) ) * wmask(ji,jj,jk)
319            END_3D
320         END IF
321         !
322         CALL lbc_lnk_multi( 'traadv_fct', zwi, 'T', 1.0_wp, zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp,  zwz, 'W',  1.0_wp )
323         !
324         !        !==  monotonicity algorithm  ==!
325         !
326         CALL nonosc( Kmm, pt(:,:,:,jn,Kbb), zwx, zwy, zwz, zwi, p2dt )
327         !
328         !        !==  final trend with corrected fluxes  ==!
329         !
330         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
331            ztra = - (  zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )   &
332               &      + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  )   &
333               &      + zwz(ji,jj,jk) - zwz(ji  ,jj  ,jk+1) ) * r1_e1e2t(ji,jj)
334            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) + ztra / e3t(ji,jj,jk,Kmm)
335            zwi(ji,jj,jk) = zwi(ji,jj,jk) + p2dt * ztra / e3t(ji,jj,jk,Krhs) * tmask(ji,jj,jk)
336         END_3D
337         !
338         IF ( ll_zAimp ) THEN
339            !
340            ztw(:,:,1) = 0._wp ; ztw(:,:,jpk) = 0._wp
341            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
342               zfp_wk = wi(ji,jj,jk) + ABS( wi(ji,jj,jk) )
343               zfm_wk = wi(ji,jj,jk) - ABS( wi(ji,jj,jk) )
344               ztw(ji,jj,jk) = - 0.5 * e1e2t(ji,jj) * ( zfp_wk * zwi(ji,jj,jk) + zfm_wk * zwi(ji,jj,jk-1) ) * wmask(ji,jj,jk)
345               zwz(ji,jj,jk) = zwz(ji,jj,jk) + ztw(ji,jj,jk) ! Update vertical fluxes for trend diagnostic
346            END_3D
347            DO_3D( 0, 0, 0, 0, 1, jpkm1 )
348               pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( ztw(ji,jj,jk) - ztw(ji  ,jj  ,jk+1) ) &
349                  &                                        * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
350            END_3D
351         END IF         
352         !
353         ! TEMP: These changes not necessary after trd_tra is tiled
354         IF( l_trd .OR. l_hst ) THEN   ! trend diagnostics // heat/salt transport
355            DO_3D( 1, 0, 1, 0, 1, jpk )
356               ztrdx(ji,jj,jk) = ztrdx(ji,jj,jk) + zwx(ji,jj,jk)  ! <<< add anti-diffusive fluxes
357               ztrdy(ji,jj,jk) = ztrdy(ji,jj,jk) + zwy(ji,jj,jk)  !     to upstream fluxes
358               ztrdz(ji,jj,jk) = ztrdz(ji,jj,jk) + zwz(ji,jj,jk)  !
359            END_3D
360            !
361            IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only for the full domain
362               IF( l_trd ) THEN              ! trend diagnostics
363                  IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )         ! Use full domain
364
365                  ! TODO: TO BE TILED- trd_tra
366                  CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kmm) )
367                  CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kmm) )
368                  CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kmm) )
369
370                  IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = itile )     ! Revert to tile domain
371               ENDIF
372            ENDIF
373            !                             ! heat/salt transport
374            IF( l_hst )   CALL dia_ar5_hst( jn, 'adv', ztrdx(ST_2D(nn_hls),:), ztrdy(ST_2D(nn_hls),:) )
375            !
376         ENDIF
377         IF( l_ptr ) THEN              ! "Poleward" transports
378            zptry(:,:,:) = zptry(:,:,:) + zwy(:,:,:)  ! <<< add anti-diffusive fluxes
379            CALL dia_ptr_hst( jn, 'adv', zptry(:,:,:) )
380         ENDIF
381         !
382      END DO                     ! end of tracer loop
383      !
384      IF ( ll_zAimp ) THEN
385         DEALLOCATE( zwdia, zwinf, zwsup )
386      ENDIF
387      ! TEMP: These changes not necessary after trd_tra is tiled
388!      IF( l_trd .OR. l_hst ) THEN
389!         DEALLOCATE( ztrdx, ztrdy, ztrdz )
390!      ENDIF
391      IF( l_ptr ) THEN
392         DEALLOCATE( zptry )
393      ENDIF
394      !
395   END SUBROUTINE tra_adv_fct
396
397
398   SUBROUTINE nonosc( Kmm, pbef, paa, pbb, pcc, paft, p2dt )
399      !!---------------------------------------------------------------------
400      !!                    ***  ROUTINE nonosc  ***
401      !!     
402      !! **  Purpose :   compute monotonic tracer fluxes from the upstream
403      !!       scheme and the before field by a nonoscillatory algorithm
404      !!
405      !! **  Method  :   ... ???
406      !!       warning : pbef and paft must be masked, but the boundaries
407      !!       conditions on the fluxes are not necessary zalezak (1979)
408      !!       drange (1995) multi-dimensional forward-in-time and upstream-
409      !!       in-space based differencing for fluid
410      !!----------------------------------------------------------------------
411      INTEGER                         , INTENT(in   ) ::   Kmm             ! time level index
412      REAL(wp)                        , INTENT(in   ) ::   p2dt            ! tracer time-step
413      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pbef            ! before field
414      REAL(wp), DIMENSION(ST_2D(nn_hls)    ,jpk), INTENT(in   ) ::   paft            ! after field
415      REAL(wp), DIMENSION(ST_2D(nn_hls)    ,jpk), INTENT(inout) ::   paa, pbb, pcc   ! monotonic fluxes in the 3 directions
416      !
417      INTEGER  ::   ji, jj, jk   ! dummy loop indices
418      INTEGER  ::   ikm1         ! local integer
419      REAL(dp) ::   zpos, zneg, zbt, za, zb, zc, zbig, zrtrn    ! local scalars
420      REAL(dp) ::   zau, zbu, zcu, zav, zbv, zcv, zup, zdo            !   -      -
421      REAL(dp), DIMENSION(ST_2D(nn_hls),jpk) :: zbetup, zbetdo, zbup, zbdo
422      !!----------------------------------------------------------------------
423      !
424      zbig  = 1.e+40_dp
425      zrtrn = 1.e-15_dp
426      zbetup(:,:,:) = 0._dp   ;   zbetdo(:,:,:) = 0._dp
427
428      ! Search local extrema
429      ! --------------------
430      ! max/min of pbef & paft with large negative/positive value (-/+zbig) inside land
431      DO_3D( 1, 1, 1, 1, 1, jpk )
432         zbup(ji,jj,jk) = MAX( pbef(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
433            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) - zbig * ( 1._wp - tmask(ji,jj,jk) )  )
434         zbdo(ji,jj,jk) = MIN( pbef(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) ),   &
435            &                  paft(ji,jj,jk) * tmask(ji,jj,jk) + zbig * ( 1._wp - tmask(ji,jj,jk) )  )
436      END_3D
437
438      DO jk = 1, jpkm1
439         ikm1 = MAX(jk-1,1)
440         DO_2D( 0, 0, 0, 0 )
441
442            ! search maximum in neighbourhood
443            zup = MAX(  zbup(ji  ,jj  ,jk  ),   &
444               &        zbup(ji-1,jj  ,jk  ), zbup(ji+1,jj  ,jk  ),   &
445               &        zbup(ji  ,jj-1,jk  ), zbup(ji  ,jj+1,jk  ),   &
446               &        zbup(ji  ,jj  ,ikm1), zbup(ji  ,jj  ,jk+1)  )
447
448            ! search minimum in neighbourhood
449            zdo = MIN(  zbdo(ji  ,jj  ,jk  ),   &
450               &        zbdo(ji-1,jj  ,jk  ), zbdo(ji+1,jj  ,jk  ),   &
451               &        zbdo(ji  ,jj-1,jk  ), zbdo(ji  ,jj+1,jk  ),   &
452               &        zbdo(ji  ,jj  ,ikm1), zbdo(ji  ,jj  ,jk+1)  )
453
454            ! positive part of the flux
455            zpos = MAX( 0., paa(ji-1,jj  ,jk  ) ) - MIN( 0., paa(ji  ,jj  ,jk  ) )   &
456               & + MAX( 0., pbb(ji  ,jj-1,jk  ) ) - MIN( 0., pbb(ji  ,jj  ,jk  ) )   &
457               & + MAX( 0., pcc(ji  ,jj  ,jk+1) ) - MIN( 0., pcc(ji  ,jj  ,jk  ) )
458
459            ! negative part of the flux
460            zneg = MAX( 0., paa(ji  ,jj  ,jk  ) ) - MIN( 0., paa(ji-1,jj  ,jk  ) )   &
461               & + MAX( 0., pbb(ji  ,jj  ,jk  ) ) - MIN( 0., pbb(ji  ,jj-1,jk  ) )   &
462               & + MAX( 0., pcc(ji  ,jj  ,jk  ) ) - MIN( 0., pcc(ji  ,jj  ,jk+1) )
463
464            ! up & down beta terms
465            zbt = e1e2t(ji,jj) * e3t(ji,jj,jk,Kmm) / p2dt
466            zbetup(ji,jj,jk) = ( zup            - paft(ji,jj,jk) ) / ( zpos + zrtrn ) * zbt
467            zbetdo(ji,jj,jk) = ( paft(ji,jj,jk) - zdo            ) / ( zneg + zrtrn ) * zbt
468         END_2D
469      END DO
470      CALL lbc_lnk_multi( 'traadv_fct', zbetup, 'T', 1.0_wp , zbetdo, 'T', 1.0_wp )   ! lateral boundary cond. (unchanged sign)
471
472      ! 3. monotonic flux in the i & j direction (paa & pbb)
473      ! ----------------------------------------
474      DO_3D( 0, 0, 0, 0, 1, jpkm1 )
475         zau = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji+1,jj,jk) )
476         zbu = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji+1,jj,jk) )
477         zcu =       ( 0.5  + SIGN( 0.5_wp , paa(ji,jj,jk) ) )
478         paa(ji,jj,jk) = paa(ji,jj,jk) * ( zcu * zau + ( 1._wp - zcu) * zbu )
479
480         zav = MIN( 1._wp, zbetdo(ji,jj,jk), zbetup(ji,jj+1,jk) )
481         zbv = MIN( 1._wp, zbetup(ji,jj,jk), zbetdo(ji,jj+1,jk) )
482         zcv =       ( 0.5  + SIGN( 0.5_wp , pbb(ji,jj,jk) ) )
483         pbb(ji,jj,jk) = pbb(ji,jj,jk) * ( zcv * zav + ( 1._wp - zcv) * zbv )
484
485! monotonic flux in the k direction, i.e. pcc
486! -------------------------------------------
487         za = MIN( 1., zbetdo(ji,jj,jk+1), zbetup(ji,jj,jk) )
488         zb = MIN( 1., zbetup(ji,jj,jk+1), zbetdo(ji,jj,jk) )
489         zc =       ( 0.5  + SIGN( 0.5_wp , pcc(ji,jj,jk+1) ) )
490         pcc(ji,jj,jk+1) = pcc(ji,jj,jk+1) * ( zc * za + ( 1._wp - zc) * zb )
491      END_3D
492      CALL lbc_lnk_multi( 'traadv_fct', paa, 'U', -1.0_wp , pbb, 'V', -1.0_wp )   ! lateral boundary condition (changed sign)
493      !
494   END SUBROUTINE nonosc
495
496
497   SUBROUTINE interp_4th_cpt_org( pt_in, pt_out )
498      !!----------------------------------------------------------------------
499      !!                  ***  ROUTINE interp_4th_cpt_org  ***
500      !!
501      !! **  Purpose :   Compute the interpolation of tracer at w-point
502      !!
503      !! **  Method  :   4th order compact interpolation
504      !!----------------------------------------------------------------------
505      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! now tracer fields
506      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(  out) ::   pt_out   ! now tracer field interpolated at w-pts
507      !
508      INTEGER :: ji, jj, jk   ! dummy loop integers
509      REAL(wp),DIMENSION(jpi,jpj,jpk) :: zwd, zwi, zws, zwrm, zwt
510      !!----------------------------------------------------------------------
511     
512      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
513         zwd (ji,jj,jk) = 4._wp
514         zwi (ji,jj,jk) = 1._wp
515         zws (ji,jj,jk) = 1._wp
516         zwrm(ji,jj,jk) = 3._wp * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
517         !
518         IF( tmask(ji,jj,jk+1) == 0._wp) THEN   ! Switch to second order centered at bottom
519            zwd (ji,jj,jk) = 1._wp
520            zwi (ji,jj,jk) = 0._wp
521            zws (ji,jj,jk) = 0._wp
522            zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )   
523         ENDIF
524      END_3D
525      !
526      jk = 2                                          ! Switch to second order centered at top
527      DO_2D( 1, 1, 1, 1 )
528         zwd (ji,jj,jk) = 1._wp
529         zwi (ji,jj,jk) = 0._wp
530         zws (ji,jj,jk) = 0._wp
531         zwrm(ji,jj,jk) = 0.5 * ( pt_in(ji,jj,jk-1) + pt_in(ji,jj,jk) )
532      END_2D
533      !
534      !                       !==  tridiagonal solve  ==!
535      DO_2D( 1, 1, 1, 1 )
536         zwt(ji,jj,2) = zwd(ji,jj,2)
537      END_2D
538      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
539         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
540      END_3D
541      !
542      DO_2D( 1, 1, 1, 1 )
543         pt_out(ji,jj,2) = zwrm(ji,jj,2)
544      END_2D
545      DO_3D( 1, 1, 1, 1, 3, jpkm1 )
546         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
547      END_3D
548
549      DO_2D( 1, 1, 1, 1 )
550         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
551      END_2D
552      DO_3DS( 1, 1, 1, 1, jpk-2, 2, -1 )
553         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
554      END_3D
555      !   
556   END SUBROUTINE interp_4th_cpt_org
557   
558
559   SUBROUTINE interp_4th_cpt( pt_in, pt_out )
560      !!----------------------------------------------------------------------
561      !!                  ***  ROUTINE interp_4th_cpt  ***
562      !!
563      !! **  Purpose :   Compute the interpolation of tracer at w-point
564      !!
565      !! **  Method  :   4th order compact interpolation
566      !!----------------------------------------------------------------------
567      REAL(wp),DIMENSION(jpi,jpj,jpk), INTENT(in   ) ::   pt_in    ! field at t-point
568      REAL(wp),DIMENSION(ST_2D(nn_hls)    ,jpk), INTENT(  out) ::   pt_out   ! field interpolated at w-point
569      !
570      INTEGER ::   ji, jj, jk   ! dummy loop integers
571      INTEGER ::   ikt, ikb     ! local integers
572      REAL(wp),DIMENSION(ST_2D(nn_hls),jpk) :: zwd, zwi, zws, zwrm, zwt
573      !!----------------------------------------------------------------------
574      !
575      !                      !==  build the three diagonal matrix & the RHS  ==!
576      !
577      DO_3D( 0, 0, 0, 0, 3, jpkm1 )
578         zwd (ji,jj,jk) = 3._wp * wmask(ji,jj,jk) + 1._wp                 !       diagonal
579         zwi (ji,jj,jk) =         wmask(ji,jj,jk)                         ! lower diagonal
580         zws (ji,jj,jk) =         wmask(ji,jj,jk)                         ! upper diagonal
581         zwrm(ji,jj,jk) = 3._wp * wmask(ji,jj,jk)                     &   ! RHS
582            &           *       ( pt_in(ji,jj,jk) + pt_in(ji,jj,jk-1) )
583      END_3D
584      !
585!!gm
586!      SELECT CASE( kbc )               !* boundary condition
587!      CASE( np_NH   )   ! Neumann homogeneous at top & bottom
588!      CASE( np_CEN2 )   ! 2nd order centered  at top & bottom
589!      END SELECT
590!!gm 
591      !
592      ! TODO: NOT TESTED- requires isf
593      IF ( ln_isfcav ) THEN            ! set level two values which may not be set in ISF case
594         zwd(:,:,2) = 1._wp  ;  zwi(:,:,2) = 0._wp  ;  zws(:,:,2) = 0._wp  ;  zwrm(:,:,2) = 0._wp
595      END IF
596      !
597      DO_2D( 0, 0, 0, 0 )
598         ikt = mikt(ji,jj) + 1            ! w-point below the 1st  wet point
599         ikb = MAX(mbkt(ji,jj), 2)        !     -   above the last wet point
600         !
601         zwd (ji,jj,ikt) = 1._wp          ! top
602         zwi (ji,jj,ikt) = 0._wp
603         zws (ji,jj,ikt) = 0._wp
604         zwrm(ji,jj,ikt) = 0.5_wp * ( pt_in(ji,jj,ikt-1) + pt_in(ji,jj,ikt) )
605         !
606         zwd (ji,jj,ikb) = 1._wp          ! bottom
607         zwi (ji,jj,ikb) = 0._wp
608         zws (ji,jj,ikb) = 0._wp
609         zwrm(ji,jj,ikb) = 0.5_wp * ( pt_in(ji,jj,ikb-1) + pt_in(ji,jj,ikb) )           
610      END_2D
611      !
612      !                       !==  tridiagonal solver  ==!
613      !
614      DO_2D( 0, 0, 0, 0 )
615         zwt(ji,jj,2) = zwd(ji,jj,2)
616      END_2D
617      DO_3D( 0, 0, 0, 0, 3, jpkm1 )
618         zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) /zwt(ji,jj,jk-1)
619      END_3D
620      !
621      DO_2D( 0, 0, 0, 0 )
622         pt_out(ji,jj,2) = zwrm(ji,jj,2)
623      END_2D
624      DO_3D( 0, 0, 0, 0, 3, jpkm1 )
625         pt_out(ji,jj,jk) = zwrm(ji,jj,jk) - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
626      END_3D
627
628      DO_2D( 0, 0, 0, 0 )
629         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
630      END_2D
631      DO_3DS( 0, 0, 0, 0, jpk-2, 2, -1 )
632         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - zws(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
633      END_3D
634      !   
635   END SUBROUTINE interp_4th_cpt
636
637
638   SUBROUTINE tridia_solver( pD, pU, pL, pRHS, pt_out , klev )
639      !!----------------------------------------------------------------------
640      !!                  ***  ROUTINE tridia_solver  ***
641      !!
642      !! **  Purpose :   solve a symmetric 3diagonal system
643      !!
644      !! **  Method  :   solve M.t_out = RHS(t)  where M is a tri diagonal matrix ( jpk*jpk )
645      !!     
646      !!             ( D_1 U_1  0   0   0  )( t_1 )   ( RHS_1 )
647      !!             ( L_2 D_2 U_2  0   0  )( t_2 )   ( RHS_2 )
648      !!             (  0  L_3 D_3 U_3  0  )( t_3 ) = ( RHS_3 )
649      !!             (        ...          )( ... )   ( ...  )
650      !!             (  0   0   0  L_k D_k )( t_k )   ( RHS_k )
651      !!     
652      !!        M is decomposed in the product of an upper and lower triangular matrix.
653      !!        The tri-diagonals matrix is given as input 3D arrays:   pD, pU, pL
654      !!        (i.e. the Diagonal, the Upper diagonal, and the Lower diagonal).
655      !!        The solution is pta.
656      !!        The 3d array zwt is used as a work space array.
657      !!----------------------------------------------------------------------
658      REAL(wp),DIMENSION(ST_2D(nn_hls),jpk), INTENT(in   ) ::   pD, pU, PL    ! 3-diagonal matrix
659      REAL(wp),DIMENSION(ST_2D(nn_hls),jpk), INTENT(in   ) ::   pRHS          ! Right-Hand-Side
660      REAL(wp),DIMENSION(ST_2D(nn_hls),jpk), INTENT(  out) ::   pt_out        !!gm field at level=F(klev)
661      INTEGER                    , INTENT(in   ) ::   klev          ! =1 pt_out at w-level
662      !                                                             ! =0 pt at t-level
663      INTEGER ::   ji, jj, jk   ! dummy loop integers
664      INTEGER ::   kstart       ! local indices
665      REAL(wp),DIMENSION(ST_2D(nn_hls),jpk) ::   zwt   ! 3D work array
666      !!----------------------------------------------------------------------
667      !
668      kstart =  1  + klev
669      !
670      DO_2D( 0, 0, 0, 0 )
671         zwt(ji,jj,kstart) = pD(ji,jj,kstart)
672      END_2D
673      DO_3D( 0, 0, 0, 0, kstart+1, jpkm1 )
674         zwt(ji,jj,jk) = pD(ji,jj,jk) - pL(ji,jj,jk) * pU(ji,jj,jk-1) /zwt(ji,jj,jk-1)
675      END_3D
676      !
677      DO_2D( 0, 0, 0, 0 )
678         pt_out(ji,jj,kstart) = pRHS(ji,jj,kstart)
679      END_2D
680      DO_3D( 0, 0, 0, 0, kstart+1, jpkm1 )
681         pt_out(ji,jj,jk) = pRHS(ji,jj,jk) - pL(ji,jj,jk) / zwt(ji,jj,jk-1) *pt_out(ji,jj,jk-1)             
682      END_3D
683
684      DO_2D( 0, 0, 0, 0 )
685         pt_out(ji,jj,jpkm1) = pt_out(ji,jj,jpkm1) / zwt(ji,jj,jpkm1)
686      END_2D
687      DO_3DS( 0, 0, 0, 0, jpk-2, kstart, -1 )
688         pt_out(ji,jj,jk) = ( pt_out(ji,jj,jk) - pU(ji,jj,jk) * pt_out(ji,jj,jk+1) ) / zwt(ji,jj,jk)
689      END_3D
690      !
691   END SUBROUTINE tridia_solver
692
693   !!======================================================================
694END MODULE traadv_fct
Note: See TracBrowser for help on using the repository browser.