source: NEMO/branches/2020/temporary_r4_trunk/src/ICE/icethd.F90 @ 13466

Last change on this file since 13466 was 13466, checked in by smasson, 7 months ago

r4_trunk: merge r4 13280:13310, see #2523

  • Property svn:keywords set to Id
File size: 35.2 KB
Line 
1MODULE icethd
2   !!======================================================================
3   !!                  ***  MODULE icethd   ***
4   !!   sea-ice : master routine for thermodynamics
5   !!======================================================================
6   !! History :  1.0  !  2000-01  (M.A. Morales Maqueda, H. Goosse, T. Fichefet) original code 1D
7   !!            4.0  !  2018     (many people)       SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_thd       : thermodynamics of sea ice
14   !!   ice_thd_init  : initialisation of sea-ice thermodynamics
15   !!----------------------------------------------------------------------
16   USE phycst         ! physical constants
17   USE dom_oce        ! ocean space and time domain variables
18   USE ice            ! sea-ice: variables
19!!gm list trop longue ==>>> why not passage en argument d'appel ?
20   USE sbc_oce , ONLY : sss_m, sst_m, e3t_m, utau, vtau, ssu_m, ssv_m, frq_m, qns_tot, qsr_tot, sprecip, ln_cpl
21   USE sbc_ice , ONLY : qsr_oce, qns_oce, qemp_oce, qsr_ice, qns_ice, dqns_ice, evap_ice, qprec_ice, qevap_ice, &
22      &                 qml_ice, qcn_ice, qtr_ice_top
23   USE ice1D          ! sea-ice: thermodynamics variables
24   USE icethd_zdf     ! sea-ice: vertical heat diffusion
25   USE icethd_dh      ! sea-ice: ice-snow growth and melt
26   USE icethd_da      ! sea-ice: lateral melting
27   USE icethd_sal     ! sea-ice: salinity
28   USE icethd_ent     ! sea-ice: enthalpy redistribution
29   USE icethd_do      ! sea-ice: growth in open water
30   USE icethd_pnd     ! sea-ice: melt ponds
31   USE iceitd         ! sea-ice: remapping thickness distribution
32   USE icetab         ! sea-ice: 1D <==> 2D transformation
33   USE icevar         ! sea-ice: operations
34   USE icectl         ! sea-ice: control print
35   !
36   USE in_out_manager ! I/O manager
37   USE iom            ! I/O manager library
38   USE lib_mpp        ! MPP library
39   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
40   USE lbclnk         ! lateral boundary conditions (or mpp links)
41   USE timing         ! Timing
42
43   IMPLICIT NONE
44   PRIVATE
45
46   PUBLIC   ice_thd         ! called by limstp module
47   PUBLIC   ice_thd_init    ! called by ice_init
48
49   !!** namelist (namthd) **
50   LOGICAL ::   ln_icedH         ! activate ice thickness change from growing/melting (T) or not (F)
51   LOGICAL ::   ln_icedA         ! activate lateral melting param. (T) or not (F)
52   LOGICAL ::   ln_icedO         ! activate ice growth in open-water (T) or not (F)
53   LOGICAL ::   ln_icedS         ! activate gravity drainage and flushing (T) or not (F)
54   LOGICAL ::   ln_leadhfx       !  heat in the leads is used to melt sea-ice before warming the ocean
55
56   !! for convergence tests
57   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   ztice_cvgerr, ztice_cvgstp
58
59   !! * Substitutions
60#  include "vectopt_loop_substitute.h90"
61   !!----------------------------------------------------------------------
62   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
63   !! $Id$
64   !! Software governed by the CeCILL license (see ./LICENSE)
65   !!----------------------------------------------------------------------
66CONTAINS
67
68   SUBROUTINE ice_thd( kt )
69      !!-------------------------------------------------------------------
70      !!                ***  ROUTINE ice_thd  ***       
71      !! 
72      !! ** Purpose : This routine manages ice thermodynamics
73      !!         
74      !! ** Action : - computation of oceanic sensible heat flux at the ice base
75      !!                              energy budget in the leads
76      !!                              net fluxes on top of ice and of ocean
77      !!             - selection of grid cells with ice
78      !!                - call ice_thd_zdf  for vertical heat diffusion
79      !!                - call ice_thd_dh   for vertical ice growth and melt
80      !!                - call ice_thd_pnd  for melt ponds
81      !!                - call ice_thd_ent  for enthalpy remapping
82      !!                - call ice_thd_sal  for ice desalination
83      !!                - call ice_thd_temp to  retrieve temperature from ice enthalpy
84      !!                - call ice_thd_mono for extra lateral ice melt if active virtual thickness distribution
85      !!                - call ice_thd_da   for lateral ice melt
86      !!             - back to the geographic grid
87      !!                - call ice_thd_rem  for remapping thickness distribution
88      !!                - call ice_thd_do   for ice growth in leads
89      !!-------------------------------------------------------------------
90      INTEGER, INTENT(in) :: kt    ! number of iteration
91      !
92      INTEGER  :: ji, jj, jk, jl   ! dummy loop indices
93      REAL(wp) :: zfric_u, zqld, zqfr, zqfr_neg
94      REAL(wp), PARAMETER :: zfric_umin = 0._wp           ! lower bound for the friction velocity (cice value=5.e-04)
95      REAL(wp), PARAMETER :: zch        = 0.0057_wp       ! heat transfer coefficient
96      REAL(wp), DIMENSION(jpi,jpj) ::   zu_io, zv_io, zfric   ! ice-ocean velocity (m/s) and frictional velocity (m2/s2)
97      !
98      !!-------------------------------------------------------------------
99      ! controls
100      IF( ln_timing    )   CALL timing_start('icethd')                                                             ! timing
101      IF( ln_icediachk )   CALL ice_cons_hsm(0, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation
102      IF( ln_icediachk )   CALL ice_cons2D  (0, 'icethd',  diag_v,  diag_s,  diag_t,  diag_fv,  diag_fs,  diag_ft) ! conservation
103
104      IF( kt == nit000 .AND. lwp ) THEN
105         WRITE(numout,*)
106         WRITE(numout,*) 'ice_thd: sea-ice thermodynamics'
107         WRITE(numout,*) '~~~~~~~'
108      ENDIF
109
110      ! convergence tests
111      IF( ln_zdf_chkcvg ) THEN
112         ALLOCATE( ztice_cvgerr(jpi,jpj,jpl) , ztice_cvgstp(jpi,jpj,jpl) )
113         ztice_cvgerr = 0._wp ; ztice_cvgstp = 0._wp
114      ENDIF
115     
116      !---------------------------------------------!
117      ! computation of friction velocity at T points
118      !---------------------------------------------!
119      IF( ln_icedyn ) THEN
120         zu_io(:,:) = u_ice(:,:) - ssu_m(:,:)
121         zv_io(:,:) = v_ice(:,:) - ssv_m(:,:)
122         DO jj = 2, jpjm1 
123            DO ji = fs_2, fs_jpim1
124               zfric(ji,jj) = rn_cio * ( 0.5_wp *  &
125                  &                    (  zu_io(ji,jj) * zu_io(ji,jj) + zu_io(ji-1,jj) * zu_io(ji-1,jj)   &
126                  &                     + zv_io(ji,jj) * zv_io(ji,jj) + zv_io(ji,jj-1) * zv_io(ji,jj-1) ) ) * tmask(ji,jj,1)
127            END DO
128         END DO
129      ELSE      !  if no ice dynamics => transmit directly the atmospheric stress to the ocean
130         DO jj = 2, jpjm1
131            DO ji = fs_2, fs_jpim1
132               zfric(ji,jj) = r1_rau0 * SQRT( 0.5_wp *  &
133                  &                         (  utau(ji,jj) * utau(ji,jj) + utau(ji-1,jj) * utau(ji-1,jj)   &
134                  &                          + vtau(ji,jj) * vtau(ji,jj) + vtau(ji,jj-1) * vtau(ji,jj-1) ) ) * tmask(ji,jj,1)
135            END DO
136         END DO
137      ENDIF
138      CALL lbc_lnk( 'icethd', zfric, 'T',  1. )
139      !
140      !--------------------------------------------------------------------!
141      ! Partial computation of forcing for the thermodynamic sea ice model
142      !--------------------------------------------------------------------!
143      DO jj = 1, jpj
144         DO ji = 1, jpi
145            rswitch  = tmask(ji,jj,1) * MAX( 0._wp , SIGN( 1._wp , at_i(ji,jj) - epsi10 ) ) ! 0 if no ice
146            !
147            !           !  solar irradiance transmission at the mixed layer bottom and used in the lead heat budget
148            !           !  practically no "direct lateral ablation"
149            !           
150            !           !  net downward heat flux from the ice to the ocean, expressed as a function of ocean
151            !           !  temperature and turbulent mixing (McPhee, 1992)
152            !
153            ! --- Energy received in the lead from atm-oce exchanges, zqld is defined everywhere (J.m-2) --- !
154            zqld =  tmask(ji,jj,1) * rdt_ice *  &
155               &    ( ( 1._wp - at_i_b(ji,jj) ) * qsr_oce(ji,jj) * frq_m(ji,jj) +  &
156               &      ( 1._wp - at_i_b(ji,jj) ) * qns_oce(ji,jj) + qemp_oce(ji,jj) )
157
158            ! --- Energy needed to bring ocean surface layer until its freezing (mostly<0 but >0 if supercooling, J.m-2) --- !
159            zqfr     = rau0 * rcp * e3t_m(ji,jj) * ( t_bo(ji,jj) - ( sst_m(ji,jj) + rt0 ) ) * tmask(ji,jj,1)  ! both < 0 (t_bo < sst) and > 0 (t_bo > sst)
160            zqfr_neg = MIN( zqfr , 0._wp )                                                                    ! only < 0
161
162            ! --- Sensible ocean-to-ice heat flux (mostly>0 but <0 if supercooling, W/m2)
163            zfric_u            = MAX( SQRT( zfric(ji,jj) ), zfric_umin ) 
164            qsb_ice_bot(ji,jj) = rswitch * rau0 * rcp * zch * zfric_u * ( ( sst_m(ji,jj) + rt0 ) - t_bo(ji,jj) ) ! W.m-2
165
166            qsb_ice_bot(ji,jj) = rswitch * MIN( qsb_ice_bot(ji,jj), - zqfr_neg * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) )
167            ! upper bound for qsb_ice_bot: the heat retrieved from the ocean must be smaller than the heat necessary to reach
168            !                              the freezing point, so that we do not have SST < T_freeze
169            !                              This implies: - ( qsb_ice_bot(ji,jj) * at_i(ji,jj) * rtdice ) - zqfr >= 0
170
171            !-- Energy Budget of the leads (J.m-2), source of ice growth in open water. Must be < 0 to form ice
172            qlead(ji,jj) = MIN( 0._wp , zqld - ( qsb_ice_bot(ji,jj) * at_i(ji,jj) * rdt_ice ) - zqfr )
173
174            ! If there is ice and leads are warming => transfer energy from the lead budget and use it for bottom melting
175            ! If the grid cell is fully covered by ice (no leads) => transfer energy from the lead budget to the ice bottom budget
176            IF( ( zqld >= 0._wp .AND. at_i(ji,jj) > 0._wp ) .OR. at_i(ji,jj) >= (1._wp - epsi10) ) THEN
177               IF( ln_leadhfx ) THEN   ;   fhld(ji,jj) = rswitch * zqld * r1_rdtice / MAX( at_i(ji,jj), epsi10 ) ! divided by at_i since this is (re)multiplied by a_i in icethd_dh.F90
178               ELSE                    ;   fhld(ji,jj) = 0._wp
179               ENDIF
180               qlead(ji,jj) = 0._wp
181            ELSE
182               fhld (ji,jj) = 0._wp
183            ENDIF
184            !
185            ! Net heat flux on top of the ice-ocean [W.m-2]
186            ! ---------------------------------------------
187            qt_atm_oi(ji,jj) = qns_tot(ji,jj) + qsr_tot(ji,jj) 
188         END DO
189      END DO
190     
191      ! In case we bypass open-water ice formation
192      IF( .NOT. ln_icedO )  qlead(:,:) = 0._wp
193      ! In case we bypass growing/melting from top and bottom
194      IF( .NOT. ln_icedH ) THEN
195         qsb_ice_bot(:,:) = 0._wp
196         fhld       (:,:) = 0._wp
197      ENDIF
198
199      ! ---------------------------------------------------------------------
200      ! Net heat flux on top of the ocean after ice thermo (1st step) [W.m-2]
201      ! ---------------------------------------------------------------------
202      !     First  step here              :  non solar + precip - qlead - qsensible
203      !     Second step in icethd_dh      :  heat remaining if total melt (zq_rema)
204      !     Third  step in iceupdate.F90  :  heat from ice-ocean mass exchange (zf_mass) + solar
205      qt_oce_ai(:,:) = ( 1._wp - at_i_b(:,:) ) * qns_oce(:,:) + qemp_oce(:,:)  &  ! Non solar heat flux received by the ocean               
206         &             - qlead(:,:) * r1_rdtice                                &  ! heat flux taken from the ocean where there is open water ice formation
207         &             - at_i (:,:) * qsb_ice_bot(:,:)                         &  ! heat flux taken by sensible flux
208         &             - at_i (:,:) * fhld       (:,:)                            ! heat flux taken during bottom growth/melt
209      !                                                                           !    (fhld should be 0 while bott growth)
210      !-------------------------------------------------------------------------------------------!
211      ! Thermodynamic computation (only on grid points covered by ice) => loop over ice categories
212      !-------------------------------------------------------------------------------------------!
213      DO jl = 1, jpl
214
215         ! select ice covered grid points
216         npti = 0 ; nptidx(:) = 0
217         DO jj = 1, jpj
218            DO ji = 1, jpi
219               IF ( a_i(ji,jj,jl) > epsi10 ) THEN     
220                  npti         = npti  + 1
221                  nptidx(npti) = (jj - 1) * jpi + ji
222               ENDIF
223            END DO
224         END DO
225
226         IF( npti > 0 ) THEN  ! If there is no ice, do nothing.
227            !                                                               
228                              CALL ice_thd_1d2d( jl, 1 )            ! --- Move to 1D arrays --- !
229            !                                                       ! --- & Change units of e_i, e_s from J/m2 to J/m3 --- !
230            !
231            s_i_new   (1:npti) = 0._wp ; dh_s_tot(1:npti) = 0._wp   ! --- some init --- !  (important to have them here)
232            dh_i_sum  (1:npti) = 0._wp ; dh_i_bom(1:npti) = 0._wp ; dh_i_itm  (1:npti) = 0._wp 
233            dh_i_sub  (1:npti) = 0._wp ; dh_i_bog(1:npti) = 0._wp
234            dh_snowice(1:npti) = 0._wp ; dh_s_mlt(1:npti) = 0._wp
235            !                                     
236                              CALL ice_thd_zdf                      ! --- Ice-Snow temperature --- !
237            !
238            IF( ln_icedH ) THEN                                     ! --- Growing/Melting --- !
239                              CALL ice_thd_dh                           ! Ice-Snow thickness   
240                              CALL ice_thd_pnd                          ! Melt ponds formation
241                              CALL ice_thd_ent( e_i_1d(1:npti,:) )      ! Ice enthalpy remapping
242            ENDIF
243                              CALL ice_thd_sal( ln_icedS )          ! --- Ice salinity --- !   
244            !
245                              CALL ice_thd_temp                     ! --- Temperature update --- !
246            !
247            IF( ln_icedH .AND. ln_virtual_itd ) &
248               &              CALL ice_thd_mono                     ! --- Extra lateral melting if virtual_itd --- !
249            !
250            IF( ln_icedA )    CALL ice_thd_da                       ! --- Lateral melting --- !
251            !
252                              CALL ice_thd_1d2d( jl, 2 )            ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
253            !                                                       ! --- & Move to 2D arrays --- !
254         ENDIF
255         !
256      END DO
257      !
258      IF( ln_icediachk )   CALL ice_cons_hsm(1, 'icethd', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft)
259      IF( ln_icediachk )   CALL ice_cons2D  (1, 'icethd',  diag_v,  diag_s,  diag_t,  diag_fv,  diag_fs,  diag_ft)
260      !                   
261      IF( jpl > 1  )          CALL ice_itd_rem( kt )                ! --- Transport ice between thickness categories --- !
262      !
263      IF( ln_icedO )          CALL ice_thd_do                       ! --- Frazil ice growth in leads --- !
264      !
265      ! convergence tests
266      IF( ln_zdf_chkcvg ) THEN
267         CALL iom_put( 'tice_cvgerr', ztice_cvgerr ) ; DEALLOCATE( ztice_cvgerr )
268         CALL iom_put( 'tice_cvgstp', ztice_cvgstp ) ; DEALLOCATE( ztice_cvgstp )
269      ENDIF
270      !
271      ! controls
272      IF( ln_icectl )   CALL ice_prt    (kt, iiceprt, jiceprt, 1, ' - ice thermodyn. - ') ! prints
273      IF( ln_ctl    )   CALL ice_prt3D  ('icethd')                                        ! prints
274      IF( ln_timing )   CALL timing_stop('icethd')                                        ! timing
275      !
276   END SUBROUTINE ice_thd 
277
278 
279   SUBROUTINE ice_thd_temp
280      !!-----------------------------------------------------------------------
281      !!                   ***  ROUTINE ice_thd_temp ***
282      !!                 
283      !! ** Purpose :   Computes sea ice temperature (Kelvin) from enthalpy
284      !!
285      !! ** Method  :   Formula (Bitz and Lipscomb, 1999)
286      !!-------------------------------------------------------------------
287      INTEGER  ::   ji, jk   ! dummy loop indices
288      REAL(wp) ::   ztmelts, zbbb, zccc  ! local scalar
289      !!-------------------------------------------------------------------
290      ! Recover ice temperature
291      DO jk = 1, nlay_i
292         DO ji = 1, npti
293            ztmelts       = -rTmlt * sz_i_1d(ji,jk)
294            ! Conversion q(S,T) -> T (second order equation)
295            zbbb          = ( rcp - rcpi ) * ztmelts + e_i_1d(ji,jk) * r1_rhoi - rLfus
296            zccc          = SQRT( MAX( zbbb * zbbb - 4._wp * rcpi * rLfus * ztmelts, 0._wp ) )
297            t_i_1d(ji,jk) = rt0 - ( zbbb + zccc ) * 0.5_wp * r1_rcpi
298           
299            ! mask temperature
300            rswitch       = 1._wp - MAX( 0._wp , SIGN( 1._wp , - h_i_1d(ji) ) ) 
301            t_i_1d(ji,jk) = rswitch * t_i_1d(ji,jk) + ( 1._wp - rswitch ) * rt0
302         END DO
303      END DO 
304      !
305   END SUBROUTINE ice_thd_temp
306
307
308   SUBROUTINE ice_thd_mono
309      !!-----------------------------------------------------------------------
310      !!                   ***  ROUTINE ice_thd_mono ***
311      !!                 
312      !! ** Purpose :   Lateral melting in case virtual_itd
313      !!                          ( dA = A/2h dh )
314      !!-----------------------------------------------------------------------
315      INTEGER  ::   ji                 ! dummy loop indices
316      REAL(wp) ::   zhi_bef            ! ice thickness before thermo
317      REAL(wp) ::   zdh_mel, zda_mel   ! net melting
318      REAL(wp) ::   zvi, zvs           ! ice/snow volumes
319      !!-----------------------------------------------------------------------
320      !
321      DO ji = 1, npti
322         zdh_mel = MIN( 0._wp, dh_i_itm(ji) + dh_i_sum(ji) + dh_i_bom(ji) + dh_snowice(ji) + dh_i_sub(ji) )
323         IF( zdh_mel < 0._wp .AND. a_i_1d(ji) > 0._wp )  THEN
324            zvi          = a_i_1d(ji) * h_i_1d(ji)
325            zvs          = a_i_1d(ji) * h_s_1d(ji)
326            ! lateral melting = concentration change
327            zhi_bef     = h_i_1d(ji) - zdh_mel
328            rswitch     = MAX( 0._wp , SIGN( 1._wp , zhi_bef - epsi20 ) )
329            zda_mel     = rswitch * a_i_1d(ji) * zdh_mel / ( 2._wp * MAX( zhi_bef, epsi20 ) )
330            a_i_1d(ji)  = MAX( epsi20, a_i_1d(ji) + zda_mel ) 
331            ! adjust thickness
332            h_i_1d(ji) = zvi / a_i_1d(ji)           
333            h_s_1d(ji) = zvs / a_i_1d(ji)           
334            ! retrieve total concentration
335            at_i_1d(ji) = a_i_1d(ji)
336         END IF
337      END DO
338      !
339   END SUBROUTINE ice_thd_mono
340
341
342   SUBROUTINE ice_thd_1d2d( kl, kn )
343      !!-----------------------------------------------------------------------
344      !!                   ***  ROUTINE ice_thd_1d2d ***
345      !!                 
346      !! ** Purpose :   move arrays from 1d to 2d and the reverse
347      !!-----------------------------------------------------------------------
348      INTEGER, INTENT(in) ::   kl   ! index of the ice category
349      INTEGER, INTENT(in) ::   kn   ! 1= from 2D to 1D   ;   2= from 1D to 2D
350      !
351      INTEGER ::   jk   ! dummy loop indices
352      !!-----------------------------------------------------------------------
353      !
354      SELECT CASE( kn )
355      !                    !---------------------!
356      CASE( 1 )            !==  from 2D to 1D  ==!
357         !                 !---------------------!
358         CALL tab_2d_1d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
359         CALL tab_2d_1d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
360         CALL tab_2d_1d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
361         CALL tab_2d_1d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
362         CALL tab_2d_1d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
363         CALL tab_2d_1d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
364         DO jk = 1, nlay_s
365            CALL tab_2d_1d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
366            CALL tab_2d_1d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
367         END DO
368         DO jk = 1, nlay_i
369            CALL tab_2d_1d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
370            CALL tab_2d_1d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
371            CALL tab_2d_1d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
372         END DO
373         CALL tab_2d_1d( npti, nptidx(1:npti), a_ip_1d     (1:npti), a_ip     (:,:,kl) )
374         CALL tab_2d_1d( npti, nptidx(1:npti), h_ip_1d     (1:npti), h_ip     (:,:,kl) )
375         CALL tab_2d_1d( npti, nptidx(1:npti), h_il_1d     (1:npti), h_il     (:,:,kl) )
376         !
377         CALL tab_2d_1d( npti, nptidx(1:npti), qprec_ice_1d  (1:npti), qprec_ice            )
378         CALL tab_2d_1d( npti, nptidx(1:npti), qsr_ice_1d    (1:npti), qsr_ice (:,:,kl)     )
379         CALL tab_2d_1d( npti, nptidx(1:npti), qns_ice_1d    (1:npti), qns_ice (:,:,kl)     )
380         CALL tab_2d_1d( npti, nptidx(1:npti), evap_ice_1d   (1:npti), evap_ice(:,:,kl)     )
381         CALL tab_2d_1d( npti, nptidx(1:npti), dqns_ice_1d   (1:npti), dqns_ice(:,:,kl)     )
382         CALL tab_2d_1d( npti, nptidx(1:npti), t_bo_1d       (1:npti), t_bo                 )
383         CALL tab_2d_1d( npti, nptidx(1:npti), sprecip_1d    (1:npti), sprecip              ) 
384         CALL tab_2d_1d( npti, nptidx(1:npti), qsb_ice_bot_1d(1:npti), qsb_ice_bot          )
385         CALL tab_2d_1d( npti, nptidx(1:npti), fhld_1d       (1:npti), fhld                 )
386         
387         CALL tab_2d_1d( npti, nptidx(1:npti), qml_ice_1d    (1:npti), qml_ice    (:,:,kl) )
388         CALL tab_2d_1d( npti, nptidx(1:npti), qcn_ice_1d    (1:npti), qcn_ice    (:,:,kl) )
389         CALL tab_2d_1d( npti, nptidx(1:npti), qtr_ice_top_1d(1:npti), qtr_ice_top(:,:,kl) )
390         !
391         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni   )
392         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum   )
393         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub       )
394         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub   )
395         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub   )
396         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub   )
397         !
398         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog          )
399         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom          )
400         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum          )
401         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni          )
402         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res          )
403         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr          )
404         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam          )
405         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd          )
406         !
407         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog          )
408         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom          )
409         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum          )
410         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni          )
411         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri          )
412         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res          )
413         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub          )
414         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam          )
415         !
416         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_thd_1d    (1:npti), hfx_thd       )
417         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_spr_1d    (1:npti), hfx_spr       )
418         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sum_1d    (1:npti), hfx_sum       )
419         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bom_1d    (1:npti), hfx_bom       )
420         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_bog_1d    (1:npti), hfx_bog       )
421         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_dif_1d    (1:npti), hfx_dif       )
422         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_opw_1d    (1:npti), hfx_opw       )
423         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_snw_1d    (1:npti), hfx_snw       )
424         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_sub_1d    (1:npti), hfx_sub       )
425         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_res_1d    (1:npti), hfx_res       )
426         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif   )
427         CALL tab_2d_1d( npti, nptidx(1:npti), qt_oce_ai_1d  (1:npti), qt_oce_ai     )
428         !
429         ! ocean surface fields
430         CALL tab_2d_1d( npti, nptidx(1:npti), sst_1d(1:npti), sst_m )
431         CALL tab_2d_1d( npti, nptidx(1:npti), sss_1d(1:npti), sss_m )
432         !
433         ! to update ice age
434         CALL tab_2d_1d( npti, nptidx(1:npti), o_i_1d (1:npti), o_i (:,:,kl) )
435         CALL tab_2d_1d( npti, nptidx(1:npti), oa_i_1d(1:npti), oa_i(:,:,kl) )
436         !
437         ! --- Change units of e_i, e_s from J/m2 to J/m3 --- !
438         DO jk = 1, nlay_i
439            WHERE( h_i_1d(1:npti)>0._wp ) e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) / (h_i_1d(1:npti) * a_i_1d(1:npti)) * nlay_i
440         END DO
441         DO jk = 1, nlay_s
442            WHERE( h_s_1d(1:npti)>0._wp ) e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) / (h_s_1d(1:npti) * a_i_1d(1:npti)) * nlay_s
443         END DO
444         !
445         !                 !---------------------!
446      CASE( 2 )            !==  from 1D to 2D  ==!
447         !                 !---------------------!
448         ! --- Change units of e_i, e_s from J/m3 to J/m2 --- !
449         DO jk = 1, nlay_i
450            e_i_1d(1:npti,jk) = e_i_1d(1:npti,jk) * h_i_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_i
451         END DO
452         DO jk = 1, nlay_s
453            e_s_1d(1:npti,jk) = e_s_1d(1:npti,jk) * h_s_1d(1:npti) * a_i_1d(1:npti) * r1_nlay_s
454         END DO
455         !
456         ! Change thickness to volume (replaces routine ice_var_eqv2glo)
457         v_i_1d (1:npti) = h_i_1d (1:npti) * a_i_1d (1:npti)
458         v_s_1d (1:npti) = h_s_1d (1:npti) * a_i_1d (1:npti)
459         sv_i_1d(1:npti) = s_i_1d (1:npti) * v_i_1d (1:npti)
460         v_ip_1d(1:npti) = h_ip_1d(1:npti) * a_ip_1d(1:npti)
461         v_il_1d(1:npti) = h_il_1d(1:npti) * a_ip_1d(1:npti)
462         oa_i_1d(1:npti) = o_i_1d (1:npti) * a_i_1d (1:npti)
463         
464         CALL tab_1d_2d( npti, nptidx(1:npti), at_i_1d(1:npti), at_i             )
465         CALL tab_1d_2d( npti, nptidx(1:npti), a_i_1d (1:npti), a_i (:,:,kl)     )
466         CALL tab_1d_2d( npti, nptidx(1:npti), h_i_1d (1:npti), h_i (:,:,kl)     )
467         CALL tab_1d_2d( npti, nptidx(1:npti), h_s_1d (1:npti), h_s (:,:,kl)     )
468         CALL tab_1d_2d( npti, nptidx(1:npti), t_su_1d(1:npti), t_su(:,:,kl)     )
469         CALL tab_1d_2d( npti, nptidx(1:npti), s_i_1d (1:npti), s_i (:,:,kl)     )
470         DO jk = 1, nlay_s
471            CALL tab_1d_2d( npti, nptidx(1:npti), t_s_1d(1:npti,jk), t_s(:,:,jk,kl)    )
472            CALL tab_1d_2d( npti, nptidx(1:npti), e_s_1d(1:npti,jk), e_s(:,:,jk,kl)    )
473         END DO
474         DO jk = 1, nlay_i
475            CALL tab_1d_2d( npti, nptidx(1:npti), t_i_1d (1:npti,jk), t_i (:,:,jk,kl)  )
476            CALL tab_1d_2d( npti, nptidx(1:npti), e_i_1d (1:npti,jk), e_i (:,:,jk,kl)  )
477            CALL tab_1d_2d( npti, nptidx(1:npti), sz_i_1d(1:npti,jk), sz_i(:,:,jk,kl)  )
478         END DO
479         CALL tab_1d_2d( npti, nptidx(1:npti), a_ip_1d     (1:npti), a_ip     (:,:,kl) )
480         CALL tab_1d_2d( npti, nptidx(1:npti), h_ip_1d     (1:npti), h_ip     (:,:,kl) )
481         CALL tab_1d_2d( npti, nptidx(1:npti), h_il_1d     (1:npti), h_il     (:,:,kl) )
482         !
483         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sni_1d(1:npti), wfx_snw_sni )
484         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sum_1d(1:npti), wfx_snw_sum )
485         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sub_1d    (1:npti), wfx_sub     )
486         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_snw_sub_1d(1:npti), wfx_snw_sub )
487         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_ice_sub_1d(1:npti), wfx_ice_sub )
488         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_err_sub_1d(1:npti), wfx_err_sub )
489         !
490         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bog_1d (1:npti), wfx_bog        )
491         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_bom_1d (1:npti), wfx_bom        )
492         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sum_1d (1:npti), wfx_sum        )
493         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_sni_1d (1:npti), wfx_sni        )
494         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_res_1d (1:npti), wfx_res        )
495         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_spr_1d (1:npti), wfx_spr        )
496         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_lam_1d (1:npti), wfx_lam        )
497         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_pnd_1d (1:npti), wfx_pnd        )
498         !
499         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bog_1d (1:npti), sfx_bog        )
500         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bom_1d (1:npti), sfx_bom        )
501         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sum_1d (1:npti), sfx_sum        )
502         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sni_1d (1:npti), sfx_sni        )
503         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_bri_1d (1:npti), sfx_bri        )
504         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_res_1d (1:npti), sfx_res        )
505         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_sub_1d (1:npti), sfx_sub        )
506         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_lam_1d (1:npti), sfx_lam        )
507         !
508         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_thd_1d    (1:npti), hfx_thd     )
509         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_spr_1d    (1:npti), hfx_spr     )
510         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sum_1d    (1:npti), hfx_sum     )
511         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bom_1d    (1:npti), hfx_bom     )
512         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_bog_1d    (1:npti), hfx_bog     )
513         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_dif_1d    (1:npti), hfx_dif     )
514         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_opw_1d    (1:npti), hfx_opw     )
515         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_snw_1d    (1:npti), hfx_snw     )
516         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_sub_1d    (1:npti), hfx_sub     )
517         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_res_1d    (1:npti), hfx_res     )
518         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_err_dif_1d(1:npti), hfx_err_dif )
519         CALL tab_1d_2d( npti, nptidx(1:npti), qt_oce_ai_1d  (1:npti), qt_oce_ai   )
520         !
521         CALL tab_1d_2d( npti, nptidx(1:npti), qns_ice_1d    (1:npti), qns_ice    (:,:,kl) )
522         CALL tab_1d_2d( npti, nptidx(1:npti), qtr_ice_bot_1d(1:npti), qtr_ice_bot(:,:,kl) )
523         ! effective conductivity and 1st layer temperature (ln_cndflx=T)
524         CALL tab_1d_2d( npti, nptidx(1:npti), cnd_ice_1d(1:npti), cnd_ice(:,:,kl) )
525         CALL tab_1d_2d( npti, nptidx(1:npti), t1_ice_1d (1:npti), t1_ice (:,:,kl) )
526         ! SIMIP diagnostics         
527         CALL tab_1d_2d( npti, nptidx(1:npti), t_si_1d       (1:npti), t_si       (:,:,kl) )
528         CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_bot_1d(1:npti), qcn_ice_bot(:,:,kl) )
529         CALL tab_1d_2d( npti, nptidx(1:npti), qcn_ice_top_1d(1:npti), qcn_ice_top(:,:,kl) )
530         ! extensive variables
531         CALL tab_1d_2d( npti, nptidx(1:npti), v_i_1d (1:npti), v_i (:,:,kl) )
532         CALL tab_1d_2d( npti, nptidx(1:npti), v_s_1d (1:npti), v_s (:,:,kl) )
533         CALL tab_1d_2d( npti, nptidx(1:npti), sv_i_1d(1:npti), sv_i(:,:,kl) )
534         CALL tab_1d_2d( npti, nptidx(1:npti), v_ip_1d(1:npti), v_ip(:,:,kl) )
535         CALL tab_1d_2d( npti, nptidx(1:npti), v_il_1d(1:npti), v_il(:,:,kl) )
536         CALL tab_1d_2d( npti, nptidx(1:npti), oa_i_1d(1:npti), oa_i(:,:,kl) )
537         ! check convergence of heat diffusion scheme
538         IF( ln_zdf_chkcvg ) THEN
539            CALL tab_1d_2d( npti, nptidx(1:npti), tice_cvgerr_1d(1:npti), ztice_cvgerr(:,:,kl) )
540            CALL tab_1d_2d( npti, nptidx(1:npti), tice_cvgstp_1d(1:npti), ztice_cvgstp(:,:,kl) )
541         ENDIF
542         !
543      END SELECT
544      !
545   END SUBROUTINE ice_thd_1d2d
546
547
548   SUBROUTINE ice_thd_init
549      !!-------------------------------------------------------------------
550      !!                   ***  ROUTINE ice_thd_init ***
551      !!                 
552      !! ** Purpose :   Physical constants and parameters associated with
553      !!                ice thermodynamics
554      !!
555      !! ** Method  :   Read the namthd namelist and check the parameters
556      !!                called at the first timestep (nit000)
557      !!
558      !! ** input   :   Namelist namthd
559      !!-------------------------------------------------------------------
560      INTEGER  ::   ios   ! Local integer output status for namelist read
561      !!
562      NAMELIST/namthd/ ln_icedH, ln_icedA, ln_icedO, ln_icedS, ln_leadhfx
563      !!-------------------------------------------------------------------
564      !
565      REWIND( numnam_ice_ref )              ! Namelist namthd in reference namelist : Ice thermodynamics
566      READ  ( numnam_ice_ref, namthd, IOSTAT = ios, ERR = 901)
567901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namthd in reference namelist' )
568      REWIND( numnam_ice_cfg )              ! Namelist namthd in configuration namelist : Ice thermodynamics
569      READ  ( numnam_ice_cfg, namthd, IOSTAT = ios, ERR = 902 )
570902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namthd in configuration namelist' )
571      IF(lwm) WRITE( numoni, namthd )
572      !
573      IF(lwp) THEN                          ! control print
574         WRITE(numout,*)
575         WRITE(numout,*) 'ice_thd_init: Ice Thermodynamics'
576         WRITE(numout,*) '~~~~~~~~~~~~'
577         WRITE(numout,*) '   Namelist namthd:'
578         WRITE(numout,*) '      activate ice thick change from top/bot (T) or not (F)                ln_icedH   = ', ln_icedH
579         WRITE(numout,*) '      activate lateral melting (T) or not (F)                              ln_icedA   = ', ln_icedA
580         WRITE(numout,*) '      activate ice growth in open-water (T) or not (F)                     ln_icedO   = ', ln_icedO
581         WRITE(numout,*) '      activate gravity drainage and flushing (T) or not (F)                ln_icedS   = ', ln_icedS
582         WRITE(numout,*) '      heat in the leads is used to melt sea-ice before warming the ocean   ln_leadhfx = ', ln_leadhfx
583     ENDIF
584      !
585                       CALL ice_thd_zdf_init   ! set ice heat diffusion parameters
586      IF( ln_icedA )   CALL ice_thd_da_init    ! set ice lateral melting parameters
587      IF( ln_icedO )   CALL ice_thd_do_init    ! set ice growth in open water parameters
588                       CALL ice_thd_sal_init   ! set ice salinity parameters
589                       CALL ice_thd_pnd_init   ! set melt ponds parameters
590      !
591   END SUBROUTINE ice_thd_init
592
593#else
594   !!----------------------------------------------------------------------
595   !!   Default option         Dummy module          NO  SI3 sea-ice model
596   !!----------------------------------------------------------------------
597#endif
598
599   !!======================================================================
600END MODULE icethd
Note: See TracBrowser for help on using the repository browser.