New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdylib.F90 in NEMO/branches/2020/r12377_ticket2386/src/OCE/BDY – NEMO

source: NEMO/branches/2020/r12377_ticket2386/src/OCE/BDY/bdylib.F90 @ 13540

Last change on this file since 13540 was 13540, checked in by andmirek, 4 years ago

Ticket #2386: update to latest trunk
  • Property svn:keywords set to Id
File size: 27.4 KB
Line 
1MODULE bdylib
2   !!======================================================================
3   !!                       ***  MODULE  bdylib  ***
4   !! Unstructured Open Boundary Cond. :  Library module of generic boundary algorithms.
5   !!======================================================================
6   !! History :  3.6  !  2013     (D. Storkey) original code
7   !!            4.0  !  2014     (T. Lovato) Generalize OBC structure
8   !!----------------------------------------------------------------------
9   !!----------------------------------------------------------------------
10   !!   bdy_orlanski_2d
11   !!   bdy_orlanski_3d
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE dom_oce        ! ocean space and time domain
15   USE bdy_oce        ! ocean open boundary conditions
16   USE phycst         ! physical constants
17   USE bdyini
18   !
19   USE in_out_manager !
20   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
21   USE lib_mpp, ONLY: ctl_stop
22
23   IMPLICIT NONE
24   PRIVATE
25
26   PUBLIC   bdy_frs, bdy_spe, bdy_nmn, bdy_orl
27   PUBLIC   bdy_orlanski_2d
28   PUBLIC   bdy_orlanski_3d
29
30   !!----------------------------------------------------------------------
31   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
32   !! $Id$
33   !! Software governed by the CeCILL license (see ./LICENSE)
34   !!----------------------------------------------------------------------
35CONTAINS
36
37   SUBROUTINE bdy_frs( idx, phia, dta )
38      !!----------------------------------------------------------------------
39      !!                 ***  SUBROUTINE bdy_frs  ***
40      !!
41      !! ** Purpose : Apply the Flow Relaxation Scheme for tracers at open boundaries.
42      !!
43      !! Reference : Engedahl H., 1995, Tellus, 365-382.
44      !!----------------------------------------------------------------------
45      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
46      REAL(wp), DIMENSION(:,:), POINTER,   INTENT(in) ::   dta  ! OBC external data
47      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   phia  ! tracer trend
48      !!
49      REAL(wp) ::   zwgt           ! boundary weight
50      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
51      INTEGER  ::   ii, ij         ! 2D addresses
52      !!----------------------------------------------------------------------
53      !
54      igrd = 1                       ! Everything is at T-points here
55      DO ib = 1, idx%nblen(igrd)
56         DO ik = 1, jpkm1
57            ii = idx%nbi(ib,igrd) 
58            ij = idx%nbj(ib,igrd)
59            zwgt = idx%nbw(ib,igrd)
60            phia(ii,ij,ik) = ( phia(ii,ij,ik) + zwgt * (dta(ib,ik) - phia(ii,ij,ik) ) ) * tmask(ii,ij,ik)
61         END DO
62      END DO
63      !
64   END SUBROUTINE bdy_frs
65
66
67   SUBROUTINE bdy_spe( idx, phia, dta )
68      !!----------------------------------------------------------------------
69      !!                 ***  SUBROUTINE bdy_spe  ***
70      !!
71      !! ** Purpose : Apply a specified value for tracers at open boundaries.
72      !!
73      !!----------------------------------------------------------------------
74      TYPE(OBC_INDEX),                     INTENT(in) ::   idx  ! OBC indices
75      REAL(wp), DIMENSION(:,:), POINTER,   INTENT(in) ::   dta  ! OBC external data
76      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   phia  ! tracer trend
77      !!
78      INTEGER  ::   ib, ik, igrd   ! dummy loop indices
79      INTEGER  ::   ii, ij         ! 2D addresses
80      !!----------------------------------------------------------------------
81      !
82      igrd = 1                       ! Everything is at T-points here
83      DO ib = 1, idx%nblenrim(igrd)
84         ii = idx%nbi(ib,igrd)
85         ij = idx%nbj(ib,igrd)
86         DO ik = 1, jpkm1
87            phia(ii,ij,ik) = dta(ib,ik) * tmask(ii,ij,ik)
88         END DO
89      END DO
90      !
91   END SUBROUTINE bdy_spe
92
93
94   SUBROUTINE bdy_orl( idx, phib, phia, dta, lrim0, ll_npo )
95      !!----------------------------------------------------------------------
96      !!                 ***  SUBROUTINE bdy_orl  ***
97      !!
98      !! ** Purpose : Apply Orlanski radiation for tracers at open boundaries.
99      !!              This is a wrapper routine for bdy_orlanski_3d below
100      !!
101      !!----------------------------------------------------------------------
102      TYPE(OBC_INDEX),                   INTENT(in   ) ::   idx  ! OBC indices
103      REAL(wp), DIMENSION(:,:), POINTER, INTENT(in   ) ::   dta  ! OBC external data
104      REAL(wp), DIMENSION(jpi,jpj,jpk),  INTENT(inout) ::   phib  ! before tracer field
105      REAL(wp), DIMENSION(jpi,jpj,jpk),  INTENT(inout) ::   phia  ! tracer trend
106      LOGICAL ,                          INTENT(in   ) ::   lrim0   ! indicate if rim 0 is treated
107      LOGICAL ,                          INTENT(in   ) ::   ll_npo  ! switch for NPO version
108      !!
109      INTEGER  ::   igrd                                    ! grid index
110      !!----------------------------------------------------------------------
111      !
112      igrd = 1                       ! Everything is at T-points here
113      !
114      CALL bdy_orlanski_3d( idx, igrd, phib(:,:,:), phia(:,:,:), dta, lrim0, ll_npo )
115      !
116   END SUBROUTINE bdy_orl
117
118
119   SUBROUTINE bdy_orlanski_2d( idx, igrd, phib, phia, phi_ext, lrim0, ll_npo )
120      !!----------------------------------------------------------------------
121      !!                 ***  SUBROUTINE bdy_orlanski_2d  ***
122      !!             
123      !!              - Apply Orlanski radiation condition adaptively to 2D fields:
124      !!                  - radiation plus weak nudging at outflow points
125      !!                  - no radiation and strong nudging at inflow points
126      !!
127      !!
128      !! References:  Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001)   
129      !!----------------------------------------------------------------------
130      TYPE(OBC_INDEX),                   INTENT(in   ) ::   idx      ! BDY indices
131      INTEGER ,                          INTENT(in   ) ::   igrd     ! grid index
132      REAL(wp), DIMENSION(:,:),          INTENT(in   ) ::   phib     ! model before 2D field
133      REAL(wp), DIMENSION(:,:),          INTENT(inout) ::   phia     ! model after 2D field (to be updated)
134      REAL(wp), DIMENSION(:  ), POINTER, INTENT(in   ) ::   phi_ext  ! external forcing data
135      LOGICAL ,                          INTENT(in   ) ::   lrim0    ! indicate if rim 0 is treated
136      LOGICAL ,                          INTENT(in   ) ::   ll_npo   ! switch for NPO version
137      !
138      INTEGER  ::   jb                                     ! dummy loop indices
139      INTEGER  ::   ii, ij, iibm1, iibm2, ijbm1, ijbm2     ! 2D addresses
140      INTEGER  ::   iijm1, iijp1, ijjm1, ijjp1             ! 2D addresses
141      INTEGER  ::   iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses
142      INTEGER  ::   ii_offset, ij_offset                   ! offsets for mask indices
143      INTEGER  ::   flagu, flagv                           ! short cuts
144      INTEGER  ::   ibeg, iend                             ! length of rim to be treated (rim 0 or rim 1 or both)
145      REAL(wp) ::   zmask_x, zmask_y1, zmask_y2
146      REAL(wp) ::   zex1, zex2, zey, zey1, zey2
147      REAL(wp) ::   zdt, zdx, zdy, znor2, zrx, zry         ! intermediate calculations
148      REAL(wp) ::   zout, zwgt, zdy_centred
149      REAL(wp) ::   zdy_1, zdy_2, zsign_ups
150      REAL(wp), PARAMETER :: zepsilon = 1.e-30                 ! local small value
151      REAL(wp), POINTER, DIMENSION(:,:)          :: zmask      ! land/sea mask for field
152      REAL(wp), POINTER, DIMENSION(:,:)          :: zmask_xdif ! land/sea mask for x-derivatives
153      REAL(wp), POINTER, DIMENSION(:,:)          :: zmask_ydif ! land/sea mask for y-derivatives
154      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_xdif    ! scale factors for x-derivatives
155      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_ydif    ! scale factors for y-derivatives
156      !!----------------------------------------------------------------------
157      !
158      ! ----------------------------------!
159      ! Orlanski boundary conditions     :!
160      ! ----------------------------------!
161     
162      SELECT CASE(igrd)
163         CASE(1)
164            zmask      => tmask(:,:,1)
165            zmask_xdif => umask(:,:,1)
166            zmask_ydif => vmask(:,:,1)
167            pe_xdif    => e1u(:,:)
168            pe_ydif    => e2v(:,:)
169            ii_offset = 0
170            ij_offset = 0
171         CASE(2)
172            zmask      => umask(:,:,1)
173            zmask_xdif => tmask(:,:,1)
174            zmask_ydif => fmask(:,:,1)
175            pe_xdif    => e1t(:,:)
176            pe_ydif    => e2f(:,:)
177            ii_offset = 1
178            ij_offset = 0
179         CASE(3)
180            zmask      => vmask(:,:,1)
181            zmask_xdif => fmask(:,:,1)
182            zmask_ydif => tmask(:,:,1)
183            pe_xdif    => e1f(:,:)
184            pe_ydif    => e2t(:,:)
185            ii_offset = 0
186            ij_offset = 1
187         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' )
188      END SELECT
189      !
190      IF( lrim0 ) THEN   ;   ibeg = 1                       ;   iend = idx%nblenrim0(igrd)   ! rim 0
191      ELSE               ;   ibeg = idx%nblenrim0(igrd)+1   ;   iend = idx%nblenrim(igrd)    ! rim 1
192      ENDIF
193      !
194      DO jb = ibeg, iend
195         ii  = idx%nbi(jb,igrd)
196         ij  = idx%nbj(jb,igrd) 
197         IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj )   CYCLE
198         flagu = int( idx%flagu(jb,igrd) )
199         flagv = int( idx%flagv(jb,igrd) )
200         !
201         ! Calculate positions of b-1 and b-2 points for this rim point
202         ! also (b-1,j-1) and (b-1,j+1) points
203         iibm1 = ii + flagu ; iibm2 = ii + 2*flagu 
204         ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv
205          !
206         iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) 
207         ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu)
208         !
209         iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) 
210         ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) 
211         !
212         ! Calculate scale factors for calculation of spatial derivatives.       
213         zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1   +ii_offset,ijbm1             )   &
214        &       + abs(ijbm1-ijbm2) * pe_ydif(iibm1             ,ijbm1   +ij_offset) ) 
215         zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2   +ii_offset,ijbm2             )   &
216        &       + abs(ijbm1-ijbm2) * pe_ydif(iibm2             ,ijbm2   +ij_offset) ) 
217         zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1          )   & 
218        &      +  (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
219         zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1   +ii_offset,ijbm1             )   &
220        &      +  (ijbm1jp1-ijbm1) * pe_ydif(iibm1             ,ijbm1   +ij_offset) ) 
221         ! make sure scale factors are nonzero
222         if( zey1 .lt. rsmall ) zey1 = zey2
223         if( zey2 .lt. rsmall ) zey2 = zey1
224         zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall)
225         zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); 
226         !
227         ! Calculate masks for calculation of spatial derivatives.
228         zmask_x  = ( abs(iibm1-iibm2) * zmask_xdif(iibm2   +ii_offset,ijbm2               )   &
229        &           + abs(ijbm1-ijbm2) * zmask_ydif(iibm2             ,ijbm2   +ij_offset) ) 
230         zmask_y1 = ( (iibm1-iibm1jm1) * zmask_xdif(iibm1jm1+ii_offset,ijbm1jm1            )   & 
231        &          +  (ijbm1-ijbm1jm1) * zmask_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
232         zmask_y2 = ( (iibm1jp1-iibm1) * zmask_xdif(iibm1   +ii_offset,ijbm1               )   &
233        &          +  (ijbm1jp1-ijbm1) * zmask_ydif(iibm1             ,ijbm1   +ij_offset) ) 
234
235         ! Calculation of terms required for both versions of the scheme.
236         ! Mask derivatives to ensure correct land boundary conditions for each variable.
237         ! Centred derivative is calculated as average of "left" and "right" derivatives for
238         ! this reason.
239         ! Note no rn_Dt factor in expression for zdt because it cancels in the expressions for
240         ! zrx and zry.
241         zdt   =     phia(iibm1   ,ijbm1   ) - phib(iibm1   ,ijbm1   )
242         zdx   = ( ( phia(iibm1   ,ijbm1   ) - phia(iibm2   ,ijbm2   ) ) / zex2 ) * zmask_x 
243         zdy_1 = ( ( phib(iibm1   ,ijbm1   ) - phib(iibm1jm1,ijbm1jm1) ) / zey1 ) * zmask_y1   
244         zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1) - phib(iibm1   ,ijbm1   ) ) / zey2 ) * zmask_y2 
245         zdy_centred = 0.5 * ( zdy_1 + zdy_2 )
246!!$         zdy_centred = phib(iibm1jp1,ijbm1jp1) - phib(iibm1jm1,ijbm1jm1)
247         ! upstream differencing for tangential derivatives
248         zsign_ups = sign( 1.0_wp, zdt * zdy_centred )
249         zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
250         zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2
251         znor2 = zdx * zdx + zdy * zdy
252         znor2 = max(znor2,zepsilon)
253         !
254         zrx = zdt * zdx / ( zex1 * znor2 ) 
255!!$         zrx = min(zrx,2.0_wp)
256         zout = sign( 1.0_wp, zrx )
257         zout = 0.5*( zout + abs(zout) )
258         zwgt = 2.*rn_Dt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) )
259         ! only apply radiation on outflow points
260         if( ll_npo ) then     !! NPO version !!
261            phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) )        &
262           &            + zout      * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1)                         &
263           &                            + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) 
264         else                  !! full oblique radiation !!
265            zsign_ups = sign( 1.0_wp, zdt * zdy )
266            zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
267            zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 
268            zry = zdt * zdy / ( zey * znor2 ) 
269            phia(ii,ij) = (1.-zout) * ( phib(ii,ij) + zwgt * ( phi_ext(jb) - phib(ii,ij) ) )        &
270           &            + zout      * ( phib(ii,ij) + zrx*phia(iibm1,ijbm1)                         &
271           &                    - zsign_ups      * zry * ( phib(ii   ,ij   ) - phib(iijm1,ijjm1 ) ) &
272           &                    - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1) - phib(ii   ,ij    ) ) &
273           &                    + zwgt * ( phi_ext(jb) - phib(ii,ij) ) ) / ( 1. + zrx ) 
274         endif
275         phia(ii,ij) = phia(ii,ij) * zmask(ii,ij)
276      END DO
277      !
278   END SUBROUTINE bdy_orlanski_2d
279
280
281   SUBROUTINE bdy_orlanski_3d( idx, igrd, phib, phia, phi_ext, lrim0, ll_npo )
282      !!----------------------------------------------------------------------
283      !!                 ***  SUBROUTINE bdy_orlanski_3d  ***
284      !!             
285      !!              - Apply Orlanski radiation condition adaptively to 3D fields:
286      !!                  - radiation plus weak nudging at outflow points
287      !!                  - no radiation and strong nudging at inflow points
288      !!
289      !!
290      !! References:  Marchesiello, McWilliams and Shchepetkin, Ocean Modelling vol. 3 (2001)   
291      !!----------------------------------------------------------------------
292      TYPE(OBC_INDEX),                     INTENT(in   ) ::   idx      ! BDY indices
293      INTEGER ,                            INTENT(in   ) ::   igrd     ! grid index
294      REAL(wp), DIMENSION(:,:,:),          INTENT(in   ) ::   phib     ! model before 3D field
295      REAL(wp), DIMENSION(:,:,:),          INTENT(inout) ::   phia     ! model after 3D field (to be updated)
296      REAL(wp), DIMENSION(:,:  ), POINTER, INTENT(in   ) ::   phi_ext  ! external forcing data
297      LOGICAL ,                            INTENT(in   ) ::   lrim0    ! indicate if rim 0 is treated
298      LOGICAL ,                            INTENT(in   ) ::   ll_npo   ! switch for NPO version
299      !
300      INTEGER  ::   jb, jk                                 ! dummy loop indices
301      INTEGER  ::   ii, ij, iibm1, iibm2, ijbm1, ijbm2     ! 2D addresses
302      INTEGER  ::   iijm1, iijp1, ijjm1, ijjp1             ! 2D addresses
303      INTEGER  ::   iibm1jp1, iibm1jm1, ijbm1jp1, ijbm1jm1 ! 2D addresses
304      INTEGER  ::   ii_offset, ij_offset                   ! offsets for mask indices
305      INTEGER  ::   flagu, flagv                           ! short cuts
306      INTEGER  ::   ibeg, iend                             ! length of rim to be treated (rim 0 or rim 1 or both)
307      REAL(wp) ::   zmask_x, zmask_y1, zmask_y2
308      REAL(wp) ::   zex1, zex2, zey, zey1, zey2
309      REAL(wp) ::   zdt, zdx, zdy, znor2, zrx, zry         ! intermediate calculations
310      REAL(wp) ::   zout, zwgt, zdy_centred
311      REAL(wp) ::   zdy_1, zdy_2,  zsign_ups
312      REAL(wp), PARAMETER :: zepsilon = 1.e-30                 ! local small value
313      REAL(wp), POINTER, DIMENSION(:,:,:)        :: zmask      ! land/sea mask for field
314      REAL(wp), POINTER, DIMENSION(:,:,:)        :: zmask_xdif ! land/sea mask for x-derivatives
315      REAL(wp), POINTER, DIMENSION(:,:,:)        :: zmask_ydif ! land/sea mask for y-derivatives
316      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_xdif    ! scale factors for x-derivatives
317      REAL(wp), POINTER, DIMENSION(:,:)          :: pe_ydif    ! scale factors for y-derivatives
318      !!----------------------------------------------------------------------
319      !
320      ! ----------------------------------!
321      ! Orlanski boundary conditions     :!
322      ! ----------------------------------!
323      !
324      SELECT CASE(igrd)
325         CASE(1)
326            zmask      => tmask(:,:,:)
327            zmask_xdif => umask(:,:,:)
328            zmask_ydif => vmask(:,:,:)
329            pe_xdif    => e1u(:,:)
330            pe_ydif    => e2v(:,:)
331            ii_offset = 0
332            ij_offset = 0
333         CASE(2)
334            zmask      => umask(:,:,:)
335            zmask_xdif => tmask(:,:,:)
336            zmask_ydif => fmask(:,:,:)
337            pe_xdif    => e1t(:,:)
338            pe_ydif    => e2f(:,:)
339            ii_offset = 1
340            ij_offset = 0
341         CASE(3)
342            zmask      => vmask(:,:,:)
343            zmask_xdif => fmask(:,:,:)
344            zmask_ydif => tmask(:,:,:)
345            pe_xdif    => e1f(:,:)
346            pe_ydif    => e2t(:,:)
347            ii_offset = 0
348            ij_offset = 1
349         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_orlanksi_2d' )
350      END SELECT
351      !
352      IF( lrim0 ) THEN   ;   ibeg = 1                       ;   iend = idx%nblenrim0(igrd)   ! rim 0
353      ELSE               ;   ibeg = idx%nblenrim0(igrd)+1   ;   iend = idx%nblenrim(igrd)    ! rim 1
354      ENDIF
355      !
356      DO jk = 1, jpk
357         !           
358         DO jb = ibeg, iend
359            ii  = idx%nbi(jb,igrd)
360            ij  = idx%nbj(jb,igrd) 
361            IF( ii == 1 .OR. ii == jpi .OR. ij == 1 .OR. ij == jpj )   CYCLE
362            flagu = int( idx%flagu(jb,igrd) )
363            flagv = int( idx%flagv(jb,igrd) )
364            !
365            ! calculate positions of b-1 and b-2 points for this rim point
366            ! also (b-1,j-1) and (b-1,j+1) points
367            iibm1 = ii + flagu ; iibm2 = ii + 2*flagu 
368            ijbm1 = ij + flagv ; ijbm2 = ij + 2*flagv
369            !
370            iijm1 = ii - abs(flagv) ; iijp1 = ii + abs(flagv) 
371            ijjm1 = ij - abs(flagu) ; ijjp1 = ij + abs(flagu)
372            !
373            iibm1jm1 = ii + flagu - abs(flagv) ; iibm1jp1 = ii + flagu + abs(flagv) 
374            ijbm1jm1 = ij + flagv - abs(flagu) ; ijbm1jp1 = ij + flagv + abs(flagu) 
375            !
376            ! Calculate scale factors for calculation of spatial derivatives.       
377            zex1 = ( abs(iibm1-iibm2) * pe_xdif(iibm1   +ii_offset,ijbm1             )   &
378           &       + abs(ijbm1-ijbm2) * pe_ydif(iibm1             ,ijbm1+ij_offset   ) ) 
379            zex2 = ( abs(iibm1-iibm2) * pe_xdif(iibm2   +ii_offset,ijbm2             )   &
380           &       + abs(ijbm1-ijbm2) * pe_ydif(iibm2             ,ijbm2+ij_offset   ) ) 
381            zey1 = ( (iibm1-iibm1jm1) * pe_xdif(iibm1jm1+ii_offset,ijbm1jm1          )   & 
382           &      +  (ijbm1-ijbm1jm1) * pe_ydif(iibm1jm1          ,ijbm1jm1+ij_offset) ) 
383            zey2 = ( (iibm1jp1-iibm1) * pe_xdif(iibm1   +ii_offset,ijbm1             )   &
384           &      +  (ijbm1jp1-ijbm1) * pe_ydif(iibm1             ,ijbm1+ij_offset   ) ) 
385            ! make sure scale factors are nonzero
386            if( zey1 .lt. rsmall ) zey1 = zey2
387            if( zey2 .lt. rsmall ) zey2 = zey1
388            zex1 = max(zex1,rsmall); zex2 = max(zex2,rsmall); 
389            zey1 = max(zey1,rsmall); zey2 = max(zey2,rsmall); 
390            !
391            ! Calculate masks for calculation of spatial derivatives.       
392            zmask_x  = ( abs(iibm1-iibm2) * zmask_xdif(iibm2   +ii_offset,ijbm2             ,jk)   &
393           &           + abs(ijbm1-ijbm2) * zmask_ydif(iibm2             ,ijbm2   +ij_offset,jk) ) 
394            zmask_y1 = ( (iibm1-iibm1jm1) * zmask_xdif(iibm1jm1+ii_offset,ijbm1jm1          ,jk)   & 
395           &          +  (ijbm1-ijbm1jm1) * zmask_ydif(iibm1jm1          ,ijbm1jm1+ij_offset,jk) ) 
396            zmask_y2 = ( (iibm1jp1-iibm1) * zmask_xdif(iibm1   +ii_offset,ijbm1             ,jk)   &
397           &          +  (ijbm1jp1-ijbm1) * zmask_ydif(iibm1             ,ijbm1   +ij_offset,jk) ) 
398            !
399            ! Calculate normal (zrx) and tangential (zry) components of radiation velocities.
400            ! Mask derivatives to ensure correct land boundary conditions for each variable.
401            ! Centred derivative is calculated as average of "left" and "right" derivatives for
402            ! this reason.
403            zdt   =     phia(iibm1   ,ijbm1   ,jk) - phib(iibm1   ,ijbm1   ,jk)
404            zdx   = ( ( phia(iibm1   ,ijbm1   ,jk) - phia(iibm2   ,ijbm2   ,jk) ) / zex2 ) * zmask_x                 
405            zdy_1 = ( ( phib(iibm1   ,ijbm1   ,jk) - phib(iibm1jm1,ijbm1jm1,jk) ) / zey1 ) * zmask_y1 
406            zdy_2 = ( ( phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1   ,ijbm1   ,jk) ) / zey2 ) * zmask_y2     
407            zdy_centred = 0.5 * ( zdy_1 + zdy_2 )
408!!$            zdy_centred = phib(iibm1jp1,ijbm1jp1,jk) - phib(iibm1jm1,ijbm1jm1,jk)
409            ! upstream differencing for tangential derivatives
410            zsign_ups = sign( 1.0_wp, zdt * zdy_centred )
411            zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
412            zdy = zsign_ups * zdy_1 + (1. - zsign_ups) * zdy_2
413            znor2 = zdx * zdx + zdy * zdy
414            znor2 = max(znor2,zepsilon)
415            !
416            ! update boundary value:
417            zrx = zdt * zdx / ( zex1 * znor2 )
418!!$            zrx = min(zrx,2.0_wp)
419            zout = sign( 1.0_wp, zrx )
420            zout = 0.5*( zout + abs(zout) )
421            zwgt = 2.*rn_Dt*( (1.-zout) * idx%nbd(jb,igrd) + zout * idx%nbdout(jb,igrd) )
422            ! only apply radiation on outflow points
423            if( ll_npo ) then     !! NPO version !!
424               phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) &
425              &               + zout      * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk)                     &
426              &                            + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) 
427            else                  !! full oblique radiation !!
428               zsign_ups = sign( 1.0_wp, zdt * zdy )
429               zsign_ups = 0.5*( zsign_ups + abs(zsign_ups) )
430               zey = zsign_ups * zey1 + (1.-zsign_ups) * zey2 
431               zry = zdt * zdy / ( zey * znor2 ) 
432               phia(ii,ij,jk) = (1.-zout) * ( phib(ii,ij,jk) + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) )    &
433              &               + zout      * ( phib(ii,ij,jk) + zrx*phia(iibm1,ijbm1,jk)                        &
434              &                       - zsign_ups      * zry * ( phib(ii   ,ij   ,jk) - phib(iijm1,ijjm1,jk) ) &
435              &                       - (1.-zsign_ups) * zry * ( phib(iijp1,ijjp1,jk) - phib(ii   ,ij   ,jk) ) &
436              &                       + zwgt * ( phi_ext(jb,jk) - phib(ii,ij,jk) ) ) / ( 1. + zrx ) 
437            endif
438            phia(ii,ij,jk) = phia(ii,ij,jk) * zmask(ii,ij,jk)
439         END DO
440         !
441      END DO
442      !
443   END SUBROUTINE bdy_orlanski_3d
444
445   SUBROUTINE bdy_nmn( idx, igrd, phia, lrim0 )
446      !!----------------------------------------------------------------------
447      !!                 ***  SUBROUTINE bdy_nmn  ***
448      !!                   
449      !! ** Purpose : Duplicate the value at open boundaries, zero gradient.
450      !!
451      !!
452      !! ** Method  : - take the average of free ocean neighbours
453      !!
454      !!      ___   !   |_____|   !   ___|    !   __|x o   !   |_   _|     ! |     
455      !!   __|x     !      x      !     x o   !      o     !     |_|       ! |x o   
456      !!      o     !      o      !     o     !            !    o x o      ! |x_x_
457      !!                                                   !      o     
458      !!----------------------------------------------------------------------
459      INTEGER,                    INTENT(in   )  ::   igrd     ! grid index
460      REAL(wp), DIMENSION(:,:,:), INTENT(inout)  ::   phia     ! model after 3D field (to be updated), must be masked
461      TYPE(OBC_INDEX),            INTENT(in   )  ::   idx      ! OBC indices
462      LOGICAL ,                   INTENT(in   )  ::   lrim0    ! indicate if rim 0 is treated
463      !!
464      REAL(wp) ::   zweight
465      REAL(wp), POINTER, DIMENSION(:,:,:)      :: zmask         ! land/sea mask for field
466      INTEGER  ::   ib, ik   ! dummy loop indices
467      INTEGER  ::   ii, ij   ! 2D addresses
468      INTEGER  ::   ipkm1    ! size of phia third dimension minus 1
469      INTEGER  ::   ibeg, iend                          ! length of rim to be treated (rim 0 or rim 1 or both)
470      INTEGER  ::   ii1, ii2, ii3, ij1, ij2, ij3, itreat
471      !!----------------------------------------------------------------------
472      !
473      ipkm1 = MAX( SIZE(phia,3) - 1, 1 ) 
474      !
475      SELECT CASE(igrd)
476         CASE(1)   ;   zmask => tmask(:,:,:)
477         CASE(2)   ;   zmask => umask(:,:,:)
478         CASE(3)   ;   zmask => vmask(:,:,:)
479         CASE DEFAULT ;   CALL ctl_stop( 'unrecognised value for igrd in bdy_nmn' )
480      END SELECT
481      !
482      IF( lrim0 ) THEN   ;   ibeg = 1                       ;   iend = idx%nblenrim0(igrd)   ! rim 0
483      ELSE               ;   ibeg = idx%nblenrim0(igrd)+1   ;   iend = idx%nblenrim(igrd)    ! rim 1
484      ENDIF
485      !
486      DO ib = ibeg, iend
487         ii = idx%nbi(ib,igrd)
488         ij = idx%nbj(ib,igrd)
489         itreat = idx%ntreat(ib,igrd)
490         CALL find_neib( ii, ij, itreat, ii1, ij1, ii2, ij2, ii3, ij3 )   ! find free ocean neighbours
491         SELECT CASE( itreat )
492         CASE( 1:8 )
493            IF( ii1 < 1 .OR. ii1 > jpi .OR. ij1 < 1 .OR. ij1 > jpj )   CYCLE
494            DO ik = 1, ipkm1
495               IF( zmask(ii1,ij1,ik) /= 0. )   phia(ii,ij,ik) = phia(ii1,ij1,ik) 
496            END DO
497         CASE( 9:12 )
498            IF( ii1 < 1 .OR. ii1 > jpi .OR. ij1 < 1 .OR. ij1 > jpj )   CYCLE
499            IF( ii2 < 1 .OR. ii2 > jpi .OR. ij2 < 1 .OR. ij2 > jpj )   CYCLE
500            DO ik = 1, ipkm1
501               zweight = zmask(ii1,ij1,ik) + zmask(ii2,ij2,ik)
502               IF( zweight /= 0. )   phia(ii,ij,ik) = ( phia(ii1,ij1,ik) + phia(ii2,ij2,ik) ) / zweight
503            END DO
504         CASE( 13:16 )
505            IF( ii1 < 1 .OR. ii1 > jpi .OR. ij1 < 1 .OR. ij1 > jpj )   CYCLE
506            IF( ii2 < 1 .OR. ii2 > jpi .OR. ij2 < 1 .OR. ij2 > jpj )   CYCLE
507            IF( ii3 < 1 .OR. ii3 > jpi .OR. ij3 < 1 .OR. ij3 > jpj )   CYCLE
508            DO ik = 1, ipkm1
509               zweight = zmask(ii1,ij1,ik) + zmask(ii2,ij2,ik) + zmask(ii3,ij3,ik)
510               IF( zweight /= 0. )   phia(ii,ij,ik) = ( phia(ii1,ij1,ik) + phia(ii2,ij2,ik) + phia(ii3,ij3,ik) ) / zweight
511            END DO
512         END SELECT
513      END DO
514      !
515   END SUBROUTINE bdy_nmn
516
517   !!======================================================================
518END MODULE bdylib
Note: See TracBrowser for help on using the repository browser.