New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
stpctl.F90 in NEMO/branches/2020/r12581_ticket2418/src/SAS – NEMO

source: NEMO/branches/2020/r12581_ticket2418/src/SAS/stpctl.F90 @ 12685

Last change on this file since 12685 was 12685, checked in by smasson, 4 years ago

r12581_ticket2418: end cleaning, see #2418
  • Property svn:keywords set to Id
File size: 10.9 KB
Line 
1MODULE stpctl
2   !!======================================================================
3   !!                       ***  MODULE  stpctl  ***
4   !! Ocean run control :  gross check of the ocean time stepping
5   !!                      version for standalone surface scheme
6   !!======================================================================
7   !! History :  OPA  ! 1991-03  (G. Madec) Original code
8   !!            6.0  ! 1992-06  (M. Imbard)
9   !!            8.0  ! 1997-06  (A.M. Treguier)
10   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
11   !!            2.0  ! 2009-07  (G. Madec)  Add statistic for time-spliting
12   !!            3.5  ! 2012-03  (S. Alderson)
13   !!            4.0  ! 2017-04  (G. Madec)  regroup global communications
14   !!----------------------------------------------------------------------
15
16   !!----------------------------------------------------------------------
17   !!   stp_ctl      : Control the run
18   !!----------------------------------------------------------------------
19   USE oce             ! ocean dynamics and tracers variables
20   USE dom_oce         ! ocean space and time domain variables
21   USE ice      , ONLY : vt_i, u_ice, tm_i
22   !
23   USE diawri          ! Standard run outputs       (dia_wri_state routine)
24   USE in_out_manager  ! I/O manager
25   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
26   USE lib_mpp         ! distributed memory computing
27   !
28   USE netcdf          ! NetCDF library
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC stp_ctl           ! routine called by step.F90
33
34   INTEGER                ::   nrunid   ! netcdf file id
35   INTEGER, DIMENSION(3)  ::   nvarid   ! netcdf variable id
36   !!----------------------------------------------------------------------
37   !! NEMO/SAS 4.0 , NEMO Consortium (2018)
38   !! $Id$
39   !! Software governed by the CeCILL license (see ./LICENSE)
40   !!----------------------------------------------------------------------
41CONTAINS
42
43   SUBROUTINE stp_ctl( kt, Kmm )
44      !!----------------------------------------------------------------------
45      !!                    ***  ROUTINE stp_ctl  ***
46      !!                     
47      !! ** Purpose :   Control the run
48      !!
49      !! ** Method  : - Save the time step in numstp
50      !!              - Print it each 50 time steps
51      !!              - Stop the run IF problem encountered by setting nstop > 0
52      !!                Problems checked: ice thickness maximum > 100 m
53      !!                                  ice velocity  maximum > 10 m/s
54      !!                                  min ice temperature   < -100 degC
55      !!
56      !! ** Actions :   "time.step" file = last ocean time-step
57      !!                "run.stat"  file = run statistics
58      !!                 nstop indicator sheared among all local domain
59      !!----------------------------------------------------------------------
60      INTEGER, INTENT(in   ) ::   kt       ! ocean time-step index
61      INTEGER, INTENT(in   ) ::   Kmm      ! ocean time level index
62      !!
63      INTEGER                         ::   ji                                    ! dummy loop indices
64      INTEGER                         ::   idtime, istatus
65      INTEGER, DIMENSION(2,3)         ::   iloc                                  ! min/max loc indices
66      REAL(wp)                        ::   zzz                                   ! local real
67      REAL(wp), DIMENSION(4)          ::   zmax, zmaxlocal, zarea
68      LOGICAL                         ::   ll_wrtstp, ll_colruns, ll_wrtruns
69      LOGICAL, DIMENSION(jpi,jpj)     ::   llmsk
70      CHARACTER(len=20)               ::   clname
71      !!----------------------------------------------------------------------
72      IF( nstop > 0 .AND. ngrdstop > -1 )   RETURN   !   stpctl was already called by a child grid
73      !
74      ll_wrtstp  = ( MOD( kt-nit000, sn_cfctl%ptimincr ) == 0 ) .OR. ( kt == nitend )
75      ll_colruns = ll_wrtstp .AND. sn_cfctl%l_runstat .AND. jpnij > 1 
76      ll_wrtruns = ( ll_colruns .OR. jpnij == 1 ) .AND. lwm
77      !
78      IF( kt == nit000 ) THEN
79         !
80         IF( lwp ) THEN
81            WRITE(numout,*)
82            WRITE(numout,*) 'stp_ctl : time-stepping control'
83            WRITE(numout,*) '~~~~~~~'
84         ENDIF
85         !                                ! open time.step    ascii file, done only by 1st subdomain
86         IF( lwm )   CALL ctl_opn( numstp, 'time.step', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
87         !
88         IF( ll_wrtruns ) THEN
89            !                             ! open run.stat     ascii file, done only by 1st subdomain
90            CALL ctl_opn( numrun, 'run.stat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, lwp, narea )
91            !                             ! open run.stat.nc netcdf file, done only by 1st subdomain
92            clname = 'run.stat.nc'
93            IF( .NOT. Agrif_Root() )   clname = TRIM(Agrif_CFixed())//"_"//TRIM(clname)
94            istatus = NF90_CREATE( TRIM(clname), NF90_CLOBBER, nrunid )
95            istatus = NF90_DEF_DIM( nrunid, 'time'     , NF90_UNLIMITED, idtime )
96            istatus = NF90_DEF_VAR( nrunid, 'vt_i_max' , NF90_DOUBLE, (/ idtime /), nvarid(1) )
97            istatus = NF90_DEF_VAR( nrunid, 'abs_u_max', NF90_DOUBLE, (/ idtime /), nvarid(2) )
98            istatus = NF90_DEF_VAR( nrunid, 'tm_i_min' , NF90_DOUBLE, (/ idtime /), nvarid(3) )
99            istatus = NF90_ENDDEF(nrunid)
100         ENDIF
101         !   
102      ENDIF
103      !
104      !                                   !==              write current time step              ==!
105      !                                   !==  done only by 1st subdomain at writting timestep  ==!
106      IF( lwm .AND. ll_wrtstp ) THEN
107         WRITE ( numstp, '(1x, i8)' )   kt
108         REWIND( numstp )
109      ENDIF
110      !                                   !==            test of local extrema           ==!
111      !                                   !==  done by all processes at every time step  ==!
112      llmsk(:,:) = tmask(:,:,1) == 1._wp
113      zmax(1) = MAXVAL(      vt_i (:,:)            , mask = llmsk )   ! max ice thickness
114      zmax(2) = MAXVAL( ABS( u_ice(:,:) )          , mask = llmsk )   ! max ice velocity (zonal only)
115      zmax(3) = MAXVAL(     -tm_i (:,:) + 273.15_wp, mask = llmsk )   ! min ice temperature
116      zmax(4) = REAL( nstop, wp )                                     ! stop indicator
117      !                                   !==               get global extrema             ==!
118      !                                   !==  done by all processes if writting run.stat  ==!
119      IF( ll_colruns ) THEN
120         zmaxlocal(:) = zmax(:)
121         CALL mpp_max( "stpctl", zmax )          ! max over the global domain
122         nstop = NINT( zmax(4) )                 ! update nstop indicator (now sheared among all local domains)
123      ENDIF
124      !                                   !==              write "run.stat" files              ==!
125      !                                   !==  done only by 1st subdomain at writting timestep  ==!
126      IF( ll_wrtruns ) THEN
127         WRITE(numrun,9500) kt, zmax(1), zmax(2), -zmax(3)
128         istatus = NF90_PUT_VAR( nrunid, nvarid(1), (/ zmax(1)/), (/kt/), (/1/) )
129         istatus = NF90_PUT_VAR( nrunid, nvarid(2), (/ zmax(2)/), (/kt/), (/1/) )
130         istatus = NF90_PUT_VAR( nrunid, nvarid(3), (/-zmax(3)/), (/kt/), (/1/) )
131         IF( kt == nitend )   istatus = NF90_CLOSE(nrunid)
132      END IF
133      !                                   !==               error handling               ==!
134      !                                   !==  done by all processes at every time step  ==!
135      !
136      IF(   zmax(1) >  100._wp .OR.   &                   ! too large ice thickness maximum ( > 100 m)
137         &  zmax(2) >   10._wp .OR.   &                   ! too large ice velocity ( > 10 m/s)
138         &  zmax(3) >  101._wp .OR.   &                   ! too cold ice temperature ( < -100 degC)
139         &  ISNAN( zmax(1) + zmax(2) + zmax(3) ) ) THEN   ! NaN encounter in the tests
140         !
141         IF( ll_colruns ) THEN   ! zmax is global, so it is the same on all subdomains -> no dead lock with mpp_maxloc
142            ! first: close the netcdf file, so we can read it
143            IF( lwm .AND. kt /= nitend )   istatus = NF90_CLOSE(nrunid)
144            ! get global loc on the min/max
145            CALL mpp_maxloc( 'stpctl',      vt_i(:,:)            , tmask(:,:,1), zzz, iloc(1:2,1) )   ! mpp_maxloc ok if mask = F
146            CALL mpp_maxloc( 'stpctl',ABS( u_ice(:,:) )          , tmask(:,:,1), zzz, iloc(1:2,2) )
147            CALL mpp_minloc( 'stpctl',      tm_i(:,:) - 273.15_wp, tmask(:,:,1), zzz, iloc(1:2,3) )
148            ! find which subdomain has the max.
149            zarea(:) = 0._wp
150            DO ji = 1, 4
151               IF( zmaxlocal(ji) == zmax(ji) )   zarea(ji) = narea 
152            END DO
153            CALL mpp_max( "stpctl", zarea )         ! max over the global domain
154         ELSE                    ! find local min and max locations:
155            ! if we are here, this means that the subdomain contains some oce points -> no need to test the mask used in maxloc
156            iloc(1:2,1) = MAXLOC(       vt_i(:,:)            , mask = llmsk ) + (/ nimpp - 1, njmpp - 1/)
157            iloc(1:2,2) = MAXLOC( ABS( u_ice(:,:) )          , mask = llmsk ) + (/ nimpp - 1, njmpp - 1/)
158            iloc(1:2,3) = MINLOC(       tm_i(:,:) - 273.15_wp, mask = llmsk ) + (/ nimpp - 1, njmpp - 1/)
159            zarea(:) = narea     ! this is local information
160         ENDIF
161         !
162         WRITE(ctmp1,*) ' stp_ctl: ice_thick > 100 m or |ice_vel| > 10 m/s or ice_temp < -100 degC or NaN encounter in the tests'
163         WRITE(ctmp2,9100) kt, ' ice_thick max',  zmax(1), iloc(1,1), iloc(2,1), NINT(zarea(1))-1
164         WRITE(ctmp3,9100) kt, ' |ice_vel| max',  zmax(2), iloc(1,2), iloc(2,3), NINT(zarea(2))-1
165         WRITE(ctmp4,9100) kt, ' ice_temp  min', -zmax(3), iloc(1,2), iloc(2,3), NINT(zarea(3))-1
166         IF( Agrif_Root() ) THEN
167            WRITE(ctmp6,*) '      ===> output of last computed fields in output.abort* files'
168         ELSE
169            WRITE(ctmp6,*) '      ===> output of last computed fields in '//TRIM(Agrif_CFixed())//'_output.abort* files'
170         ENDIF
171         !
172         CALL dia_wri_state( Kmm, 'output.abort' )     ! create an output.abort file
173         !
174         IF( ll_colruns .or. jpnij == 1 ) THEN   ! all processes synchronized -> use lwp to print in opened ocean.output files
175            IF(lwp)   CALL ctl_stop( ctmp1, ' ', ctmp2, ctmp3, ctmp4, ctmp5, ' ', ctmp6 )
176         ELSE   ! only mpi subdomains with errors are here -> STOP now
177            CALL ctl_stop( 'STOP', ctmp1, ' ', ctmp2, ctmp3, ctmp4, ctmp5, ' ', ctmp6 )
178         ENDIF
179         !
180         IF( nstop == 0 )   nstop = 1 
181         ngrdstop = Agrif_Fixed()
182         !
183      ENDIF
184      !
1859100  FORMAT(' kt ',i8,a,1pg11.4,' at i j',2i6,' MPI rank',i6)
1869500  FORMAT(' it :', i8, '    vt_i_max: ', D23.16, ' |u|_max: ', D23.16,' tm_i_min: ', D23.16)
187      !
188   END SUBROUTINE stp_ctl
189
190   !!======================================================================
191END MODULE stpctl
Note: See TracBrowser for help on using the repository browser.