New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcfwb.F90 in NEMO/branches/2020/ticket2487/src/OCE/SBC – NEMO

source: NEMO/branches/2020/ticket2487/src/OCE/SBC/sbcfwb.F90 @ 13301

Last change on this file since 13301 was 13301, checked in by smueller, 4 years ago

Addition of warning output from model runs with sea ice, with active freshwater-budget adjustment, but without sea-level compensation for non-zero initial sea-ice/snow mass (see ticket #2487)
  • Property svn:keywords set to Id
File size: 12.3 KB
Line 
1MODULE sbcfwb
2   !!======================================================================
3   !!                       ***  MODULE  sbcfwb  ***
4   !! Ocean fluxes   : domain averaged freshwater budget
5   !!======================================================================
6   !! History :  OPA  ! 2001-02  (E. Durand)  Original code
7   !!   NEMO     1.0  ! 2002-06  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-08  (G. Madec)  Surface module
9   !!            3.2  ! 2009-07  (C. Talandier) emp mean s spread over erp area
10   !!            3.6  ! 2014-11  (P. Mathiot  ) add ice shelf melting
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_fwb       : freshwater budget for global ocean configurations (free surface & forced mode)
15   !!----------------------------------------------------------------------
16   USE oce            ! ocean dynamics and tracers
17   USE dom_oce        ! ocean space and time domain
18   USE sbc_oce        ! surface ocean boundary condition
19   USE sbc_ice , ONLY : snwice_mass, snwice_mass_b, snwice_fmass
20   USE phycst         ! physical constants
21   USE sbcrnf         ! ocean runoffs
22   USE sbcisf         ! ice shelf melting contribution
23   USE sbcssr         ! Sea-Surface damping terms
24   !
25   USE in_out_manager ! I/O manager
26   USE lib_mpp        ! distribued memory computing library
27   USE timing         ! Timing
28   USE lbclnk         ! ocean lateral boundary conditions
29   USE lib_fortran    !
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   sbc_fwb    ! routine called by step
35
36   REAL(wp) ::   a_fwb_b   ! annual domain averaged freshwater budget
37   REAL(wp) ::   a_fwb     ! for 2 year before (_b) and before year.
38   REAL(wp) ::   fwfold    ! fwfold to be suppressed
39   REAL(wp) ::   area      ! global mean ocean surface (interior domain)
40   REAL(wp) ::   area2     ! global ocean surface area (interior domain) incl. ice-shelf cavities
41
42   !! * Substitutions
43#  include "vectopt_loop_substitute.h90"
44   !!----------------------------------------------------------------------
45   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
46   !! $Id$
47   !! Software governed by the CeCILL license (see ./LICENSE)
48   !!----------------------------------------------------------------------
49CONTAINS
50
51   SUBROUTINE sbc_fwb( kt, kn_fwb, kn_fsbc )
52      !!---------------------------------------------------------------------
53      !!                  ***  ROUTINE sbc_fwb  ***
54      !!
55      !! ** Purpose :   Control the mean sea surface drift
56      !!
57      !! ** Method  :   several ways  depending on kn_fwb
58      !!                =0 no control
59      !!                =1 global mean of emp set to zero at each nn_fsbc time step
60      !!                =2 annual global mean corrected from previous year
61      !!                =3 global mean of emp set to zero at each nn_fsbc time step
62      !!                   & spread out over erp area depending its sign
63      !! Note: if sea ice is embedded it is taken into account when computing the budget
64      !!----------------------------------------------------------------------
65      INTEGER, INTENT( in ) ::   kt       ! ocean time-step index
66      INTEGER, INTENT( in ) ::   kn_fsbc  !
67      INTEGER, INTENT( in ) ::   kn_fwb   ! ocean time-step index
68      !
69      INTEGER  ::   inum, ikty, iyear     ! local integers
70      REAL(wp) ::   z_fwf, z_fwf_nsrf, zsum_fwf, zsum_erp                ! local scalars
71      REAL(wp) ::   zsurf_neg, zsurf_pos, zsurf_tospread, zcoef          !   -      -
72      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_neg, ztmsk_pos, z_wgt ! 2D workspaces
73      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   ztmsk_tospread, zerp_cor    !   -      -
74      REAL(wp)   ,DIMENSION(1) ::   z_fwfprv 
75      COMPLEX(wp),DIMENSION(1) ::   y_fwfnow 
76      !!----------------------------------------------------------------------
77      !
78      IF( kt == nit000 ) THEN
79         IF(lwp) THEN
80            WRITE(numout,*)
81            WRITE(numout,*) 'sbc_fwb : FreshWater Budget correction'
82            WRITE(numout,*) '~~~~~~~'
83            IF( kn_fwb == 1 )   WRITE(numout,*) '          instantaneously set to zero'
84            IF( kn_fwb == 2 )   WRITE(numout,*) '          adjusted from previous year budget'
85            IF( kn_fwb == 3 )   WRITE(numout,*) '          fwf set to zero and spread out over erp area'
86         ENDIF
87         !
88         IF( kn_fwb == 3 .AND. nn_sssr /= 2 )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 requires nn_sssr = 2, we stop ' )
89         IF( kn_fwb == 3 .AND. ln_isfcav    )   CALL ctl_stop( 'sbc_fwb: nn_fwb = 3 with ln_isfcav = .TRUE. not working, we stop ' )
90         IF( ( nn_ice > 0 ) .AND. .NOT. ln_ice_sladj ) THEN
91            CALL ctl_warn( 'sbc_fwb: no sea-level adjustment to compensate for initial sea-ice/snow mass', &
92               '         (ln_ice_sladj = .FALSE.)' )
93         END IF
94         !
95         area = glob_sum( 'sbcfwb', e1e2t(:,:) * tmask(:,:,1))           ! interior global domain surface
96         ! isf cavities are excluded because it can feedback to the melting with generation of inhibition of plumes
97         ! and in case of no melt, it can generate HSSW.
98         area2 = glob_sum( 'sbcfwb', e1e2t(:,:) )                        ! global interior-domain ocean surface incl. ice-shelf cavities
99         !
100#if ! defined key_si3 && ! defined key_cice
101         snwice_mass_b(:,:) = 0.e0               ! no sea-ice model is being used : no snow+ice mass
102         snwice_mass  (:,:) = 0.e0
103#endif
104         !
105      ENDIF
106
107      SELECT CASE ( kn_fwb )
108      !
109      CASE ( 1 )                             !==  global mean fwf set to zero  ==!
110         !
111         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
112            y_fwfnow(1) = local_sum( e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf(:,:) - snwice_fmass(:,:) ) )
113            CALL mpp_delay_sum( 'sbcfwb', 'fwb', y_fwfnow(:), z_fwfprv(:), kt == nitend - nn_fsbc + 1 )
114            z_fwfprv(1) = z_fwfprv(1) / area
115            zcoef = z_fwfprv(1) * rcp
116            emp(:,:) = emp(:,:) - z_fwfprv(1)        * tmask(:,:,1)
117            qns(:,:) = qns(:,:) + zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
118         ENDIF
119         !
120      CASE ( 2 )                             !==  fwf budget adjusted from the previous year  ==!
121         !
122         IF( kt == nit000 ) THEN                      ! initialisation
123            !                                         ! Read the corrective factor on precipitations (fwfold)
124            CALL ctl_opn( inum, 'EMPave_old.dat', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE. )
125            READ ( inum, "(24X,I8,2ES24.16)" ) iyear, a_fwb_b, a_fwb
126            CLOSE( inum )
127            fwfold = a_fwb                            ! current year freshwater budget correction
128            !                                         ! estimate from the previous year budget
129            IF(lwp)WRITE(numout,*)
130            IF(lwp)WRITE(numout,*)'sbc_fwb : year = ',iyear  , ' freshwater budget correction = ', fwfold
131            IF(lwp)WRITE(numout,*)'          year = ',iyear-1, ' freshwater budget read       = ', a_fwb
132            IF(lwp)WRITE(numout,*)'          year = ',iyear-2, ' freshwater budget read       = ', a_fwb_b
133         ELSEIF( ( nday_year == 1 ) .AND. ( nsec_day == NINT( 0.5_wp * rdt ) ) ) THEN   ! Update fwfold at the start of 1 January
134            a_fwb_b = a_fwb                           ! mean sea level taking into account the ice+snow
135                                                      ! sum over the global domain
136            a_fwb   = glob_sum( 'sbcfwb', e1e2t(:,:) * ( sshn(:,:) + snwice_mass(:,:) * r1_rau0 ) )
137            a_fwb   = a_fwb * rau0 / ( area2 * rday * nyear_len(1) )   ! convert in kg/m3/s
138            fwfold =  a_fwb                           ! current year freshwater budget correction
139            !                                         ! estimate from the previous year budget
140         ENDIF
141         !
142         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN         ! correct the freshwater fluxes
143            zcoef = fwfold * rcp
144            emp(:,:) = emp(:,:) + fwfold             * tmask(:,:,1)
145            qns(:,:) = qns(:,:) - zcoef * sst_m(:,:) * tmask(:,:,1) ! account for change to the heat budget due to fw correction
146         ENDIF
147         !
148         IF( kt == nitend .AND. lwm ) THEN            ! save fwfold value in a file (only one required)
149            CALL ctl_opn( inum, 'EMPave.dat', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, numout, .FALSE., narea )
150            WRITE( inum, "(24X,I8,2ES24.16)" ) nyear, a_fwb_b, a_fwb
151            CLOSE( inum )
152         ENDIF
153         !
154      CASE ( 3 )                             !==  global fwf set to zero and spread out over erp area  ==!
155         !
156         ALLOCATE( ztmsk_neg(jpi,jpj) , ztmsk_pos(jpi,jpj) , ztmsk_tospread(jpi,jpj) , z_wgt(jpi,jpj) , zerp_cor(jpi,jpj) )
157         !
158         IF( MOD( kt-1, kn_fsbc ) == 0 ) THEN
159            ztmsk_pos(:,:) = tmask_i(:,:)                      ! Select <0 and >0 area of erp
160            WHERE( erp < 0._wp )   ztmsk_pos = 0._wp
161            ztmsk_neg(:,:) = tmask_i(:,:) - ztmsk_pos(:,:)
162            !                                                  ! fwf global mean (excluding ocean to ice/snow exchanges)
163            z_fwf     = glob_sum( 'sbcfwb', e1e2t(:,:) * ( emp(:,:) - rnf(:,:) + fwfisf(:,:) - snwice_fmass(:,:) ) ) / area
164            !           
165            IF( z_fwf < 0._wp ) THEN         ! spread out over >0 erp area to increase evaporation
166               zsurf_pos = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_pos(:,:) )
167               zsurf_tospread      = zsurf_pos
168               ztmsk_tospread(:,:) = ztmsk_pos(:,:)
169            ELSE                             ! spread out over <0 erp area to increase precipitation
170               zsurf_neg = glob_sum( 'sbcfwb', e1e2t(:,:)*ztmsk_neg(:,:) )  ! Area filled by <0 and >0 erp
171               zsurf_tospread      = zsurf_neg
172               ztmsk_tospread(:,:) = ztmsk_neg(:,:)
173            ENDIF
174            !
175            zsum_fwf   = glob_sum( 'sbcfwb', e1e2t(:,:) * z_fwf )         ! fwf global mean over <0 or >0 erp area
176!!gm :  zsum_fwf   = z_fwf * area   ???  it is right?  I think so....
177            z_fwf_nsrf =  zsum_fwf / ( zsurf_tospread + rsmall )
178            !                                                  ! weight to respect erp field 2D structure
179            zsum_erp   = glob_sum( 'sbcfwb', ztmsk_tospread(:,:) * erp(:,:) * e1e2t(:,:) )
180            z_wgt(:,:) = ztmsk_tospread(:,:) * erp(:,:) / ( zsum_erp + rsmall )
181            !                                                  ! final correction term to apply
182            zerp_cor(:,:) = -1. * z_fwf_nsrf * zsurf_tospread * z_wgt(:,:)
183            !
184!!gm   ===>>>>  lbc_lnk should be useless as all the computation is done over the whole domain !
185            CALL lbc_lnk( 'sbcfwb', zerp_cor, 'T', 1. )
186            !
187            emp(:,:) = emp(:,:) + zerp_cor(:,:)
188            qns(:,:) = qns(:,:) - zerp_cor(:,:) * rcp * sst_m(:,:)  ! account for change to the heat budget due to fw correction
189            erp(:,:) = erp(:,:) + zerp_cor(:,:)
190            !
191            IF( nprint == 1 .AND. lwp ) THEN                   ! control print
192               IF( z_fwf < 0._wp ) THEN
193                  WRITE(numout,*)'   z_fwf < 0'
194                  WRITE(numout,*)'   SUM(erp+)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
195               ELSE
196                  WRITE(numout,*)'   z_fwf >= 0'
197                  WRITE(numout,*)'   SUM(erp-)     = ', SUM( ztmsk_tospread(:,:)*erp(:,:)*e1e2t(:,:) )*1.e-9,' Sv'
198               ENDIF
199               WRITE(numout,*)'   SUM(empG)     = ', SUM( z_fwf*e1e2t(:,:) )*1.e-9,' Sv'
200               WRITE(numout,*)'   z_fwf         = ', z_fwf      ,' Kg/m2/s'
201               WRITE(numout,*)'   z_fwf_nsrf    = ', z_fwf_nsrf ,' Kg/m2/s'
202               WRITE(numout,*)'   MIN(zerp_cor) = ', MINVAL(zerp_cor) 
203               WRITE(numout,*)'   MAX(zerp_cor) = ', MAXVAL(zerp_cor) 
204            ENDIF
205         ENDIF
206         DEALLOCATE( ztmsk_neg , ztmsk_pos , ztmsk_tospread , z_wgt , zerp_cor )
207         !
208      CASE DEFAULT                           !==  you should never be there  ==!
209         CALL ctl_stop( 'sbc_fwb : wrong nn_fwb value for the FreshWater Budget correction, choose either 1, 2 or 3' )
210         !
211      END SELECT
212      !
213   END SUBROUTINE sbc_fwb
214
215   !!======================================================================
216END MODULE sbcfwb
Note: See TracBrowser for help on using the repository browser.