New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p2zopt.F90 in NEMO/branches/2020/r12377_ticket2386/src/TOP/PISCES/P2Z – NEMO

source: NEMO/branches/2020/r12377_ticket2386/src/TOP/PISCES/P2Z/p2zopt.F90 @ 13540

Last change on this file since 13540 was 13540, checked in by andmirek, 3 years ago

Ticket #2386: update to latest trunk

  • Property svn:keywords set to Id
File size: 8.9 KB
Line 
1MODULE p2zopt
2   !!======================================================================
3   !!                         ***  MODULE p2zopt  ***
4   !! TOP :   LOBSTER Compute the light availability in the water column
5   !!======================================================================
6   !! History :    -   !  1995-05  (M. Levy) Original code
7   !!              -   !  1999-09  (J.-M. Andre, M. Levy)
8   !!              -   !  1999-11  (C. Menkes, M.-A. Foujols) itabe initial
9   !!              -   !  2000-02  (M.A. Foujols) change x**y par exp(y*log(x))
10   !!   NEMO      2.0  !  2007-12  (C. Deltel, G. Madec)  F90
11   !!             3.2  !  2009-04  (C. Ethe, G. Madec)  minor optimisation + style
12   !!----------------------------------------------------------------------
13
14   !!----------------------------------------------------------------------
15   !!   p2z_opt        :   Compute the light availability in the water column
16   !!----------------------------------------------------------------------
17   USE oce_trc         !
18   USE trc
19   USE sms_pisces
20   USE prtctl          ! Print control for debbuging
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   p2z_opt   !
26   PUBLIC   p2z_opt_init   !
27
28   REAL(wp), PUBLIC ::  xkr0      !: water coefficient absorption in red     
29   REAL(wp), PUBLIC ::  xkg0      !: water coefficient absorption in green   
30   REAL(wp), PUBLIC ::  xkrp      !: pigment coefficient absorption in red   
31   REAL(wp), PUBLIC ::  xkgp      !: pigment coefficient absorption in green 
32   REAL(wp), PUBLIC ::  xlr       !: exposant for pigment absorption in red 
33   REAL(wp), PUBLIC ::  xlg       !: exposant for pigment absorption in green
34   REAL(wp), PUBLIC ::  rpig      !: chla/chla+phea ratio   
35   !                 
36   REAL(wp), PUBLIC ::  rcchl     ! Carbone/Chlorophyl ratio [mgC.mgChla-1]
37   REAL(wp), PUBLIC ::  redf      ! redfield ratio (C:N) for phyto
38   REAL(wp), PUBLIC ::  reddom    ! redfield ratio (C:N) for DOM
39
40   !! * Substitutions
41#  include "do_loop_substitute.h90"
42#  include "domzgr_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
45   !! $Id$
46   !! Software governed by the CeCILL license (see ./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE p2z_opt( kt, Kmm )
51      !!---------------------------------------------------------------------
52      !!                     ***  ROUTINE p2z_opt  ***
53      !!
54      !! ** Purpose :   computes the light propagation in the water column
55      !!              and the euphotic layer depth
56      !!
57      !! ** Method  :   local par is computed in w layers using light propagation
58      !!              mean par in t layers are computed by integration
59      !!
60!!gm please remplace the '???' by true comments
61      !! ** Action  :   etot   ???
62      !!                neln   ???
63      !!---------------------------------------------------------------------
64      !!
65      INTEGER, INTENT( in ) ::   kt   ! index of the time stepping
66      INTEGER, INTENT( in ) ::   Kmm  ! time level index
67      !!
68      INTEGER  ::   ji, jj, jk          ! dummy loop indices
69      CHARACTER (len=25) ::   charout   ! temporary character
70      REAL(wp) ::   zpig                ! log of the total pigment
71      REAL(wp) ::   zkr, zkg            ! total absorption coefficient in red and green
72      REAL(wp) ::   zcoef               ! temporary scalar
73      REAL(wp), DIMENSION(jpi,jpj    ) :: zpar100, zpar0m
74      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zparr, zparg
75      !!---------------------------------------------------------------------
76      !
77      IF( ln_timing )   CALL timing_start('p2z_opt')
78      !
79
80      IF( kt == nittrc000 ) THEN
81         IF(lwp) WRITE(numout,*)
82         IF(lwp) WRITE(numout,*) ' p2z_opt : LOBSTER optic-model'
83         IF(lwp) WRITE(numout,*) ' ~~~~~~~ '
84      ENDIF
85
86      !                                          ! surface irradiance
87      !                                          ! ------------------
88      IF( ln_dm2dc ) THEN   ;   zpar0m(:,:) = qsr_mean(:,:) * 0.43
89      ELSE                  ;   zpar0m(:,:) = qsr     (:,:) * 0.43
90      ENDIF
91      zpar100(:,:)   = zpar0m(:,:) * 0.01
92      zparr  (:,:,1) = zpar0m(:,:) * 0.5
93      zparg  (:,:,1) = zpar0m(:,:) * 0.5
94
95      !                                          ! Photosynthetically Available Radiation (PAR)
96      zcoef = 12 * redf / rcchl / rpig           ! --------------------------------------
97      DO_3D( 1, 1, 1, 1, 2, jpk )                     ! local par at w-levels
98         zpig = LOG(  MAX( TINY(0.), tr(ji,jj,jk-1,jpphy,Kmm) ) * zcoef  )
99         zkr  = xkr0 + xkrp * EXP( xlr * zpig )
100         zkg  = xkg0 + xkgp * EXP( xlg * zpig )
101         zparr(ji,jj,jk) = zparr(ji,jj,jk-1) * EXP( -zkr * e3t(ji,jj,jk-1,Kmm) )
102         zparg(ji,jj,jk) = zparg(ji,jj,jk-1) * EXP( -zkg * e3t(ji,jj,jk-1,Kmm) )
103      END_3D
104      DO_3D( 1, 1, 1, 1, 1, jpkm1 )                   ! mean par at t-levels
105         zpig = LOG(  MAX( TINY(0.), tr(ji,jj,jk,jpphy,Kmm) ) * zcoef  )
106         zkr  = xkr0 + xkrp * EXP( xlr * zpig )
107         zkg  = xkg0 + xkgp * EXP( xlg * zpig )
108         zparr(ji,jj,jk) = zparr(ji,jj,jk) / ( zkr * e3t(ji,jj,jk,Kmm) ) * ( 1 - EXP( -zkr * e3t(ji,jj,jk,Kmm) ) )
109         zparg(ji,jj,jk) = zparg(ji,jj,jk) / ( zkg * e3t(ji,jj,jk,Kmm) ) * ( 1 - EXP( -zkg * e3t(ji,jj,jk,Kmm) ) )
110         etot (ji,jj,jk) = MAX( zparr(ji,jj,jk) + zparg(ji,jj,jk), 1.e-15 )
111      END_3D
112
113      !                                          ! Euphotic layer
114      !                                          ! --------------
115      neln(:,:) = 1                                   ! euphotic layer level
116      DO_3D( 1, 1, 1, 1, 1, jpkm1 )                   ! (i.e. 1rst T-level strictly below EL bottom)
117        IF( etot(ji,jj,jk) >= zpar100(ji,jj) )   neln(ji,jj) = jk + 1 
118      END_3D
119      !                                               ! Euphotic layer depth
120      DO_2D( 1, 1, 1, 1 )
121         heup(ji,jj) = gdepw(ji,jj,neln(ji,jj),Kmm)
122      END_2D
123
124
125      IF(sn_cfctl%l_prttrc) THEN      ! print mean trends (used for debugging)
126         WRITE(charout, FMT="('opt')")
127         CALL prt_ctl_info( charout, cdcomp = 'top' )
128         CALL prt_ctl( tab4d_1=tr(:,:,:,:,Kmm), mask1=tmask, clinfo=ctrcnm )
129      ENDIF
130      !
131      IF( ln_timing )   CALL timing_stop('p2z_opt')
132      !
133   END SUBROUTINE p2z_opt
134
135
136   SUBROUTINE p2z_opt_init
137      !!----------------------------------------------------------------------
138      !!                  ***  ROUTINE p2z_opt_init  ***
139      !!
140      !! ** Purpose :  optical parameters
141      !!
142      !! ** Method  :   Read the namlobopt namelist and check the parameters
143      !!
144      !!----------------------------------------------------------------------
145      INTEGER ::   ios   ! Local integer
146      !!
147      NAMELIST/namlobopt/ xkg0, xkr0, xkgp, xkrp, xlg, xlr, rpig
148      NAMELIST/namlobrat/ rcchl, redf, reddom
149      !!----------------------------------------------------------------------
150
151      READ  ( numnatp_ref, namlobopt, IOSTAT = ios, ERR = 901)
152901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namlobopt in reference namelist' )
153
154      READ  ( numnatp_cfg, namlobopt, IOSTAT = ios, ERR = 902 )
155902   IF( ios >  0 ) CALL ctl_nam ( ios , 'namlobopt in configuration namelist' )
156      IF(lwm) WRITE ( numonp, namlobopt )
157
158      IF(lwp) THEN
159         WRITE(numout,*)
160         WRITE(numout,*) ' Namelist namlobopt'
161         WRITE(numout,*) '    green   water absorption coeff                       xkg0  = ', xkg0
162         WRITE(numout,*) '    red water absorption coeff                           xkr0  = ', xkr0
163         WRITE(numout,*) '    pigment red absorption coeff                         xkrp  = ', xkrp
164         WRITE(numout,*) '    pigment green absorption coeff                       xkgp  = ', xkgp
165         WRITE(numout,*) '    green chl exposant                                   xlg   = ', xlg
166         WRITE(numout,*) '    red   chl exposant                                   xlr   = ', xlr
167         WRITE(numout,*) '    chla/chla+phea ratio                                 rpig  = ', rpig
168         WRITE(numout,*) ' '
169      ENDIF
170      !
171      READ  ( numnatp_ref, namlobrat, IOSTAT = ios, ERR = 903)
172903   IF( ios /= 0 ) CALL ctl_nam ( ios , 'namlobrat in reference namelist' )
173
174      READ  ( numnatp_cfg, namlobrat, IOSTAT = ios, ERR = 904 )
175904   IF( ios >  0 ) CALL ctl_nam ( ios , 'namlobrat in configuration namelist' )
176      IF(lwm) WRITE ( numonp, namlobrat )
177
178      IF(lwp) THEN
179          WRITE(numout,*) ' Namelist namlobrat'
180         WRITE(numout,*) '     carbone/chlorophyl ratio                             rcchl = ', rcchl
181          WRITE(numout,*) '    redfield ratio  c:n for phyto                        redf      =', redf
182          WRITE(numout,*) '    redfield ratio  c:n for DOM                          reddom    =', reddom
183          WRITE(numout,*) ' '
184      ENDIF
185      !
186   END SUBROUTINE p2z_opt_init
187
188   !!======================================================================
189END MODULE p2zopt
Note: See TracBrowser for help on using the repository browser.