New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
bdydta.F90 in NEMO/branches/2020/r4.0-HEAD_ticket2425/src/OCE/BDY – NEMO

source: NEMO/branches/2020/r4.0-HEAD_ticket2425/src/OCE/BDY/bdydta.F90 @ 13077

Last change on this file since 13077 was 13077, checked in by davestorkey, 4 years ago

branches/2020/r4.0-HEAD_ticket2425: update to r13076 of r4.0-HEAD

  • Property svn:keywords set to Id
File size: 40.6 KB
Line 
1MODULE bdydta
2   !!======================================================================
3   !!                       ***  MODULE bdydta  ***
4   !! Open boundary data : read the data for the unstructured open boundaries.
5   !!======================================================================
6   !! History :  1.0  !  2005-01  (J. Chanut, A. Sellar)  Original code
7   !!             -   !  2007-01  (D. Storkey) Update to use IOM module
8   !!             -   !  2007-07  (D. Storkey) add bdy_dta_fla
9   !!            3.0  !  2008-04  (NEMO team)  add in the reference version
10   !!            3.3  !  2010-09  (E.O'Dea) modifications for Shelf configurations
11   !!            3.3  !  2010-09  (D.Storkey) add ice boundary conditions
12   !!            3.4  !  2011     (D. Storkey) rewrite in preparation for OBC-BDY merge
13   !!            3.6  !  2012-01  (C. Rousset) add ice boundary conditions for sea ice
14   !!            4.0  !  2018     (C. Rousset) SI3 compatibility
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!    bdy_dta      : read external data along open boundaries from file
19   !!    bdy_dta_init : initialise arrays etc for reading of external data
20   !!----------------------------------------------------------------------
21   USE oce            ! ocean dynamics and tracers
22   USE dom_oce        ! ocean space and time domain
23   USE phycst         ! physical constants
24   USE sbcapr         ! atmospheric pressure forcing
25   USE sbctide        ! Tidal forcing or not
26   USE bdy_oce        ! ocean open boundary conditions 
27   USE bdytides       ! tidal forcing at boundaries
28#if defined key_si3
29   USE ice            ! sea-ice variables
30   USE icevar         ! redistribute ice input into categories
31#endif
32   !
33   USE lib_mpp, ONLY: ctl_stop, ctl_nam
34   USE fldread        ! read input fields
35   USE iom            ! IOM library
36   USE in_out_manager ! I/O logical units
37   USE timing         ! Timing
38
39   IMPLICIT NONE
40   PRIVATE
41
42   PUBLIC   bdy_dta          ! routine called by step.F90 and dynspg_ts.F90
43   PUBLIC   bdy_dta_init     ! routine called by nemogcm.F90
44
45   INTEGER , PARAMETER ::   jpbdyfld  = 16    ! maximum number of files to read
46   INTEGER , PARAMETER ::   jp_bdyssh = 1     !
47   INTEGER , PARAMETER ::   jp_bdyu2d = 2     !
48   INTEGER , PARAMETER ::   jp_bdyv2d = 3     !
49   INTEGER , PARAMETER ::   jp_bdyu3d = 4     !
50   INTEGER , PARAMETER ::   jp_bdyv3d = 5     !
51   INTEGER , PARAMETER ::   jp_bdytem = 6     !
52   INTEGER , PARAMETER ::   jp_bdysal = 7     !
53   INTEGER , PARAMETER ::   jp_bdya_i = 8     !
54   INTEGER , PARAMETER ::   jp_bdyh_i = 9     !
55   INTEGER , PARAMETER ::   jp_bdyh_s = 10    !
56   INTEGER , PARAMETER ::   jp_bdyt_i = 11    !
57   INTEGER , PARAMETER ::   jp_bdyt_s = 12    !
58   INTEGER , PARAMETER ::   jp_bdytsu = 13    !
59   INTEGER , PARAMETER ::   jp_bdys_i = 14    !
60   INTEGER , PARAMETER ::   jp_bdyaip = 15    !
61   INTEGER , PARAMETER ::   jp_bdyhip = 16    !
62#if ! defined key_si3
63   INTEGER , PARAMETER ::   jpl = 1
64#endif
65
66!$AGRIF_DO_NOT_TREAT
67   TYPE(FLD), PUBLIC, ALLOCATABLE, DIMENSION(:,:), TARGET ::   bf   ! structure of input fields (file informations, fields read)
68!$AGRIF_END_DO_NOT_TREAT
69
70   !!----------------------------------------------------------------------
71   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
72   !! $Id$
73   !! Software governed by the CeCILL license (see ./LICENSE)
74   !!----------------------------------------------------------------------
75CONTAINS
76
77   SUBROUTINE bdy_dta( kt, kit, kt_offset )
78      !!----------------------------------------------------------------------
79      !!                   ***  SUBROUTINE bdy_dta  ***
80      !!                   
81      !! ** Purpose :   Update external data for open boundary conditions
82      !!
83      !! ** Method  :   Use fldread.F90
84      !!               
85      !!----------------------------------------------------------------------
86      INTEGER, INTENT(in)           ::   kt           ! ocean time-step index
87      INTEGER, INTENT(in), OPTIONAL ::   kit          ! subcycle time-step index (for timesplitting option)
88      INTEGER, INTENT(in), OPTIONAL ::   kt_offset    ! time offset in units of timesteps. NB. if kit
89      !                                               ! is present then units = subcycle timesteps.
90      !                                               ! kt_offset = 0 => get data at "now" time level
91      !                                               ! kt_offset = -1 => get data at "before" time level
92      !                                               ! kt_offset = +1 => get data at "after" time level
93      !                                               ! etc.
94      !
95      INTEGER ::  jbdy, jfld, jstart, jend, ib, jl    ! dummy loop indices
96      INTEGER ::  ii, ij, ik, igrd, ipl               ! local integers
97      TYPE(OBC_DATA)         , POINTER ::   dta_alias        ! short cut
98      TYPE(FLD), DIMENSION(:), POINTER ::   bf_alias
99      !!---------------------------------------------------------------------------
100      !
101      IF( ln_timing )   CALL timing_start('bdy_dta')
102      !
103      ! Initialise data arrays once for all from initial conditions where required
104      !---------------------------------------------------------------------------
105      IF( kt == nit000 .AND. .NOT.PRESENT(kit) ) THEN
106
107         ! Calculate depth-mean currents
108         !-----------------------------
109
110         DO jbdy = 1, nb_bdy
111            !
112            IF( nn_dyn2d_dta(jbdy) == 0 ) THEN
113               IF( dta_bdy(jbdy)%lneed_ssh ) THEN
114                  igrd = 1
115                  DO ib = 1, idx_bdy(jbdy)%nblenrim(igrd)   ! ssh is allocated and used only on the rim
116                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
117                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
118                     dta_bdy(jbdy)%ssh(ib) = sshn(ii,ij) * tmask(ii,ij,1)         
119                  END DO
120               ENDIF
121               IF( ASSOCIATED(dta_bdy(jbdy)%u2d) ) THEN   ! no SIZE with a unassociated pointer. v2d and u2d can differ on subdomain
122                  igrd = 2
123                  DO ib = 1, SIZE(dta_bdy(jbdy)%u2d)      ! u2d is used either over the whole bdy or only on the rim
124                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
125                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
126                     dta_bdy(jbdy)%u2d(ib) = un_b(ii,ij) * umask(ii,ij,1)         
127                  END DO
128               ENDIF
129               IF( ASSOCIATED(dta_bdy(jbdy)%v2d) ) THEN   ! no SIZE with a unassociated pointer. v2d and u2d can differ on subdomain
130                  igrd = 3
131                  DO ib = 1, SIZE(dta_bdy(jbdy)%v2d)      ! v2d is used either over the whole bdy or only on the rim
132                     ii = idx_bdy(jbdy)%nbi(ib,igrd)
133                     ij = idx_bdy(jbdy)%nbj(ib,igrd)
134                     dta_bdy(jbdy)%v2d(ib) = vn_b(ii,ij) * vmask(ii,ij,1)         
135                  END DO
136               ENDIF
137            ENDIF
138            !
139            IF( nn_dyn3d_dta(jbdy) == 0 ) THEN
140               IF( dta_bdy(jbdy)%lneed_dyn3d ) THEN
141                  igrd = 2 
142                  DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
143                     DO ik = 1, jpkm1
144                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
145                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
146                        dta_bdy(jbdy)%u3d(ib,ik) =  ( un(ii,ij,ik) - un_b(ii,ij) ) * umask(ii,ij,ik)         
147                     END DO
148                  END DO
149                  igrd = 3 
150                  DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
151                     DO ik = 1, jpkm1
152                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
153                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
154                        dta_bdy(jbdy)%v3d(ib,ik) =  ( vn(ii,ij,ik) - vn_b(ii,ij) ) * vmask(ii,ij,ik)         
155                     END DO
156                  END DO
157               ENDIF
158            ENDIF
159
160            IF( nn_tra_dta(jbdy) == 0 ) THEN
161               IF( dta_bdy(jbdy)%lneed_tra ) THEN
162                  igrd = 1 
163                  DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
164                     DO ik = 1, jpkm1
165                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
166                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
167                        dta_bdy(jbdy)%tem(ib,ik) = tsn(ii,ij,ik,jp_tem) * tmask(ii,ij,ik)         
168                        dta_bdy(jbdy)%sal(ib,ik) = tsn(ii,ij,ik,jp_sal) * tmask(ii,ij,ik)         
169                     END DO
170                  END DO
171               ENDIF
172            ENDIF
173
174#if defined key_si3
175            IF( nn_ice_dta(jbdy) == 0 ) THEN    ! set ice to initial values
176               IF( dta_bdy(jbdy)%lneed_ice ) THEN
177                  igrd = 1   
178                  DO jl = 1, jpl
179                     DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
180                        ii = idx_bdy(jbdy)%nbi(ib,igrd)
181                        ij = idx_bdy(jbdy)%nbj(ib,igrd)
182                        dta_bdy(jbdy)%a_i(ib,jl) =  a_i (ii,ij,jl) * tmask(ii,ij,1) 
183                        dta_bdy(jbdy)%h_i(ib,jl) =  h_i (ii,ij,jl) * tmask(ii,ij,1) 
184                        dta_bdy(jbdy)%h_s(ib,jl) =  h_s (ii,ij,jl) * tmask(ii,ij,1) 
185                        dta_bdy(jbdy)%t_i(ib,jl) =  SUM(t_i (ii,ij,:,jl)) * r1_nlay_i * tmask(ii,ij,1) 
186                        dta_bdy(jbdy)%t_s(ib,jl) =  SUM(t_s (ii,ij,:,jl)) * r1_nlay_s * tmask(ii,ij,1)
187                        dta_bdy(jbdy)%tsu(ib,jl) =  t_su(ii,ij,jl) * tmask(ii,ij,1) 
188                        dta_bdy(jbdy)%s_i(ib,jl) =  s_i (ii,ij,jl) * tmask(ii,ij,1)
189                        ! melt ponds
190                        dta_bdy(jbdy)%aip(ib,jl) =  a_ip(ii,ij,jl) * tmask(ii,ij,1) 
191                        dta_bdy(jbdy)%hip(ib,jl) =  h_ip(ii,ij,jl) * tmask(ii,ij,1) 
192                     END DO
193                  END DO
194               ENDIF
195            ENDIF
196#endif
197         END DO ! jbdy
198         !
199      ENDIF ! kt == nit000
200
201      ! update external data from files
202      !--------------------------------
203
204      DO jbdy = 1, nb_bdy
205
206         dta_alias => dta_bdy(jbdy)
207         bf_alias  => bf(:,jbdy)
208
209         ! read/update all bdy data
210         ! ------------------------
211         CALL fld_read( kt, 1, bf_alias, kit = kit, kt_offset = kt_offset )
212
213         ! apply some corrections in some specific cases...
214         ! --------------------------------------------------
215         !
216         ! if runoff condition: change river flow we read (in m3/s) into barotropic velocity (m/s)
217         IF( cn_tra(jbdy) == 'runoff' ) THEN   ! runoff
218            !
219            IF( ASSOCIATED(dta_bdy(jbdy)%u2d) ) THEN   ! no SIZE with a unassociated pointer. v2d and u2d can differ on subdomain
220               igrd = 2                         ! zonal flow (m3/s) to barotropic zonal velocity (m/s)
221               DO ib = 1, SIZE(dta_alias%u2d)   ! u2d is used either over the whole bdy or only on the rim
222                  ii   = idx_bdy(jbdy)%nbi(ib,igrd)
223                  ij   = idx_bdy(jbdy)%nbj(ib,igrd)
224                  dta_alias%u2d(ib) = dta_alias%u2d(ib) / ( e2u(ii,ij) * hu_0(ii,ij) )
225               END DO
226            ENDIF
227            IF( ASSOCIATED(dta_bdy(jbdy)%v2d) ) THEN   ! no SIZE with a unassociated pointer. v2d and u2d can differ on subdomain
228               igrd = 3                         ! meridional flow (m3/s) to barotropic meridional velocity (m/s)
229               DO ib = 1, SIZE(dta_alias%v2d)   ! v2d is used either over the whole bdy or only on the rim
230                  ii   = idx_bdy(jbdy)%nbi(ib,igrd)
231                  ij   = idx_bdy(jbdy)%nbj(ib,igrd)
232                  dta_alias%v2d(ib) = dta_alias%v2d(ib) / ( e1v(ii,ij) * hv_0(ii,ij) )
233               END DO
234            ENDIF
235         ENDIF
236
237         ! tidal harmonic forcing ONLY: initialise arrays
238         IF( nn_dyn2d_dta(jbdy) == 2 ) THEN   ! we did not read ssh, u/v2d
239            IF( ASSOCIATED(dta_alias%ssh) ) dta_alias%ssh(:) = 0._wp
240            IF( ASSOCIATED(dta_alias%u2d) ) dta_alias%u2d(:) = 0._wp
241            IF( ASSOCIATED(dta_alias%v2d) ) dta_alias%v2d(:) = 0._wp
242         ENDIF
243
244         ! If full velocities in boundary data, then split it into barotropic and baroclinic component
245         IF( bf_alias(jp_bdyu3d)%ltotvel ) THEN     ! if we read 3D total velocity (can be true only if u3d was read)
246            !
247            igrd = 2                       ! zonal velocity
248            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
249               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
250               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
251               dta_alias%u2d(ib) = 0._wp   ! compute barotrope zonal velocity and put it in u2d
252               DO ik = 1, jpkm1
253                  dta_alias%u2d(ib) = dta_alias%u2d(ib) + e3u_n(ii,ij,ik) * umask(ii,ij,ik) * dta_alias%u3d(ib,ik)
254               END DO
255               dta_alias%u2d(ib) =  dta_alias%u2d(ib) * r1_hu_n(ii,ij)
256               DO ik = 1, jpkm1            ! compute barocline zonal velocity and put it in u3d
257                  dta_alias%u3d(ib,ik) = dta_alias%u3d(ib,ik) - dta_alias%u2d(ib)
258               END DO
259            END DO
260            igrd = 3                       ! meridional velocity
261            DO ib = 1, idx_bdy(jbdy)%nblen(igrd)
262               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
263               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
264               dta_alias%v2d(ib) = 0._wp   ! compute barotrope meridional velocity and put it in v2d
265               DO ik = 1, jpkm1
266                  dta_alias%v2d(ib) = dta_alias%v2d(ib) + e3v_n(ii,ij,ik) * vmask(ii,ij,ik) * dta_alias%v3d(ib,ik)
267               END DO
268               dta_alias%v2d(ib) =  dta_alias%v2d(ib) * r1_hv_n(ii,ij)
269               DO ik = 1, jpkm1            ! compute barocline meridional velocity and put it in v3d
270                  dta_alias%v3d(ib,ik) = dta_alias%v3d(ib,ik) - dta_alias%v2d(ib)
271               END DO
272            END DO
273         ENDIF   ! ltotvel
274
275         ! update tidal harmonic forcing
276         IF( PRESENT(kit) .AND. nn_dyn2d_dta(jbdy) .GE. 2 ) THEN
277            CALL bdytide_update( kt = kt, idx = idx_bdy(jbdy), dta = dta_alias, td = tides(jbdy),   & 
278               &                 kit = kit, kt_offset = kt_offset )
279         ENDIF
280
281         !  atm surface pressure : add inverted barometer effect to ssh if it was read
282         IF ( ln_apr_obc .AND. TRIM(bf_alias(jp_bdyssh)%clrootname) /= 'NOT USED' ) THEN
283            igrd = 1
284            DO ib = 1, idx_bdy(jbdy)%nblenrim(igrd)   ! ssh is used only on the rim
285               ii   = idx_bdy(jbdy)%nbi(ib,igrd)
286               ij   = idx_bdy(jbdy)%nbj(ib,igrd)
287               dta_alias%ssh(ib) = dta_alias%ssh(ib) + ssh_ib(ii,ij)
288            END DO
289         ENDIF
290
291#if defined key_si3
292         IF( dta_alias%lneed_ice .AND. idx_bdy(jbdy)%nblen(1) > 0 ) THEN
293            ! fill temperature and salinity arrays
294            IF( TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyt_i)%fnow(:,1,:) = rice_tem (jbdy)
295            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyt_s)%fnow(:,1,:) = rice_tem (jbdy)
296            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) == 'NOT USED' )   bf_alias(jp_bdytsu)%fnow(:,1,:) = rice_tem (jbdy)
297            IF( TRIM(bf_alias(jp_bdys_i)%clrootname) == 'NOT USED' )   bf_alias(jp_bdys_i)%fnow(:,1,:) = rice_sal (jbdy)
298            IF( TRIM(bf_alias(jp_bdyaip)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyaip)%fnow(:,1,:) = rice_apnd(jbdy) * & ! rice_apnd is the pond fraction
299               &                                                                         bf_alias(jp_bdya_i)%fnow(:,1,:)     !   ( a_ip = rice_apnd * a_i )
300            IF( TRIM(bf_alias(jp_bdyhip)%clrootname) == 'NOT USED' )   bf_alias(jp_bdyhip)%fnow(:,1,:) = rice_hpnd(jbdy)
301
302            ! if T_i is read and not T_su, set T_su = T_i
303            IF( TRIM(bf_alias(jp_bdyt_i)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdytsu)%clrootname) == 'NOT USED' ) &
304               &   bf_alias(jp_bdytsu)%fnow(:,1,:) = bf_alias(jp_bdyt_i)%fnow(:,1,:)
305            ! if T_s is read and not T_su, set T_su = T_s
306            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdytsu)%clrootname) == 'NOT USED' ) &
307               &   bf_alias(jp_bdytsu)%fnow(:,1,:) = bf_alias(jp_bdyt_s)%fnow(:,1,:)
308            ! if T_i is read and not T_s, set T_s = T_i
309            IF( TRIM(bf_alias(jp_bdyt_i)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_s)%clrootname) == 'NOT USED' ) &
310               &   bf_alias(jp_bdyt_s)%fnow(:,1,:) = bf_alias(jp_bdyt_i)%fnow(:,1,:)
311            ! if T_su is read and not T_s, set T_s = T_su
312            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_s)%clrootname) == 'NOT USED' ) &
313               &   bf_alias(jp_bdyt_s)%fnow(:,1,:) = bf_alias(jp_bdytsu)%fnow(:,1,:)
314            ! if T_su is read and not T_i, set T_i = (T_su + T_freeze)/2
315            IF( TRIM(bf_alias(jp_bdytsu)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' ) &
316               &   bf_alias(jp_bdyt_i)%fnow(:,1,:) = 0.5_wp * ( bf_alias(jp_bdytsu)%fnow(:,1,:) + 271.15 )
317            ! if T_s is read and not T_i, set T_i = (T_s + T_freeze)/2
318            IF( TRIM(bf_alias(jp_bdyt_s)%clrootname) /= 'NOT USED' .AND. TRIM(bf_alias(jp_bdyt_i)%clrootname) == 'NOT USED' ) &
319               &   bf_alias(jp_bdyt_i)%fnow(:,1,:) = 0.5_wp * ( bf_alias(jp_bdyt_s)%fnow(:,1,:) + 271.15 )
320
321            ! make sure ponds = 0 if no ponds scheme
322            IF ( .NOT.ln_pnd ) THEN
323               bf_alias(jp_bdyaip)%fnow(:,1,:) = 0._wp
324               bf_alias(jp_bdyhip)%fnow(:,1,:) = 0._wp
325            ENDIF
326           
327            ! convert N-cat fields (input) into jpl-cat (output)
328            ipl = SIZE(bf_alias(jp_bdya_i)%fnow, 3)           
329            IF( ipl /= jpl ) THEN      ! ice: convert N-cat fields (input) into jpl-cat (output)
330               CALL ice_var_itd( bf_alias(jp_bdyh_i)%fnow(:,1,:), bf_alias(jp_bdyh_s)%fnow(:,1,:), bf_alias(jp_bdya_i)%fnow(:,1,:), &
331                  &              dta_alias%h_i                  , dta_alias%h_s                  , dta_alias%a_i                  , &
332                  &              bf_alias(jp_bdyt_i)%fnow(:,1,:), bf_alias(jp_bdyt_s)%fnow(:,1,:), &
333                  &              bf_alias(jp_bdytsu)%fnow(:,1,:), bf_alias(jp_bdys_i)%fnow(:,1,:), &
334                  &              bf_alias(jp_bdyaip)%fnow(:,1,:), bf_alias(jp_bdyhip)%fnow(:,1,:), &
335                  &              dta_alias%t_i                  , dta_alias%t_s                  , &
336                  &              dta_alias%tsu                  , dta_alias%s_i                  , &
337                  &              dta_alias%aip                  , dta_alias%hip )
338            ENDIF
339         ENDIF
340#endif
341      END DO  ! jbdy
342
343      IF ( ln_tide ) THEN
344         IF (ln_dynspg_ts) THEN      ! Fill temporary arrays with slow-varying bdy data                           
345            DO jbdy = 1, nb_bdy      ! Tidal component added in ts loop
346               IF ( nn_dyn2d_dta(jbdy) .GE. 2 ) THEN
347                  IF( ASSOCIATED(dta_bdy(jbdy)%ssh) ) dta_bdy_s(jbdy)%ssh(:) = dta_bdy(jbdy)%ssh(:)
348                  IF( ASSOCIATED(dta_bdy(jbdy)%u2d) ) dta_bdy_s(jbdy)%u2d(:) = dta_bdy(jbdy)%u2d(:)
349                  IF( ASSOCIATED(dta_bdy(jbdy)%v2d) ) dta_bdy_s(jbdy)%v2d(:) = dta_bdy(jbdy)%v2d(:)
350               ENDIF
351            END DO
352         ELSE ! Add tides if not split-explicit free surface else this is done in ts loop
353            !
354            CALL bdy_dta_tides( kt=kt, kt_offset=kt_offset )
355         ENDIF
356      ENDIF
357      !
358      IF( ln_timing )   CALL timing_stop('bdy_dta')
359      !
360   END SUBROUTINE bdy_dta
361   
362
363   SUBROUTINE bdy_dta_init
364      !!----------------------------------------------------------------------
365      !!                   ***  SUBROUTINE bdy_dta_init  ***
366      !!                   
367      !! ** Purpose :   Initialise arrays for reading of external data
368      !!                for open boundary conditions
369      !!
370      !! ** Method  :   
371      !!               
372      !!----------------------------------------------------------------------
373      INTEGER ::   jbdy, jfld    ! Local integers
374      INTEGER ::   ierror, ios     !
375      !
376      CHARACTER(len=3)                       ::   cl3           !
377      CHARACTER(len=100)                     ::   cn_dir        ! Root directory for location of data files
378      LOGICAL                                ::   ln_full_vel   ! =T => full velocities in 3D boundary data
379      !                                                         ! =F => baroclinic velocities in 3D boundary data
380      LOGICAL                                ::   ln_zinterp    ! =T => requires a vertical interpolation of the bdydta
381      REAL(wp)                               ::   rn_ice_tem, rn_ice_sal, rn_ice_age, rn_ice_apnd, rn_ice_hpnd 
382      INTEGER                                ::   ipk,ipl       !
383      INTEGER                                ::   idvar         ! variable ID
384      INTEGER                                ::   indims        ! number of dimensions of the variable
385      INTEGER                                ::   iszdim        ! number of dimensions of the variable
386      INTEGER, DIMENSION(4)                  ::   i4dimsz       ! size of variable dimensions
387      INTEGER                                ::   igrd          ! index for grid type (1,2,3 = T,U,V)
388      LOGICAL                                ::   lluld         ! is the variable using the unlimited dimension
389      LOGICAL                                ::   llneed        !
390      LOGICAL                                ::   llread        !
391      LOGICAL                                ::   llfullbdy     !
392      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_tem, bn_sal, bn_u3d, bn_v3d   ! must be an array to be used with fld_fill
393      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_ssh, bn_u2d, bn_v2d           ! informations about the fields to be read
394      TYPE(FLD_N), DIMENSION(1), TARGET  ::   bn_a_i, bn_h_i, bn_h_s, bn_t_i, bn_t_s, bn_tsu, bn_s_i, bn_aip, bn_hip       
395      TYPE(FLD_N), DIMENSION(:), POINTER ::   bn_alias                        ! must be an array to be used with fld_fill
396      TYPE(FLD  ), DIMENSION(:), POINTER ::   bf_alias
397      !
398      NAMELIST/nambdy_dta/ cn_dir, bn_tem, bn_sal, bn_u3d, bn_v3d, bn_ssh, bn_u2d, bn_v2d 
399      NAMELIST/nambdy_dta/ bn_a_i, bn_h_i, bn_h_s, bn_t_i, bn_t_s, bn_tsu, bn_s_i, bn_aip, bn_hip
400      NAMELIST/nambdy_dta/ rn_ice_tem, rn_ice_sal, rn_ice_age, rn_ice_apnd, rn_ice_hpnd
401      NAMELIST/nambdy_dta/ ln_full_vel, ln_zinterp
402      !!---------------------------------------------------------------------------
403      !
404      IF(lwp) WRITE(numout,*)
405      IF(lwp) WRITE(numout,*) 'bdy_dta_ini : initialization of data at the open boundaries'
406      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
407      IF(lwp) WRITE(numout,*) ''
408
409      ALLOCATE( bf(jpbdyfld,nb_bdy), STAT=ierror )
410      IF( ierror > 0 ) THEN   
411         CALL ctl_stop( 'bdy_dta: unable to allocate bf structure' )   ;   RETURN 
412      ENDIF
413      bf(:,:)%clrootname = 'NOT USED'   ! default definition used as a flag in fld_read to do nothing.
414      bf(:,:)%lzint      = .FALSE.      ! default definition
415      bf(:,:)%ltotvel    = .FALSE.      ! default definition
416 
417      ! Read namelists
418      ! --------------
419      REWIND(numnam_cfg)
420      DO jbdy = 1, nb_bdy
421
422         WRITE(ctmp1, '(a,i2)') 'BDY number ', jbdy
423         WRITE(ctmp2, '(a,i2)') 'block nambdy_dta number ', jbdy
424
425         ! There is only one nambdy_dta block in namelist_ref -> use it for each bdy so we do a rewind
426         REWIND(numnam_ref)
427         READ  ( numnam_ref, nambdy_dta, IOSTAT = ios, ERR = 901)
428901      IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy_dta in reference namelist' )
429
430         !   by-pass nambdy_dta reading if no input data used in this bdy   
431         IF(       ( dta_bdy(jbdy)%lneed_dyn2d .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1 )   &
432            & .OR. ( dta_bdy(jbdy)%lneed_dyn3d .AND.     nn_dyn3d_dta(jbdy)    == 1 )   &
433            & .OR. ( dta_bdy(jbdy)%lneed_tra   .AND.       nn_tra_dta(jbdy)    == 1 )   &
434            & .OR. ( dta_bdy(jbdy)%lneed_ice   .AND.       nn_ice_dta(jbdy)    == 1 )   )   THEN
435            ! WARNING: we don't do a rewind here, each bdy reads its own nambdy_dta block one after another
436            READ  ( numnam_cfg, nambdy_dta, IOSTAT = ios, ERR = 902 )
437902         IF( ios >  0 )   CALL ctl_nam ( ios , 'nambdy_dta in configuration namelist' )
438            IF(lwm) WRITE( numond, nambdy_dta )           
439         ENDIF
440
441         ! get the number of ice categories in bdy data file (use a_i information to do this)
442         ipl = jpl   ! default definition
443         IF( dta_bdy(jbdy)%lneed_ice ) THEN    ! if we need ice bdy data
444            IF( nn_ice_dta(jbdy) == 1 ) THEN   ! if we get ice bdy data from netcdf file
445               CALL fld_fill(  bf(jp_bdya_i,jbdy:jbdy), bn_a_i, cn_dir, 'bdy_dta', 'a_i'//' '//ctmp1, ctmp2 )   ! use namelist info
446               CALL fld_clopn( bf(jp_bdya_i,jbdy), nyear, nmonth, nday )   ! not a problem when we call it again after
447               idvar = iom_varid( bf(jp_bdya_i,jbdy)%num, bf(jp_bdya_i,jbdy)%clvar, kndims=indims, kdimsz=i4dimsz, lduld=lluld )
448               IF( indims == 4 .OR. ( indims == 3 .AND. .NOT. lluld ) ) THEN   ;   ipl = i4dimsz(3)   ! xylt or xyl
449               ELSE                                                            ;   ipl = 1            ! xy or xyt
450               ENDIF
451               bf(jp_bdya_i,jbdy)%clrootname = 'NOT USED'   ! reset to default value as this subdomain may not need to read this bdy
452            ENDIF
453         ENDIF
454
455#if defined key_si3
456         IF( .NOT.ln_pnd ) THEN
457            rn_ice_apnd = 0. ; rn_ice_hpnd = 0.
458            CALL ctl_warn( 'rn_ice_apnd & rn_ice_hpnd = 0 when no ponds' )
459         ENDIF
460#endif
461
462         ! temp, salt, age and ponds of incoming ice
463         rice_tem (jbdy) = rn_ice_tem
464         rice_sal (jbdy) = rn_ice_sal
465         rice_age (jbdy) = rn_ice_age
466         rice_apnd(jbdy) = rn_ice_apnd
467         rice_hpnd(jbdy) = rn_ice_hpnd
468         
469         
470         DO jfld = 1, jpbdyfld
471
472            ! =====================
473            !          ssh
474            ! =====================
475            IF( jfld == jp_bdyssh ) THEN
476               cl3 = 'ssh'
477               igrd = 1                                                    ! T point
478               ipk = 1                                                     ! surface data
479               llneed = dta_bdy(jbdy)%lneed_ssh                            ! dta_bdy(jbdy)%ssh will be needed
480               llread = MOD(nn_dyn2d_dta(jbdy),2) == 1                     ! get data from NetCDF file
481               bf_alias => bf(jp_bdyssh,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
482               bn_alias => bn_ssh                                          ! alias for ssh structure of nambdy_dta
483               iszdim = idx_bdy(jbdy)%nblenrim(igrd)                       ! length of this bdy on this MPI processus : used only on the rim
484            ENDIF
485            ! =====================
486            !         dyn2d
487            ! =====================
488            IF( jfld == jp_bdyu2d ) THEN
489               cl3 = 'u2d'
490               igrd = 2                                                    ! U point
491               ipk = 1                                                     ! surface data
492               llneed = dta_bdy(jbdy)%lneed_dyn2d                          ! dta_bdy(jbdy)%u2d will be needed
493               llread = .NOT. ln_full_vel .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1   ! don't get u2d from u3d and read NetCDF file
494               bf_alias => bf(jp_bdyu2d,jbdy:jbdy)                         ! alias for u2d structure of bdy number jbdy
495               bn_alias => bn_u2d                                          ! alias for u2d structure of nambdy_dta
496               llfullbdy = ln_full_vel .OR. cn_dyn2d(jbdy) == 'frs'        ! need u2d over the whole bdy or only over the rim?
497               IF( llfullbdy ) THEN  ;   iszdim = idx_bdy(jbdy)%nblen(igrd)
498               ELSE                  ;   iszdim = idx_bdy(jbdy)%nblenrim(igrd)
499               ENDIF
500            ENDIF
501            IF( jfld == jp_bdyv2d ) THEN
502               cl3 = 'v2d'
503               igrd = 3                                                    ! V point
504               ipk = 1                                                     ! surface data
505               llneed = dta_bdy(jbdy)%lneed_dyn2d                          ! dta_bdy(jbdy)%v2d will be needed
506               llread = .NOT. ln_full_vel .AND. MOD(nn_dyn2d_dta(jbdy),2) == 1   ! don't get v2d from v3d and read NetCDF file
507               bf_alias => bf(jp_bdyv2d,jbdy:jbdy)                         ! alias for v2d structure of bdy number jbdy
508               bn_alias => bn_v2d                                          ! alias for v2d structure of nambdy_dta
509               llfullbdy = ln_full_vel .OR. cn_dyn2d(jbdy) == 'frs'        ! need v2d over the whole bdy or only over the rim?
510               IF( llfullbdy ) THEN  ;   iszdim = idx_bdy(jbdy)%nblen(igrd)
511               ELSE                  ;   iszdim = idx_bdy(jbdy)%nblenrim(igrd)
512               ENDIF
513            ENDIF
514            ! =====================
515            !         dyn3d
516            ! =====================
517            IF( jfld == jp_bdyu3d ) THEN
518               cl3 = 'u3d'
519               igrd = 2                                                    ! U point
520               ipk = jpk                                                   ! 3d data
521               llneed = dta_bdy(jbdy)%lneed_dyn3d .OR.               &     ! dta_bdy(jbdy)%u3d will be needed
522                  &   ( dta_bdy(jbdy)%lneed_dyn2d .AND. ln_full_vel )      !   u3d needed to compute u2d
523               llread = nn_dyn3d_dta(jbdy) == 1                            ! get data from NetCDF file
524               bf_alias => bf(jp_bdyu3d,jbdy:jbdy)                         ! alias for u3d structure of bdy number jbdy
525               bn_alias => bn_u3d                                          ! alias for u3d structure of nambdy_dta
526               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
527           ENDIF
528            IF( jfld == jp_bdyv3d ) THEN
529               cl3 = 'v3d'
530               igrd = 3                                                    ! V point
531               ipk = jpk                                                   ! 3d data
532               llneed = dta_bdy(jbdy)%lneed_dyn3d .OR.               &     ! dta_bdy(jbdy)%v3d will be needed
533                  &   ( dta_bdy(jbdy)%lneed_dyn2d .AND. ln_full_vel )      !   v3d needed to compute v2d
534               llread = nn_dyn3d_dta(jbdy) == 1                            ! get data from NetCDF file
535               bf_alias => bf(jp_bdyv3d,jbdy:jbdy)                         ! alias for v3d structure of bdy number jbdy
536               bn_alias => bn_v3d                                          ! alias for v3d structure of nambdy_dta
537               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
538           ENDIF
539
540            ! =====================
541            !          tra
542            ! =====================
543            IF( jfld == jp_bdytem ) THEN
544               cl3 = 'tem'
545               igrd = 1                                                    ! T point
546               ipk = jpk                                                   ! 3d data
547               llneed = dta_bdy(jbdy)%lneed_tra                            ! dta_bdy(jbdy)%tem will be needed
548               llread = nn_tra_dta(jbdy) == 1                              ! get data from NetCDF file
549               bf_alias => bf(jp_bdytem,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
550               bn_alias => bn_tem                                          ! alias for ssh structure of nambdy_dta
551               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
552            ENDIF
553            IF( jfld == jp_bdysal ) THEN
554               cl3 = 'sal'
555               igrd = 1                                                    ! T point
556               ipk = jpk                                                   ! 3d data
557               llneed = dta_bdy(jbdy)%lneed_tra                            ! dta_bdy(jbdy)%sal will be needed
558               llread = nn_tra_dta(jbdy) == 1                              ! get data from NetCDF file
559               bf_alias => bf(jp_bdysal,jbdy:jbdy)                         ! alias for ssh structure of bdy number jbdy
560               bn_alias => bn_sal                                          ! alias for ssh structure of nambdy_dta
561               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
562            ENDIF
563
564            ! =====================
565            !          ice
566            ! =====================
567            IF(  jfld == jp_bdya_i .OR. jfld == jp_bdyh_i .OR. jfld == jp_bdyh_s .OR. &
568               & jfld == jp_bdyt_i .OR. jfld == jp_bdyt_s .OR. jfld == jp_bdytsu .OR. &
569               & jfld == jp_bdys_i .OR. jfld == jp_bdyaip .OR. jfld == jp_bdyhip      ) THEN
570               igrd = 1                                                    ! T point
571               ipk = ipl                                                   ! jpl-cat data
572               llneed = dta_bdy(jbdy)%lneed_ice                            ! ice will be needed
573               llread = nn_ice_dta(jbdy) == 1                              ! get data from NetCDF file
574               iszdim = idx_bdy(jbdy)%nblen(igrd)                          ! length of this bdy on this MPI processus
575            ENDIF
576            IF( jfld == jp_bdya_i ) THEN
577               cl3 = 'a_i'
578               bf_alias => bf(jp_bdya_i,jbdy:jbdy)                         ! alias for a_i structure of bdy number jbdy
579               bn_alias => bn_a_i                                          ! alias for a_i structure of nambdy_dta
580            ENDIF
581            IF( jfld == jp_bdyh_i ) THEN
582               cl3 = 'h_i'
583               bf_alias => bf(jp_bdyh_i,jbdy:jbdy)                         ! alias for h_i structure of bdy number jbdy
584               bn_alias => bn_h_i                                          ! alias for h_i structure of nambdy_dta
585            ENDIF
586            IF( jfld == jp_bdyh_s ) THEN
587               cl3 = 'h_s'
588               bf_alias => bf(jp_bdyh_s,jbdy:jbdy)                         ! alias for h_s structure of bdy number jbdy
589               bn_alias => bn_h_s                                          ! alias for h_s structure of nambdy_dta
590            ENDIF
591            IF( jfld == jp_bdyt_i ) THEN
592               cl3 = 't_i'
593               bf_alias => bf(jp_bdyt_i,jbdy:jbdy)                         ! alias for t_i structure of bdy number jbdy
594               bn_alias => bn_t_i                                          ! alias for t_i structure of nambdy_dta
595            ENDIF
596            IF( jfld == jp_bdyt_s ) THEN
597               cl3 = 't_s'
598               bf_alias => bf(jp_bdyt_s,jbdy:jbdy)                         ! alias for t_s structure of bdy number jbdy
599               bn_alias => bn_t_s                                          ! alias for t_s structure of nambdy_dta
600            ENDIF
601            IF( jfld == jp_bdytsu ) THEN
602               cl3 = 'tsu'
603               bf_alias => bf(jp_bdytsu,jbdy:jbdy)                         ! alias for tsu structure of bdy number jbdy
604               bn_alias => bn_tsu                                          ! alias for tsu structure of nambdy_dta
605            ENDIF
606            IF( jfld == jp_bdys_i ) THEN
607               cl3 = 's_i'
608               bf_alias => bf(jp_bdys_i,jbdy:jbdy)                         ! alias for s_i structure of bdy number jbdy
609               bn_alias => bn_s_i                                          ! alias for s_i structure of nambdy_dta
610            ENDIF
611            IF( jfld == jp_bdyaip ) THEN
612               cl3 = 'aip'
613               bf_alias => bf(jp_bdyaip,jbdy:jbdy)                         ! alias for aip structure of bdy number jbdy
614               bn_alias => bn_aip                                          ! alias for aip structure of nambdy_dta
615            ENDIF
616            IF( jfld == jp_bdyhip ) THEN
617               cl3 = 'hip'
618               bf_alias => bf(jp_bdyhip,jbdy:jbdy)                         ! alias for hip structure of bdy number jbdy
619               bn_alias => bn_hip                                          ! alias for hip structure of nambdy_dta
620            ENDIF
621
622            IF( llneed .AND. iszdim > 0 ) THEN                             ! dta_bdy(jbdy)%xxx will be needed
623               !                                                           !   -> must be associated with an allocated target
624               ALLOCATE( bf_alias(1)%fnow( iszdim, 1, ipk ) )              ! allocate the target
625               !
626               IF( llread ) THEN                                           ! get data from NetCDF file
627                  CALL fld_fill( bf_alias, bn_alias, cn_dir, 'bdy_dta', cl3//' '//ctmp1, ctmp2 )   ! use namelist info
628                  IF( bf_alias(1)%ln_tint ) ALLOCATE( bf_alias(1)%fdta( iszdim, 1, ipk, 2 ) )
629                  bf_alias(1)%imap    => idx_bdy(jbdy)%nbmap(1:iszdim,igrd)   ! associate the mapping used for this bdy
630                  bf_alias(1)%igrd    = igrd                                  ! used only for vertical integration of 3D arrays
631                  bf_alias(1)%ibdy    = jbdy                                  !  "    "    "     "          "      "  "    "   
632                  bf_alias(1)%ltotvel = ln_full_vel                           ! T if u3d is full velocity
633                  bf_alias(1)%lzint   = ln_zinterp                            ! T if it requires a vertical interpolation
634               ENDIF
635
636               ! associate the pointer and get rid of the dimensions with a size equal to 1
637               IF( jfld == jp_bdyssh )        dta_bdy(jbdy)%ssh => bf_alias(1)%fnow(:,1,1)
638               IF( jfld == jp_bdyu2d )        dta_bdy(jbdy)%u2d => bf_alias(1)%fnow(:,1,1)
639               IF( jfld == jp_bdyv2d )        dta_bdy(jbdy)%v2d => bf_alias(1)%fnow(:,1,1)
640               IF( jfld == jp_bdyu3d )        dta_bdy(jbdy)%u3d => bf_alias(1)%fnow(:,1,:)
641               IF( jfld == jp_bdyv3d )        dta_bdy(jbdy)%v3d => bf_alias(1)%fnow(:,1,:)
642               IF( jfld == jp_bdytem )        dta_bdy(jbdy)%tem => bf_alias(1)%fnow(:,1,:)
643               IF( jfld == jp_bdysal )        dta_bdy(jbdy)%sal => bf_alias(1)%fnow(:,1,:)
644               IF( jfld == jp_bdya_i ) THEN
645                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%a_i => bf_alias(1)%fnow(:,1,:)
646                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%a_i(iszdim,jpl) )
647                  ENDIF
648               ENDIF
649               IF( jfld == jp_bdyh_i ) THEN
650                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%h_i => bf_alias(1)%fnow(:,1,:)
651                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%h_i(iszdim,jpl) )
652                  ENDIF
653               ENDIF
654               IF( jfld == jp_bdyh_s ) THEN
655                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%h_s => bf_alias(1)%fnow(:,1,:)
656                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%h_s(iszdim,jpl) )
657                  ENDIF
658               ENDIF
659               IF( jfld == jp_bdyt_i ) THEN
660                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%t_i => bf_alias(1)%fnow(:,1,:)
661                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%t_i(iszdim,jpl) )
662                  ENDIF
663               ENDIF
664               IF( jfld == jp_bdyt_s ) THEN
665                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%t_s => bf_alias(1)%fnow(:,1,:)
666                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%t_s(iszdim,jpl) )
667                  ENDIF
668               ENDIF
669               IF( jfld == jp_bdytsu ) THEN
670                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%tsu => bf_alias(1)%fnow(:,1,:)
671                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%tsu(iszdim,jpl) )
672                  ENDIF
673               ENDIF
674               IF( jfld == jp_bdys_i ) THEN
675                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%s_i => bf_alias(1)%fnow(:,1,:)
676                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%s_i(iszdim,jpl) )
677                  ENDIF
678               ENDIF
679               IF( jfld == jp_bdyaip ) THEN
680                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%aip => bf_alias(1)%fnow(:,1,:)
681                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%aip(iszdim,jpl) )
682                  ENDIF
683               ENDIF
684               IF( jfld == jp_bdyhip ) THEN
685                  IF( ipk == jpl ) THEN   ;   dta_bdy(jbdy)%hip => bf_alias(1)%fnow(:,1,:)
686                  ELSE                    ;   ALLOCATE( dta_bdy(jbdy)%hip(iszdim,jpl) )
687                  ENDIF
688               ENDIF
689            ENDIF
690
691         END DO   ! jpbdyfld
692         !
693      END DO ! jbdy
694      !
695   END SUBROUTINE bdy_dta_init
696   
697   !!==============================================================================
698END MODULE bdydta
Note: See TracBrowser for help on using the repository browser.