New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traadv_mus.F90 in NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/TRA – NEMO

source: NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/TRA/traadv_mus.F90 @ 13516

Last change on this file since 13516 was 13516, checked in by hadcv, 4 years ago

Tiling for tra_adv
  • Property svn:keywords set to Id
File size: 15.8 KB
Line 
1MODULE traadv_mus
2   !!======================================================================
3   !!                       ***  MODULE  traadv_mus  ***
4   !! Ocean  tracers:  horizontal & vertical advective trend
5   !!======================================================================
6   !! History :       !  2000-06  (A.Estublier)  for passive tracers
7   !!                 !  2001-08  (E.Durand, G.Madec)  adapted for T & S
8   !!   NEMO     1.0  !  2002-06  (G. Madec)  F90: Free form and module
9   !!            3.2  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA + switch from velocity to transport
10   !!            3.4  !  2012-06  (P. Oddo, M. Vichi) include the upstream where needed
11   !!            3.7  !  2015-09  (G. Madec) add the ice-shelf cavities boundary condition
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   tra_adv_mus   : update the tracer trend with the horizontal
16   !!                   and vertical advection trends using MUSCL scheme
17   !!----------------------------------------------------------------------
18   USE oce            ! ocean dynamics and active tracers
19   USE trc_oce        ! share passive tracers/Ocean variables
20   USE dom_oce        ! ocean space and time domain
21   ! TEMP: This change not necessary after trd_tra is tiled
22   USE domain, ONLY : dom_tile
23   USE trd_oce        ! trends: ocean variables
24   USE trdtra         ! tracers trends manager
25   USE sbcrnf         ! river runoffs
26   USE diaptr         ! poleward transport diagnostics
27   USE diaar5         ! AR5 diagnostics
28
29   !
30   USE iom            ! XIOS library
31   USE in_out_manager ! I/O manager
32   USE lib_mpp        ! distribued memory computing
33   USE lbclnk         ! ocean lateral boundary condition (or mpp link)
34   USE lib_fortran    ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) 
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   tra_adv_mus   ! routine called by traadv.F90
40   
41   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   upsmsk   !: mixed upstream/centered scheme near some straits
42   !                                                           !  and in closed seas (orca 2 and 1 configurations)
43   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xind     !: mixed upstream/centered index
44   
45   LOGICAL  ::   l_trd   ! flag to compute trends
46   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
47   LOGICAL  ::   l_hst   ! flag to compute heat/salt transport
48
49   !! * Substitutions
50#  include "do_loop_substitute.h90"
51#  include "domzgr_substitute.h90"
52   !!----------------------------------------------------------------------
53   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
54   !! $Id$
55   !! Software governed by the CeCILL license (see ./LICENSE)
56   !!----------------------------------------------------------------------
57CONTAINS
58
59   SUBROUTINE tra_adv_mus( kt, kit000, cdtype, p2dt, pU, pV, pW,             &
60      &                    Kbb, Kmm, pt, kjpt, Krhs, ld_msc_ups )
61      !!----------------------------------------------------------------------
62      !!                    ***  ROUTINE tra_adv_mus  ***
63      !!
64      !! ** Purpose :   Compute the now trend due to total advection of tracers
65      !!              using a MUSCL scheme (Monotone Upstream-centered Scheme for
66      !!              Conservation Laws) and add it to the general tracer trend.
67      !!
68      !! ** Method  : MUSCL scheme plus centered scheme at ocean boundaries
69      !!              ld_msc_ups=T :
70      !!
71      !! ** Action : - update pt(:,:,:,:,Krhs)  with the now advective tracer trends
72      !!             - send trends to trdtra module for further diagnostcs (l_trdtra=T)
73      !!             - poleward advective heat and salt transport (ln_diaptr=T)
74      !!
75      !! References : Estubier, A., and M. Levy, Notes Techn. Pole de Modelisation
76      !!              IPSL, Sept. 2000 (http://www.lodyc.jussieu.fr/opa)
77      !!----------------------------------------------------------------------
78      INTEGER                                  , INTENT(in   ) ::   kt              ! ocean time-step index
79      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs  ! ocean time level indices
80      INTEGER                                  , INTENT(in   ) ::   kit000          ! first time step index
81      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype          ! =TRA or TRC (tracer indicator)
82      INTEGER                                  , INTENT(in   ) ::   kjpt            ! number of tracers
83      LOGICAL                                  , INTENT(in   ) ::   ld_msc_ups      ! use upstream scheme within muscl
84      REAL(wp)                                 , INTENT(in   ) ::   p2dt            ! tracer time-step
85      ! TEMP: This can be ST_2D(nn_hls) after trd_tra is tiled
86      REAL(wp), DIMENSION(jpi,jpj,jpk         ), INTENT(in   ) ::   pU, pV, pW      ! 3 ocean volume flux components
87      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt              ! tracers and RHS of tracer equation
88      !
89      ! TEMP: This change not necessary after trd_tra is tiled
90      INTEGER  ::   itile
91      INTEGER  ::   ji, jj, jk, jn   ! dummy loop indices
92      INTEGER  ::   ierr             ! local integer
93      REAL(wp) ::   zu, z0u, zzwx, zw , zalpha   ! local scalars
94      REAL(wp) ::   zv, z0v, zzwy, z0w           !   -      -
95      REAL(wp), DIMENSION(ST_2D(nn_hls),jpk) ::   zwx, zslpx   ! 3D workspace
96      REAL(wp), DIMENSION(ST_2D(nn_hls),jpk) ::   zwy, zslpy   ! -      -
97      ! TEMP: This change not necessary after trd_tra is tiled
98      REAL(wp), DIMENSION(:,:,:), SAVE, ALLOCATABLE ::   ztrdx, ztrdy, ztrdz
99      !!----------------------------------------------------------------------
100      ! TEMP: This change not necessary after trd_tra is tiled
101      itile = ntile
102      !
103      IF( ntile == 0 .OR. ntile == 1 )  THEN                       ! Do only on the first tile
104         IF( kt == kit000 )  THEN
105            IF(lwp) WRITE(numout,*)
106            IF(lwp) WRITE(numout,*) 'tra_adv : MUSCL advection scheme on ', cdtype
107            IF(lwp) WRITE(numout,*) '        : mixed up-stream           ', ld_msc_ups
108            IF(lwp) WRITE(numout,*) '~~~~~~~'
109            IF(lwp) WRITE(numout,*)
110            !
111            ! Upstream / MUSCL scheme indicator
112            !
113            ALLOCATE( xind(jpi,jpj,jpk), STAT=ierr )
114            xind(:,:,:) = 1._wp              ! set equal to 1 where up-stream is not needed
115            !
116            IF( ld_msc_ups ) THEN            ! define the upstream indicator (if asked)
117               ALLOCATE( upsmsk(jpi,jpj), STAT=ierr )
118               upsmsk(:,:) = 0._wp                             ! not upstream by default
119               !
120               DO jk = 1, jpkm1
121                  xind(:,:,jk) = 1._wp                              &                 ! =>1 where up-stream is not needed
122                     &         - MAX ( rnfmsk(:,:) * rnfmsk_z(jk),  &                 ! =>0 near runoff mouths (& closed sea outflows)
123                     &                 upsmsk(:,:)                ) * tmask(:,:,jk)   ! =>0 in some user defined area
124               END DO
125            ENDIF
126            !
127         ENDIF
128         !
129         l_trd = .FALSE.
130         l_hst = .FALSE.
131         l_ptr = .FALSE.
132         IF( ( cdtype == 'TRA' .AND. l_trdtra ) .OR. ( cdtype == 'TRC' .AND. l_trdtrc ) )      l_trd = .TRUE.
133         IF(   cdtype == 'TRA' .AND. ( iom_use( 'sophtadv' ) .OR. iom_use( 'sophtadv' ) )  )   l_ptr = .TRUE.
134         IF(   cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
135            &                          iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) ) l_hst = .TRUE.
136
137         ! TEMP: This can be ST_2D(nn_hls) after trd_tra is tiled
138         IF( kt == kit000 .AND. l_trd ) THEN
139            ALLOCATE( ztrdx(jpi,jpj,jpk), ztrdy(jpi,jpj,jpk), ztrdz(jpi,jpj,jpk) )
140         ENDIF
141      ENDIF
142      !
143      DO jn = 1, kjpt            !==  loop over the tracers  ==!
144         !
145         !                          !* Horizontal advective fluxes
146         !
147         !                                !-- first guess of the slopes
148         zwx(:,:,jpk) = 0._wp                   ! bottom values
149         zwy(:,:,jpk) = 0._wp 
150         DO_3D( 1, 0, 1, 0, 1, jpkm1 )
151            zwx(ji,jj,jk) = umask(ji,jj,jk) * ( pt(ji+1,jj,jk,jn,Kbb) - pt(ji,jj,jk,jn,Kbb) )
152            zwy(ji,jj,jk) = vmask(ji,jj,jk) * ( pt(ji,jj+1,jk,jn,Kbb) - pt(ji,jj,jk,jn,Kbb) )
153         END_3D
154         ! lateral boundary conditions   (changed sign)
155         CALL lbc_lnk_multi( 'traadv_mus', zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp )
156         !                                !-- Slopes of tracer
157         zslpx(:,:,jpk) = 0._wp                 ! bottom values
158         zslpy(:,:,jpk) = 0._wp
159         DO_3D( 0, 1, 0, 1, 1, jpkm1 )
160            zslpx(ji,jj,jk) =                       ( zwx(ji,jj,jk) + zwx(ji-1,jj  ,jk) )   &
161               &            * ( 0.25 + SIGN( 0.25_wp, zwx(ji,jj,jk) * zwx(ji-1,jj  ,jk) ) )
162            zslpy(ji,jj,jk) =                       ( zwy(ji,jj,jk) + zwy(ji  ,jj-1,jk) )   &
163               &            * ( 0.25 + SIGN( 0.25_wp, zwy(ji,jj,jk) * zwy(ji  ,jj-1,jk) ) )
164         END_3D
165         !
166         DO_3D( 0, 1, 0, 1, 1, jpkm1 )
167            zslpx(ji,jj,jk) = SIGN( 1.0_wp, zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji  ,jj,jk) ),   &
168               &                                                     2.*ABS( zwx  (ji-1,jj,jk) ),   &
169               &                                                     2.*ABS( zwx  (ji  ,jj,jk) ) )
170            zslpy(ji,jj,jk) = SIGN( 1.0_wp, zslpy(ji,jj,jk) ) * MIN(    ABS( zslpy(ji,jj  ,jk) ),   &
171               &                                                     2.*ABS( zwy  (ji,jj-1,jk) ),   &
172               &                                                     2.*ABS( zwy  (ji,jj  ,jk) ) )
173         END_3D
174         !
175         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
176            ! MUSCL fluxes
177            z0u = SIGN( 0.5_wp, pU(ji,jj,jk) )
178            zalpha = 0.5 - z0u
179            zu  = z0u - 0.5 * pU(ji,jj,jk) * p2dt * r1_e1e2u(ji,jj) / e3u(ji,jj,jk,Kmm)
180            zzwx = pt(ji+1,jj,jk,jn,Kbb) + xind(ji,jj,jk) * zu * zslpx(ji+1,jj,jk)
181            zzwy = pt(ji  ,jj,jk,jn,Kbb) + xind(ji,jj,jk) * zu * zslpx(ji  ,jj,jk)
182            zwx(ji,jj,jk) = pU(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
183            !
184            z0v = SIGN( 0.5_wp, pV(ji,jj,jk) )
185            zalpha = 0.5 - z0v
186            zv  = z0v - 0.5 * pV(ji,jj,jk) * p2dt * r1_e1e2v(ji,jj) / e3v(ji,jj,jk,Kmm)
187            zzwx = pt(ji,jj+1,jk,jn,Kbb) + xind(ji,jj,jk) * zv * zslpy(ji,jj+1,jk)
188            zzwy = pt(ji,jj  ,jk,jn,Kbb) + xind(ji,jj,jk) * zv * zslpy(ji,jj  ,jk)
189            zwy(ji,jj,jk) = pV(ji,jj,jk) * ( zalpha * zzwx + (1.-zalpha) * zzwy )
190         END_3D
191         CALL lbc_lnk_multi( 'traadv_mus', zwx, 'U', -1.0_wp , zwy, 'V', -1.0_wp )   ! lateral boundary conditions   (changed sign)
192         !
193         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
194            pt(ji,jj,jk,jn,Krhs) = pt(ji,jj,jk,jn,Krhs) - ( zwx(ji,jj,jk) - zwx(ji-1,jj  ,jk  )       &
195            &                                     + zwy(ji,jj,jk) - zwy(ji  ,jj-1,jk  ) )     &
196            &                                   * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
197         END_3D
198         !                                ! trend diagnostics
199         ! TEMP: These changes not necessary after trd_tra is tiled
200         IF( l_trd )  THEN
201            DO_3D( 1, 0, 1, 0, 1, jpk )
202               ztrdx(ji,jj,jk) = zwx(ji,jj,jk)
203               ztrdy(ji,jj,jk) = zwy(ji,jj,jk)
204            END_3D
205
206            IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only for the full domain
207               IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )         ! Use full domain
208
209               ! TODO: TO BE TILED- trd_tra
210               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_xad, ztrdx, pU, pt(:,:,:,jn,Kbb) )
211               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_yad, ztrdy, pV, pt(:,:,:,jn,Kbb) )
212
213               IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = itile )   ! Revert to tile domain
214            ENDIF
215         END IF
216         !                                 ! "Poleward" heat and salt transports
217         IF( l_ptr )  CALL dia_ptr_hst( jn, 'adv', zwy(:,:,:) )
218         !                                 !  heat transport
219         IF( l_hst )  CALL dia_ar5_hst( jn, 'adv', zwx(:,:,:), zwy(:,:,:) )
220         !
221         !                          !* Vertical advective fluxes
222         !
223         !                                !-- first guess of the slopes
224         zwx(:,:, 1 ) = 0._wp                   ! surface & bottom boundary conditions
225         zwx(:,:,jpk) = 0._wp
226         DO_3D( 1, 1, 1, 1, 2, jpkm1 )                ! interior values
227            zwx(ji,jj,jk) = tmask(ji,jj,jk) * ( pt(ji,jj,jk-1,jn,Kbb) - pt(ji,jj,jk,jn,Kbb) )
228         END_3D
229         !                                !-- Slopes of tracer
230         zslpx(:,:,1) = 0._wp                   ! surface values
231         DO_3D( 1, 1, 1, 1, 2, jpkm1 )
232            zslpx(ji,jj,jk) =                        ( zwx(ji,jj,jk) + zwx(ji,jj,jk+1) )  &
233               &            * (  0.25 + SIGN( 0.25_wp, zwx(ji,jj,jk) * zwx(ji,jj,jk+1) )  )
234         END_3D
235         DO_3D( 1, 1, 1, 1, 2, jpkm1 )
236            zslpx(ji,jj,jk) = SIGN( 1.0_wp, zslpx(ji,jj,jk) ) * MIN(    ABS( zslpx(ji,jj,jk  ) ),   &
237               &                                                     2.*ABS( zwx  (ji,jj,jk+1) ),   &
238               &                                                     2.*ABS( zwx  (ji,jj,jk  ) )  )
239         END_3D
240         DO_3D( 0, 0, 0, 0, 1, jpk-2 )
241            z0w = SIGN( 0.5_wp, pW(ji,jj,jk+1) )
242            zalpha = 0.5 + z0w
243            zw  = z0w - 0.5 * pW(ji,jj,jk+1) * p2dt * r1_e1e2t(ji,jj) / e3w(ji,jj,jk+1,Kmm)
244            zzwx = pt(ji,jj,jk+1,jn,Kbb) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk+1)
245            zzwy = pt(ji,jj,jk  ,jn,Kbb) + xind(ji,jj,jk) * zw * zslpx(ji,jj,jk  )
246            zwx(ji,jj,jk+1) = pW(ji,jj,jk+1) * ( zalpha * zzwx + (1.-zalpha) * zzwy ) * wmask(ji,jj,jk)
247         END_3D
248         IF( ln_linssh ) THEN                   ! top values, linear free surface only
249            ! TODO: NOT TESTED- requires isf
250            IF( ln_isfcav ) THEN                      ! ice-shelf cavities (top of the ocean)
251               DO_2D( 1, 1, 1, 1 )
252                  zwx(ji,jj, mikt(ji,jj) ) = pW(ji,jj,mikt(ji,jj)) * pt(ji,jj,mikt(ji,jj),jn,Kbb)
253               END_2D
254            ELSE                                      ! no cavities: only at the ocean surface
255               DO_2D( 1, 1, 1, 1 )
256                  zwx(ji,jj,1) = pW(ji,jj,1) * pt(ji,jj,1,jn,Kbb)
257               END_2D
258            ENDIF
259         ENDIF
260         !
261         DO_3D( 0, 0, 0, 0, 1, jpkm1 )
262            pt(ji,jj,jk,jn,Krhs) =  pt(ji,jj,jk,jn,Krhs) - ( zwx(ji,jj,jk) - zwx(ji,jj,jk+1) )   &
263               &                                      * r1_e1e2t(ji,jj) / e3t(ji,jj,jk,Kmm)
264         END_3D
265         !                                ! send trends for diagnostic
266         ! TEMP: These changes not necessary after trd_tra is tiled
267         IF( l_trd ) THEN
268            DO_3D( 0, 0, 0, 0, 1, jpk )
269               ztrdz(ji,jj,jk) = zwx(ji,jj,jk)
270            END_3D
271
272            IF( ntile == 0 .OR. ntile == nijtile )  THEN                ! Do only for the full domain
273               IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )         ! Use full domain
274
275               ! TODO: TO BE TILED- trd_tra
276               CALL trd_tra( kt, Kmm, Krhs, cdtype, jn, jptra_zad, ztrdz, pW, pt(:,:,:,jn,Kbb) )
277
278               IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = itile )     ! Revert to tile domain
279            ENDIF
280         ENDIF
281         !
282      END DO                     ! end of tracer loop
283      !
284   END SUBROUTINE tra_adv_mus
285
286   !!======================================================================
287END MODULE traadv_mus
Note: See TracBrowser for help on using the repository browser.