New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trazdf.F90 in NEMO/branches/2020/dev_r13648_ASINTER-04_laurent_bulk_ice/tests/CANAL/MY_SRC – NEMO

source: NEMO/branches/2020/dev_r13648_ASINTER-04_laurent_bulk_ice/tests/CANAL/MY_SRC/trazdf.F90 @ 14021

Last change on this file since 14021 was 14021, checked in by laurent, 3 years ago

Caught up with trunk rev 14020...
  • Property svn:keywords set to Id
File size: 13.0 KB
Line 
1MODULE trazdf
2   !!==============================================================================
3   !!                 ***  MODULE  trazdf  ***
4   !! Ocean active tracers:  vertical component of the tracer mixing trend
5   !!==============================================================================
6   !! History :  1.0  !  2005-11  (G. Madec)  Original code
7   !!            3.0  !  2008-01  (C. Ethe, G. Madec)  merge TRC-TRA
8   !!            4.0  !  2017-06  (G. Madec)  remove explict time-stepping option
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   tra_zdf       : Update the tracer trend with the vertical diffusion
13   !!----------------------------------------------------------------------
14   USE oce            ! ocean dynamics and tracers variables
15   USE dom_oce        ! ocean space and time domain variables
16   USE domvvl         ! variable volume
17   USE phycst         ! physical constant
18   USE zdf_oce        ! ocean vertical physics variables
19   USE sbc_oce        ! surface boundary condition: ocean
20   USE ldftra         ! lateral diffusion: eddy diffusivity
21   USE ldfslp         ! lateral diffusion: iso-neutral slope
22   USE trd_oce        ! trends: ocean variables
23   USE trdtra         ! trends: tracer trend manager
24   !
25   USE in_out_manager ! I/O manager
26   USE prtctl         ! Print control
27   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
28   USE lib_mpp        ! MPP library
29   USE timing         ! Timing
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   tra_zdf       ! called by step.F90
35   PUBLIC   tra_zdf_imp   ! called by trczdf.F90
36
37   !! * Substitutions
38#  include "do_loop_substitute.h90"
39   !!----------------------------------------------------------------------
40   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
41   !! $Id$
42   !! Software governed by the CeCILL license (see ./LICENSE)
43   !!----------------------------------------------------------------------
44CONTAINS
45
46   SUBROUTINE tra_zdf( kt, Kbb, Kmm, Krhs, pts, Kaa )
47      !!----------------------------------------------------------------------
48      !!                  ***  ROUTINE tra_zdf  ***
49      !!
50      !! ** Purpose :   compute the vertical ocean tracer physics.
51      !!---------------------------------------------------------------------
52      INTEGER                                  , INTENT(in)    :: kt                  ! ocean time-step index
53      INTEGER                                  , INTENT(in)    :: Kbb, Kmm, Krhs, Kaa ! time level indices
54      REAL(wp), DIMENSION(jpi,jpj,jpk,jpts,jpt), INTENT(inout) :: pts                 ! active tracers and RHS of tracer equation
55      !
56      INTEGER  ::   ji, jj, jk   ! Dummy loop indices
57      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdt, ztrds   ! 3D workspace
58      !!---------------------------------------------------------------------
59      !
60      IF( ln_timing )   CALL timing_start('tra_zdf')
61      !
62      IF( kt == nit000 )  THEN
63         IF( ntile == 0 .OR. ntile == 1 )  THEN                   ! Do only on the first tile
64            IF(lwp)WRITE(numout,*)
65            IF(lwp)WRITE(numout,*) 'tra_zdf : implicit vertical mixing on T & S'
66            IF(lwp)WRITE(numout,*) '~~~~~~~ '
67         ENDIF
68      ENDIF
69      !
70      IF( l_trdtra )   THEN                  !* Save ta and sa trends
71         ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) )
72         ztrdt(:,:,:) = pts(:,:,:,jp_tem,Kaa)
73         ztrds(:,:,:) = pts(:,:,:,jp_sal,Kaa)
74      ENDIF
75      !
76      !                                      !* compute lateral mixing trend and add it to the general trend
77      CALL tra_zdf_imp( kt, nit000, 'TRA', rDt, Kbb, Kmm, Krhs, pts, Kaa, jpts ) 
78
79!!gm WHY here !   and I don't like that !
80      ! DRAKKAR SSS control {
81      ! JMM avoid negative salinities near river outlet ! Ugly fix
82      ! JMM : restore negative salinities to small salinities:
83!!$      WHERE( pts(:,:,:,jp_sal,Kaa) < 0._wp )   pts(:,:,:,jp_sal,Kaa) = 0.1_wp
84!!gm
85
86      IF( l_trdtra )   THEN                      ! save the vertical diffusive trends for further diagnostics
87         DO jk = 1, jpk
88            ztrdt(:,:,jk) = (   (  pts(:,:,jk,jp_tem,Kaa)*e3t(:,:,jk,Kaa)     &
89               &                 - pts(:,:,jk,jp_tem,Kbb)*e3t(:,:,jk,Kbb)  )  &
90               &              / (  e3t(:,:,jk,Kmm)*rDt  )   )                 &
91               &          - ztrdt(:,:,jk)
92            ztrds(:,:,jk) = (   (  pts(:,:,jk,jp_sal,Kaa)*e3t(:,:,jk,Kaa)     &
93               &                 - pts(:,:,jk,jp_sal,Kbb)*e3t(:,:,jk,Kbb)  )  &
94               &             / (   e3t(:,:,jk,Kmm)*rDt  )   )                 &
95               &          - ztrds(:,:,jk)
96         END DO
97!!gm this should be moved in trdtra.F90 and done on all trends
98         CALL lbc_lnk_multi( 'trazdf', ztrdt, 'T', 1. , ztrds, 'T', 1. )
99!!gm
100         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_tem, jptra_zdf, ztrdt )
101         CALL trd_tra( kt, Kmm, Krhs, 'TRA', jp_sal, jptra_zdf, ztrds )
102         DEALLOCATE( ztrdt , ztrds )
103      ENDIF
104      !                                          ! print mean trends (used for debugging)
105      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=pts(:,:,:,jp_tem,Kaa), clinfo1=' zdf  - Ta: ', mask1=tmask,               &
106         &                                  tab3d_2=pts(:,:,:,jp_sal,Kaa), clinfo2=       ' Sa: ', mask2=tmask, clinfo3='tra' )
107      !
108      IF( ln_timing )   CALL timing_stop('tra_zdf')
109      !
110   END SUBROUTINE tra_zdf
111
112 
113   SUBROUTINE tra_zdf_imp( kt, kit000, cdtype, p2dt, Kbb, Kmm, Krhs, pt, Kaa, kjpt ) 
114      !!----------------------------------------------------------------------
115      !!                  ***  ROUTINE tra_zdf_imp  ***
116      !!
117      !! ** Purpose :   Compute the after tracer through a implicit computation
118      !!     of the vertical tracer diffusion (including the vertical component
119      !!     of lateral mixing (only for 2nd order operator, for fourth order
120      !!     it is already computed and add to the general trend in traldf)
121      !!
122      !! ** Method  :  The vertical diffusion of a tracer ,t , is given by:
123      !!          difft = dz( avt dz(t) ) = 1/e3t dk+1( avt/e3w dk(t) )
124      !!      It is computed using a backward time scheme (t=after field)
125      !!      which provide directly the after tracer field.
126      !!      If ln_zdfddm=T, use avs for salinity or for passive tracers
127      !!      Surface and bottom boundary conditions: no diffusive flux on
128      !!      both tracers (bottom, applied through the masked field avt).
129      !!      If iso-neutral mixing, add to avt the contribution due to lateral mixing.
130      !!
131      !! ** Action  : - pt(:,:,:,:,Kaa)  becomes the after tracer
132      !!---------------------------------------------------------------------
133      INTEGER                                  , INTENT(in   ) ::   kt       ! ocean time-step index
134      INTEGER                                  , INTENT(in   ) ::   Kbb, Kmm, Krhs, Kaa  ! ocean time level indices
135      INTEGER                                  , INTENT(in   ) ::   kit000   ! first time step index
136      CHARACTER(len=3)                         , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
137      INTEGER                                  , INTENT(in   ) ::   kjpt     ! number of tracers
138      REAL(wp)                                 , INTENT(in   ) ::   p2dt     ! tracer time-step
139      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt,jpt), INTENT(inout) ::   pt       ! tracers and RHS of tracer equation
140      !
141      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
142      REAL(wp) ::  zrhs, zzwi, zzws ! local scalars
143      REAL(wp), DIMENSION(A2D(nn_hls),jpk) ::  zwi, zwt, zwd, zws
144      !!---------------------------------------------------------------------
145      !
146      !                                               ! ============= !
147      DO jn = 1, kjpt                                 !  tracer loop  !
148         !                                            ! ============= !
149         !  Matrix construction
150         ! --------------------
151         ! Build matrix if temperature or salinity (only in double diffusion case) or first passive tracer
152         !
153         IF(  ( cdtype == 'TRA' .AND. ( jn == jp_tem .OR. ( jn == jp_sal .AND. ln_zdfddm ) ) ) .OR.   &
154            & ( cdtype == 'TRC' .AND. jn == 1 )  )  THEN
155            !
156            ! vertical mixing coef.: avt for temperature, avs for salinity and passive tracers
157            IF( cdtype == 'TRA' .AND. jn == jp_tem ) THEN
158               DO_3D( 1, 1, 1, 1, 2, jpk )
159                  zwt(ji,jj,jk) = avt(ji,jj,jk)
160               END_3D
161            ELSE
162               DO_3D( 1, 1, 1, 1, 2, jpk )
163                  zwt(ji,jj,jk) = avs(ji,jj,jk)
164               END_3D
165            ENDIF
166            zwt(:,:,1) = 0._wp
167            !
168            IF( l_ldfslp ) THEN            ! isoneutral diffusion: add the contribution
169               IF( ln_traldf_msc  ) THEN     ! MSC iso-neutral operator
170                  DO_3D( 0, 0, 0, 0, 2, jpkm1 )
171                     zwt(ji,jj,jk) = zwt(ji,jj,jk) + akz(ji,jj,jk) 
172                  END_3D
173               ELSE                          ! standard or triad iso-neutral operator
174                  DO_3D( 0, 0, 0, 0, 2, jpkm1 )
175                     zwt(ji,jj,jk) = zwt(ji,jj,jk) + ah_wslp2(ji,jj,jk)
176                  END_3D
177               ENDIF
178            ENDIF
179            !
180            ! Diagonal, lower (i), upper (s)  (including the bottom boundary condition since avt is masked)
181            IF( ln_zad_Aimp ) THEN         ! Adaptive implicit vertical advection
182               DO_3D( 0, 0, 0, 0, 1, jpkm1 )
183                  zzwi = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk  ,Kmm)
184                  zzws = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
185                  zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zzwi - zzws   &
186                     &                 + p2dt * ( MAX( wi(ji,jj,jk  ) , 0._wp ) - MIN( wi(ji,jj,jk+1) , 0._wp ) )
187                  zwi(ji,jj,jk) = zzwi + p2dt *   MIN( wi(ji,jj,jk  ) , 0._wp )
188                  zws(ji,jj,jk) = zzws - p2dt *   MAX( wi(ji,jj,jk+1) , 0._wp )
189               END_3D
190            ELSE
191               DO_3D( 0, 0, 0, 0, 1, jpkm1 )
192                  zwi(ji,jj,jk) = - p2dt * zwt(ji,jj,jk  ) / e3w(ji,jj,jk,Kmm)
193                  zws(ji,jj,jk) = - p2dt * zwt(ji,jj,jk+1) / e3w(ji,jj,jk+1,Kmm)
194                  zwd(ji,jj,jk) = e3t(ji,jj,jk,Kaa) - zwi(ji,jj,jk) - zws(ji,jj,jk)
195               END_3D
196            ENDIF
197            !
198            !! Matrix inversion from the first level
199            !!----------------------------------------------------------------------
200            !   solve m.x = y  where m is a tri diagonal matrix ( jpk*jpk )
201            !
202            !        ( zwd1 zws1   0    0    0  )( zwx1 ) ( zwy1 )
203            !        ( zwi2 zwd2 zws2   0    0  )( zwx2 ) ( zwy2 )
204            !        (  0   zwi3 zwd3 zws3   0  )( zwx3 )=( zwy3 )
205            !        (        ...               )( ...  ) ( ...  )
206            !        (  0    0    0   zwik zwdk )( zwxk ) ( zwyk )
207            !
208            !   m is decomposed in the product of an upper and lower triangular matrix.
209            !   The 3 diagonal terms are in 3d arrays: zwd, zws, zwi.
210            !   Suffices i,s and d indicate "inferior" (below diagonal), diagonal
211            !   and "superior" (above diagonal) components of the tridiagonal system.
212            !   The solution will be in the 4d array pta.
213            !   The 3d array zwt is used as a work space array.
214            !   En route to the solution pt(:,:,:,:,Kaa) is used a to evaluate the rhs and then
215            !   used as a work space array: its value is modified.
216            !
217            DO_2D( 0, 0, 0, 0 )
218               zwt(ji,jj,1) = zwd(ji,jj,1)
219            END_2D
220            DO_3D( 0, 0, 0, 0, 2, jpkm1 )
221               zwt(ji,jj,jk) = zwd(ji,jj,jk) - zwi(ji,jj,jk) * zws(ji,jj,jk-1) / zwt(ji,jj,jk-1)
222            END_3D
223            !
224         ENDIF 
225         !         
226         DO_2D( 0, 0, 0, 0 )
227            pt(ji,jj,1,jn,Kaa) = e3t(ji,jj,1,Kbb) * pt(ji,jj,1,jn,Kbb) + p2dt * e3t(ji,jj,1,Kmm) * pt(ji,jj,1,jn,Krhs)
228         END_2D
229         DO_3D( 0, 0, 0, 0, 2, jpkm1 )
230            zrhs = e3t(ji,jj,jk,Kbb) * pt(ji,jj,jk,jn,Kbb) + p2dt * e3t(ji,jj,jk,Kmm) * pt(ji,jj,jk,jn,Krhs)   ! zrhs=right hand side
231            pt(ji,jj,jk,jn,Kaa) = zrhs - zwi(ji,jj,jk) / zwt(ji,jj,jk-1) * pt(ji,jj,jk-1,jn,Kaa)
232         END_3D
233         !
234         DO_2D( 0, 0, 0, 0 )
235            pt(ji,jj,jpkm1,jn,Kaa) = pt(ji,jj,jpkm1,jn,Kaa) / zwt(ji,jj,jpkm1) * tmask(ji,jj,jpkm1)
236         END_2D
237         DO_3DS( 0, 0, 0, 0, jpk-2, 1, -1 )
238            pt(ji,jj,jk,jn,Kaa) = ( pt(ji,jj,jk,jn,Kaa) - zws(ji,jj,jk) * pt(ji,jj,jk+1,jn,Kaa) )   &
239               &             / zwt(ji,jj,jk) * tmask(ji,jj,jk)
240         END_3D
241         !                                            ! ================= !
242      END DO                                          !  end tracer loop  !
243      !                                               ! ================= !
244   END SUBROUTINE tra_zdf_imp
245
246   !!==============================================================================
247END MODULE trazdf
Note: See TracBrowser for help on using the repository browser.