New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdydta.F90 in NEMO/branches/2020/r4.0-HEAD_r12713_clem_dan_fixcpl/src/OCE/BDY – NEMO

source: NEMO/branches/2020/r4.0-HEAD_r12713_clem_dan_fixcpl/src/OCE/BDY/bdydta.F90 @ 12720

Last change on this file since 12720 was 12720, checked in by clem, 4 years ago

implementation of ice pond lids (before debugging)
  • Property svn:keywords set to Id
File size: 41.6 KB
Line 
1MODULE bdydta
2   !!======================================================================
3   !!                       ***  MODULE bdydta  ***
4   !! Open boundary data : read the data for the unstructured open boundaries.
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!             -   !  2007-01  (D. Storkey) Update to use IOM module
8   !!             -   !  2007-07  (D. Storkey) add bdy_dta_fla
9   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
10   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations
11   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
12   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
13   !!            3.6  !  2012-01  (C. Rousset) add ice boundary conditions for sea ice
14   !!            4.0  !  2018     (C. Rousset) SI3 compatibility
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!    bdy_dta      : read external data along open boundaries from file
19   !!    bdy_dta_init : initialise arrays etc for reading of external data
20   !!----------------------------------------------------------------------
21   USE oce            ! ocean dynamics and tracers
22   USE dom_oce        ! ocean space and time domain
23   USE phycst         ! physical constants
24   USE sbcapr         ! atmospheric pressure forcing
25   USE sbctide        ! Tidal forcing or not
26   USE bdy_oce        ! ocean open boundary conditions 
27   USE bdytides       ! tidal forcing at boundaries
28#if defined key_si3
29   USE ice            ! sea-ice variables
30   USE icevar         ! redistribute ice input into categories
31#endif
32   !
33   USE lib_mpp, ONLY: ctl_stop, ctl_nam
34   USE fldread        ! read input fields
35   USE iom            ! IOM library
36   USE in_out_manager ! I/O logical units
37   USE timing         ! Timing
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   bdy_dta          ! routine called by step.F90 and dynspg_ts.F90
43   PUBLIC   bdy_dta_init     ! routine called by nemogcm.F90
44
45   INTEGER , PARAMETER ::   jpbdyfld  = 17    ! maximum number of files to read
46   INTEGER , PARAMETER ::   jp_bdyssh = 1     !
47   INTEGER , PARAMETER ::   jp_bdyu2d = 2     !
48   INTEGER , PARAMETER ::   jp_bdyv2d = 3     !
49   INTEGER , PARAMETER ::   jp_bdyu3d = 4     !
50   INTEGER , PARAMETER ::   jp_bdyv3d = 5     !
51   INTEGER , PARAMETER ::   jp_bdytem = 6     !
52   INTEGER , PARAMETER ::   jp_bdysal = 7     !
53   INTEGER , PARAMETER ::   jp_bdya_i = 8     !
54   INTEGER , PARAMETER ::   jp_bdyh_i = 9     !
55   INTEGER , PARAMETER ::   jp_bdyh_s = 10    !
56   INTEGER , PARAMETER ::   jp_bdyt_i = 11    !
57   INTEGER , PARAMETER ::   jp_bdyt_s = 12    !
58   INTEGER , PARAMETER ::   jp_bdytsu = 13    !
59   INTEGER , PARAMETER ::   jp_bdys_i = 14    !
60   INTEGER , PARAMETER ::   jp_bdyaip = 15    !
61   INTEGER , PARAMETER ::   jp_bdyhip = 16    !
62   INTEGER , PARAMETER ::   jp_bdyhil = 17    !
63#if ! defined key_si3
64   INTEGER , PARAMETER ::   jpl = 1
65#endif
66
67!$AGRIF_DO_NOT_TREAT
68   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:,:), TARGET ::   bf   ! structure of input fields (file informations, fields read)
69!$AGRIF_END_DO_NOT_TREAT
70
71   !!----------------------------------------------------------------------
72   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
73   !! $Id$
74   !! Software governed by the CeCILL license (see ./LICENSE)
75   !!----------------------------------------------------------------------
76CONTAINS
77
78   SUBROUTINE bdy_dta( kt, kit, kt_offset )
79      !!----------------------------------------------------------------------
80      !!                   ***  SUBROUTINE bdy_dta  ***
81      !!                   
82      !! ** Purpose :   Update external data for open boundary conditions
83      !!
84      !! ** Method  :   Use fldread.F90
85      !!               
86      !!----------------------------------------------------------------------
87      INTEGER, INTENT(in)           ::   kt           ! ocean time-step index
88      INTEGER, INTENT(in), OPTIONAL ::   kit          ! subcycle time-step index (for timesplitting option)
89      INTEGER, INTENT(in), OPTIONAL ::   kt_offset    ! time offset in units of timesteps. NB. if kit
90      !                                               ! is present then units = subcycle timesteps.
91      !                                               ! kt_offset = 0 => get data at "now" time level
92      !                                               ! kt_offset = -1 => get data at "before" time level
93      !                                               ! kt_offset = +1 => get data at "after" time level
94      !                                               ! etc.
95      !
96      INTEGER ::  jbdy, jfld, jstart, jend, ib, jl    ! dummy loop indices
97      INTEGER ::  ii, ij, ik, igrd, ipl               ! local integers
98      INTEGER,   DIMENSION(jpbgrd)     ::   ilen1 
99      TYPE(OBC_DATA)         , POINTER ::   dta_alias        ! short cut
100      TYPE(FLD), DIMENSION(:), POINTER ::   bf_alias
101      !!---------------------------------------------------------------------------
102      !
103      IF( ln_timing )   CALL timing_start('bdy_dta')
104      !
105      ! Initialise data arrays once for all from initial conditions where required
106      !---------------------------------------------------------------------------
107      IF( kt == nit000 .AND. .NOT.PRESENT(kit) ) THEN
108
109         ! Calculate depth-mean currents
110         !-----------------------------
111
112         DO jbdy = 1, nb_bdy
113            !
114            IF( nn_dyn2d_dta(jbdy) == 0 ) THEN
115               IF( dta_bdy(jbdy)%lneed_ssh ) THEN
116                  igrd = 1
117                  DO ib = 1, idx_bdy(jbdy)%nblenrim(igrd)   ! ssh is allocated and used only on the rim
118                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
119                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
120                     dta_bdy(jbdy)%ssh(ib) = sshn(ii,ij) * tmask(ii,ij,1)         
121                  END DO
122               ENDIF
123               IF( dta_bdy(jbdy)%lneed_dyn2d .AND. ASSOCIATED(dta_bdy(jbdy)%u2d) ) THEN   ! no SIZE with a unassociated pointer
124                  igrd = 2
125                  DO ib = 1, SIZE(dta_bdy(jbdy)%u2d)   ! u2d is used only on the rim except if ln_full_vel = T, see bdy_dta_init
126                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
127                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
128                     dta_bdy(jbdy)%u2d(ib) = un_b(ii,ij) * umask(ii,ij,1)         
129                  END DO
130                  igrd = 3
131                  DO ib = 1, SIZE(dta_bdy(jbdy)%v2d)   ! v2d is used only on the rim except if ln_full_vel = T, see bdy_dta_init
132                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
133                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
134                     dta_bdy(jbdy)%v2d(ib) = vn_b(ii,ij) * vmask(ii,ij,1)         
135                  END DO
136               ENDIF
137            ENDIF
138            !
139            IF( nn_dyn3d_dta(jbdy) == 0 ) THEN
140               IF( dta_bdy(jbdy)%lneed_dyn3d ) THEN
141                  igrd = 2 
142                  DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
143                     DO ik = 1, jpkm1
144                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
145                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
146                        dta_bdy(jbdy)%u3d(ib,ik) =  ( un(ii,ij,ik) - un_b(ii,ij) ) * umask(ii,ij,ik)         
147                     END DO
148                  END DO
149                  igrd = 3 
150                  DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
151                     DO ik = 1, jpkm1
152                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
153                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
154                        dta_bdy(jbdy)%v3d(ib,ik) =  ( vn(ii,ij,ik) - vn_b(ii,ij) ) * vmask(ii,ij,ik)         
155                     END DO
156                  END DO
157               ENDIF
158            ENDIF
159
160            IF( nn_tra_dta(jbdy) == 0 ) THEN
161               IF( dta_bdy(jbdy)%lneed_tra ) THEN
162                  igrd = 1 
163                  DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
164                     DO ik = 1, jpkm1
165                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
166                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
167                        dta_bdy(jbdy)%tem(ib,ik) = tsn(ii,ij,ik,jp_tem) * tmask(ii,ij,ik)         
168                        dta_bdy(jbdy)%sal(ib,ik) = tsn(ii,ij,ik,jp_sal) * tmask(ii,ij,ik)         
169                     END DO
170                  END DO
171               ENDIF
172            ENDIF
173
174#if defined key_si3
175            IF( nn_ice_dta(jbdy) == 0 ) THEN    ! set ice to initial values
176               IF( dta_bdy(jbdy)%lneed_ice ) THEN
177                  igrd = 1   
178                  DO jl = 1, jpl
179                     DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
180                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
181                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
182                        dta_bdy(jbdy)%a_i(ib,jl) =  a_i (ii,ij,jl) * tmask(ii,ij,1) 
183                        dta_bdy(jbdy)%h_i(ib,jl) =  h_i (ii,ij,jl) * tmask(ii,ij,1) 
184                        dta_bdy(jbdy)%h_s(ib,jl) =  h_s (ii,ij,jl) * tmask(ii,ij,1) 
185                        dta_bdy(jbdy)%t_i(ib,jl) =  SUM(t_i (ii,ij,:,jl)) * r1_nlay_i * tmask(ii,ij,1) 
186                        dta_bdy(jbdy)%t_s(ib,jl) =  SUM(t_s (ii,ij,:,jl)) * r1_nlay_s * tmask(ii,ij,1)
187                        dta_bdy(jbdy)%tsu(ib,jl) =  t_su(ii,ij,jl) * tmask(ii,ij,1) 
188                        dta_bdy(jbdy)%s_i(ib,jl) =  s_i (ii,ij,jl) * tmask(ii,ij,1)
189                        ! melt ponds
190                        dta_bdy(jbdy)%aip(ib,jl) =  a_ip(ii,ij,jl) * tmask(ii,ij,1) 
191                        dta_bdy(jbdy)%hip(ib,jl) =  h_ip(ii,ij,jl) * tmask(ii,ij,1) 
192                        dta_bdy(jbdy)%hil(ib,jl) =  h_il(ii,ij,jl) * tmask(ii,ij,1) 
193                     END DO
194                  END DO
195               ENDIF
196            ENDIF
197#endif
198         END DO ! jbdy
199         !
200      ENDIF ! kt == nit000
201
202      ! update external data from files
203      !--------------------------------
204
205      DO jbdy = 1, nb_bdy
206
207         dta_alias => dta_bdy(jbdy)
208         bf_alias  => bf(:,jbdy)
209
210         ! read/update all bdy data
211         ! ------------------------
212         CALL fld_read( kt, 1, bf_alias, kit = kit, kt_offset = kt_offset )
213
214         ! apply some corrections in some specific cases...
215         ! --------------------------------------------------
216         !
217         ! if runoff condition: change river flow we read (in m3/s) into barotropic velocity (m/s)
218         IF( cn_tra(jbdy) == 'runoff' .AND. TRIM(bf_alias(jp_bdyu2d)%clrootname) /= 'NOT USED' ) THEN   ! runoff and we read u/v2d
219            !
220            igrd = 2                      ! zonal flow (m3/s) to barotropic zonal velocity (m/s)
221            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
222               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
223               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
224               dta_alias%u2d(ib) = dta_alias%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) )
225            END DO
226            igrd = 3                      ! meridional flow (m3/s) to barotropic meridional velocity (m/s)
227            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
228               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
229               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
230               dta_alias%v2d(ib) = dta_alias%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) )
231            END DO
232         ENDIF
233
234         ! tidal harmonic forcing ONLY: initialise arrays
235         IF( nn_dyn2d_dta(jbdy) == 2 ) THEN   ! we did not read ssh, u/v2d
236            IF( dta_alias%lneed_ssh   .AND. ASSOCIATED(dta_alias%ssh) ) dta_alias%ssh(:) = 0._wp
237            IF( dta_alias%lneed_dyn2d .AND. ASSOCIATED(dta_alias%u2d) ) dta_alias%u2d(:) = 0._wp
238            IF( dta_alias%lneed_dyn2d .AND. ASSOCIATED(dta_alias%v2d) ) dta_alias%v2d(:) = 0._wp
239         ENDIF
240
241         ! If full velocities in boundary data, then split it into barotropic and baroclinic component
242         IF( bf_alias(jp_bdyu3d)%ltotvel ) THEN     ! if we read 3D total velocity (can be true only if u3d was read)
243            !
244            igrd = 2                       ! zonal velocity
245            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
246               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
247               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
248               dta_alias%u2d(ib) = 0._wp   ! compute barotrope zonal velocity and put it in u2d
249               DO ik = 1, jpkm1
250                  dta_alias%u2d(ib) = dta_alias%u2d(ib) + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta_alias%u3d(ib,ik)
251               END DO
252               dta_alias%u2d(ib) =  dta_alias%u2d(ib) * r1_hu_n(ii,ij)
253               DO ik = 1, jpkm1            ! compute barocline zonal velocity and put it in u3d
254                  dta_alias%u3d(ib,ik) = dta_alias%u3d(ib,ik) - dta_alias%u2d(ib)
255               END DO
256            END DO
257            igrd = 3                       ! meridional velocity
258            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
259               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
260               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
261               dta_alias%v2d(ib) = 0._wp   ! compute barotrope meridional velocity and put it in v2d
262               DO ik = 1, jpkm1
263                  dta_alias%v2d(ib) = dta_alias%v2d(ib) + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta_alias%v3d(ib,ik)
264               END DO
265               dta_alias%v2d(ib) =  dta_alias%v2d(ib) * r1_hv_n(ii,ij)
266               DO ik = 1, jpkm1            ! compute barocline meridional velocity and put it in v3d
267                  dta_alias%v3d(ib,ik) = dta_alias%v3d(ib,ik) - dta_alias%v2d(ib)
268               END DO
269            END DO
270         ENDIF   ! ltotvel
271
272         ! update tidal harmonic forcing
273         IF( PRESENT(kit) .AND. nn_dyn2d_dta(jbdy) .GE. 2 ) THEN
274            CALL bdytide_update( kt = kt, idx = idx_bdy(jbdy), dta = dta_alias, td = tides(jbdy),   & 
275               &                 kit = kit, kt_offset = kt_offset )
276         ENDIF
277
278         !  atm surface pressure : add inverted barometer effect to ssh if it was read
279         IF ( ln_apr_obc .AND. TRIM(bf_alias(jp_bdyssh)%clrootname) /= 'NOT USED' ) THEN
280            igrd = 1
281            DO ib = 1, idx_bdy(jbdy)%nblenrim(igrd)   ! ssh is used only on the rim
282               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
283               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
284               dta_alias%ssh(ib) = dta_alias%ssh(ib) + ssh_ib(ii,ij)
285            END DO
286         ENDIF
287
288#if defined key_si3
289         IF( dta_alias%lneed_ice .AND. idx_bdy(jbdy)%nblen(1) > 0 ) THEN
290            ! fill temperature and salinity arrays
291            IF( TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyt_i)%fnow(:,1,:) = rice_tem (jbdy)
292            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyt_s)%fnow(:,1,:) = rice_tem (jbdy)
293            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) == 'NOT USED' )   bf_alias(jp_bdytsu)%fnow(:,1,:) = rice_tem (jbdy)
294            IF( TRIM(bf_alias(jp_bdys_i)%clrootname) == 'NOT USED' )   bf_alias(jp_bdys_i)%fnow(:,1,:) = rice_sal (jbdy)
295            IF( TRIM(bf_alias(jp_bdyaip)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyaip)%fnow(:,1,:) = rice_apnd(jbdy) * & ! rice_apnd is the pond fraction
296               &                                                                         bf_alias(jp_bdya_i)%fnow(:,1,:)     !   ( a_ip = rice_apnd * a_i )
297            IF( TRIM(bf_alias(jp_bdyhip)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyhip)%fnow(:,1,:) = rice_hpnd(jbdy)
298            IF( TRIM(bf_alias(jp_bdyhil)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyhil)%fnow(:,1,:) = rice_hlid(jbdy)
299
300            ! if T_i is read and not T_su, set T_su = T_i
301            IF( TRIM(bf_alias(jp_bdyt_i)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdytsu)%clrootname) == 'NOT USED' ) &
302               &   bf_alias(jp_bdytsu)%fnow(:,1,:) = bf_alias(jp_bdyt_i)%fnow(:,1,:)
303            ! if T_s is read and not T_su, set T_su = T_s
304            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdytsu)%clrootname) == 'NOT USED' ) &
305               &   bf_alias(jp_bdytsu)%fnow(:,1,:) = bf_alias(jp_bdyt_s)%fnow(:,1,:)
306            ! if T_i is read and not T_s, set T_s = T_i
307            IF( TRIM(bf_alias(jp_bdyt_i)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_s)%clrootname) == 'NOT USED' ) &
308               &   bf_alias(jp_bdyt_s)%fnow(:,1,:) = bf_alias(jp_bdyt_i)%fnow(:,1,:)
309            ! if T_su is read and not T_s, set T_s = T_su
310            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_s)%clrootname) == 'NOT USED' ) &
311               &   bf_alias(jp_bdyt_s)%fnow(:,1,:) = bf_alias(jp_bdytsu)%fnow(:,1,:)
312            ! if T_su is read and not T_i, set T_i = (T_su + T_freeze)/2
313            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' ) &
314               &   bf_alias(jp_bdyt_i)%fnow(:,1,:) = 0.5_wp * ( bf_alias(jp_bdytsu)%fnow(:,1,:) + 271.15 )
315            ! if T_s is read and not T_i, set T_i = (T_s + T_freeze)/2
316            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' ) &
317               &   bf_alias(jp_bdyt_i)%fnow(:,1,:) = 0.5_wp * ( bf_alias(jp_bdyt_s)%fnow(:,1,:) + 271.15 )
318
319            ! make sure ponds = 0 if no ponds scheme
320            IF ( .NOT.ln_pnd ) THEN
321               bf_alias(jp_bdyaip)%fnow(:,1,:) = 0._wp
322               bf_alias(jp_bdyhip)%fnow(:,1,:) = 0._wp
323               bf_alias(jp_bdyhil)%fnow(:,1,:) = 0._wp
324            ENDIF
325           
326            ! convert N-cat fields (input) into jpl-cat (output)
327            ipl = SIZE(bf_alias(jp_bdya_i)%fnow, 3)           
328            IF( ipl /= jpl ) THEN      ! ice: convert N-cat fields (input) into jpl-cat (output)
329               CALL ice_var_itd( bf_alias(jp_bdyh_i)%fnow(:,1,:), bf_alias(jp_bdyh_s)%fnow(:,1,:), bf_alias(jp_bdya_i)%fnow(:,1,:), & ! in
330                  &              dta_alias%h_i                  , dta_alias%h_s                  , dta_alias%a_i                  , & ! out
331                  &              bf_alias(jp_bdyt_i)%fnow(:,1,:), bf_alias(jp_bdyt_s)%fnow(:,1,:), &                                  ! in (optional)
332                  &              bf_alias(jp_bdytsu)%fnow(:,1,:), bf_alias(jp_bdys_i)%fnow(:,1,:), &                                  ! in     -
333                  &              bf_alias(jp_bdyaip)%fnow(:,1,:), bf_alias(jp_bdyhip)%fnow(:,1,:), bf_alias(jp_bdyhil)%fnow(:,1,:), & ! in     -
334                  &              dta_alias%t_i                  , dta_alias%t_s                  , &                                  ! out    -
335                  &              dta_alias%tsu                  , dta_alias%s_i                  , &                                  ! out    -
336                  &              dta_alias%aip                  , dta_alias%hip                  , dta_alias%hil )                    ! out    -
337            ENDIF
338         ENDIF
339#endif
340      END DO  ! jbdy
341
342      IF ( ln_tide ) THEN
343         IF (ln_dynspg_ts) THEN      ! Fill temporary arrays with slow-varying bdy data                           
344            DO jbdy = 1, nb_bdy      ! Tidal component added in ts loop
345               IF ( nn_dyn2d_dta(jbdy) .GE. 2 ) THEN
346                  IF( cn_dyn2d(jbdy) == 'frs' ) THEN   ;   ilen1(:)=idx_bdy(jbdy)%nblen(:)
347                  ELSE                                 ;   ilen1(:)=idx_bdy(jbdy)%nblenrim(:)
348                  ENDIF
349                     IF ( dta_bdy(jbdy)%lneed_ssh   ) dta_bdy_s(jbdy)%ssh(1:ilen1(1)) = dta_bdy(jbdy)%ssh(1:ilen1(1))
350                     IF ( dta_bdy(jbdy)%lneed_dyn2d ) dta_bdy_s(jbdy)%u2d(1:ilen1(2)) = dta_bdy(jbdy)%u2d(1:ilen1(2))
351                     IF ( dta_bdy(jbdy)%lneed_dyn2d ) dta_bdy_s(jbdy)%v2d(1:ilen1(3)) = dta_bdy(jbdy)%v2d(1:ilen1(3))
352                  ENDIF
353               END DO
354            ELSE ! Add tides if not split-explicit free surface else this is done in ts loop
355               !
356               CALL bdy_dta_tides( kt=kt, kt_offset=kt_offset )
357            ENDIF
358         ENDIF
359         !
360         IF( ln_timing )   CALL timing_stop('bdy_dta')
361         !
362      END SUBROUTINE bdy_dta
363
364
365   SUBROUTINE bdy_dta_init
366      !!----------------------------------------------------------------------
367      !!                   ***  SUBROUTINE bdy_dta_init  ***
368      !!                   
369      !! ** Purpose :   Initialise arrays for reading of external data
370      !!                for open boundary conditions
371      !!
372      !! ** Method  :   
373      !!               
374      !!----------------------------------------------------------------------
375      INTEGER ::   jbdy, jfld    ! Local integers
376      INTEGER ::   ierror, ios     !
377      !
378      CHARACTER(len=3)                       ::   cl3           !
379      CHARACTER(len=100)                     ::   cn_dir        ! Root directory for location of data files
380      LOGICAL                                ::   ln_full_vel   ! =T => full velocities in 3D boundary data
381      !                                                         ! =F => baroclinic velocities in 3D boundary data
382      LOGICAL                                ::   ln_zinterp    ! =T => requires a vertical interpolation of the bdydta
383      REAL(wp)                               ::   rn_ice_tem, rn_ice_sal, rn_ice_age, rn_ice_apnd, rn_ice_hpnd, rn_ice_hlid
384      INTEGER                                ::   ipk,ipl       !
385      INTEGER                                ::   idvar         ! variable ID
386      INTEGER                                ::   indims        ! number of dimensions of the variable
387      INTEGER                                ::   iszdim        ! number of dimensions of the variable
388      INTEGER, DIMENSION(4)                  ::   i4dimsz       ! size of variable dimensions
389      INTEGER                                ::   igrd          ! index for grid type (1,2,3 = T,U,V)
390      LOGICAL                                ::   lluld         ! is the variable using the unlimited dimension
391      LOGICAL                                ::   llneed        !
392      LOGICAL                                ::   llread        !
393      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_tem, bn_sal, bn_u3d, bn_v3d   ! must be an array to be used with fld_fill
394      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_ssh, bn_u2d, bn_v2d           ! informations about the fields to be read
395      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_a_i, bn_h_i, bn_h_s, bn_t_i, bn_t_s, bn_tsu, bn_s_i, bn_aip, bn_hip, bn_hil       
396      TYPE(FLD_N), DIMENSION(:), POINTER ::   bn_alias                        ! must be an array to be used with fld_fill
397      TYPE(FLD  ), DIMENSION(:), POINTER ::   bf_alias
398      !
399      NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d 
400      NAMELIST/nambdy_dta/ bn_a_i, bn_h_i, bn_h_s, bn_t_i, bn_t_s, bn_tsu, bn_s_i, bn_aip, bn_hip, bn_hil
401      NAMELIST/nambdy_dta/ rn_ice_tem, rn_ice_sal, rn_ice_age, rn_ice_apnd, rn_ice_hpnd, rn_ice_hlid
402      NAMELIST/nambdy_dta/ ln_full_vel, ln_zinterp
403      !!---------------------------------------------------------------------------
404      !
405      IF(lwp) WRITE(numout,*)
406      IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries'
407      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
408      IF(lwp) WRITE(numout,*) ''
409
410      ALLOCATE( bf(jpbdyfld,nb_bdy), STAT=ierror )
411      IF( ierror > 0 ) THEN   
412         CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' )   ;   RETURN 
413      ENDIF
414      bf(:,:)%clrootname = 'NOT USED'   ! default definition used as a flag in fld_read to do nothing.
415      bf(:,:)%lzint      = .FALSE.      ! default definition
416      bf(:,:)%ltotvel    = .FALSE.      ! default definition
417 
418      ! Read namelists
419      ! --------------
420      REWIND(numnam_cfg)
421      DO jbdy = 1, nb_bdy
422
423         WRITE(ctmp1, '(a,i2)') 'BDY number ', jbdy
424         WRITE(ctmp2, '(a,i2)') 'block nambdy_dta number ', jbdy
425
426         ! There is only one nambdy_dta block in namelist_ref -> use it for each bdy so we do a rewind
427         REWIND(numnam_ref)
428         READ  ( numnam_ref, nambdy_dta, IOSTAT = ios, ERR = 901)
429901      IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy_dta in reference namelist' )
430
431         !   by-pass nambdy_dta reading if no input data used in this bdy   
432         IF(       ( dta_bdy(jbdy)%lneed_dyn2d .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1 )   &
433            & .OR. ( dta_bdy(jbdy)%lneed_dyn3d .AND.     nn_dyn3d_dta(jbdy)    == 1 )   &
434            & .OR. ( dta_bdy(jbdy)%lneed_tra   .AND.       nn_tra_dta(jbdy)    == 1 )   &
435            & .OR. ( dta_bdy(jbdy)%lneed_ice   .AND.       nn_ice_dta(jbdy)    == 1 )   )   THEN
436            ! WARNING: we don't do a rewind here, each bdy reads its own nambdy_dta block one after another
437            READ  ( numnam_cfg, nambdy_dta, IOSTAT = ios, ERR = 902 )
438902         IF( ios >  0 )   CALL ctl_nam ( ios , 'nambdy_dta in configuration namelist' )
439            IF(lwm) WRITE( numond, nambdy_dta )           
440         ENDIF
441
442         ! get the number of ice categories in bdy data file (use a_i information to do this)
443         ipl = jpl   ! default definition
444         IF( dta_bdy(jbdy)%lneed_ice ) THEN    ! if we need ice bdy data
445            IF( nn_ice_dta(jbdy) == 1 ) THEN   ! if we get ice bdy data from netcdf file
446               CALL fld_fill(  bf(jp_bdya_i,jbdy:jbdy), bn_a_i, cn_dir, 'bdy_dta', 'a_i'//' '//ctmp1, ctmp2 )   ! use namelist info
447               CALL fld_clopn( bf(jp_bdya_i,jbdy), nyear, nmonth, nday )   ! not a problem when we call it again after
448               idvar = iom_varid( bf(jp_bdya_i,jbdy)%num, bf(jp_bdya_i,jbdy)%clvar, kndims=indims, kdimsz=i4dimsz, lduld=lluld )
449               IF( indims == 4 .OR. ( indims == 3 .AND. .NOT. lluld ) ) THEN   ;   ipl = i4dimsz(3)   ! xylt or xyl
450               ELSE                                                            ;   ipl = 1            ! xy or xyt
451               ENDIF
452               bf(jp_bdya_i,jbdy)%clrootname = 'NOT USED'   ! reset to default value as this subdomain may not need to read this bdy
453            ENDIF
454         ENDIF
455
456#if defined key_si3
457         IF( .NOT.ln_pnd ) THEN
458            rn_ice_apnd = 0. ; rn_ice_hpnd = 0. ; rn_ice_hlid = 0.
459            CALL ctl_warn( 'rn_ice_apnd & rn_ice_hpnd = 0 & rn_ice_hlid = 0 when no ponds' )
460         ENDIF
461#endif
462
463         ! temp, salt, age and ponds of incoming ice
464         rice_tem (jbdy) = rn_ice_tem
465         rice_sal (jbdy) = rn_ice_sal
466         rice_age (jbdy) = rn_ice_age
467         rice_apnd(jbdy) = rn_ice_apnd
468         rice_hpnd(jbdy) = rn_ice_hpnd
469         rice_hlid(jbdy) = rn_ice_hlid
470
471         
472         DO jfld = 1, jpbdyfld
473
474            ! =====================
475            !          ssh
476            ! =====================
477            IF( jfld == jp_bdyssh ) THEN
478               cl3 = 'ssh'
479               igrd = 1                                                    ! T point
480               ipk = 1                                                     ! surface data
481               llneed = dta_bdy(jbdy)%lneed_ssh                            ! dta_bdy(jbdy)%ssh will be needed
482               llread = MOD(nn_dyn2d_dta(jbdy),2) == 1                     ! get data from NetCDF file
483               bf_alias => bf(jp_bdyssh,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
484               bn_alias => bn_ssh                                          ! alias for ssh structure of nambdy_dta
485               iszdim = idx_bdy(jbdy)%nblenrim(igrd)                       ! length of this bdy on this MPI processus : used only on the rim
486            ENDIF
487            ! =====================
488            !         dyn2d
489            ! =====================
490            IF( jfld == jp_bdyu2d ) THEN
491               cl3 = 'u2d'
492               igrd = 2                                                    ! U point
493               ipk = 1                                                     ! surface data
494               llneed = dta_bdy(jbdy)%lneed_dyn2d                          ! dta_bdy(jbdy)%ssh will be needed
495               llread = .NOT. ln_full_vel .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1   ! don't get u2d from u3d and read NetCDF file
496               bf_alias => bf(jp_bdyu2d,jbdy:jbdy)                         ! alias for u2d structure of bdy number jbdy
497               bn_alias => bn_u2d                                          ! alias for u2d structure of nambdy_dta
498               IF( ln_full_vel ) THEN  ;   iszdim = idx_bdy(jbdy)%nblen(igrd)      ! will be computed from u3d -> need on the full bdy
499               ELSE                    ;   iszdim = idx_bdy(jbdy)%nblenrim(igrd)   ! used only on the rim
500               ENDIF
501            ENDIF
502            IF( jfld == jp_bdyv2d ) THEN
503               cl3 = 'v2d'
504               igrd = 3                                                    ! V point
505               ipk = 1                                                     ! surface data
506               llneed = dta_bdy(jbdy)%lneed_dyn2d                          ! dta_bdy(jbdy)%ssh will be needed
507               llread = .NOT. ln_full_vel .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1   ! don't get v2d from v3d and read NetCDF file
508               bf_alias => bf(jp_bdyv2d,jbdy:jbdy)                         ! alias for v2d structure of bdy number jbdy
509               bn_alias => bn_v2d                                          ! alias for v2d structure of nambdy_dta
510               IF( ln_full_vel ) THEN  ;   iszdim = idx_bdy(jbdy)%nblen(igrd)      ! will be computed from v3d -> need on the full bdy
511               ELSE                    ;   iszdim = idx_bdy(jbdy)%nblenrim(igrd)   ! used only on the rim
512               ENDIF
513            ENDIF
514            ! =====================
515            !         dyn3d
516            ! =====================
517            IF( jfld == jp_bdyu3d ) THEN
518               cl3 = 'u3d'
519               igrd = 2                                                    ! U point
520               ipk = jpk                                                   ! 3d data
521               llneed = dta_bdy(jbdy)%lneed_dyn3d .OR.               &     ! dta_bdy(jbdy)%u3d will be needed
522                  &   ( dta_bdy(jbdy)%lneed_dyn2d .AND. ln_full_vel )      !   u3d needed to compute u2d
523               llread = nn_dyn3d_dta(jbdy) == 1                            ! get data from NetCDF file
524               bf_alias => bf(jp_bdyu3d,jbdy:jbdy)                         ! alias for u3d structure of bdy number jbdy
525               bn_alias => bn_u3d                                          ! alias for u3d structure of nambdy_dta
526               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
527           ENDIF
528            IF( jfld == jp_bdyv3d ) THEN
529               cl3 = 'v3d'
530               igrd = 3                                                    ! V point
531               ipk = jpk                                                   ! 3d data
532               llneed = dta_bdy(jbdy)%lneed_dyn3d .OR.               &     ! dta_bdy(jbdy)%v3d will be needed
533                  &   ( dta_bdy(jbdy)%lneed_dyn2d .AND. ln_full_vel )      !   v3d needed to compute v2d
534               llread = nn_dyn3d_dta(jbdy) == 1                            ! get data from NetCDF file
535               bf_alias => bf(jp_bdyv3d,jbdy:jbdy)                         ! alias for v3d structure of bdy number jbdy
536               bn_alias => bn_v3d                                          ! alias for v3d structure of nambdy_dta
537               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
538           ENDIF
539
540            ! =====================
541            !          tra
542            ! =====================
543            IF( jfld == jp_bdytem ) THEN
544               cl3 = 'tem'
545               igrd = 1                                                    ! T point
546               ipk = jpk                                                   ! 3d data
547               llneed = dta_bdy(jbdy)%lneed_tra                            ! dta_bdy(jbdy)%tem will be needed
548               llread = nn_tra_dta(jbdy) == 1                              ! get data from NetCDF file
549               bf_alias => bf(jp_bdytem,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
550               bn_alias => bn_tem                                          ! alias for ssh structure of nambdy_dta
551               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
552            ENDIF
553            IF( jfld == jp_bdysal ) THEN
554               cl3 = 'sal'
555               igrd = 1                                                    ! T point
556               ipk = jpk                                                   ! 3d data
557               llneed = dta_bdy(jbdy)%lneed_tra                            ! dta_bdy(jbdy)%sal will be needed
558               llread = nn_tra_dta(jbdy) == 1                              ! get data from NetCDF file
559               bf_alias => bf(jp_bdysal,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
560               bn_alias => bn_sal                                          ! alias for ssh structure of nambdy_dta
561               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
562            ENDIF
563
564            ! =====================
565            !          ice
566            ! =====================
567            IF(  jfld == jp_bdya_i .OR. jfld == jp_bdyh_i .OR. jfld == jp_bdyh_s .OR. &
568               & jfld == jp_bdyt_i .OR. jfld == jp_bdyt_s .OR. jfld == jp_bdytsu .OR. &
569               & jfld == jp_bdys_i .OR. jfld == jp_bdyaip .OR. jfld == jp_bdyhip .OR. jfld == jp_bdyhil ) THEN
570               igrd = 1                                                    ! T point
571               ipk = ipl                                                   ! jpl-cat data
572               llneed = dta_bdy(jbdy)%lneed_ice                            ! ice will be needed
573               llread = nn_ice_dta(jbdy) == 1                              ! get data from NetCDF file
574               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
575            ENDIF
576            IF( jfld == jp_bdya_i ) THEN
577               cl3 = 'a_i'
578               bf_alias => bf(jp_bdya_i,jbdy:jbdy)                         ! alias for a_i structure of bdy number jbdy
579               bn_alias => bn_a_i                                          ! alias for a_i structure of nambdy_dta
580            ENDIF
581            IF( jfld == jp_bdyh_i ) THEN
582               cl3 = 'h_i'
583               bf_alias => bf(jp_bdyh_i,jbdy:jbdy)                         ! alias for h_i structure of bdy number jbdy
584               bn_alias => bn_h_i                                          ! alias for h_i structure of nambdy_dta
585            ENDIF
586            IF( jfld == jp_bdyh_s ) THEN
587               cl3 = 'h_s'
588               bf_alias => bf(jp_bdyh_s,jbdy:jbdy)                         ! alias for h_s structure of bdy number jbdy
589               bn_alias => bn_h_s                                          ! alias for h_s structure of nambdy_dta
590            ENDIF
591            IF( jfld == jp_bdyt_i ) THEN
592               cl3 = 't_i'
593               bf_alias => bf(jp_bdyt_i,jbdy:jbdy)                         ! alias for t_i structure of bdy number jbdy
594               bn_alias => bn_t_i                                          ! alias for t_i structure of nambdy_dta
595            ENDIF
596            IF( jfld == jp_bdyt_s ) THEN
597               cl3 = 't_s'
598               bf_alias => bf(jp_bdyt_s,jbdy:jbdy)                         ! alias for t_s structure of bdy number jbdy
599               bn_alias => bn_t_s                                          ! alias for t_s structure of nambdy_dta
600            ENDIF
601            IF( jfld == jp_bdytsu ) THEN
602               cl3 = 'tsu'
603               bf_alias => bf(jp_bdytsu,jbdy:jbdy)                         ! alias for tsu structure of bdy number jbdy
604               bn_alias => bn_tsu                                          ! alias for tsu structure of nambdy_dta
605            ENDIF
606            IF( jfld == jp_bdys_i ) THEN
607               cl3 = 's_i'
608               bf_alias => bf(jp_bdys_i,jbdy:jbdy)                         ! alias for s_i structure of bdy number jbdy
609               bn_alias => bn_s_i                                          ! alias for s_i structure of nambdy_dta
610            ENDIF
611            IF( jfld == jp_bdyaip ) THEN
612               cl3 = 'aip'
613               bf_alias => bf(jp_bdyaip,jbdy:jbdy)                         ! alias for aip structure of bdy number jbdy
614               bn_alias => bn_aip                                          ! alias for aip structure of nambdy_dta
615            ENDIF
616            IF( jfld == jp_bdyhip ) THEN
617               cl3 = 'hip'
618               bf_alias => bf(jp_bdyhip,jbdy:jbdy)                         ! alias for hip structure of bdy number jbdy
619               bn_alias => bn_hip                                          ! alias for hip structure of nambdy_dta
620            ENDIF
621            IF( jfld == jp_bdyhil ) THEN
622               cl3 = 'hil'
623               bf_alias => bf(jp_bdyhil,jbdy:jbdy)                         ! alias for hil structure of bdy number jbdy
624               bn_alias => bn_hil                                          ! alias for hil structure of nambdy_dta
625            ENDIF
626
627            IF( llneed .AND. iszdim > 0 ) THEN                             ! dta_bdy(jbdy)%xxx will be needed
628               !                                                           !   -> must be associated with an allocated target
629               ALLOCATE( bf_alias(1)%fnow( iszdim, 1, ipk ) )              ! allocate the target
630               !
631               IF( llread ) THEN                                           ! get data from NetCDF file
632                  CALL fld_fill( bf_alias, bn_alias, cn_dir, 'bdy_dta', cl3//' '//ctmp1, ctmp2 )   ! use namelist info
633                  IF( bf_alias(1)%ln_tint ) ALLOCATE( bf_alias(1)%fdta( iszdim, 1, ipk, 2 ) )
634                  bf_alias(1)%imap    => idx_bdy(jbdy)%nbmap(1:iszdim,igrd)   ! associate the mapping used for this bdy
635                  bf_alias(1)%igrd    = igrd                                  ! used only for vertical integration of 3D arrays
636                  bf_alias(1)%ibdy    = jbdy                                  !  "    "    "     "          "      "  "    "   
637                  bf_alias(1)%ltotvel = ln_full_vel                           ! T if u3d is full velocity
638                  bf_alias(1)%lzint   = ln_zinterp                            ! T if it requires a vertical interpolation
639               ENDIF
640
641               ! associate the pointer and get rid of the dimensions with a size equal to 1
642               IF( jfld == jp_bdyssh )        dta_bdy(jbdy)%ssh => bf_alias(1)%fnow(:,1,1)
643               IF( jfld == jp_bdyu2d )        dta_bdy(jbdy)%u2d => bf_alias(1)%fnow(:,1,1)
644               IF( jfld == jp_bdyv2d )        dta_bdy(jbdy)%v2d => bf_alias(1)%fnow(:,1,1)
645               IF( jfld == jp_bdyu3d )        dta_bdy(jbdy)%u3d => bf_alias(1)%fnow(:,1,:)
646               IF( jfld == jp_bdyv3d )        dta_bdy(jbdy)%v3d => bf_alias(1)%fnow(:,1,:)
647               IF( jfld == jp_bdytem )        dta_bdy(jbdy)%tem => bf_alias(1)%fnow(:,1,:)
648               IF( jfld == jp_bdysal )        dta_bdy(jbdy)%sal => bf_alias(1)%fnow(:,1,:)
649               IF( jfld == jp_bdya_i ) THEN
650                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%a_i => bf_alias(1)%fnow(:,1,:)
651                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%a_i(iszdim,jpl) )
652                  ENDIF
653               ENDIF
654               IF( jfld == jp_bdyh_i ) THEN
655                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%h_i => bf_alias(1)%fnow(:,1,:)
656                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%h_i(iszdim,jpl) )
657                  ENDIF
658               ENDIF
659               IF( jfld == jp_bdyh_s ) THEN
660                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%h_s => bf_alias(1)%fnow(:,1,:)
661                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%h_s(iszdim,jpl) )
662                  ENDIF
663               ENDIF
664               IF( jfld == jp_bdyt_i ) THEN
665                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%t_i => bf_alias(1)%fnow(:,1,:)
666                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%t_i(iszdim,jpl) )
667                  ENDIF
668               ENDIF
669               IF( jfld == jp_bdyt_s ) THEN
670                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%t_s => bf_alias(1)%fnow(:,1,:)
671                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%t_s(iszdim,jpl) )
672                  ENDIF
673               ENDIF
674               IF( jfld == jp_bdytsu ) THEN
675                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%tsu => bf_alias(1)%fnow(:,1,:)
676                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%tsu(iszdim,jpl) )
677                  ENDIF
678               ENDIF
679               IF( jfld == jp_bdys_i ) THEN
680                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%s_i => bf_alias(1)%fnow(:,1,:)
681                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%s_i(iszdim,jpl) )
682                  ENDIF
683               ENDIF
684               IF( jfld == jp_bdyaip ) THEN
685                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%aip => bf_alias(1)%fnow(:,1,:)
686                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%aip(iszdim,jpl) )
687                  ENDIF
688               ENDIF
689               IF( jfld == jp_bdyhip ) THEN
690                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%hip => bf_alias(1)%fnow(:,1,:)
691                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%hip(iszdim,jpl) )
692                  ENDIF
693               ENDIF
694               IF( jfld == jp_bdyhil ) THEN
695                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%hil => bf_alias(1)%fnow(:,1,:)
696                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%hil(iszdim,jpl) )
697                  ENDIF
698               ENDIF
699            ENDIF
700
701         END DO   ! jpbdyfld
702         !
703      END DO ! jbdy
704      !
705   END SUBROUTINE bdy_dta_init
706   
707   !!==============================================================================
708END MODULE bdydta
Note: See TracBrowser for help on using the repository browser.