New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dynzad.F90 in NEMO/branches/2020/dev_r2052_ENHANCE-09_rbourdal_massfluxconvection/src/OCE/DYN – NEMO

source: NEMO/branches/2020/dev_r2052_ENHANCE-09_rbourdal_massfluxconvection/src/OCE/DYN/dynzad.F90 @ 14009

Last change on this file since 14009 was 14009, checked in by gsamson, 3 years ago

dev_r2052_ENHANCE-09_rbourdal_massfluxconvection update with trunk@r14008

  • Property svn:keywords set to Id
File size: 5.8 KB
Line 
1MODULE dynzad
2   !!======================================================================
3   !!                       ***  MODULE  dynzad  ***
4   !! Ocean dynamics : vertical advection trend
5   !!======================================================================
6   !! History :  OPA  ! 1991-01  (G. Madec) Original code
7   !!   NEMO     0.5  ! 2002-07  (G. Madec) Free form, F90
8   !!----------------------------------------------------------------------
9   
10   !!----------------------------------------------------------------------
11   !!   dyn_zad       : vertical advection momentum trend
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE sbc_oce        ! surface boundary condition: ocean
16   USE trd_oce        ! trends: ocean variables
17   USE trddyn         ! trend manager: dynamics
18   USE sbcwave, ONLY: wsd   ! Surface Waves (add vertical Stokes-drift)
19   !
20   USE in_out_manager ! I/O manager
21   USE lib_mpp        ! MPP library
22   USE prtctl         ! Print control
23   USE timing         ! Timing
24
25   IMPLICIT NONE
26   PRIVATE
27   
28   PUBLIC   dyn_zad       ! routine called by dynadv.F90
29
30   !! * Substitutions
31#  include "do_loop_substitute.h90"
32#  include "domzgr_substitute.h90"
33   !!----------------------------------------------------------------------
34   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
35   !! $Id$
36   !! Software governed by the CeCILL license (see ./LICENSE)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE dyn_zad ( kt, Kmm, puu, pvv, Krhs )
41      !!----------------------------------------------------------------------
42      !!                  ***  ROUTINE dynzad  ***
43      !!
44      !! ** Purpose :   Compute the now vertical momentum advection trend and
45      !!      add it to the general trend of momentum equation.
46      !!
47      !! ** Method  :   The now vertical advection of momentum is given by:
48      !!         w dz(u) = u(rhs) + 1/(e1e2u*e3u) mk+1[ mi(e1e2t*ww) dk(u) ]
49      !!         w dz(v) = v(rhs) + 1/(e1e2v*e3v) mk+1[ mj(e1e2t*ww) dk(v) ]
50      !!      Add this trend to the general trend (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)):
51      !!         (u(rhs),v(rhs)) = (u(rhs),v(rhs)) + w dz(u,v)
52      !!
53      !! ** Action  : - Update (puu(:,:,:,Krhs),pvv(:,:,:,Krhs)) with the vert. momentum adv. trends
54      !!              - Send the trends to trddyn for diagnostics (l_trddyn=T)
55      !!----------------------------------------------------------------------
56      INTEGER                             , INTENT( in )  ::  kt               ! ocean time-step inedx
57      INTEGER                             , INTENT( in )  ::  Kmm, Krhs        ! ocean time level indices
58      REAL(wp), DIMENSION(jpi,jpj,jpk,jpt), INTENT(inout) ::  puu, pvv         ! ocean velocities and RHS of momentum equation
59      !
60      INTEGER  ::   ji, jj, jk   ! dummy loop indices
61      REAL(wp) ::   zua, zva     ! local scalars
62      REAL(wp), DIMENSION(jpi,jpj)     ::   zww
63      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zwuw, zwvw
64      REAL(wp), DIMENSION(:,:,:), ALLOCATABLE ::   ztrdu, ztrdv
65      !!----------------------------------------------------------------------
66      !
67      IF( ln_timing )   CALL timing_start('dyn_zad')
68      !
69      IF( kt == nit000 ) THEN
70         IF(lwp) WRITE(numout,*)
71         IF(lwp) WRITE(numout,*) 'dyn_zad : 2nd order vertical advection scheme'
72      ENDIF
73
74      IF( l_trddyn )   THEN           ! Save puu(:,:,:,Krhs) and pvv(:,:,:,Krhs) trends
75         ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) ) 
76         ztrdu(:,:,:) = puu(:,:,:,Krhs) 
77         ztrdv(:,:,:) = pvv(:,:,:,Krhs) 
78      ENDIF
79     
80      DO jk = 2, jpkm1                ! Vertical momentum advection at level w and u- and v- vertical
81         DO_2D( 0, 1, 0, 1 )              ! vertical fluxes
82          IF( ln_vortex_force ) THEN
83            zww(ji,jj) = 0.25_wp * e1e2t(ji,jj) * ( ww(ji,jj,jk) + wsd(ji,jj,jk) )
84          ELSE
85            zww(ji,jj) = 0.25_wp * e1e2t(ji,jj) * ww(ji,jj,jk)
86          ENDIF
87         END_2D
88         DO_2D( 0, 0, 0, 0 )              ! vertical momentum advection at w-point
89            zwuw(ji,jj,jk) = ( zww(ji+1,jj  ) + zww(ji,jj) ) * ( puu(ji,jj,jk-1,Kmm) - puu(ji,jj,jk,Kmm) )
90            zwvw(ji,jj,jk) = ( zww(ji  ,jj+1) + zww(ji,jj) ) * ( pvv(ji,jj,jk-1,Kmm) - pvv(ji,jj,jk,Kmm) )
91         END_2D
92      END DO
93      !
94      ! Surface and bottom advective fluxes set to zero
95      DO_2D( 0, 0, 0, 0 )
96         zwuw(ji,jj, 1 ) = 0._wp
97         zwvw(ji,jj, 1 ) = 0._wp
98         zwuw(ji,jj,jpk) = 0._wp
99         zwvw(ji,jj,jpk) = 0._wp
100      END_2D
101      !
102      DO_3D( 0, 0, 0, 0, 1, jpkm1 )   ! Vertical momentum advection at u- and v-points
103         puu(ji,jj,jk,Krhs) = puu(ji,jj,jk,Krhs) - ( zwuw(ji,jj,jk) + zwuw(ji,jj,jk+1) ) * r1_e1e2u(ji,jj)   &
104            &                                      / e3u(ji,jj,jk,Kmm)
105         pvv(ji,jj,jk,Krhs) = pvv(ji,jj,jk,Krhs) - ( zwvw(ji,jj,jk) + zwvw(ji,jj,jk+1) ) * r1_e1e2v(ji,jj)   &
106            &                                      / e3v(ji,jj,jk,Kmm)
107      END_3D
108
109      IF( l_trddyn ) THEN             ! save the vertical advection trends for diagnostic
110         ztrdu(:,:,:) = puu(:,:,:,Krhs) - ztrdu(:,:,:)
111         ztrdv(:,:,:) = pvv(:,:,:,Krhs) - ztrdv(:,:,:)
112         CALL trd_dyn( ztrdu, ztrdv, jpdyn_zad, kt, Kmm )
113         DEALLOCATE( ztrdu, ztrdv ) 
114      ENDIF
115      !                               ! Control print
116      IF(sn_cfctl%l_prtctl)   CALL prt_ctl( tab3d_1=puu(:,:,:,Krhs), clinfo1=' zad  - Ua: ', mask1=umask,   &
117         &                                  tab3d_2=pvv(:,:,:,Krhs), clinfo2=       ' Va: ', mask2=vmask, clinfo3='dyn' )
118      !
119      IF( ln_timing )   CALL timing_stop('dyn_zad')
120      !
121   END SUBROUTINE dyn_zad
122
123   !!======================================================================
124END MODULE dynzad
Note: See TracBrowser for help on using the repository browser.