New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
daymod.F90 in NEMO/branches/2020/r12377_ticket2386/src/OCE/DOM – NEMO

source: NEMO/branches/2020/r12377_ticket2386/src/OCE/DOM/daymod.F90 @ 13694

Last change on this file since 13694 was 13694, checked in by andmirek, 3 years ago

Ticket #2386: merge with trunk rev 13688
  • Property svn:keywords set to Id
File size: 21.1 KB
Line 
1MODULE daymod
2   !!======================================================================
3   !!                       ***  MODULE  daymod  ***
4   !! Ocean :   management of the model calendar
5   !!=====================================================================
6   !! History :  OPA  ! 1994-09  (M. Pontaud M. Imbard)  Original code
7   !!                 ! 1997-03  (O. Marti)
8   !!                 ! 1997-05  (G. Madec)
9   !!                 ! 1997-08  (M. Imbard)
10   !!   NEMO     1.0  ! 2003-09  (G. Madec)  F90 + nyear, nmonth, nday
11   !!                 ! 2004-01  (A.M. Treguier) new calculation based on adatrj
12   !!                 ! 2006-08  (G. Madec)  surface module major update
13   !!                 ! 2015-11  (D. Lea) Allow non-zero initial time of day
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   day        : calendar
18   !!----------------------------------------------------------------------
19   !!                    ----------- WARNING -----------
20   !!                    -------------------------------
21   !!   sbcmod assume that the time step is dividing the number of second of
22   !!   in a day, i.e. ===> MOD( rday, rn_Dt ) == 0
23   !!   except when user defined forcing is used (see sbcmod.F90)
24   !!----------------------------------------------------------------------
25   USE dom_oce        ! ocean space and time domain
26   USE phycst         ! physical constants
27   USE ioipsl  , ONLY :   ymds2ju      ! for calendar
28   USE trc_oce , ONLY :   l_offline   ! offline flag
29   !
30   USE in_out_manager ! I/O manager
31   USE prtctl         ! Print control
32   USE iom            !
33   USE timing         ! Timing
34   USE restart        ! restart
35
36   IMPLICIT NONE
37   PRIVATE
38
39   PUBLIC   day        ! called by step.F90
40   PUBLIC   day_init   ! called by istate.F90
41   PUBLIC   day_mth    ! Needed by TAM
42
43   INTEGER, PUBLIC ::   nsecd, nsecd05, ndt, ndt05   !: (PUBLIC for TAM)
44
45   !!----------------------------------------------------------------------
46   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
47   !! $Id$
48   !! Software governed by the CeCILL license (see ./LICENSE)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE day_init
53      !!----------------------------------------------------------------------
54      !!                   ***  ROUTINE day_init  ***
55      !!
56      !! ** Purpose :   Initialization of the calendar values to their values 1 time step before nit000
57      !!                because day will be called at the beginning of step
58      !!
59      !! ** Action  : - nyear        : current year
60      !!              - nmonth       : current month of the current nyear
61      !!              - nday         : current   day of the current nmonth
62      !!              - nday_year    : current   day of the current nyear
63      !!              - nsec_year    : seconds between 00h jan 1st of the current  year and half of the current time step
64      !!              - nsec_month   : seconds between 00h 1st day of the current month and half of the current time step
65      !!              - nsec_monday  : seconds between 00h         of the   last Monday and half of the current time step
66      !!              - nsec_day     : seconds between 00h         of the current   day and half of the current time step
67      !!              - nsec1jan000  : seconds between Jan. 1st 00h of nit000 year and Jan. 1st 00h of the current year
68      !!              - nmonth_len, nyear_len, nmonth_beg through day_mth
69      !!----------------------------------------------------------------------
70      INTEGER  ::   inbday, imonday, isecrst   ! local integers
71      REAL(wp) ::   zjul             ! local scalar
72      !!----------------------------------------------------------------------
73      !
74      ! max number of seconds between each restart
75      IF( REAL( nitend - nit000 + 1 ) * rn_Dt > REAL( HUGE( nsec1jan000 ) ) ) THEN
76         CALL ctl_stop( 'The number of seconds between each restart exceeds the integer 4 max value: 2^31-1. ',   &
77            &           'You must do a restart at higher frequency (or remove this stop and recompile the code in I8)' )
78      ENDIF
79      nsecd   = NINT(       rday )
80      nsecd05 = NINT( 0.5 * rday )
81      ndt     = NINT(       rn_Dt  )
82      ndt05   = NINT( 0.5 * rn_Dt  )
83
84      lrst_oce = .NOT. l_offline   ! force definition of offline
85      IF( lrst_oce )   CALL day_rst( nit000, 'READ' )
86     
87      ! set the calandar from ndastp (read in restart file and namelist)
88      nyear   =   ndastp / 10000
89      nmonth  = ( ndastp - (nyear * 10000) ) / 100
90      nday    =   ndastp - (nyear * 10000) - ( nmonth * 100 )
91
92      nhour   =   nn_time0 / 100
93      nminute = ( nn_time0 - nhour * 100 )
94      isecrst = ( nhour * NINT(rhhmm) + nminute ) * NINT(rmmss)
95
96      CALL ymds2ju( nyear, nmonth, nday, REAL(isecrst,wp), fjulday ) 
97      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < 0.1 / rday )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
98      IF( nhour*NINT(rhhmm*rmmss) + nminute*NINT(rmmss) - ndt05 .LT. 0 ) fjulday = fjulday+1.       ! move back to the day at nit000 (and not at nit000 - 1)
99
100      nsec1jan000 = 0
101      CALL day_mth
102
103      IF ( nday == 0 ) THEN     !   for ex if ndastp = ndate0 - 1
104         nmonth = nmonth - 1
105         nday = nmonth_len(nmonth)
106      ENDIF
107      IF ( nmonth == 0 ) THEN   ! go at the end of previous year
108         nmonth = 12
109         nyear = nyear - 1
110         nsec1jan000 = nsec1jan000 - nsecd * nyear_len(0)
111         IF( nleapy == 1 )   CALL day_mth
112      ENDIF
113
114      ! day since january 1st
115      nday_year = nday + SUM( nmonth_len(1:nmonth - 1) )
116
117      !compute number of days between last Monday and today
118      CALL ymds2ju( 1900, 01, 01, 0.0_wp, zjul )     ! compute julian day value of 01.01.1900 (our reference that was a Monday)
119      inbday = FLOOR(fjulday - zjul)              ! compute nb day between  01.01.1900 and start of current day
120      imonday = MOD(inbday, 7)                    ! compute nb day between last monday and current day
121      IF (imonday .LT. 0) imonday = imonday + 7   ! Avoid negative values for dates before 01.01.1900
122
123      ! number of seconds since the beginning of current year/month/week/day at the middle of the time-step
124      IF( isecrst - ndt05 .GT. 0 ) THEN
125         ! 1 timestep before current middle of first time step is still the same day
126         nsec_year  = (nday_year-1) * nsecd + isecrst - ndt05 
127         nsec_month = (nday-1)      * nsecd + isecrst - ndt05   
128      ELSE
129         ! 1 time step before the middle of the first time step is the previous day
130         nsec_year  = nday_year     * nsecd + isecrst - ndt05 
131         nsec_month = nday          * nsecd + isecrst - ndt05   
132      ENDIF
133      nsec_monday   = imonday       * nsecd + isecrst - ndt05
134      nsec_day      =                         isecrst - ndt05 
135      IF( nsec_day    .LT. 0 ) nsec_day    = nsec_day    + nsecd
136      IF( nsec_monday .LT. 0 ) nsec_monday = nsec_monday + nsecd*7
137
138      ! control print
139      IF(lwp) WRITE(numout,'(a,i6,a,i2,a,i2,a,i8,a,i8,a,i8,a,i8)')   &
140           &                   ' =======>> 1/2 time step before the start of the run DATE Y/M/D = ',   &
141           &                   nyear, '/', nmonth, '/', nday, '  nsec_day:', nsec_day, '  nsec_monday:', nsec_monday, '  &
142           &                   nsec_month:', nsec_month , '  nsec_year:' , nsec_year
143
144      nsec000_1jan000 = nsec1jan000 + nsec_year + ndt05
145      nsecend_1jan000 = nsec000_1jan000 + ndt * ( nitend - nit000 + 1 )
146     
147      ! Up to now, calendar parameters are related to the end of previous run (nit000-1)
148      ! call day to set the calendar parameters at the begining of the current simulaton. needed by iom_init
149      CALL day( nit000 )
150      !
151      IF( lwxios ) THEN
152! define variables in restart file when writing with XIOS
153          CALL iom_set_rstw_var_active('kt')
154          CALL iom_set_rstw_var_active('ndastp')
155          CALL iom_set_rstw_var_active('adatrj')
156          CALL iom_set_rstw_var_active('ntime')
157      ENDIF
158
159   END SUBROUTINE day_init
160
161
162   SUBROUTINE day_mth
163      !!----------------------------------------------------------------------
164      !!                   ***  ROUTINE day_init  ***
165      !!
166      !! ** Purpose :   calendar values related to the months
167      !!
168      !! ** Action  : - nyear_len     : length in days of the previous/current year
169      !!              - nmonth_len    : length in days of the months of the current year
170      !!              - nmonth_half   : second since the beginning of the current year and the halft of the months
171      !!              - nmonth_end    : second since the beginning of the current year and the end of the months
172      !!----------------------------------------------------------------------
173      INTEGER  ::   jm ,jy                   ! dummy loop indice
174      INTEGER, DIMENSION(12) ::   idaymt     ! length in days of the 12 months for non-leap year
175      !!----------------------------------------------------------------------
176
177      ! length of the month of the current year (from nleapy, read in namelist)
178      IF ( nleapy < 2 ) THEN
179         ! default values
180         idaymt(1:12) = (/ 31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31 /)
181         nmonth_len(-11: 25) = (/ idaymt(1:12), idaymt(1:12), idaymt(1:12), idaymt(1) /)
182         nyear_len(:) = 365
183         !
184         IF ( nleapy == 1 ) THEN   ! we are using calandar with leap years
185            DO jy = -1,1
186               IF ( MOD(nyear+jy, 4) == 0 .AND. ( MOD(nyear+jy, 400) == 0 .OR. MOD(nyear+jy, 100) /= 0 ) ) THEN
187                  nmonth_len(2 + 12*jy) = 29
188                  nyear_len( 1 +    jy) = 366
189               ENDIF
190            ENDDO
191         ENDIF
192      ELSE
193         nmonth_len(:) = nleapy   ! all months with nleapy days per year
194         nyear_len(:) = 12 * nleapy
195      ENDIF
196
197      ! time since Jan 1st   0     1     2    ...    11    12    13
198      !          ---------*--|--*--|--*--| ... |--*--|--*--|--*--|--------------------------------------
199      !                 <---> <---> <--->  ...  <---> <---> <--->
200      ! month number      0     1     2    ...    11    12    13
201      nmonth_beg(1) = 0
202      DO jm = 2, 25
203         nmonth_beg(jm) = nmonth_beg(jm-1) + nsecd * nmonth_len(jm-1)
204      END DO
205      DO jm = 0,-11,-1
206         nmonth_beg(jm) = nmonth_beg(jm+1) - nsecd * nmonth_len(jm)
207      END DO
208      !
209   END SUBROUTINE
210
211
212   SUBROUTINE day( kt )
213      !!----------------------------------------------------------------------
214      !!                      ***  ROUTINE day  ***
215      !!
216      !! ** Purpose :   Compute the date with a day iteration IF necessary.
217      !!
218      !! ** Method  : - ???
219      !!
220      !! ** Action  : - nyear     : current year
221      !!              - nmonth    : current month of the year nyear
222      !!              - nday      : current day of the month nmonth
223      !!              - nday_year : current day of the year nyear
224      !!              - ndastp    : = nyear*10000 + nmonth*100 + nday
225      !!              - adatrj    : date in days since the beginning of the run
226      !!              - nsec_year : current time of the year (in second since 00h, jan 1st)
227      !!----------------------------------------------------------------------
228      INTEGER, INTENT(in) ::   kt        ! ocean time-step indices
229      !
230      CHARACTER (len=25) ::   charout
231      REAL(wp)           ::   zprec      ! fraction of day corresponding to 0.1 second
232      !!----------------------------------------------------------------------
233      !
234      IF( ln_timing )   CALL timing_start('day')
235      !
236      zprec = 0.1 / rday
237      !                                                 ! New time-step
238      nsec_year    = nsec_year    + ndt
239      nsec_month   = nsec_month   + ndt
240      nsec_monday  = nsec_monday  + ndt
241      nsec_day   = nsec_day   + ndt
242      adatrj  = adatrj  + rn_Dt / rday
243      fjulday = fjulday + rn_Dt / rday
244      IF( ABS(fjulday - REAL(NINT(fjulday),wp)) < zprec )   fjulday = REAL(NINT(fjulday),wp)   ! avoid truncation error
245      IF( ABS(adatrj  - REAL(NINT(adatrj ),wp)) < zprec )   adatrj  = REAL(NINT(adatrj ),wp)   ! avoid truncation error
246
247      IF( nsec_day > nsecd ) THEN                       ! New day
248         !
249         nday      = nday + 1
250         nday_year = nday_year + 1
251         nsec_day  = ndt05
252         !
253         IF( nday == nmonth_len(nmonth) + 1 ) THEN      ! New month
254            nday   = 1
255            nmonth = nmonth + 1
256            nsec_month = ndt05
257            IF( nmonth == 13 ) THEN                     ! New year
258               nyear     = nyear + 1
259               nmonth    = 1
260               nday_year = 1
261               nsec_year = ndt05
262               nsec1jan000 = nsec1jan000 + nsecd * nyear_len(1)
263               IF( nleapy == 1 )   CALL day_mth
264            ENDIF
265         ENDIF
266         !
267         ndastp = nyear * 10000 + nmonth * 100 + nday   ! New date
268         !
269         !compute first day of the year in julian days
270         CALL ymds2ju( nyear, 01, 01, 0.0_wp, fjulstartyear )
271         !
272         IF(lwp) WRITE(numout,'(a,i8,a,i4.4,a,i2.2,a,i2.2,a,i3.3)') '======>> time-step =', kt,   &
273              &   '      New day, DATE Y/M/D = ', nyear, '/', nmonth, '/', nday, '      nday_year = ', nday_year
274         IF(lwp) WRITE(numout,'(a,i8,a,i7,a,i5)') '         nsec_year = ', nsec_year,   &
275              &   '   nsec_month = ', nsec_month, '   nsec_day = ', nsec_day, '   nsec_monday = ', nsec_monday
276      ENDIF
277
278      IF( nsec_monday > 7*nsecd )   nsec_monday = ndt05     ! New week
279
280      IF(sn_cfctl%l_prtctl) THEN
281         WRITE(charout,FMT="('kt =', I4,'  d/m/y =',I2,I2,I4)") kt, nday, nmonth, nyear
282         CALL prt_ctl_info( charout )
283      ENDIF
284
285      IF( .NOT. l_offline ) CALL rst_opn( kt )               ! Open the restart file if needed and control lrst_oce
286      IF( lrst_oce         ) CALL day_rst( kt, 'WRITE' )      ! write day restart information
287      !
288      IF( ln_timing )   CALL timing_stop('day')
289      !
290   END SUBROUTINE day
291
292
293   SUBROUTINE day_rst( kt, cdrw )
294      !!---------------------------------------------------------------------
295      !!                   ***  ROUTINE day_rst  ***
296      !!
297      !!  ** Purpose : Read or write calendar in restart file:
298      !!
299      !!  WRITE(READ) mode:
300      !!       kt        : number of time step since the begining of the experiment at the
301      !!                   end of the current(previous) run
302      !!       adatrj(0) : number of elapsed days since the begining of the experiment at the
303      !!                   end of the current(previous) run (REAL -> keep fractions of day)
304      !!       ndastp    : date at the end of the current(previous) run (coded as yyyymmdd integer)
305      !!
306      !!   According to namelist parameter nrstdt,
307      !!       nrstdt = 0  no control on the date (nit000 is  arbitrary).
308      !!       nrstdt = 1  we verify that nit000 is equal to the last
309      !!                   time step of previous run + 1.
310      !!       In both those options, the  exact duration of the experiment
311      !!       since the beginning (cumulated duration of all previous restart runs)
312      !!       is not stored in the restart and is assumed to be (nit000-1)*rn_Dt.
313      !!       This is valid is the time step has remained constant.
314      !!
315      !!       nrstdt = 2  the duration of the experiment in days (adatrj)
316      !!                    has been stored in the restart file.
317      !!----------------------------------------------------------------------
318      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
319      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
320      !
321      REAL(wp) ::   zkt, zndastp, zdayfrac, ksecs, ktime
322      INTEGER  ::   ihour, iminute, isecond
323      !!----------------------------------------------------------------------
324
325      IF( TRIM(cdrw) == 'READ' ) THEN
326
327         IF( iom_varid( numror, 'kt', ldstop = .FALSE. ) > 0 ) THEN
328            ! Get Calendar informations
329            CALL iom_get( numror, 'kt', zkt, ldxios = lrxios )   ! last time-step of previous run
330            IF(lwp) THEN
331               WRITE(numout,*) ' *** Info read in restart : '
332               WRITE(numout,*) '   previous time-step                               : ', NINT( zkt )
333               WRITE(numout,*) ' *** restart option'
334               SELECT CASE ( nrstdt )
335               CASE ( 0 )   ;   WRITE(numout,*) ' nrstdt = 0 : no control of nit000'
336               CASE ( 1 )   ;   WRITE(numout,*) ' nrstdt = 1 : no control the date at nit000 (use ndate0 read in the namelist)'
337               CASE ( 2 )   ;   WRITE(numout,*) ' nrstdt = 2 : calendar parameters read in restart'
338               END SELECT
339               WRITE(numout,*)
340            ENDIF
341            ! Control of date
342            IF( nit000 - NINT( zkt ) /= 1 .AND. nrstdt /= 0 )                                         &
343                 &   CALL ctl_stop( ' ===>>>> : problem with nit000 for the restart',                 &
344                 &                  ' verify the restart file or rerun with nrstdt = 0 (namelist)' )
345            ! define ndastp and adatrj
346            IF ( nrstdt == 2 ) THEN
347               ! read the parameters corresponding to nit000 - 1 (last time step of previous run)
348               CALL iom_get( numror, 'ndastp', zndastp, ldxios = lrxios )
349               ndastp = NINT( zndastp )
350               CALL iom_get( numror, 'adatrj', adatrj , ldxios = lrxios )
351          CALL iom_get( numror, 'ntime' , ktime  , ldxios = lrxios )
352               nn_time0 = NINT(ktime)
353               ! calculate start time in hours and minutes
354               zdayfrac = adatrj - REAL(INT(adatrj), wp)
355          ksecs = NINT(zdayfrac * rday)          ! Nearest second to catch rounding errors in adatrj         
356               ihour = ksecs / NINT( rhhmm*rmmss )
357          iminute = ksecs / NINT(rmmss) - ihour*NINT(rhhmm)
358           
359               ! Add to nn_time0
360               nhour   =   nn_time0 / 100
361               nminute = ( nn_time0 - nhour * 100 )
362          nminute = nminute + iminute
363         
364               IF( nminute >= NINT(rhhmm) ) THEN
365             nminute = nminute - NINT(rhhmm)
366        nhour = nhour+1
367          ENDIF
368          nhour=nhour+ihour
369          IF( nhour >= NINT(rjjhh) ) THEN
370        nhour = nhour - NINT(rjjhh)
371             adatrj = adatrj + 1.
372          ENDIF         
373          nn_time0 = nhour * 100 + nminute
374               adatrj = REAL(INT(adatrj), wp)                    ! adatrj set to integer as nn_time0 updated         
375            ELSE
376               ! parameters corresponding to nit000 - 1 (as we start the step loop with a call to day)
377               ndastp = ndate0        ! ndate0 read in the namelist in dom_nam
378               nhour   =   nn_time0 / 100
379               nminute = ( nn_time0 - nhour * 100 )
380               isecond = ( nhour * NINT(rhhmm) + nminute ) * NINT(rmmss)
381               IF( isecond - ndt05 .lt. 0 )   ndastp = ndastp - 1      ! Start hour is specified in the namelist (default 0)
382               adatrj = ( REAL( nit000-1, wp ) * rn_Dt ) / rday
383               ! note this is wrong if time step has changed during run
384            ENDIF
385         ELSE
386            ! parameters corresponding to nit000 - 1 (as we start the step loop with a call to day)
387            ndastp = ndate0           ! ndate0 read in the namelist in dom_nam
388            nhour   =   nn_time0 / 100
389       nminute = ( nn_time0 - nhour * 100 )
390            isecond = ( nhour * NINT(rhhmm) + nminute ) * NINT(rmmss)
391            IF( isecond - ndt05 .LT. 0 )   ndastp = ndastp - 1         ! Start hour is specified in the namelist (default 0)
392            adatrj = ( REAL( nit000-1, wp ) * rn_Dt ) / rday
393         ENDIF
394         IF( ABS(adatrj  - REAL(NINT(adatrj),wp)) < 0.1 / rday )   adatrj = REAL(NINT(adatrj),wp)   ! avoid truncation error
395         !
396         IF(lwp) THEN
397            WRITE(numout,*) ' *** Info used values : '
398            WRITE(numout,*) '   date ndastp                                      : ', ndastp
399            WRITE(numout,*) '   number of elapsed days since the begining of run : ', adatrj
400       WRITE(numout,*) '   nn_time0                                         : ',nn_time0
401            WRITE(numout,*)
402         ENDIF
403         !
404      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
405         !
406         IF( kt == nitrst ) THEN
407            IF(lwp) WRITE(numout,*)
408            IF(lwp) WRITE(numout,*) 'rst_write : write oce restart file  kt =', kt
409            IF(lwp) WRITE(numout,*) '~~~~~~~'
410         ENDIF
411         ! calendar control
412         IF( lwxios ) CALL iom_swap(      cwxios_context          )
413         CALL iom_rstput( kt, nitrst, numrow, 'kt'     , REAL( kt    , wp)  , ldxios = lwxios )   ! time-step
414         CALL iom_rstput( kt, nitrst, numrow, 'ndastp' , REAL( ndastp, wp)  , ldxios = lwxios )   ! date
415         CALL iom_rstput( kt, nitrst, numrow, 'adatrj' , adatrj             , ldxios = lwxios            )   ! number of elapsed days since
416         !                                                                                                   ! the begining of the run [s]
417         CALL iom_rstput( kt, nitrst, numrow, 'ntime'  , REAL( nn_time0, wp), ldxios = lwxios ) ! time
418         IF( lwxios ) CALL iom_swap(      cxios_context          )
419      ENDIF
420      !
421   END SUBROUTINE day_rst
422
423   !!======================================================================
424END MODULE daymod
Note: See TracBrowser for help on using the repository browser.