| 1 | MODULE nemogcm |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE nemogcm *** |
|---|
| 4 | !! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice) |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code |
|---|
| 7 | !! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec) |
|---|
| 8 | !! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
|---|
| 9 | !! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1 |
|---|
| 10 | !! - ! 1992-06 (L.Terray) coupling implementation |
|---|
| 11 | !! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice |
|---|
| 12 | !! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar, |
|---|
| 13 | !! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0 |
|---|
| 14 | !! 8.1 ! 1997-06 (M. Imbard, G. Madec) |
|---|
| 15 | !! 8.2 ! 1999-11 (M. Imbard, H. Goosse) sea-ice model |
|---|
| 16 | !! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP |
|---|
| 17 | !! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER) |
|---|
| 18 | !! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules |
|---|
| 19 | !! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces |
|---|
| 20 | !! - ! 2004-08 (C. Talandier) New trends organization |
|---|
| 21 | !! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility |
|---|
| 22 | !! - ! 2005-11 (V. Garnier) Surface pressure gradient organization |
|---|
| 23 | !! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation |
|---|
| 24 | !! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization |
|---|
| 25 | !! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY) |
|---|
| 26 | !! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp |
|---|
| 27 | !! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface |
|---|
| 28 | !! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase |
|---|
| 29 | !! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation |
|---|
| 30 | !! - ! 2011-11 (C. Harris) decomposition changes for running with CICE |
|---|
| 31 | !! 3.6 ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening |
|---|
| 32 | !! - ! 2014-12 (G. Madec) remove KPP scheme and cross-land advection (cla) |
|---|
| 33 | !! 4.0 ! 2016-10 (G. Madec, S. Flavoni) domain configuration / user defined interface |
|---|
| 34 | !!---------------------------------------------------------------------- |
|---|
| 35 | |
|---|
| 36 | !!---------------------------------------------------------------------- |
|---|
| 37 | !! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice |
|---|
| 38 | !! nemo_init : initialization of the NEMO system |
|---|
| 39 | !! nemo_ctl : initialisation of the contol print |
|---|
| 40 | !! nemo_closefile: close remaining open files |
|---|
| 41 | !! nemo_alloc : dynamical allocation |
|---|
| 42 | !!---------------------------------------------------------------------- |
|---|
| 43 | USE step_oce ! module used in the ocean time stepping module (step.F90) |
|---|
| 44 | USE phycst ! physical constant (par_cst routine) |
|---|
| 45 | USE domain ! domain initialization (dom_init & dom_cfg routines) |
|---|
| 46 | USE closea ! treatment of closed seas (for ln_closea) |
|---|
| 47 | USE usrdef_nam ! user defined configuration |
|---|
| 48 | USE tide_mod, ONLY : tide_init ! tidal components initialization (tide_init routine) |
|---|
| 49 | USE bdyini ! open boundary cond. setting (bdy_init routine) |
|---|
| 50 | USE istate ! initial state setting (istate_init routine) |
|---|
| 51 | USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine) |
|---|
| 52 | USE ldftra ! lateral diffusivity setting (ldftra_init routine) |
|---|
| 53 | USE trdini ! dyn/tra trends initialization (trd_init routine) |
|---|
| 54 | USE asminc ! assimilation increments |
|---|
| 55 | USE asmbkg ! writing out state trajectory |
|---|
| 56 | USE diaptr ! poleward transports (dia_ptr_init routine) |
|---|
| 57 | USE diadct ! sections transports (dia_dct_init routine) |
|---|
| 58 | USE diaobs ! Observation diagnostics (dia_obs_init routine) |
|---|
| 59 | USE diacfl ! CFL diagnostics (dia_cfl_init routine) |
|---|
| 60 | USE diamlr ! IOM context management for multiple-linear-regression analysis |
|---|
| 61 | #if defined key_qco |
|---|
| 62 | USE stepMLF ! NEMO time-stepping (stp_MLF routine) |
|---|
| 63 | #else |
|---|
| 64 | USE step ! NEMO time-stepping (stp routine) |
|---|
| 65 | #endif |
|---|
| 66 | USE isfstp ! ice shelf (isf_stp_init routine) |
|---|
| 67 | USE icbini ! handle bergs, initialisation |
|---|
| 68 | USE icbstp ! handle bergs, calving, themodynamics and transport |
|---|
| 69 | USE cpl_oasis3 ! OASIS3 coupling |
|---|
| 70 | USE c1d ! 1D configuration |
|---|
| 71 | USE step_c1d ! Time stepping loop for the 1D configuration |
|---|
| 72 | USE dyndmp ! Momentum damping |
|---|
| 73 | USE stopar ! Stochastic param.: ??? |
|---|
| 74 | USE stopts ! Stochastic param.: ??? |
|---|
| 75 | USE diu_layers ! diurnal bulk SST and coolskin |
|---|
| 76 | USE step_diu ! diurnal bulk SST timestepping (called from here if run offline) |
|---|
| 77 | USE crsini ! initialise grid coarsening utility |
|---|
| 78 | USE dia25h ! 25h mean output |
|---|
| 79 | USE diadetide ! Weights computation for daily detiding of model diagnostics |
|---|
| 80 | USE sbc_oce , ONLY : lk_oasis |
|---|
| 81 | USE wet_dry ! Wetting and drying setting (wad_init routine) |
|---|
| 82 | #if defined key_top |
|---|
| 83 | USE trcini ! passive tracer initialisation |
|---|
| 84 | #endif |
|---|
| 85 | #if defined key_nemocice_decomp |
|---|
| 86 | USE ice_domain_size, only: nx_global, ny_global |
|---|
| 87 | #endif |
|---|
| 88 | ! |
|---|
| 89 | USE prtctl ! Print control |
|---|
| 90 | USE in_out_manager ! I/O manager |
|---|
| 91 | USE lib_mpp ! distributed memory computing |
|---|
| 92 | USE mppini ! shared/distributed memory setting (mpp_init routine) |
|---|
| 93 | USE lbcnfd , ONLY : isendto, nsndto ! Setup of north fold exchanges |
|---|
| 94 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 95 | #if defined key_iomput |
|---|
| 96 | USE xios ! xIOserver |
|---|
| 97 | #endif |
|---|
| 98 | #if defined key_agrif |
|---|
| 99 | USE agrif_all_update ! Master Agrif update |
|---|
| 100 | #endif |
|---|
| 101 | USE halo_mng |
|---|
| 102 | |
|---|
| 103 | IMPLICIT NONE |
|---|
| 104 | PRIVATE |
|---|
| 105 | |
|---|
| 106 | PUBLIC nemo_gcm ! called by model.F90 |
|---|
| 107 | PUBLIC nemo_init ! needed by AGRIF |
|---|
| 108 | PUBLIC nemo_alloc ! needed by TAM |
|---|
| 109 | |
|---|
| 110 | CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing |
|---|
| 111 | |
|---|
| 112 | #if defined key_mpp_mpi |
|---|
| 113 | ! need MPI_Wtime |
|---|
| 114 | INCLUDE 'mpif.h' |
|---|
| 115 | #endif |
|---|
| 116 | |
|---|
| 117 | !!---------------------------------------------------------------------- |
|---|
| 118 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 119 | !! $Id$ |
|---|
| 120 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 121 | !!---------------------------------------------------------------------- |
|---|
| 122 | CONTAINS |
|---|
| 123 | |
|---|
| 124 | SUBROUTINE nemo_gcm |
|---|
| 125 | !!---------------------------------------------------------------------- |
|---|
| 126 | !! *** ROUTINE nemo_gcm *** |
|---|
| 127 | !! |
|---|
| 128 | !! ** Purpose : NEMO solves the primitive equations on an orthogonal |
|---|
| 129 | !! curvilinear mesh on the sphere. |
|---|
| 130 | !! |
|---|
| 131 | !! ** Method : - model general initialization |
|---|
| 132 | !! - launch the time-stepping (stp routine) |
|---|
| 133 | !! - finalize the run by closing files and communications |
|---|
| 134 | !! |
|---|
| 135 | !! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL. |
|---|
| 136 | !! Madec, 2008, internal report, IPSL. |
|---|
| 137 | !!---------------------------------------------------------------------- |
|---|
| 138 | INTEGER :: istp ! time step index |
|---|
| 139 | REAL(wp):: zstptiming ! elapsed time for 1 time step |
|---|
| 140 | !!---------------------------------------------------------------------- |
|---|
| 141 | ! |
|---|
| 142 | #if defined key_agrif |
|---|
| 143 | CALL Agrif_Init_Grids() ! AGRIF: set the meshes |
|---|
| 144 | #endif |
|---|
| 145 | ! !-----------------------! |
|---|
| 146 | CALL nemo_init !== Initialisations ==! |
|---|
| 147 | ! !-----------------------! |
|---|
| 148 | #if defined key_agrif |
|---|
| 149 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 150 | CALL Agrif_Declare_Var ! " " " " " DYN/TRA |
|---|
| 151 | # if defined key_top |
|---|
| 152 | CALL Agrif_Declare_Var_top ! " " " " " TOP |
|---|
| 153 | # endif |
|---|
| 154 | #endif |
|---|
| 155 | ! check that all process are still there... If some process have an error, |
|---|
| 156 | ! they will never enter in step and other processes will wait until the end of the cpu time! |
|---|
| 157 | CALL mpp_max( 'nemogcm', nstop ) |
|---|
| 158 | |
|---|
| 159 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 160 | |
|---|
| 161 | ! !-----------------------! |
|---|
| 162 | ! !== time stepping ==! |
|---|
| 163 | ! !-----------------------! |
|---|
| 164 | ! |
|---|
| 165 | ! !== set the model time-step ==! |
|---|
| 166 | ! |
|---|
| 167 | istp = nit000 |
|---|
| 168 | ! |
|---|
| 169 | #if defined key_c1d |
|---|
| 170 | DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== C1D time-stepping ==! |
|---|
| 171 | CALL stp_c1d( istp ) |
|---|
| 172 | istp = istp + 1 |
|---|
| 173 | END DO |
|---|
| 174 | #else |
|---|
| 175 | ! |
|---|
| 176 | # if defined key_agrif |
|---|
| 177 | ! !== AGRIF time-stepping ==! |
|---|
| 178 | CALL Agrif_Regrid() |
|---|
| 179 | ! |
|---|
| 180 | ! Recursive update from highest nested level to lowest: |
|---|
| 181 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 182 | CALL Agrif_step_child_adj(Agrif_Update_All) |
|---|
| 183 | ! |
|---|
| 184 | DO WHILE( istp <= nitend .AND. nstop == 0 ) |
|---|
| 185 | #if defined key_qco |
|---|
| 186 | CALL stp_MLF |
|---|
| 187 | #else |
|---|
| 188 | CALL stp |
|---|
| 189 | #endif |
|---|
| 190 | istp = istp + 1 |
|---|
| 191 | END DO |
|---|
| 192 | ! |
|---|
| 193 | # else |
|---|
| 194 | ! |
|---|
| 195 | IF( .NOT.ln_diurnal_only ) THEN !== Standard time-stepping ==! |
|---|
| 196 | ! |
|---|
| 197 | DO WHILE( istp <= nitend .AND. nstop == 0 ) |
|---|
| 198 | |
|---|
| 199 | ncom_stp = istp |
|---|
| 200 | IF( ln_timing ) THEN |
|---|
| 201 | zstptiming = MPI_Wtime() |
|---|
| 202 | IF ( istp == ( nit000 + 1 ) ) elapsed_time = zstptiming |
|---|
| 203 | IF ( istp == nitend ) elapsed_time = zstptiming - elapsed_time |
|---|
| 204 | ENDIF |
|---|
| 205 | |
|---|
| 206 | #if defined key_qco |
|---|
| 207 | CALL stp_MLF ( istp ) |
|---|
| 208 | #else |
|---|
| 209 | CALL stp ( istp ) |
|---|
| 210 | #endif |
|---|
| 211 | istp = istp + 1 |
|---|
| 212 | |
|---|
| 213 | IF( lwp .AND. ln_timing ) WRITE(numtime,*) 'timing step ', istp-1, ' : ', MPI_Wtime() - zstptiming |
|---|
| 214 | |
|---|
| 215 | END DO |
|---|
| 216 | ! |
|---|
| 217 | ELSE !== diurnal SST time-steeping only ==! |
|---|
| 218 | ! |
|---|
| 219 | DO WHILE( istp <= nitend .AND. nstop == 0 ) |
|---|
| 220 | CALL stp_diurnal( istp ) ! time step only the diurnal SST |
|---|
| 221 | istp = istp + 1 |
|---|
| 222 | END DO |
|---|
| 223 | ! |
|---|
| 224 | ENDIF |
|---|
| 225 | ! |
|---|
| 226 | # endif |
|---|
| 227 | ! |
|---|
| 228 | #endif |
|---|
| 229 | ! |
|---|
| 230 | IF( ln_diaobs ) CALL dia_obs_wri |
|---|
| 231 | ! |
|---|
| 232 | IF( ln_icebergs ) CALL icb_end( nitend ) |
|---|
| 233 | |
|---|
| 234 | ! !------------------------! |
|---|
| 235 | ! !== finalize the run ==! |
|---|
| 236 | ! !------------------------! |
|---|
| 237 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 238 | ! |
|---|
| 239 | IF( nstop /= 0 .AND. lwp ) THEN ! error print |
|---|
| 240 | WRITE(ctmp1,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found' |
|---|
| 241 | IF( ngrdstop > 0 ) THEN |
|---|
| 242 | WRITE(ctmp9,'(i2)') ngrdstop |
|---|
| 243 | WRITE(ctmp2,*) ' E R R O R detected in Agrif grid '//TRIM(ctmp9) |
|---|
| 244 | WRITE(ctmp3,*) ' Look for "E R R O R" messages in all existing '//TRIM(ctmp9)//'_ocean_output* files' |
|---|
| 245 | CALL ctl_stop( ' ', ctmp1, ' ', ctmp2, ' ', ctmp3 ) |
|---|
| 246 | ELSE |
|---|
| 247 | WRITE(ctmp2,*) ' Look for "E R R O R" messages in all existing ocean_output* files' |
|---|
| 248 | CALL ctl_stop( ' ', ctmp1, ' ', ctmp2 ) |
|---|
| 249 | ENDIF |
|---|
| 250 | ENDIF |
|---|
| 251 | ! |
|---|
| 252 | IF( ln_timing ) CALL timing_finalize |
|---|
| 253 | ! |
|---|
| 254 | CALL nemo_closefile |
|---|
| 255 | ! |
|---|
| 256 | #if defined key_iomput |
|---|
| 257 | CALL xios_finalize ! end mpp communications with xios |
|---|
| 258 | IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS |
|---|
| 259 | #else |
|---|
| 260 | IF ( lk_oasis ) THEN ; CALL cpl_finalize ! end coupling and mpp communications with OASIS |
|---|
| 261 | ELSEIF( lk_mpp ) THEN ; CALL mppstop ! end mpp communications |
|---|
| 262 | ENDIF |
|---|
| 263 | #endif |
|---|
| 264 | ! |
|---|
| 265 | IF(lwm) THEN |
|---|
| 266 | IF( nstop == 0 ) THEN ; STOP 0 |
|---|
| 267 | ELSE ; STOP 123 |
|---|
| 268 | ENDIF |
|---|
| 269 | ENDIF |
|---|
| 270 | ! |
|---|
| 271 | END SUBROUTINE nemo_gcm |
|---|
| 272 | |
|---|
| 273 | |
|---|
| 274 | SUBROUTINE nemo_init |
|---|
| 275 | !!---------------------------------------------------------------------- |
|---|
| 276 | !! *** ROUTINE nemo_init *** |
|---|
| 277 | !! |
|---|
| 278 | !! ** Purpose : initialization of the NEMO GCM |
|---|
| 279 | !!---------------------------------------------------------------------- |
|---|
| 280 | INTEGER :: ios, ilocal_comm ! local integers |
|---|
| 281 | !! |
|---|
| 282 | NAMELIST/namctl/ sn_cfctl, ln_timing, ln_diacfl, & |
|---|
| 283 | & nn_isplt, nn_jsplt, nn_ictls, nn_ictle, nn_jctls, nn_jctle |
|---|
| 284 | NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr |
|---|
| 285 | !!---------------------------------------------------------------------- |
|---|
| 286 | ! |
|---|
| 287 | cxios_context = 'nemo' |
|---|
| 288 | ! |
|---|
| 289 | ! !-------------------------------------------------! |
|---|
| 290 | ! ! set communicator & select the local rank ! |
|---|
| 291 | ! ! must be done as soon as possible to get narea ! |
|---|
| 292 | ! !-------------------------------------------------! |
|---|
| 293 | ! |
|---|
| 294 | #if defined key_iomput |
|---|
| 295 | IF( Agrif_Root() ) THEN |
|---|
| 296 | IF( lk_oasis ) THEN |
|---|
| 297 | CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis |
|---|
| 298 | CALL xios_initialize( "not used" , local_comm =ilocal_comm ) ! send nemo communicator to xios |
|---|
| 299 | ELSE |
|---|
| 300 | CALL xios_initialize( "for_xios_mpi_id", return_comm=ilocal_comm ) ! nemo local communicator given by xios |
|---|
| 301 | ENDIF |
|---|
| 302 | ENDIF |
|---|
| 303 | CALL mpp_start( ilocal_comm ) |
|---|
| 304 | #else |
|---|
| 305 | IF( lk_oasis ) THEN |
|---|
| 306 | IF( Agrif_Root() ) THEN |
|---|
| 307 | CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis |
|---|
| 308 | ENDIF |
|---|
| 309 | CALL mpp_start( ilocal_comm ) |
|---|
| 310 | ELSE |
|---|
| 311 | CALL mpp_start( ) |
|---|
| 312 | ENDIF |
|---|
| 313 | #endif |
|---|
| 314 | ! |
|---|
| 315 | narea = mpprank + 1 ! mpprank: the rank of proc (0 --> mppsize -1 ) |
|---|
| 316 | lwm = (narea == 1) ! control of output namelists |
|---|
| 317 | ! |
|---|
| 318 | ! !---------------------------------------------------------------! |
|---|
| 319 | ! ! Open output files, reference and configuration namelist files ! |
|---|
| 320 | ! !---------------------------------------------------------------! |
|---|
| 321 | ! |
|---|
| 322 | ! open ocean.output as soon as possible to get all output prints (including errors messages) |
|---|
| 323 | IF( lwm ) CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 324 | ! open reference and configuration namelist files |
|---|
| 325 | CALL load_nml( numnam_ref, 'namelist_ref', -1, lwm ) |
|---|
| 326 | CALL load_nml( numnam_cfg, 'namelist_cfg', -1, lwm ) |
|---|
| 327 | IF( lwm ) CALL ctl_opn( numond, 'output.namelist.dyn', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 328 | ! open /dev/null file to be able to supress output write easily |
|---|
| 329 | IF( Agrif_Root() ) THEN |
|---|
| 330 | CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE. ) |
|---|
| 331 | #ifdef key_agrif |
|---|
| 332 | ELSE |
|---|
| 333 | numnul = Agrif_Parent(numnul) |
|---|
| 334 | #endif |
|---|
| 335 | ENDIF |
|---|
| 336 | ! !--------------------! |
|---|
| 337 | ! ! Open listing units ! -> need sn_cfctl from namctl to define lwp |
|---|
| 338 | ! !--------------------! |
|---|
| 339 | ! |
|---|
| 340 | READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 ) |
|---|
| 341 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist' ) |
|---|
| 342 | READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 ) |
|---|
| 343 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist' ) |
|---|
| 344 | ! |
|---|
| 345 | ! finalize the definition of namctl variables |
|---|
| 346 | IF( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax .OR. MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) & |
|---|
| 347 | & CALL nemo_set_cfctl( sn_cfctl, .FALSE. ) |
|---|
| 348 | ! |
|---|
| 349 | lwp = (narea == 1) .OR. sn_cfctl%l_oceout ! control of all listing output print |
|---|
| 350 | ! |
|---|
| 351 | IF(lwp) THEN ! open listing units |
|---|
| 352 | ! |
|---|
| 353 | IF( .NOT. lwm ) & ! alreay opened for narea == 1 |
|---|
| 354 | & CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, -1, .FALSE., narea ) |
|---|
| 355 | ! |
|---|
| 356 | WRITE(numout,*) |
|---|
| 357 | WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - CMCC' |
|---|
| 358 | WRITE(numout,*) ' NEMO team' |
|---|
| 359 | WRITE(numout,*) ' Ocean General Circulation Model' |
|---|
| 360 | WRITE(numout,*) ' NEMO version 4.0 (2019) ' |
|---|
| 361 | WRITE(numout,*) |
|---|
| 362 | WRITE(numout,*) " ._ ._ ._ ._ ._ " |
|---|
| 363 | WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ " |
|---|
| 364 | WRITE(numout,*) |
|---|
| 365 | WRITE(numout,*) " o _, _, " |
|---|
| 366 | WRITE(numout,*) " o .' ( .-' / " |
|---|
| 367 | WRITE(numout,*) " o _/..._'. .' / " |
|---|
| 368 | WRITE(numout,*) " ( o .-'` ` '-./ _.' " |
|---|
| 369 | WRITE(numout,*) " ) ( o) ;= <_ ( " |
|---|
| 370 | WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) " |
|---|
| 371 | WRITE(numout,*) " ) ) \) |`\ \) '. \ ( ( " |
|---|
| 372 | WRITE(numout,*) " ( ( \_/ '-._\ ) ) " |
|---|
| 373 | WRITE(numout,*) " ) ) jgs ` ( ( " |
|---|
| 374 | WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ " |
|---|
| 375 | WRITE(numout,*) |
|---|
| 376 | |
|---|
| 377 | ! Print the working precision to ocean.output |
|---|
| 378 | IF (wp == dp) THEN |
|---|
| 379 | WRITE(numout,*) "Working precision = double-precision" |
|---|
| 380 | ELSE |
|---|
| 381 | WRITE(numout,*) "Working precision = single-precision" |
|---|
| 382 | ENDIF |
|---|
| 383 | WRITE(numout,*) |
|---|
| 384 | ! |
|---|
| 385 | WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 386 | ! |
|---|
| 387 | ENDIF |
|---|
| 388 | ! |
|---|
| 389 | IF(lwm) WRITE( numond, namctl ) |
|---|
| 390 | ! |
|---|
| 391 | ! !------------------------------------! |
|---|
| 392 | ! ! Set global domain size parameters ! |
|---|
| 393 | ! !------------------------------------! |
|---|
| 394 | ! |
|---|
| 395 | READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 ) |
|---|
| 396 | 903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist' ) |
|---|
| 397 | READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 ) |
|---|
| 398 | 904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist' ) |
|---|
| 399 | ! |
|---|
| 400 | IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file |
|---|
| 401 | CALL domain_cfg ( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio ) |
|---|
| 402 | ELSE ! user-defined namelist |
|---|
| 403 | CALL usr_def_nam( cn_cfg, nn_cfg, Ni0glo, Nj0glo, jpkglo, jperio ) |
|---|
| 404 | ENDIF |
|---|
| 405 | ! |
|---|
| 406 | IF(lwm) WRITE( numond, namcfg ) |
|---|
| 407 | ! |
|---|
| 408 | ! !-----------------------------------------! |
|---|
| 409 | ! ! mpp parameters and domain decomposition ! |
|---|
| 410 | ! !-----------------------------------------! |
|---|
| 411 | CALL mpp_init |
|---|
| 412 | |
|---|
| 413 | CALL halo_mng_init() |
|---|
| 414 | ! Now we know the dimensions of the grid and numout has been set: we can allocate arrays |
|---|
| 415 | CALL nemo_alloc() |
|---|
| 416 | |
|---|
| 417 | ! Initialise time level indices |
|---|
| 418 | Nbb = 1; Nnn = 2; Naa = 3; Nrhs = Naa |
|---|
| 419 | #if defined key_agrif |
|---|
| 420 | Kbb_a = Nbb; Kmm_a = Nnn; Krhs_a = Nrhs ! agrif_oce module copies of time level indices |
|---|
| 421 | #endif |
|---|
| 422 | ! !-------------------------------! |
|---|
| 423 | ! ! NEMO general initialization ! |
|---|
| 424 | ! !-------------------------------! |
|---|
| 425 | |
|---|
| 426 | CALL nemo_ctl ! Control prints |
|---|
| 427 | ! |
|---|
| 428 | ! ! General initialization |
|---|
| 429 | IF( ln_timing ) CALL timing_init ! timing |
|---|
| 430 | IF( ln_timing ) CALL timing_start( 'nemo_init') |
|---|
| 431 | ! |
|---|
| 432 | CALL phy_cst ! Physical constants |
|---|
| 433 | CALL eos_init ! Equation of state |
|---|
| 434 | IF( lk_c1d ) CALL c1d_init ! 1D column configuration |
|---|
| 435 | CALL wad_init ! Wetting and drying options |
|---|
| 436 | |
|---|
| 437 | #if defined key_agrif |
|---|
| 438 | CALL Agrif_Declare_Var_ini ! " " " " " DOM |
|---|
| 439 | #endif |
|---|
| 440 | CALL dom_init( Nbb, Nnn, Naa, "OPA") ! Domain |
|---|
| 441 | IF( ln_crs ) CALL crs_init( Nnn ) ! coarsened grid: domain initialization |
|---|
| 442 | IF( sn_cfctl%l_prtctl ) & |
|---|
| 443 | & CALL prt_ctl_init ! Print control |
|---|
| 444 | |
|---|
| 445 | CALL diurnal_sst_bulk_init ! diurnal sst |
|---|
| 446 | IF( ln_diurnal ) CALL diurnal_sst_coolskin_init ! cool skin |
|---|
| 447 | ! |
|---|
| 448 | IF( ln_diurnal_only ) THEN ! diurnal only: a subset of the initialisation routines |
|---|
| 449 | CALL istate_init( Nbb, Nnn, Naa ) ! ocean initial state (Dynamics and tracers) |
|---|
| 450 | CALL sbc_init( Nbb, Nnn, Naa ) ! Forcings : surface module |
|---|
| 451 | CALL tra_qsr_init ! penetrative solar radiation qsr |
|---|
| 452 | IF( ln_diaobs ) THEN ! Observation & model comparison |
|---|
| 453 | CALL dia_obs_init( Nnn ) ! Initialize observational data |
|---|
| 454 | CALL dia_obs( nit000 - 1, Nnn ) ! Observation operator for restart |
|---|
| 455 | ENDIF |
|---|
| 456 | IF( lk_asminc ) CALL asm_inc_init( Nbb, Nnn, Nrhs ) ! Assimilation increments |
|---|
| 457 | ! |
|---|
| 458 | RETURN ! end of initialization |
|---|
| 459 | ENDIF |
|---|
| 460 | ! |
|---|
| 461 | |
|---|
| 462 | CALL istate_init( Nbb, Nnn, Naa ) ! ocean initial state (Dynamics and tracers) |
|---|
| 463 | |
|---|
| 464 | ! ! external forcing |
|---|
| 465 | CALL tide_init ! tidal harmonics |
|---|
| 466 | CALL sbc_init( Nbb, Nnn, Naa ) ! surface boundary conditions (including sea-ice) |
|---|
| 467 | CALL bdy_init ! Open boundaries initialisation |
|---|
| 468 | |
|---|
| 469 | ! ! Ocean physics |
|---|
| 470 | CALL zdf_phy_init( Nnn ) ! Vertical physics |
|---|
| 471 | |
|---|
| 472 | ! ! Lateral physics |
|---|
| 473 | CALL ldf_tra_init ! Lateral ocean tracer physics |
|---|
| 474 | CALL ldf_eiv_init ! eddy induced velocity param. |
|---|
| 475 | CALL ldf_dyn_init ! Lateral ocean momentum physics |
|---|
| 476 | |
|---|
| 477 | ! ! Active tracers |
|---|
| 478 | IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation qsr |
|---|
| 479 | CALL tra_bbc_init ! bottom heat flux |
|---|
| 480 | CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme |
|---|
| 481 | CALL tra_dmp_init ! internal tracer damping |
|---|
| 482 | CALL tra_adv_init ! horizontal & vertical advection |
|---|
| 483 | CALL tra_ldf_init ! lateral mixing |
|---|
| 484 | |
|---|
| 485 | ! ! Dynamics |
|---|
| 486 | IF( lk_c1d ) CALL dyn_dmp_init ! internal momentum damping |
|---|
| 487 | CALL dyn_adv_init ! advection (vector or flux form) |
|---|
| 488 | CALL dyn_vor_init ! vorticity term including Coriolis |
|---|
| 489 | CALL dyn_ldf_init ! lateral mixing |
|---|
| 490 | CALL dyn_hpg_init( Nnn ) ! horizontal gradient of Hydrostatic pressure |
|---|
| 491 | CALL dyn_spg_init ! surface pressure gradient |
|---|
| 492 | |
|---|
| 493 | #if defined key_top |
|---|
| 494 | ! ! Passive tracers |
|---|
| 495 | CALL trc_init( Nbb, Nnn, Naa ) |
|---|
| 496 | #endif |
|---|
| 497 | IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing |
|---|
| 498 | |
|---|
| 499 | ! ! Icebergs |
|---|
| 500 | CALL icb_init( rn_Dt, nit000) ! initialise icebergs instance |
|---|
| 501 | |
|---|
| 502 | ! ice shelf |
|---|
| 503 | CALL isf_init( Nbb, Nnn, Naa ) |
|---|
| 504 | |
|---|
| 505 | ! ! Misc. options |
|---|
| 506 | CALL sto_par_init ! Stochastic parametrization |
|---|
| 507 | IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations |
|---|
| 508 | |
|---|
| 509 | ! ! Diagnostics |
|---|
| 510 | CALL flo_init( Nnn ) ! drifting Floats |
|---|
| 511 | IF( ln_diacfl ) CALL dia_cfl_init ! Initialise CFL diagnostics |
|---|
| 512 | ! CALL dia_ptr_init ! Poleward TRansports initialization |
|---|
| 513 | CALL dia_dct_init ! Sections tranports |
|---|
| 514 | CALL dia_hsb_init( Nnn ) ! heat content, salt content and volume budgets |
|---|
| 515 | CALL trd_init( Nnn ) ! Mixed-layer/Vorticity/Integral constraints trends |
|---|
| 516 | CALL dia_obs_init( Nnn ) ! Initialize observational data |
|---|
| 517 | CALL dia_25h_init( Nbb ) ! 25h mean outputs |
|---|
| 518 | CALL dia_detide_init ! Weights computation for daily detiding of model diagnostics |
|---|
| 519 | IF( ln_diaobs ) CALL dia_obs( nit000-1, Nnn ) ! Observation operator for restart |
|---|
| 520 | CALL dia_mlr_init ! Initialisation of IOM context management for multiple-linear-regression analysis |
|---|
| 521 | |
|---|
| 522 | ! ! Assimilation increments |
|---|
| 523 | IF( lk_asminc ) CALL asm_inc_init( Nbb, Nnn, Nrhs ) ! Initialize assimilation increments |
|---|
| 524 | ! |
|---|
| 525 | IF(lwp) WRITE(numout,cform_aaa) ! Flag AAAAAAA |
|---|
| 526 | ! |
|---|
| 527 | IF( ln_timing ) CALL timing_stop( 'nemo_init') |
|---|
| 528 | ! |
|---|
| 529 | END SUBROUTINE nemo_init |
|---|
| 530 | |
|---|
| 531 | |
|---|
| 532 | SUBROUTINE nemo_ctl |
|---|
| 533 | !!---------------------------------------------------------------------- |
|---|
| 534 | !! *** ROUTINE nemo_ctl *** |
|---|
| 535 | !! |
|---|
| 536 | !! ** Purpose : control print setting |
|---|
| 537 | !! |
|---|
| 538 | !! ** Method : - print namctl and namcfg information and check some consistencies |
|---|
| 539 | !!---------------------------------------------------------------------- |
|---|
| 540 | ! |
|---|
| 541 | IF(lwp) THEN ! control print |
|---|
| 542 | WRITE(numout,*) |
|---|
| 543 | WRITE(numout,*) 'nemo_ctl: Control prints' |
|---|
| 544 | WRITE(numout,*) '~~~~~~~~' |
|---|
| 545 | WRITE(numout,*) ' Namelist namctl' |
|---|
| 546 | WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat |
|---|
| 547 | WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat |
|---|
| 548 | WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout |
|---|
| 549 | WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout |
|---|
| 550 | WRITE(numout,*) ' sn_cfctl%l_prtctl = ', sn_cfctl%l_prtctl |
|---|
| 551 | WRITE(numout,*) ' sn_cfctl%l_prttrc = ', sn_cfctl%l_prttrc |
|---|
| 552 | WRITE(numout,*) ' sn_cfctl%l_oasout = ', sn_cfctl%l_oasout |
|---|
| 553 | WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin |
|---|
| 554 | WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax |
|---|
| 555 | WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr |
|---|
| 556 | WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr |
|---|
| 557 | WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing |
|---|
| 558 | WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl |
|---|
| 559 | ENDIF |
|---|
| 560 | ! |
|---|
| 561 | IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file |
|---|
| 562 | IF(lwp) THEN ! control print |
|---|
| 563 | WRITE(numout,*) |
|---|
| 564 | WRITE(numout,*) ' Namelist namcfg' |
|---|
| 565 | WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg |
|---|
| 566 | WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg) |
|---|
| 567 | WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea |
|---|
| 568 | WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg |
|---|
| 569 | WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out) |
|---|
| 570 | WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr |
|---|
| 571 | ENDIF |
|---|
| 572 | ! |
|---|
| 573 | IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', & |
|---|
| 574 | & 'Compile with key_nosignedzero enabled:', & |
|---|
| 575 | & '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' ) |
|---|
| 576 | ! |
|---|
| 577 | #if defined key_agrif |
|---|
| 578 | IF( ln_timing ) CALL ctl_stop( 'AGRIF not implemented with ln_timing = true') |
|---|
| 579 | #endif |
|---|
| 580 | ! |
|---|
| 581 | END SUBROUTINE nemo_ctl |
|---|
| 582 | |
|---|
| 583 | |
|---|
| 584 | SUBROUTINE nemo_closefile |
|---|
| 585 | !!---------------------------------------------------------------------- |
|---|
| 586 | !! *** ROUTINE nemo_closefile *** |
|---|
| 587 | !! |
|---|
| 588 | !! ** Purpose : Close the files |
|---|
| 589 | !!---------------------------------------------------------------------- |
|---|
| 590 | ! |
|---|
| 591 | IF( lk_mpp ) CALL mppsync |
|---|
| 592 | ! |
|---|
| 593 | CALL iom_close ! close all input/output files managed by iom_* |
|---|
| 594 | ! |
|---|
| 595 | IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file |
|---|
| 596 | IF( numrun /= -1 ) CLOSE( numrun ) ! run statistics file |
|---|
| 597 | IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist |
|---|
| 598 | IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist |
|---|
| 599 | IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution) |
|---|
| 600 | IF( numout /= 6 ) CLOSE( numout ) ! standard model output file |
|---|
| 601 | IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports |
|---|
| 602 | IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports |
|---|
| 603 | IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports |
|---|
| 604 | ! |
|---|
| 605 | numout = 6 ! redefine numout in case it is used after this point... |
|---|
| 606 | ! |
|---|
| 607 | END SUBROUTINE nemo_closefile |
|---|
| 608 | |
|---|
| 609 | |
|---|
| 610 | SUBROUTINE nemo_alloc |
|---|
| 611 | !!---------------------------------------------------------------------- |
|---|
| 612 | !! *** ROUTINE nemo_alloc *** |
|---|
| 613 | !! |
|---|
| 614 | !! ** Purpose : Allocate all the dynamic arrays of the OPA modules |
|---|
| 615 | !! |
|---|
| 616 | !! ** Method : |
|---|
| 617 | !!---------------------------------------------------------------------- |
|---|
| 618 | USE diawri , ONLY : dia_wri_alloc |
|---|
| 619 | USE dom_oce , ONLY : dom_oce_alloc |
|---|
| 620 | USE trc_oce , ONLY : trc_oce_alloc |
|---|
| 621 | USE bdy_oce , ONLY : bdy_oce_alloc |
|---|
| 622 | ! |
|---|
| 623 | INTEGER :: ierr |
|---|
| 624 | !!---------------------------------------------------------------------- |
|---|
| 625 | ! |
|---|
| 626 | ierr = oce_alloc () ! ocean |
|---|
| 627 | ierr = ierr + dia_wri_alloc() |
|---|
| 628 | ierr = ierr + dom_oce_alloc() ! ocean domain |
|---|
| 629 | ierr = ierr + zdf_oce_alloc() ! ocean vertical physics |
|---|
| 630 | ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays |
|---|
| 631 | ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization) |
|---|
| 632 | ! |
|---|
| 633 | CALL mpp_sum( 'nemogcm', ierr ) |
|---|
| 634 | IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' ) |
|---|
| 635 | ! |
|---|
| 636 | END SUBROUTINE nemo_alloc |
|---|
| 637 | |
|---|
| 638 | |
|---|
| 639 | SUBROUTINE nemo_set_cfctl(sn_cfctl, setto ) |
|---|
| 640 | !!---------------------------------------------------------------------- |
|---|
| 641 | !! *** ROUTINE nemo_set_cfctl *** |
|---|
| 642 | !! |
|---|
| 643 | !! ** Purpose : Set elements of the output control structure to setto. |
|---|
| 644 | !! |
|---|
| 645 | !! ** Method : Note this routine can be used to switch on/off some |
|---|
| 646 | !! types of output for selected areas. |
|---|
| 647 | !!---------------------------------------------------------------------- |
|---|
| 648 | TYPE(sn_ctl), INTENT(inout) :: sn_cfctl |
|---|
| 649 | LOGICAL , INTENT(in ) :: setto |
|---|
| 650 | !!---------------------------------------------------------------------- |
|---|
| 651 | sn_cfctl%l_runstat = setto |
|---|
| 652 | sn_cfctl%l_trcstat = setto |
|---|
| 653 | sn_cfctl%l_oceout = setto |
|---|
| 654 | sn_cfctl%l_layout = setto |
|---|
| 655 | sn_cfctl%l_prtctl = setto |
|---|
| 656 | sn_cfctl%l_prttrc = setto |
|---|
| 657 | sn_cfctl%l_oasout = setto |
|---|
| 658 | END SUBROUTINE nemo_set_cfctl |
|---|
| 659 | |
|---|
| 660 | !!====================================================================== |
|---|
| 661 | END MODULE nemogcm |
|---|
