New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
step.F90 in NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE – NEMO

source: NEMO/branches/2020/dev_r13383_HPC-02_Daley_Tiling/src/OCE/step.F90 @ 13819

Last change on this file since 13819 was 13819, checked in by hadcv, 3 years ago

#2365: Final fixes and changes

  • Property svn:keywords set to Id
File size: 23.5 KB
Line 
1MODULE step
2   !!======================================================================
3   !!                       ***  MODULE step  ***
4   !! Time-stepping   : manager of the ocean, tracer and ice time stepping
5   !!======================================================================
6   !! History :  OPA  !  1991-03  (G. Madec)  Original code
7   !!             -   !  1991-11  (G. Madec)
8   !!             -   !  1992-06  (M. Imbard)  add a first output record
9   !!             -   !  1996-04  (G. Madec)  introduction of dynspg
10   !!             -   !  1996-04  (M.A. Foujols)  introduction of passive tracer
11   !!            8.0  !  1997-06  (G. Madec)  new architecture of call
12   !!            8.2  !  1997-06  (G. Madec, M. Imbard, G. Roullet)  free surface
13   !!             -   !  1999-02  (G. Madec, N. Grima)  hpg implicit
14   !!             -   !  2000-07  (J-M Molines, M. Imbard)  Open Bondary Conditions
15   !!   NEMO     1.0  !  2002-06  (G. Madec)  free form, suppress macro-tasking
16   !!             -   !  2004-08  (C. Talandier) New trends organization
17   !!             -   !  2005-01  (C. Ethe) Add the KPP closure scheme
18   !!             -   !  2005-11  (G. Madec)  Reorganisation of tra and dyn calls
19   !!             -   !  2006-01  (L. Debreu, C. Mazauric)  Agrif implementation
20   !!             -   !  2006-07  (S. Masson)  restart using iom
21   !!            3.2  !  2009-02  (G. Madec, R. Benshila)  reintroduicing z*-coordinate
22   !!             -   !  2009-06  (S. Masson, G. Madec)  TKE restart compatible with key_cpl
23   !!            3.3  !  2010-05  (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
24   !!             -   !  2010-10  (C. Ethe, G. Madec) reorganisation of initialisation phase + merge TRC-TRA
25   !!            3.4  !  2011-04  (G. Madec, C. Ethe) Merge of dtatem and dtasal
26   !!            3.6  !  2012-07  (J. Simeon, G. Madec. C. Ethe)  Online coarsening of outputs
27   !!            3.6  !  2014-04  (F. Roquet, G. Madec) New equations of state
28   !!            3.6  !  2014-10  (E. Clementi, P. Oddo) Add Qiao vertical mixing in case of waves
29   !!            3.7  !  2014-10  (G. Madec)  LDF simplication
30   !!             -   !  2014-12  (G. Madec) remove KPP scheme
31   !!             -   !  2015-11  (J. Chanut) free surface simplification (remove filtered free surface)
32   !!            4.0  !  2017-05  (G. Madec)  introduction of the vertical physics manager (zdfphy)
33   !!            4.1  !  2019-08  (A. Coward, D. Storkey) rewrite in preparation for new timestepping scheme
34   !!----------------------------------------------------------------------
35#if defined key_qco
36   !!----------------------------------------------------------------------
37   !!   'key_qco'      EMPTY MODULE      Quasi-Eulerian vertical coordonate
38   !!----------------------------------------------------------------------
39#else
40   !!----------------------------------------------------------------------
41   !!   stp             : OPA system time-stepping
42   !!----------------------------------------------------------------------
43   USE step_oce         ! time stepping definition modules
44   !
45   USE iom              ! xIOs server
46
47   IMPLICIT NONE
48   PRIVATE
49
50   PUBLIC   stp   ! called by nemogcm.F90
51
52   !!----------------------------------------------------------------------
53   !! time level indices
54   !!----------------------------------------------------------------------
55   INTEGER, PUBLIC :: Nbb, Nnn, Naa, Nrhs          !! used by nemo_init
56
57   !! * Substitutions
58#  include "do_loop_substitute.h90"
59   !!----------------------------------------------------------------------
60   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
61   !! $Id$
62   !! Software governed by the CeCILL license (see ./LICENSE)
63   !!----------------------------------------------------------------------
64CONTAINS
65
66#if defined key_agrif
67   RECURSIVE SUBROUTINE stp( )
68      INTEGER             ::   kstp   ! ocean time-step index
69#else
70   SUBROUTINE stp( kstp )
71      INTEGER, INTENT(in) ::   kstp   ! ocean time-step index
72#endif
73      !!----------------------------------------------------------------------
74      !!                     ***  ROUTINE stp  ***
75      !!
76      !! ** Purpose : - Time stepping of OPA  (momentum and active tracer eqs.)
77      !!              - Time stepping of SI3 (dynamic and thermodynamic eqs.)
78      !!              - Time stepping of TRC  (passive tracer eqs.)
79      !!
80      !! ** Method  : -1- Update forcings and data
81      !!              -2- Update ocean physics
82      !!              -3- Compute the t and s trends
83      !!              -4- Update t and s
84      !!              -5- Compute the momentum trends
85      !!              -6- Update the horizontal velocity
86      !!              -7- Compute the diagnostics variables (rd,N2, hdiv,w)
87      !!              -8- Outputs and diagnostics
88      !!----------------------------------------------------------------------
89      INTEGER ::   ji, jj, jk, jtile   ! dummy loop indice
90!!gm kcall can be removed, I guess
91      INTEGER ::   kcall        ! optional integer argument (dom_vvl_sf_nxt)
92      !! ---------------------------------------------------------------------
93#if defined key_agrif
94      IF( nstop > 0 ) RETURN   ! avoid to go further if an error was detected during previous time step (child grid)
95      kstp = nit000 + Agrif_Nb_Step()
96      Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs   ! agrif_oce module copies of time level indices
97      IF( lk_agrif_debug ) THEN
98         IF( Agrif_Root() .and. lwp)   WRITE(*,*) '---'
99         IF(lwp)   WRITE(*,*) 'Grid Number', Agrif_Fixed(),' time step ', kstp, 'int tstep', Agrif_NbStepint()
100      ENDIF
101      IF( kstp == nit000 + 1 )   lk_agrif_fstep = .FALSE.
102# if defined key_iomput
103      IF( Agrif_Nbstepint() == 0 )   CALL iom_swap( cxios_context )
104# endif
105#endif
106      !
107      IF( ln_timing )   CALL timing_start('stp')
108      !
109      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
110      ! model timestep
111      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
112      !
113      IF( l_1st_euler ) THEN 
114         ! start or restart with Euler 1st time-step
115         rDt =  rn_Dt   
116         r1_Dt = 1._wp / rDt
117      ENDIF
118      !
119      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
120      ! update I/O and calendar
121      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
122      IF( kstp == nit000 ) THEN                       ! initialize IOM context (must be done after nemo_init for AGRIF+XIOS+OASIS)
123                             CALL iom_init( cxios_context, ld_closedef=.FALSE. )   ! for model grid (including possible AGRIF zoom)
124         IF( lk_diamlr   )   CALL dia_mlr_iom_init    ! with additional setup for multiple-linear-regression analysis
125                             CALL iom_init_closedef
126         IF( ln_crs      )   CALL iom_init( TRIM(cxios_context)//"_crs" )  ! for coarse grid
127      ENDIF
128      IF( kstp /= nit000 )   CALL day( kstp )         ! Calendar (day was already called at nit000 in day_init)
129                             CALL iom_setkt( kstp - nit000 + 1,      cxios_context          )   ! tell IOM we are at time step kstp
130      IF( ln_crs         )   CALL iom_setkt( kstp - nit000 + 1, TRIM(cxios_context)//"_crs" )   ! tell IOM we are at time step kstp
131
132      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
133      ! Update external forcing (tides, open boundaries, ice shelf interaction and surface boundary condition (including sea-ice)
134      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
135      IF( ln_tide    )   CALL tide_update( kstp )                     ! update tide potential
136      IF( ln_apr_dyn )   CALL sbc_apr ( kstp )                        ! atmospheric pressure (NB: call before bdy_dta which needs ssh_ib)
137      IF( ln_bdy     )   CALL bdy_dta ( kstp, Nnn )                   ! update dynamic & tracer data at open boundaries
138      IF( ln_isf     )   CALL isf_stp ( kstp, Nnn )
139                         CALL sbc     ( kstp, Nbb, Nnn )              ! Sea Boundary Condition (including sea-ice)
140
141      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
142      ! Update stochastic parameters and random T/S fluctuations
143      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
144      IF( ln_sto_eos ) CALL sto_par( kstp )          ! Stochastic parameters
145      IF( ln_sto_eos ) CALL sto_pts( ts(:,:,:,:,Nnn)  )          ! Random T/S fluctuations
146
147      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
148      ! Ocean physics update
149      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
150      !  THERMODYNAMICS
151                         CALL eos_rab( ts(:,:,:,:,Nbb), rab_b, Nnn )       ! before local thermal/haline expension ratio at T-points
152                         CALL eos_rab( ts(:,:,:,:,Nnn), rab_n, Nnn )       ! now    local thermal/haline expension ratio at T-points
153                         CALL bn2    ( ts(:,:,:,:,Nbb), rab_b, rn2b, Nnn ) ! before Brunt-Vaisala frequency
154                         CALL bn2    ( ts(:,:,:,:,Nnn), rab_n, rn2, Nnn  ) ! now    Brunt-Vaisala frequency
155
156      !  VERTICAL PHYSICS
157                         CALL zdf_phy( kstp, Nbb, Nnn, Nrhs )   ! vertical physics update (top/bot drag, avt, avs, avm + MLD)
158
159      !  LATERAL  PHYSICS
160      !
161      IF( l_ldfslp ) THEN                             ! slope of lateral mixing
162                         CALL eos( ts(:,:,:,:,Nbb), rhd, gdept_0(:,:,:) )               ! before in situ density
163
164         IF( ln_zps .AND. .NOT. ln_isfcav)                                    &
165            &            CALL zps_hde    ( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv,  &  ! Partial steps: before horizontal gradient
166            &                                          rhd, gru , grv    )       ! of t, s, rd at the last ocean level
167
168         IF( ln_zps .AND.       ln_isfcav)                                                &
169            &            CALL zps_hde_isf( kstp, Nnn, jpts, ts(:,:,:,:,Nbb), gtsu, gtsv, gtui, gtvi,  &  ! Partial steps for top cell (ISF)
170            &                                          rhd, gru , grv , grui, grvi   )       ! of t, s, rd at the first ocean level
171         IF( ln_traldf_triad ) THEN
172                         CALL ldf_slp_triad( kstp, Nbb, Nnn )             ! before slope for triad operator
173         ELSE     
174                         CALL ldf_slp     ( kstp, rhd, rn2b, Nbb, Nnn )   ! before slope for standard operator
175         ENDIF
176      ENDIF
177      !                                                                        ! eddy diffusivity coeff.
178      IF( l_ldftra_time .OR. l_ldfeiv_time )   CALL ldf_tra( kstp, Nbb, Nnn )  !       and/or eiv coeff.
179      IF( l_ldfdyn_time                    )   CALL ldf_dyn( kstp, Nbb )       ! eddy viscosity coeff.
180
181      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
182      !  Ocean dynamics : hdiv, ssh, e3, u, v, w
183      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
184
185                            CALL ssh_nxt       ( kstp, Nbb, Nnn, ssh, Naa )    ! after ssh (includes call to div_hor)
186      IF( .NOT.ln_linssh )  CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn,      Naa )    ! after vertical scale factors
187                            CALL wzv           ( kstp, Nbb, Nnn, Naa, ww  )    ! now cross-level velocity
188      IF( ln_zad_Aimp )     CALL wAimp         ( kstp,      Nnn           )  ! Adaptive-implicit vertical advection partitioning
189                            CALL eos    ( ts(:,:,:,:,Nnn), rhd, rhop, gdept(:,:,:,Nnn) )  ! now in situ density for hpg computation
190                           
191                           
192                         uu(:,:,:,Nrhs) = 0._wp            ! set dynamics trends to zero
193                         vv(:,:,:,Nrhs) = 0._wp
194
195      IF(  lk_asminc .AND. ln_asmiau .AND. ln_dyninc )   &
196               &         CALL dyn_asm_inc   ( kstp, Nbb, Nnn, uu, vv, Nrhs )  ! apply dynamics assimilation increment
197      IF( ln_bdy     )   CALL bdy_dyn3d_dmp ( kstp, Nbb,      uu, vv, Nrhs )  ! bdy damping trends
198#if defined key_agrif
199      IF(.NOT. Agrif_Root())  & 
200               &         CALL Agrif_Sponge_dyn        ! momentum sponge
201#endif
202                         CALL dyn_adv( kstp, Nbb, Nnn      , uu, vv, Nrhs )  ! advection (VF or FF)   ==> RHS
203                         CALL dyn_vor( kstp,      Nnn      , uu, vv, Nrhs )  ! vorticity              ==> RHS
204                         CALL dyn_ldf( kstp, Nbb, Nnn      , uu, vv, Nrhs )  ! lateral mixing
205      IF( ln_zdfosm  )   CALL dyn_osm( kstp,      Nnn      , uu, vv, Nrhs )  ! OSMOSIS non-local velocity fluxes ==> RHS
206                         CALL dyn_hpg( kstp,      Nnn      , uu, vv, Nrhs )  ! horizontal gradient of Hydrostatic pressure
207                         CALL dyn_spg( kstp, Nbb, Nnn, Nrhs, uu, vv, ssh, uu_b, vv_b, Naa )  ! surface pressure gradient
208
209                                                      ! With split-explicit free surface, since now transports have been updated and ssh(:,:,Nrhs) as well
210      IF( ln_dynspg_ts ) THEN                         ! vertical scale factors and vertical velocity need to be updated
211                            CALL div_hor       ( kstp, Nbb, Nnn )                ! Horizontal divergence  (2nd call in time-split case)
212         IF(.NOT.ln_linssh) CALL dom_vvl_sf_nxt( kstp, Nbb, Nnn, Naa, kcall=2 )  ! after vertical scale factors (update depth average component)
213      ENDIF
214                            CALL dyn_zdf    ( kstp, Nbb, Nnn, Nrhs, uu, vv, Naa  )  ! vertical diffusion
215      IF( ln_dynspg_ts ) THEN                                                       ! vertical scale factors and vertical velocity need to be updated
216                            CALL wzv        ( kstp, Nbb, Nnn, Naa, ww )             ! now cross-level velocity
217         IF( ln_zad_Aimp )  CALL wAimp      ( kstp,      Nnn )                      ! Adaptive-implicit vertical advection partitioning
218      ENDIF
219     
220
221      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
222      ! cool skin
223      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
224      IF ( ln_diurnal )  CALL diurnal_layers( kstp )
225     
226      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
227      ! diagnostics and outputs
228      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
229      IF( ln_floats  )   CALL flo_stp   ( kstp, Nbb, Nnn )      ! drifting Floats
230      IF( ln_diacfl  )   CALL dia_cfl   ( kstp,      Nnn )      ! Courant number diagnostics
231                         CALL dia_hth   ( kstp,      Nnn )      ! Thermocline depth (20 degres isotherm depth)
232      IF( ln_diadct  )   CALL dia_dct   ( kstp,      Nnn )      ! Transports
233                         CALL dia_ar5   ( kstp,      Nnn )      ! ar5 diag
234                         CALL dia_ptr   ( kstp,      Nnn )      ! Poleward adv/ldf TRansports diagnostics
235                         CALL dia_wri   ( kstp,      Nnn )      ! ocean model: outputs
236      IF( ln_crs     )   CALL crs_fld   ( kstp,      Nnn )      ! ocean model: online field coarsening & output
237      IF( lk_diadetide ) CALL dia_detide( kstp )                ! Weights computation for daily detiding of model diagnostics
238      IF( lk_diamlr  )   CALL dia_mlr                           ! Update time used in multiple-linear-regression analysis
239     
240#if defined key_top
241      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
242      ! Passive Tracer Model
243      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
244                         CALL trc_stp       ( kstp, Nbb, Nnn, Nrhs, Naa )  ! time-stepping
245#endif
246
247      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
248      ! Active tracers                             
249      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
250      ! Loop over tile domains
251      DO jtile = 1, nijtile
252         IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile )
253
254         DO_3D( 0, 0, 0, 0, 1, jpk )
255            ts(ji,jj,jk,:,Nrhs) = 0._wp                                         ! set tracer trends to zero
256         END_3D
257
258         IF(  lk_asminc .AND. ln_asmiau .AND. &
259            & ln_trainc )   CALL tra_asm_inc( kstp, Nbb, Nnn, ts, Nrhs )  ! apply tracer assimilation increment
260                            CALL tra_sbc    ( kstp,      Nnn, ts, Nrhs )  ! surface boundary condition
261         IF( ln_traqsr  )   CALL tra_qsr    ( kstp,      Nnn, ts, Nrhs )  ! penetrative solar radiation qsr
262         IF( ln_isf     )   CALL tra_isf    ( kstp,      Nnn, ts, Nrhs )  ! ice shelf heat flux
263         IF( ln_trabbc  )   CALL tra_bbc    ( kstp,      Nnn, ts, Nrhs )  ! bottom heat flux
264         IF( ln_trabbl  )   CALL tra_bbl    ( kstp, Nbb, Nnn, ts, Nrhs )  ! advective (and/or diffusive) bottom boundary layer scheme
265         IF( ln_tradmp  )   CALL tra_dmp    ( kstp, Nbb, Nnn, ts, Nrhs )  ! internal damping trends
266         IF( ln_bdy     )   CALL bdy_tra_dmp( kstp, Nbb,      ts, Nrhs )  ! bdy damping trends
267      END DO
268
269#if defined key_agrif
270         IF(.NOT. Agrif_Root()) THEN
271            IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 )
272            CALL Agrif_Sponge_tra        ! tracers sponge
273         ENDIF
274#endif
275
276      ! TEMP: [tiling] Separate loop over tile domains (due to tra_adv workarounds for tiling)
277      DO jtile = 1, nijtile
278         IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = jtile )
279
280                            CALL tra_adv    ( kstp, Nbb, Nnn, ts, Nrhs )  ! hor. + vert. advection ==> RHS
281         IF( ln_zdfosm  )   CALL tra_osm    ( kstp,      Nnn, ts, Nrhs )  ! OSMOSIS non-local tracer fluxes ==> RHS
282         IF( lrst_oce .AND. ln_zdfosm ) &
283              &             CALL osm_rst    ( kstp,      Nnn, 'WRITE'  )  ! write OSMOSIS outputs + ww (so must do here) to restarts
284                            CALL tra_ldf    ( kstp, Nbb, Nnn, ts, Nrhs )  ! lateral mixing
285
286                            CALL tra_zdf    ( kstp, Nbb, Nnn, Nrhs, ts, Naa  )  ! vertical mixing and after tracer fields
287         IF( ln_zdfnpc  )   CALL tra_npc    ( kstp,      Nnn, Nrhs, ts, Naa  )  ! update after fields by non-penetrative convection
288      END DO
289
290      IF( ln_tile ) CALL dom_tile( ntsi, ntsj, ntei, ntej, ktile = 0 ) ! Revert to tile over full domain
291      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
292      ! Set boundary conditions, time filter and swap time levels
293      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
294!!jc1: For agrif, it would be much better to finalize tracers/momentum here (e.g. bdy conditions) and move the swap
295!!    (and time filtering) after Agrif update. Then restart would be done after and would contain updated fields.
296!!    If so:
297!!    (i) no need to call agrif update at initialization time
298!!    (ii) no need to update "before" fields
299!!
300!!    Apart from creating new tra_swp/dyn_swp routines, this however:
301!!    (i) makes boundary conditions at initialization time computed from updated fields which is not the case between
302!!    two restarts => restartability issue. One can circumvent this, maybe, by assuming "interface separation",
303!!    e.g. a shift of the feedback interface inside child domain.
304!!    (ii) requires that all restart outputs of updated variables by agrif (e.g. passive tracers/tke/barotropic arrays) are done at the same
305!!    place.
306!!
307!!jc2: dynnxt must be the latest call. e3t(:,:,:,Nbb) are indeed updated in that routine
308                         CALL tra_atf       ( kstp, Nbb, Nnn, Naa, ts )                      ! time filtering of "now" tracer arrays
309                         CALL dyn_atf       ( kstp, Nbb, Nnn, Naa, uu, vv, e3t, e3u, e3v  )  ! time filtering of "now" velocities and scale factors
310                         CALL ssh_atf       ( kstp, Nbb, Nnn, Naa, ssh )                     ! time filtering of "now" sea surface height
311      !
312      ! Swap time levels
313      Nrhs = Nbb
314      Nbb = Nnn
315      Nnn = Naa
316      Naa = Nrhs
317      !
318      IF(.NOT.ln_linssh) CALL dom_vvl_sf_update( kstp, Nbb, Nnn, Naa )  ! recompute vertical scale factors
319      !
320      IF( ln_diahsb  )   CALL dia_hsb       ( kstp, Nbb, Nnn )  ! - ML - global conservation diagnostics
321
322!!gm : This does not only concern the dynamics ==>>> add a new title
323!!gm2: why ouput restart before AGRIF update?
324!!
325!!jc: That would be better, but see comment above
326!!
327      IF( lrst_oce   )   CALL rst_write    ( kstp, Nbb, Nnn )   ! write output ocean restart file
328      IF( ln_sto_eos )   CALL sto_rst_write( kstp )   ! write restart file for stochastic parameters
329
330#if defined key_agrif
331      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
332      ! AGRIF recursive integration
333      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
334                         Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs      ! agrif_oce module copies of time level indices
335                         CALL Agrif_Integrate_ChildGrids( stp )       ! allows to finish all the Child Grids before updating
336
337#endif
338      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
339      ! Control
340      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
341                         CALL stp_ctl      ( kstp, Nnn )
342
343#if defined key_agrif
344      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
345      ! AGRIF update
346      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<     
347      IF( Agrif_NbStepint() == 0 .AND. nstop == 0 ) THEN
348                         CALL Agrif_update_all( )                  ! Update all components
349      ENDIF
350
351#endif
352      IF( ln_diaobs .AND. nstop == 0 )  CALL dia_obs( kstp, Nnn )  ! obs-minus-model (assimilation) diags (after dynamics update)
353
354      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
355      ! File manipulation at the end of the first time step
356      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<                         
357      IF( kstp == nit000 ) THEN                          ! 1st time step only
358                                        CALL iom_close( numror )   ! close input  ocean restart file
359         IF(lwm)                        CALL FLUSH    ( numond )   ! flush output namelist oce
360         IF(lwm .AND. numoni /= -1 )    CALL FLUSH    ( numoni )   ! flush output namelist ice (if exist)
361      ENDIF
362
363      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
364      ! Coupled mode
365      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
366      IF( lk_oasis .AND. nstop == 0 )   CALL sbc_cpl_snd( kstp, Nbb, Nnn )     ! coupled mode : field exchanges
367      !
368#if defined key_iomput
369      !>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
370      ! Finalize contextes if end of simulation or error detected
371      !<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<                         
372      IF( kstp == nitend .OR. nstop > 0 ) THEN
373                      CALL iom_context_finalize(      cxios_context          ) ! needed for XIOS+AGRIF
374         IF( lrxios ) CALL iom_context_finalize(      crxios_context         )
375         IF( ln_crs ) CALL iom_context_finalize( trim(cxios_context)//"_crs" ) !
376      ENDIF
377#endif
378      !
379      IF( l_1st_euler ) THEN         ! recover Leap-frog timestep
380         rDt = 2._wp * rn_Dt   
381         r1_Dt = 1._wp / rDt
382         l_1st_euler = .FALSE.     
383      ENDIF
384      !
385      IF( ln_timing )   CALL timing_stop('stp')
386      !
387   END SUBROUTINE stp
388   !
389#endif
390   !!======================================================================
391END MODULE step
Note: See TracBrowser for help on using the repository browser.