New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcfwb.F90 in NEMO/branches/2020/ticket2377/src/OCE/SBC – NEMO

source: NEMO/branches/2020/ticket2377/src/OCE/SBC/sbcfwb.F90 @ 12602

Last change on this file since 12602 was 12602, checked in by smueller, 4 years ago

Addition of XIOS-based restart I/O to the restart capability of option 2 of the freshwater-budget adjustment mechanism (ticket #2377)

This changeset extends the standard restart capability added in r12591 by adding optional XIOS-based restart I/O according to the recipe provided in section 10.2.1 of the reference manual for NEMO version 4.0.1.

  • Property svn:keywords set to Id
File size: 13.4 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!            3.6  ! 2014-11  (P. Mathiot  ) add ice shelf melting
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_fwb       : freshwater budget for global ocean configurations (free surface & forced mode)
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers
17   USE dom_oce        ! ocean space and time domain
18   USE sbc_oce        ! surface ocean boundary condition
19   USE isf_oce , ONLY : fwfisf_cav, fwfisf_par                    ! ice shelf melting contribution
20   USE sbc_ice , ONLY : snwice_mass, snwice_mass_b, snwice_fmass
21   USE phycst         ! physical constants
22   USE sbcrnf         ! ocean runoffs
23   USE sbcssr         ! Sea-Surface damping terms
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            ! IOM
27   USE lib_mpp        ! distribued memory computing library
28   USE timing         ! Timing
29   USE lbclnk         ! ocean lateral boundary conditions
30   USE lib_fortran    !
31
32   IMPLICIT NONE
33   PRIVATE
34
35   PUBLIC   sbc_fwb    ! routine called by step
36
37   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget
38   REAL(wp) ::   a_fwb     ! for 2 year before (_b) and before year.
39   REAL(wp) ::   fwfold    ! fwfold to be suppressed
40   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
41
42   !!----------------------------------------------------------------------
43   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
44   !! $Id$
45   !! Software governed by the CeCILL license (see ./LICENSE)
46   !!----------------------------------------------------------------------
47CONTAINS
48
49   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc, Kmm )
50      !!---------------------------------------------------------------------
51      !!                  ***  ROUTINE sbc_fwb  ***
52      !!
53      !! ** Purpose :   Control the mean sea surface drift
54      !!
55      !! ** Method  :   several ways  depending on kn_fwb
56      !!                =0 no control
57      !!                =1 global mean of emp set to zero at each nn_fsbc time step
58      !!                =2 annual global mean corrected from previous year
59      !!                =3 global mean of emp set to zero at each nn_fsbc time step
60      !!                   & spread out over erp area depending its sign
61      !! Note: if sea ice is embedded it is taken into account when computing the budget
62      !!----------------------------------------------------------------------
63      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
64      INTEGER, INTENT( in ) ::   kn_fsbc  !
65      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
66      INTEGER, INTENT( in ) ::   Kmm      ! ocean time level index
67      !
68      INTEGER  ::   inum, ikty, iyear     ! local integers
69      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp                ! local scalars
70      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread, zcoef          !   -      -
71      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces
72      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_tospread, zerp_cor    !   -      -
73      REAL(wp)   ,DIMENSION(1) ::   z_fwfprv 
74      COMPLEX(wp),DIMENSION(1) ::   y_fwfnow 
75      !!----------------------------------------------------------------------
76      !
77      IF( kt == nit000 ) THEN
78         IF(lwp) THEN
79            WRITE(numout,*)
80            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
81            WRITE(numout,*) '~~~~~~~'
82            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
83            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
84            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
85         ENDIF
86         !
87         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
88         IF( kn_fwb == 3 .AND. ln_isfcav    )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' )
89         !
90         area = glob_sum( 'sbcfwb', e1e2t(:,:) * tmask(:,:,1))           ! interior global domain surface
91         ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes
92         ! and in case of no melt, it can generate HSSW.
93         !
94#if ! defined key_si3 && ! defined key_cice
95         snwice_mass_b(:,:) = 0.e0               ! no sea-ice model is being used : no snow+ice mass
96         snwice_mass  (:,:) = 0.e0
97#endif
98         !
99      ENDIF
100
101      SELECT CASE ( kn_fwb )
102      !
103      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
104         !
105         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
106            y_fwfnow(1) = local_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) ) )
107            CALL mpp_delay_sum( 'sbcfwb', 'fwb', y_fwfnow(:), z_fwfprv(:), kt == nitend - nn_fsbc + 1 )
108            z_fwfprv(1) = z_fwfprv(1) / area
109            zcoef = z_fwfprv(1) * rcp
110            emp(:,:) = emp(:,:) - z_fwfprv(1)        * tmask(:,:,1)
111            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
112         ENDIF
113         !
114      CASE ( 2 )                             !==  fwf budget adjusted from the previous year  ==!
115         !
116         IF( kt == nit000 ) THEN                      ! initialisation
117            !                                         ! Read the corrective factor on precipitations (fwfold)
118            IF ( ln_rstart .AND. iom_varid( numror, 'a_fwb_b', ldstop = .FALSE. ) > 0     &
119               &           .AND. iom_varid( numror, 'a_fwb',   ldstop = .FALSE. ) > 0 ) THEN
120               IF(lwp) WRITE(numout,*) 'sbc_fwb : reading FW-budget adjustment from restart file'
121               CALL iom_get( numror, 'a_fwb_b', a_fwb_b, ldxios = lrxios )
122               CALL iom_get( numror, 'a_fwb',   a_fwb,   ldxios = lrxios )
123            ELSE
124               CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
125               READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
126               CLOSE( inum )
127            END IF
128            fwfold = a_fwb                            ! current year freshwater budget correction
129            !                                         ! estimate from the previous year budget
130            IF(lwp)WRITE(numout,*)
131            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
132            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
133            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
134            !
135            IF( lwxios ) THEN                         ! Activate output of restart variables
136               CALL iom_set_rstw_var_active( 'a_fwb_b' )
137               CALL iom_set_rstw_var_active( 'a_fwb'   )
138            END IF
139         ENDIF   
140         !                                         ! Update fwfold if new year start
141         ikty = 365 * 86400 / rn_Dt                  !!bug  use of 365 days leap year or 360d year !!!!!!!
142         IF( MOD( kt, ikty ) == 0 ) THEN
143            a_fwb_b = a_fwb                           ! mean sea level taking into account the ice+snow
144                                                      ! sum over the global domain
145            a_fwb   = glob_sum( 'sbcfwb', e1e2t(:,:) * ( ssh(:,:,Kmm) + snwice_mass(:,:) * r1_rho0 ) )
146            a_fwb   = a_fwb * 1.e+3 / ( area * rday * 365. )     ! convert in Kg/m3/s = mm/s
147!!gm        !                                                      !!bug 365d year
148            fwfold =  a_fwb                           ! current year freshwater budget correction
149            !                                         ! estimate from the previous year budget
150         ENDIF
151         !
152         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN         ! correct the freshwater fluxes
153            zcoef = fwfold * rcp
154            emp(:,:) = emp(:,:) + fwfold             * tmask(:,:,1)
155            qns(:,:) = qns(:,:) - zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
156         ENDIF
157         ! Output restart information
158         IF( lrst_oce ) THEN
159            IF(lwp) WRITE(numout,*)
160            IF(lwp) WRITE(numout,*) 'sbc_fwb : writing FW-budget adjustment to ocean restart file at it = ', kt
161            IF(lwp) WRITE(numout,*) '~~~~'
162            IF( lwxios ) CALL iom_swap( cwxios_context )
163            CALL iom_rstput( kt, nitrst, numrow, 'a_fwb_b', a_fwb_b, ldxios = lwxios )
164            CALL iom_rstput( kt, nitrst, numrow, 'a_fwb',   a_fwb,   ldxios = lwxios )
165            IF( lwxios ) CALL iom_swap( cxios_context  )
166         END IF
167         !
168         IF( kt == nitend .AND. lwm ) THEN            ! save fwfold value in a file (only one required)
169            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
170            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
171            CLOSE( inum )
172         ENDIF
173         !
174      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
175         !
176         ALLOCATE( ztmsk_neg(jpi,jpj) , ztmsk_pos(jpi,jpj) , ztmsk_tospread(jpi,jpj) , z_wgt(jpi,jpj) , zerp_cor(jpi,jpj) )
177         !
178         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
179            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
180            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
181            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
182            !                                                  ! fwf global mean (excluding ocean to ice/snow exchanges)
183            z_fwf     = glob_sum( 'sbcfwb', e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf_cav(:,:) + fwfisf_par(:,:) - snwice_fmass(:,:) ) ) / area
184            !           
185            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
186               zsurf_pos = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_pos(:,:) )
187               zsurf_tospread      = zsurf_pos
188               ztmsk_tospread(:,:) = ztmsk_pos(:,:)
189            ELSE                             ! spread out over <0 erp area to increase precipitation
190               zsurf_neg = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_neg(:,:) )  ! Area filled by <0 and >0 erp
191               zsurf_tospread      = zsurf_neg
192               ztmsk_tospread(:,:) = ztmsk_neg(:,:)
193            ENDIF
194            !
195            zsum_fwf   = glob_sum( 'sbcfwb', e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
196!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
197            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
198            !                                                  ! weight to respect erp field 2D structure
199            zsum_erp   = glob_sum( 'sbcfwb', ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
200            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
201            !                                                  ! final correction term to apply
202            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
203            !
204!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
205            CALL lbc_lnk( 'sbcfwb', zerp_cor, 'T', 1. )
206            !
207            emp(:,:) = emp(:,:) + zerp_cor(:,:)
208            qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:)  ! account for change to the heat budget due to fw correction
209            erp(:,:) = erp(:,:) + zerp_cor(:,:)
210            !
211            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
212               IF( z_fwf < 0._wp ) THEN
213                  WRITE(numout,*)'   z_fwf < 0'
214                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
215               ELSE
216                  WRITE(numout,*)'   z_fwf >= 0'
217                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
218               ENDIF
219               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
220               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
221               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
222               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
223               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
224            ENDIF
225         ENDIF
226         DEALLOCATE( ztmsk_neg , ztmsk_pos , ztmsk_tospread , z_wgt , zerp_cor )
227         !
228      CASE DEFAULT                           !==  you should never be there  ==!
229         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
230         !
231      END SELECT
232      !
233   END SUBROUTINE sbc_fwb
234
235   !!======================================================================
236END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.