New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icethd.F90 in NEMO/branches/2020/dev_r13541_TOP-01_rlod_Antarctic_ice_Sheet_Fe_Source/src/ICE – NEMO

source: NEMO/branches/2020/dev_r13541_TOP-01_rlod_Antarctic_ice_Sheet_Fe_Source/src/ICE/icethd.F90 @ 13886

Last change on this file since 13886 was 13886, checked in by rlod, 3 years ago

phasing with trunk at revision r13787
  • Property svn:keywords set to Id
File size: 35.3 KB
Line 
1MODULE icethd
2   !!======================================================================
3   !!                  ***  MODULE icethd   ***
4   !!   sea-ice : master routine for thermodynamics
5   !!======================================================================
6   !! History :  1.0  !  2000-01  (M.A. Morales Maqueda, H. Goosse, T. Fichefet) original code 1D
7   !!            4.0  !  2018     (many people)       SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_thd       : thermodynamics of sea ice
14   !!   ice_thd_init  : initialisation of sea-ice thermodynamics
15   !!----------------------------------------------------------------------
16   USE phycst         ! physical constants
17   USE dom_oce        ! ocean space and time domain variables
18   USE ice            ! sea-ice: variables
19!!gm list trop longue ==>>> why not passage en argument d'appel ?
20   USE sbc_oce , ONLY : sss_m, sst_m, e3t_m, utau, vtau, ssu_m, ssv_m, frq_m, sprecip, ln_cpl
21   USE sbc_ice , ONLY : qsr_oce, qns_oce, qemp_oce, qsr_ice, qns_ice, dqns_ice, evap_ice, qprec_ice, qevap_ice, &
22      &                 qml_ice, qcn_ice, qtr_ice_top
23   USE ice1D          ! sea-ice: thermodynamics variables
24   USE icethd_zdf     ! sea-ice: vertical heat diffusion
25   USE icethd_dh      ! sea-ice: ice-snow growth and melt
26   USE icethd_da      ! sea-ice: lateral melting
27   USE icethd_sal     ! sea-ice: salinity
28   USE icethd_ent     ! sea-ice: enthalpy redistribution
29   USE icethd_do      ! sea-ice: growth in open water
30   USE icethd_pnd     ! sea-ice: melt ponds
31   USE iceitd         ! sea-ice: remapping thickness distribution
32   USE icecor         ! sea-ice: corrections
33   USE icetab         ! sea-ice: 1D <==> 2D transformation
34   USE icevar         ! sea-ice: operations
35   USE icectl         ! sea-ice: control print
36   !
37   USE in_out_manager ! I/O manager
38   USE iom            ! I/O manager library
39   USE lib_mpp        ! MPP library
40   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
41   USE lbclnk         ! lateral boundary conditions (or mpp links)
42   USE timing         ! Timing
43
44   IMPLICIT NONE
45   PRIVATE
46
47   PUBLIC   ice_thd         ! called by limstp module
48   PUBLIC   ice_thd_init    ! called by ice_init
49
50   !!** namelist (namthd) **
51   LOGICAL ::   ln_icedH         ! activate ice thickness change from growing/melting (T) or not (F)
52   LOGICAL ::   ln_icedA         ! activate lateral melting param. (T) or not (F)
53   LOGICAL ::   ln_icedO         ! activate ice growth in open-water (T) or not (F)
54   LOGICAL ::   ln_icedS         ! activate gravity drainage and flushing (T) or not (F)
55   LOGICAL ::   ln_leadhfx       ! heat in the leads is used to melt sea-ice before warming the ocean
56
57   !! for convergence tests
58   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztice_cvgerr, ztice_cvgstp
59
60   !! * Substitutions
61#  include "do_loop_substitute.h90"
62   !!----------------------------------------------------------------------
63   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
64   !! $Id$
65   !! Software governed by the CeCILL license (see ./LICENSE)
66   !!----------------------------------------------------------------------
67CONTAINS
68
69   SUBROUTINE ice_thd( kt )
70      !!-------------------------------------------------------------------
71      !!                ***  ROUTINE ice_thd  ***       
72      !! 
73      !! ** Purpose : This routine manages ice thermodynamics
74      !!         
75      !! ** Action : - computation of oceanic sensible heat flux at the ice base
76      !!                              energy budget in the leads
77      !!                              net fluxes on top of ice and of ocean
78      !!             - selection of grid cells with ice
79      !!                - call ice_thd_zdf  for vertical heat diffusion
80      !!                - call ice_thd_dh   for vertical ice growth and melt
81      !!                - call ice_thd_pnd  for melt ponds
82      !!                - call ice_thd_ent  for enthalpy remapping
83      !!                - call ice_thd_sal  for ice desalination
84      !!                - call ice_thd_temp to  retrieve temperature from ice enthalpy
85      !!                - call ice_thd_mono for extra lateral ice melt if active virtual thickness distribution
86      !!                - call ice_thd_da   for lateral ice melt
87      !!             - back to the geographic grid
88      !!                - call ice_thd_rem  for remapping thickness distribution
89      !!                - call ice_thd_do   for ice growth in leads
90      !!-------------------------------------------------------------------
91      INTEGER, INTENT(in) :: kt    ! number of iteration
92      !
93      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
94      REAL(wp) :: zfric_u, zqld, zqfr, zqfr_neg, zqfr_pos
95      REAL(wp), PARAMETER :: zfric_umin = 0._wp       ! lower bound for the friction velocity (cice value=5.e-04)
96      REAL(wp), PARAMETER :: zch        = 0.0057_wp   ! heat transfer coefficient
97      REAL(wp), DIMENSION(jpi,jpj) ::   zu_io, zv_io, zfric, zvel   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
98      !
99      !!-------------------------------------------------------------------
100      ! controls
101      IF( ln_timing    )   CALL timing_start('icethd')                                                             ! timing
102      IF( ln_icediachk )   CALL ice_cons_hsm(0, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
103      IF( ln_icediachk )   CALL ice_cons2D  (0, 'icethd',  diag_v,  diag_s,  diag_t,  diag_fv,  diag_fs,  diag_ft) ! conservation
104
105      IF( kt == nit000 .AND. lwp ) THEN
106         WRITE(numout,*)
107         WRITE(numout,*) 'ice_thd: sea-ice thermodynamics'
108         WRITE(numout,*) '~~~~~~~'
109      ENDIF
110
111      ! convergence tests
112      IF( ln_zdf_chkcvg ) THEN
113         ALLOCATE( ztice_cvgerr(jpi,jpj,jpl) , ztice_cvgstp(jpi,jpj,jpl) )
114         ztice_cvgerr = 0._wp ; ztice_cvgstp = 0._wp
115      ENDIF
116     
117      !---------------------------------------------!
118      ! computation of friction velocity at T points
119      !---------------------------------------------!
120      IF( ln_icedyn ) THEN
121         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
122         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
123         DO_2D( 0, 0, 0, 0 )
124            zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
125               &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
126               &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
127            zvel(ji,jj) = 0.5_wp * SQRT( ( u_ice(ji-1,jj) + u_ice(ji,jj) ) * ( u_ice(ji-1,jj) + u_ice(ji,jj) ) + &
128               &                         ( v_ice(ji,jj-1) + v_ice(ji,jj) ) * ( v_ice(ji,jj-1) + v_ice(ji,jj) ) )
129         END_2D
130      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
131         DO_2D( 0, 0, 0, 0 )
132            zfric(ji,jj) = r1_rho0 * SQRT( 0.5_wp *  &
133               &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
134               &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
135            zvel(ji,jj) = 0._wp
136         END_2D
137      ENDIF
138      CALL lbc_lnk_multi( 'icethd', zfric, 'T',  1.0_wp, zvel, 'T', 1.0_wp )
139      !
140      !--------------------------------------------------------------------!
141      ! Partial computation of forcing for the thermodynamic sea ice model
142      !--------------------------------------------------------------------!
143      DO_2D( 1, 1, 1, 1 )
144         rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
145         !
146         ! --- Energy received in the lead from atm-oce exchanges, zqld is defined everywhere (J.m-2) --- !
147         zqld =  tmask(ji,jj,1) * rDt_ice *  &
148            &    ( ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * frq_m(ji,jj) +  &
149            &      ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
150
151         ! --- Energy needed to bring ocean surface layer until its freezing, zqfr is defined everywhere (J.m-2) --- !
152         !     (mostly<0 but >0 if supercooling)
153         zqfr     = rho0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ) * tmask(ji,jj,1)  ! both < 0 (t_bo < sst) and > 0 (t_bo > sst)
154         zqfr_neg = MIN( zqfr , 0._wp )                                                                    ! only < 0
155         zqfr_pos = MAX( zqfr , 0._wp )                                                                    ! only > 0
156
157         ! --- Sensible ocean-to-ice heat flux (W/m2) --- !
158         !     (mostly>0 but <0 if supercooling)
159         zfric_u            = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
160         qsb_ice_bot(ji,jj) = rswitch * rho0 * rcp * zch * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) )
161         
162         ! upper bound for qsb_ice_bot: the heat retrieved from the ocean must be smaller than the heat necessary to reach
163         !                              the freezing point, so that we do not have SST < T_freeze
164         !                              This implies: qsb_ice_bot(ji,jj) * at_i(ji,jj) * rtdice <= - zqfr_neg
165         !                              The following formulation is ok for both normal conditions and supercooling
166         qsb_ice_bot(ji,jj) = rswitch * MIN( qsb_ice_bot(ji,jj), - zqfr_neg * r1_Dt_ice / MAX( at_i(ji,jj), epsi10 ) )
167
168         ! --- Energy Budget of the leads (qlead, J.m-2) --- !
169         !     qlead is the energy received from the atm. in the leads.
170         !     If warming (zqld >= 0), then the energy in the leads is used to melt ice (bottom melting) => fhld  (W/m2)
171         !     If cooling (zqld <  0), then the energy in the leads is used to grow ice in open water    => qlead (J.m-2)
172         IF( zqld >= 0._wp .AND. at_i(ji,jj) > 0._wp ) THEN
173            ! upper bound for fhld: fhld should be equal to zqld
174            !                        but we have to make sure that this heat will not make the sst drop below the freezing point
175            !                        so the max heat that can be pulled out of the ocean is zqld - qsb - zqfr_pos
176            !                        The following formulation is ok for both normal conditions and supercooling
177            fhld (ji,jj) = rswitch * MAX( 0._wp, ( zqld - zqfr_pos ) * r1_Dt_ice / MAX( at_i(ji,jj), epsi10 ) &  ! divided by at_i since this is (re)multiplied by a_i in icethd_dh.F90
178               &                                 - qsb_ice_bot(ji,jj) )
179            qlead(ji,jj) = 0._wp
180         ELSE
181            fhld (ji,jj) = 0._wp
182            ! upper bound for qlead: qlead should be equal to zqld
183            !                        but before using this heat for ice formation, we suppose that the ocean cools down till the freezing point.
184            !                        The energy for this cooling down is zqfr. Also some heat will be removed from the ocean from turbulent fluxes (qsb)
185            !                        and freezing point is reached if zqfr = zqld - qsb*a/dt
186            !                        so the max heat that can be pulled out of the ocean is zqld - qsb - zqfr
187            !                        The following formulation is ok for both normal conditions and supercooling
188            qlead(ji,jj) = MIN( 0._wp , zqld - ( qsb_ice_bot(ji,jj) * at_i(ji,jj) * rDt_ice ) - zqfr )
189         ENDIF
190         !
191         ! If ice is landfast and ice concentration reaches its max
192         ! => stop ice formation in open water
193         IF(  zvel(ji,jj) <= 5.e-04_wp .AND. at_i(ji,jj) >= rn_amax_2d(ji,jj)-epsi06 )   qlead(ji,jj) = 0._wp
194         !
195         ! If the grid cell is almost fully covered by ice (no leads)
196         ! => stop ice formation in open water
197         IF( at_i(ji,jj) >= (1._wp - epsi10) )   qlead(ji,jj) = 0._wp
198         !
199         ! If ln_leadhfx is false
200         ! => do not use energy of the leads to melt sea-ice
201         IF( .NOT.ln_leadhfx )   fhld(ji,jj) = 0._wp
202         !
203      END_2D
204     
205      ! In case we bypass open-water ice formation
206      IF( .NOT. ln_icedO )  qlead(:,:) = 0._wp
207      ! In case we bypass growing/melting from top and bottom
208      IF( .NOT. ln_icedH ) THEN
209         qsb_ice_bot(:,:) = 0._wp
210         fhld       (:,:) = 0._wp
211      ENDIF
212
213      !-------------------------------------------------------------------------------------------!
214      ! Thermodynamic computation (only on grid points covered by ice) => loop over ice categories
215      !-------------------------------------------------------------------------------------------!
216      DO jl = 1, jpl
217
218         ! select ice covered grid points
219         npti = 0 ; nptidx(:) = 0
220         DO_2D( 1, 1, 1, 1 )
221            IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
222               npti         = npti  + 1
223               nptidx(npti) = (jj - 1) * jpi + ji
224            ENDIF
225         END_2D
226
227         IF( npti > 0 ) THEN  ! If there is no ice, do nothing.
228            !                                                               
229                              CALL ice_thd_1d2d( jl, 1 )            ! --- Move to 1D arrays --- !
230            !                                                       ! --- & Change units of e_i, e_s from J/m2 to J/m3 --- !
231            !
232            s_i_new   (1:npti) = 0._wp ; dh_s_tot(1:npti) = 0._wp   ! --- some init --- !  (important to have them here)
233            dh_i_sum  (1:npti) = 0._wp ; dh_i_bom(1:npti) = 0._wp ; dh_i_itm  (1:npti) = 0._wp 
234            dh_i_sub  (1:npti) = 0._wp ; dh_i_bog(1:npti) = 0._wp
235            dh_snowice(1:npti) = 0._wp ; dh_s_mlt(1:npti) = 0._wp
236            !                                     
237                              CALL ice_thd_zdf                      ! --- Ice-Snow temperature --- !
238            !
239            IF( ln_icedH ) THEN                                     ! --- Growing/Melting --- !
240                              CALL ice_thd_dh                           ! Ice-Snow thickness   
241                              CALL ice_thd_pnd                          ! Melt ponds formation
242                              CALL ice_thd_ent( e_i_1d(1:npti,:) )      ! Ice enthalpy remapping
243            ENDIF
244                              CALL ice_thd_sal( ln_icedS )          ! --- Ice salinity --- !   
245            !
246                              CALL ice_thd_temp                     ! --- Temperature update --- !
247            !
248            IF( ln_icedH .AND. ln_virtual_itd ) &
249               &              CALL ice_thd_mono                     ! --- Extra lateral melting if virtual_itd --- !
250            !
251            IF( ln_icedA )    CALL ice_thd_da                       ! --- Lateral melting --- !
252            !
253                              CALL ice_thd_1d2d( jl, 2 )            ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
254            !                                                       ! --- & Move to 2D arrays --- !
255         ENDIF
256         !
257      END DO
258      !
259      IF( ln_icediachk )   CALL ice_cons_hsm(1, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft)
260      IF( ln_icediachk )   CALL ice_cons2D  (1, 'icethd',  diag_v,  diag_s,  diag_t,  diag_fv,  diag_fs,  diag_ft)
261      !                   
262      IF( jpl > 1  )          CALL ice_itd_rem( kt )                ! --- Transport ice between thickness categories --- !
263      !
264      IF( ln_icedO )          CALL ice_thd_do                       ! --- Frazil ice growth in leads --- !
265      !
266                              CALL ice_cor( kt , 2 )                ! --- Corrections --- !
267      !
268      oa_i(:,:,:) = oa_i(:,:,:) + a_i(:,:,:) * rdt_ice              ! ice natural aging incrementation     
269      !
270      ! convergence tests
271      IF( ln_zdf_chkcvg ) THEN
272         CALL iom_put( 'tice_cvgerr', ztice_cvgerr ) ; DEALLOCATE( ztice_cvgerr )
273         CALL iom_put( 'tice_cvgstp', ztice_cvgstp ) ; DEALLOCATE( ztice_cvgstp )
274      ENDIF
275      !
276      ! controls
277      IF( ln_icectl )   CALL ice_prt    (kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ') ! prints
278      IF( sn_cfctl%l_prtctl )   &
279        &               CALL ice_prt3D  ('icethd')                                        ! prints
280      IF( ln_timing )   CALL timing_stop('icethd')                                        ! timing
281      !
282   END SUBROUTINE ice_thd 
283
284 
285   SUBROUTINE ice_thd_temp
286      !!-----------------------------------------------------------------------
287      !!                   ***  ROUTINE ice_thd_temp ***
288      !!                 
289      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
290      !!
291      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
292      !!-------------------------------------------------------------------
293      INTEGER  ::   ji, jk   ! dummy loop indices
294      REAL(wp) ::   ztmelts, zbbb, zccc  ! local scalar
295      !!-------------------------------------------------------------------
296      ! Recover ice temperature
297      DO jk = 1, nlay_i
298         DO ji = 1, npti
299            ztmelts       = -rTmlt * sz_i_1d(ji,jk)
300            ! Conversion q(S,T) -> T (second order equation)
301            zbbb          = ( rcp - rcpi ) * ztmelts + e_i_1d(ji,jk) * r1_rhoi - rLfus
302            zccc          = SQRT( MAX( zbbb * zbbb - 4._wp * rcpi * rLfus * ztmelts, 0._wp ) )
303            t_i_1d(ji,jk) = rt0 - ( zbbb + zccc ) * 0.5_wp * r1_rcpi
304           
305            ! mask temperature
306            rswitch       = 1._wp - MAX( 0._wp , SIGN( 1._wp , - h_i_1d(ji) ) ) 
307            t_i_1d(ji,jk) = rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
308         END DO
309      END DO 
310      !
311   END SUBROUTINE ice_thd_temp
312
313
314   SUBROUTINE ice_thd_mono
315      !!-----------------------------------------------------------------------
316      !!                   ***  ROUTINE ice_thd_mono ***
317      !!                 
318      !! ** Purpose :   Lateral melting in case virtual_itd
319      !!                          ( dA = A/2h dh )
320      !!-----------------------------------------------------------------------
321      INTEGER  ::   ji                 ! dummy loop indices
322      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
323      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
324      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
325      !!-----------------------------------------------------------------------
326      !
327      DO ji = 1, npti
328         zdh_mel = MIN( 0._wp, dh_i_itm(ji) + dh_i_sum(ji) + dh_i_bom(ji) + dh_snowice(ji) + dh_i_sub(ji) )
329         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
330            zvi          = a_i_1d(ji) * h_i_1d(ji)
331            zvs          = a_i_1d(ji) * h_s_1d(ji)
332            ! lateral melting = concentration change
333            zhi_bef     = h_i_1d(ji) - zdh_mel
334            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
335            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
336            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
337            ! adjust thickness
338            h_i_1d(ji) = zvi / a_i_1d(ji)           
339            h_s_1d(ji) = zvs / a_i_1d(ji)           
340            ! retrieve total concentration
341            at_i_1d(ji) = a_i_1d(ji)
342         END IF
343      END DO
344      !
345   END SUBROUTINE ice_thd_mono
346
347
348   SUBROUTINE ice_thd_1d2d( kl, kn )
349      !!-----------------------------------------------------------------------
350      !!                   ***  ROUTINE ice_thd_1d2d ***
351      !!                 
352      !! ** Purpose :   move arrays from 1d to 2d and the reverse
353      !!-----------------------------------------------------------------------
354      INTEGER, INTENT(in) ::   kl   ! index of the ice category
355      INTEGER, INTENT(in) ::   kn   ! 1= from 2D to 1D   ;   2= from 1D to 2D
356      !
357      INTEGER ::   jk   ! dummy loop indices
358      !!-----------------------------------------------------------------------
359      !
360      SELECT CASE( kn )
361      !                    !---------------------!
362      CASE( 1 )            !==  from 2D to 1D  ==!
363         !                 !---------------------!
364         CALL tab_2d_1d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
365         CALL tab_2d_1d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
366         CALL tab_2d_1d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
367         CALL tab_2d_1d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
368         CALL tab_2d_1d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
369         CALL tab_2d_1d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
370         DO jk = 1, nlay_s
371            CALL tab_2d_1d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
372            CALL tab_2d_1d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
373         END DO
374         DO jk = 1, nlay_i
375            CALL tab_2d_1d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
376            CALL tab_2d_1d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
377            CALL tab_2d_1d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
378         END DO
379         CALL tab_2d_1d( npti, nptidx(1:npti), a_ip_1d     (1:npti), a_ip     (:,:,kl) )
380         CALL tab_2d_1d( npti, nptidx(1:npti), h_ip_1d     (1:npti), h_ip     (:,:,kl) )
381         CALL tab_2d_1d( npti, nptidx(1:npti), h_il_1d     (1:npti), h_il     (:,:,kl) )
382         !
383         CALL tab_2d_1d( npti, nptidx(1:npti), qprec_ice_1d  (1:npti), qprec_ice            )
384         CALL tab_2d_1d( npti, nptidx(1:npti), qsr_ice_1d    (1:npti), qsr_ice (:,:,kl)     )
385         CALL tab_2d_1d( npti, nptidx(1:npti), qns_ice_1d    (1:npti), qns_ice (:,:,kl)     )
386         CALL tab_2d_1d( npti, nptidx(1:npti), evap_ice_1d   (1:npti), evap_ice(:,:,kl)     )
387         CALL tab_2d_1d( npti, nptidx(1:npti), dqns_ice_1d   (1:npti), dqns_ice(:,:,kl)     )
388         CALL tab_2d_1d( npti, nptidx(1:npti), t_bo_1d       (1:npti), t_bo                 )
389         CALL tab_2d_1d( npti, nptidx(1:npti), sprecip_1d    (1:npti), sprecip              ) 
390         CALL tab_2d_1d( npti, nptidx(1:npti), qsb_ice_bot_1d(1:npti), qsb_ice_bot          )
391         CALL tab_2d_1d( npti, nptidx(1:npti), fhld_1d       (1:npti), fhld                 )
392         
393         CALL tab_2d_1d( npti, nptidx(1:npti), qml_ice_1d    (1:npti), qml_ice    (:,:,kl) )
394         CALL tab_2d_1d( npti, nptidx(1:npti), qcn_ice_1d    (1:npti), qcn_ice    (:,:,kl) )
395         CALL tab_2d_1d( npti, nptidx(1:npti), qtr_ice_top_1d(1:npti), qtr_ice_top(:,:,kl) )
396         !
397         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni   )
398         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum   )
399         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub       )
400         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub   )
401         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub   )
402         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub   )
403         !
404         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog          )
405         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom          )
406         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum          )
407         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni          )
408         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res          )
409         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr          )
410         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam          )
411         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd          )
412         !
413         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog          )
414         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom          )
415         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum          )
416         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni          )
417         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri          )
418         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res          )
419         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub          )
420         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam          )
421         !
422         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_thd_1d    (1:npti), hfx_thd       )
423         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_spr_1d    (1:npti), hfx_spr       )
424         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sum_1d    (1:npti), hfx_sum       )
425         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bom_1d    (1:npti), hfx_bom       )
426         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bog_1d    (1:npti), hfx_bog       )
427         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_dif_1d    (1:npti), hfx_dif       )
428         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_opw_1d    (1:npti), hfx_opw       )
429         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_snw_1d    (1:npti), hfx_snw       )
430         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sub_1d    (1:npti), hfx_sub       )
431         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_res_1d    (1:npti), hfx_res       )
432         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif   )
433         !
434         ! ocean surface fields
435         CALL tab_2d_1d( npti, nptidx(1:npti), sst_1d(1:npti), sst_m )
436         CALL tab_2d_1d( npti, nptidx(1:npti), sss_1d(1:npti), sss_m )
437         CALL tab_2d_1d( npti, nptidx(1:npti), frq_m_1d(1:npti), frq_m )
438         !
439         ! to update ice age
440         CALL tab_2d_1d( npti, nptidx(1:npti), o_i_1d (1:npti), o_i (:,:,kl) )
441         CALL tab_2d_1d( npti, nptidx(1:npti), oa_i_1d(1:npti), oa_i(:,:,kl) )
442         !
443         ! --- Change units of e_i, e_s from J/m2 to J/m3 --- !
444         DO jk = 1, nlay_i
445            WHERE( h_i_1d(1:npti)>0._wp ) e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) / (h_i_1d(1:npti) * a_i_1d(1:npti)) * nlay_i
446         END DO
447         DO jk = 1, nlay_s
448            WHERE( h_s_1d(1:npti)>0._wp ) e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) / (h_s_1d(1:npti) * a_i_1d(1:npti)) * nlay_s
449         END DO
450         !
451         !                 !---------------------!
452      CASE( 2 )            !==  from 1D to 2D  ==!
453         !                 !---------------------!
454         ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
455         DO jk = 1, nlay_i
456            e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) * h_i_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_i
457         END DO
458         DO jk = 1, nlay_s
459            e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) * h_s_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_s
460         END DO
461         !
462         ! Change thickness to volume (replaces routine ice_var_eqv2glo)
463         v_i_1d (1:npti) = h_i_1d (1:npti) * a_i_1d (1:npti)
464         v_s_1d (1:npti) = h_s_1d (1:npti) * a_i_1d (1:npti)
465         sv_i_1d(1:npti) = s_i_1d (1:npti) * v_i_1d (1:npti)
466         v_ip_1d(1:npti) = h_ip_1d(1:npti) * a_ip_1d(1:npti)
467         v_il_1d(1:npti) = h_il_1d(1:npti) * a_ip_1d(1:npti)
468         oa_i_1d(1:npti) = o_i_1d (1:npti) * a_i_1d (1:npti)
469         
470         CALL tab_1d_2d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
471         CALL tab_1d_2d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
472         CALL tab_1d_2d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
473         CALL tab_1d_2d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
474         CALL tab_1d_2d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
475         CALL tab_1d_2d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
476         DO jk = 1, nlay_s
477            CALL tab_1d_2d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
478            CALL tab_1d_2d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
479         END DO
480         DO jk = 1, nlay_i
481            CALL tab_1d_2d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
482            CALL tab_1d_2d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
483            CALL tab_1d_2d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
484         END DO
485         CALL tab_1d_2d( npti, nptidx(1:npti), a_ip_1d     (1:npti), a_ip     (:,:,kl) )
486         CALL tab_1d_2d( npti, nptidx(1:npti), h_ip_1d     (1:npti), h_ip     (:,:,kl) )
487         CALL tab_1d_2d( npti, nptidx(1:npti), h_il_1d     (1:npti), h_il     (:,:,kl) )
488         !
489         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni )
490         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum )
491         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub     )
492         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub )
493         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub )
494         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub )
495         !
496         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog        )
497         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom        )
498         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum        )
499         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni        )
500         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res        )
501         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr        )
502         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam        )
503         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd        )
504         !
505         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog        )
506         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom        )
507         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum        )
508         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni        )
509         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri        )
510         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res        )
511         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub        )
512         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam        )
513         !
514         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_thd_1d    (1:npti), hfx_thd     )
515         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_spr_1d    (1:npti), hfx_spr     )
516         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sum_1d    (1:npti), hfx_sum     )
517         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bom_1d    (1:npti), hfx_bom     )
518         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bog_1d    (1:npti), hfx_bog     )
519         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_dif_1d    (1:npti), hfx_dif     )
520         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_opw_1d    (1:npti), hfx_opw     )
521         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_snw_1d    (1:npti), hfx_snw     )
522         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sub_1d    (1:npti), hfx_sub     )
523         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_res_1d    (1:npti), hfx_res     )
524         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif )
525         !
526         CALL tab_1d_2d( npti, nptidx(1:npti), qns_ice_1d    (1:npti), qns_ice    (:,:,kl) )
527         CALL tab_1d_2d( npti, nptidx(1:npti), qtr_ice_bot_1d(1:npti), qtr_ice_bot(:,:,kl) )
528         ! effective conductivity and 1st layer temperature (ln_cndflx=T)
529         CALL tab_1d_2d( npti, nptidx(1:npti), cnd_ice_1d(1:npti), cnd_ice(:,:,kl) )
530         CALL tab_1d_2d( npti, nptidx(1:npti), t1_ice_1d (1:npti), t1_ice (:,:,kl) )
531         ! SIMIP diagnostics         
532         CALL tab_1d_2d( npti, nptidx(1:npti), t_si_1d       (1:npti), t_si       (:,:,kl) )
533         CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_bot_1d(1:npti), qcn_ice_bot(:,:,kl) )
534         CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_top_1d(1:npti), qcn_ice_top(:,:,kl) )
535         ! extensive variables
536         CALL tab_1d_2d( npti, nptidx(1:npti), v_i_1d (1:npti), v_i (:,:,kl) )
537         CALL tab_1d_2d( npti, nptidx(1:npti), v_s_1d (1:npti), v_s (:,:,kl) )
538         CALL tab_1d_2d( npti, nptidx(1:npti), sv_i_1d(1:npti), sv_i(:,:,kl) )
539         CALL tab_1d_2d( npti, nptidx(1:npti), v_ip_1d(1:npti), v_ip(:,:,kl) )
540         CALL tab_1d_2d( npti, nptidx(1:npti), v_il_1d(1:npti), v_il(:,:,kl) )
541         CALL tab_1d_2d( npti, nptidx(1:npti), oa_i_1d(1:npti), oa_i(:,:,kl) )
542         ! check convergence of heat diffusion scheme
543         IF( ln_zdf_chkcvg ) THEN
544            CALL tab_1d_2d( npti, nptidx(1:npti), tice_cvgerr_1d(1:npti), ztice_cvgerr(:,:,kl) )
545            CALL tab_1d_2d( npti, nptidx(1:npti), tice_cvgstp_1d(1:npti), ztice_cvgstp(:,:,kl) )
546         ENDIF
547         !
548      END SELECT
549      !
550   END SUBROUTINE ice_thd_1d2d
551
552
553   SUBROUTINE ice_thd_init
554      !!-------------------------------------------------------------------
555      !!                   ***  ROUTINE ice_thd_init ***
556      !!                 
557      !! ** Purpose :   Physical constants and parameters associated with
558      !!                ice thermodynamics
559      !!
560      !! ** Method  :   Read the namthd namelist and check the parameters
561      !!                called at the first timestep (nit000)
562      !!
563      !! ** input   :   Namelist namthd
564      !!-------------------------------------------------------------------
565      INTEGER  ::   ios   ! Local integer output status for namelist read
566      !!
567      NAMELIST/namthd/ ln_icedH, ln_icedA, ln_icedO, ln_icedS, ln_leadhfx
568      !!-------------------------------------------------------------------
569      !
570      READ  ( numnam_ice_ref, namthd, IOSTAT = ios, ERR = 901)
571901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namthd in reference namelist' )
572      READ  ( numnam_ice_cfg, namthd, IOSTAT = ios, ERR = 902 )
573902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namthd in configuration namelist' )
574      IF(lwm) WRITE( numoni, namthd )
575      !
576      IF(lwp) THEN                          ! control print
577         WRITE(numout,*)
578         WRITE(numout,*) 'ice_thd_init: Ice Thermodynamics'
579         WRITE(numout,*) '~~~~~~~~~~~~'
580         WRITE(numout,*) '   Namelist namthd:'
581         WRITE(numout,*) '      activate ice thick change from top/bot (T) or not (F)                ln_icedH   = ', ln_icedH
582         WRITE(numout,*) '      activate lateral melting (T) or not (F)                              ln_icedA   = ', ln_icedA
583         WRITE(numout,*) '      activate ice growth in open-water (T) or not (F)                     ln_icedO   = ', ln_icedO
584         WRITE(numout,*) '      activate gravity drainage and flushing (T) or not (F)                ln_icedS   = ', ln_icedS
585         WRITE(numout,*) '      heat in the leads is used to melt sea-ice before warming the ocean   ln_leadhfx = ', ln_leadhfx
586     ENDIF
587      !
588                       CALL ice_thd_zdf_init   ! set ice heat diffusion parameters
589      IF( ln_icedA )   CALL ice_thd_da_init    ! set ice lateral melting parameters
590      IF( ln_icedO )   CALL ice_thd_do_init    ! set ice growth in open water parameters
591                       CALL ice_thd_sal_init   ! set ice salinity parameters
592                       CALL ice_thd_pnd_init   ! set melt ponds parameters
593      !
594   END SUBROUTINE ice_thd_init
595
596#else
597   !!----------------------------------------------------------------------
598   !!   Default option         Dummy module          NO  SI3 sea-ice model
599   !!----------------------------------------------------------------------
600#endif
601
602   !!======================================================================
603END MODULE icethd
Note: See TracBrowser for help on using the repository browser.