source: NEMO/branches/UKMO/2018_NEMO4_beta_mirror_10037_Benchmark/src/OCE/ICB/icbrst.F90 @ 10280

Last change on this file since 10280 was 10280, checked in by andmirek, 2 years ago

GMED 425 merge dev_r9950_GO8_package

File size: 21.2 KB
Line 
1MODULE icbrst
2   !!======================================================================
3   !!                       ***  MODULE  icbrst  ***
4   !! Ocean physics:  read and write iceberg restart files
5   !!======================================================================
6   !! History : 3.3.1 !  2010-01  (Martin&Adcroft) Original code
7   !!            -    !  2011-03  (Madec)          Part conversion to NEMO form
8   !!            -    !                            Removal of mapping from another grid
9   !!            -    !  2011-04  (Alderson)       Split into separate modules
10   !!            -    !  2011-04  (Alderson)       Restore restart routine
11   !!            -    !                            Currently needs a fixed processor
12   !!            -    !                            layout between restarts
13   !!            -    !  2015-11  Dave Storkey     Convert icb_rst_read to use IOM so can
14   !!                                              read single restart files
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   icb_rst_read    : read restart file
19   !!   icb_rst_write   : write restart file
20   !!----------------------------------------------------------------------
21   USE par_oce        ! NEMO parameters
22   USE dom_oce        ! NEMO domain
23   USE in_out_manager ! NEMO IO routines
24   USE lib_mpp        ! NEMO MPI library, lk_mpp in particular
25   USE netcdf         ! netcdf routines for IO
26   USE iom
27   USE ioipsl, ONLY : ju2ymds    ! for calendar
28   USE icb_oce        ! define iceberg arrays
29   USE icbutl         ! iceberg utility routines
30
31   IMPLICIT NONE
32   PRIVATE
33
34   PUBLIC   icb_rst_read    ! routine called in icbini.F90 module
35   PUBLIC   icb_rst_write   ! routine called in icbstp.F90 module
36   
37   INTEGER ::   nlonid, nlatid, nxid, nyid, nuvelid, nvvelid
38   INTEGER ::   nmassid, nthicknessid, nwidthid, nlengthid
39   INTEGER ::   nyearid, ndayid
40   INTEGER ::   nscaling_id, nmass_of_bits_id, nheat_density_id, numberid
41   INTEGER ::   nsiceid, nsheatid, ncalvid, ncalvhid, nkountid
42   INTEGER ::   nret, ncid, nc_dim
43   
44   INTEGER,  DIMENSION(3)                  :: nstrt3, nlngth3
45
46   !!----------------------------------------------------------------------
47   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
48   !! $Id$
49   !! Software governed by the CeCILL licence     (./LICENSE)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE icb_rst_read()
54      !!----------------------------------------------------------------------
55      !!                 ***  SUBROUTINE icb_rst_read  ***
56      !!
57      !! ** Purpose :   read a iceberg restart file
58      !!      NB: for this version, we just read back in the restart for this processor
59      !!      so we cannot change the processor layout currently with iceberg code
60      !!----------------------------------------------------------------------
61      INTEGER                      ::   idim, ivar, iatt
62      INTEGER                      ::   jn, iunlim_dim, ibergs_in_file
63      INTEGER                      ::   ii,ij,iclass
64      REAL(wp), DIMENSION(nkounts) ::   zdata     
65      LOGICAL                      ::   ll_found_restart
66      CHARACTER(len=256)           ::   cl_path
67      CHARACTER(len=256)           ::   cl_filename
68      CHARACTER(len=NF90_MAX_NAME) ::   cl_dname
69      TYPE(iceberg)                ::   localberg ! NOT a pointer but an actual local variable
70      TYPE(point)                  ::   localpt   ! NOT a pointer but an actual local variable
71      !!----------------------------------------------------------------------
72
73      ! Find a restart file. Assume iceberg restarts in same directory as ocean restarts
74      ! and are called TRIM(cn_ocerst)//'_icebergs'
75      cl_path = TRIM(cn_ocerst_indir)
76      IF( cl_path(LEN_TRIM(cl_path):) /= '/' ) cl_path = TRIM(cl_path) // '/'
77      cl_filename = TRIM(cn_ocerst_in)//'_icebergs'
78      CALL iom_open( TRIM(cl_path)//cl_filename, ncid )
79
80      IF( iom_file(ncid)%iduld .GE. 0) THEN
81
82         ibergs_in_file = iom_file(ncid)%lenuld
83         DO jn = 1,ibergs_in_file
84
85            ! iom_get treats the unlimited dimension as time. Here the unlimited dimension
86            ! is the iceberg index, but we can still use the ktime keyword to get the iceberg we want.
87
88            CALL iom_get( ncid, 'xi'     ,localpt%xi  , ktime=jn )
89            CALL iom_get( ncid, 'yj'     ,localpt%yj  , ktime=jn )
90
91            ii = INT( localpt%xi + 0.5 )
92            ij = INT( localpt%yj + 0.5 )
93            ! Only proceed if this iceberg is on the local processor (excluding halos).
94            IF ( ii .GE. nldi+nimpp-1 .AND. ii .LE. nlei+nimpp-1 .AND. &
95           &     ij .GE. nldj+njmpp-1 .AND. ij .LE. nlej+njmpp-1 ) THEN           
96
97               CALL iom_get( ncid, jpdom_unknown, 'number'       , zdata(:) , ktime=jn, kstart=(/1/), kcount=(/nkounts/) )
98               localberg%number(:) = INT(zdata(:))
99               CALL iom_get( ncid, 'mass_scaling' , localberg%mass_scaling, ktime=jn )
100               CALL iom_get( ncid, 'lon'          , localpt%lon           , ktime=jn )
101               CALL iom_get( ncid, 'lat'          , localpt%lat           , ktime=jn )
102               CALL iom_get( ncid, 'uvel'         , localpt%uvel          , ktime=jn )
103               CALL iom_get( ncid, 'vvel'         , localpt%vvel          , ktime=jn )
104               CALL iom_get( ncid, 'mass'         , localpt%mass          , ktime=jn )
105               CALL iom_get( ncid, 'thickness'    , localpt%thickness     , ktime=jn )
106               CALL iom_get( ncid, 'width'        , localpt%width         , ktime=jn )
107               CALL iom_get( ncid, 'length'       , localpt%length        , ktime=jn )
108               CALL iom_get( ncid, 'year'         , zdata(1)              , ktime=jn )
109               localpt%year = INT(zdata(1))
110               CALL iom_get( ncid, 'day'          , localpt%day           , ktime=jn )
111               CALL iom_get( ncid, 'mass_of_bits' , localpt%mass_of_bits  , ktime=jn )
112               CALL iom_get( ncid, 'heat_density' , localpt%heat_density  , ktime=jn )
113               !
114               CALL icb_utl_add( localberg, localpt )
115               !
116            ENDIF
117            !
118         END DO
119         !
120      ELSE
121         ibergs_in_file = 0
122      ENDIF 
123
124      ! Gridded variables
125      CALL iom_get( ncid, jpdom_autoglo,    'calving'     , src_calving  )
126      CALL iom_get( ncid, jpdom_autoglo,    'calving_hflx', src_calving_hflx  )
127      CALL iom_get( ncid, jpdom_autoglo,    'stored_heat' , berg_grid%stored_heat  )
128      CALL iom_get( ncid, jpdom_autoglo_xy, 'stored_ice'  , berg_grid%stored_ice, kstart=(/1,1,1/), kcount=(/1,1,nclasses/) )
129     
130      CALL iom_get( ncid, jpdom_unknown, 'kount' , zdata(:) )
131      num_bergs(:) = INT(zdata(:))
132
133      ! Sanity check
134      jn = icb_utl_count()
135      IF ( lwp .AND. nn_verbose_level >= 0 )   &
136         WRITE(numout,'(2(a,i5))') 'icebergs, read_restart_bergs: # bergs =',jn,' on PE',narea-1
137      IF( lk_mpp ) THEN
138         ! Only mpp_sum ibergs_in_file if we are reading from multiple restart files.
139         IF( INDEX(iom_file(ncid)%name,'icebergs.nc' ) .EQ. 0 ) CALL mpp_sum(ibergs_in_file)
140         CALL mpp_sum(jn)
141      ENDIF
142      IF( lwp )   WRITE(numout,'(a,i5,a,i5,a)') 'icebergs, icb_rst_read: there were',ibergs_in_file,   &
143         &                                    ' bergs in the restart file and', jn,' bergs have been read'
144      !
145      ! Finish up
146      CALL iom_close( ncid )
147      !
148      IF( lwp .AND. nn_verbose_level >= 0 )  WRITE(numout,'(a)') 'icebergs, icb_rst_read: completed'
149      !
150   END SUBROUTINE icb_rst_read
151
152
153   SUBROUTINE icb_rst_write( kt )
154      !!----------------------------------------------------------------------
155      !!                 ***  SUBROUTINE icb_rst_write  ***
156      !!
157      !!----------------------------------------------------------------------
158      INTEGER, INTENT( in ) :: kt
159      !
160      INTEGER ::   jn   ! dummy loop index
161      INTEGER ::   ix_dim, iy_dim, ik_dim, in_dim
162      INTEGER             ::   iyear, imonth, iday
163      REAL (wp)           ::   zsec
164      REAL (wp)           ::   zfjulday
165      CHARACTER(len=256)  :: cl_path
166      CHARACTER(len=256)  :: cl_filename
167      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
168      TYPE(iceberg), POINTER :: this
169      TYPE(point)  , POINTER :: pt
170      !!----------------------------------------------------------------------
171
172      ! Following the normal restart procedure, this routine will be called
173      ! the timestep before a restart stage as well as the restart timestep.
174      ! This is a performance step enabling the file to be opened and contents
175      ! defined in advance of the write. This is not possible with icebergs
176      ! since the number of bergs to be written could change between timesteps
177      IF( kt == nitrst ) THEN
178         ! Only operate on the restart timestep itself.
179         ! Assume we write iceberg restarts to same directory as ocean restarts.
180         cl_path = TRIM(cn_ocerst_outdir)
181         IF( cl_path(LEN_TRIM(cl_path):) /= '/' ) cl_path = TRIM(cl_path) // '/'
182         IF ( ln_rstdate ) THEN
183            zfjulday = fjulday + rdt / rday
184            IF( ABS(zfjulday - REAL(NINT(zfjulday),wp)) < 0.1 / rday )   zfjulday = REAL(NINT(zfjulday),wp)   ! avoid truncation error
185            CALL ju2ymds( zfjulday, iyear, imonth, iday, zsec )           
186            WRITE(clkt, '(i4.4,2i2.2)') iyear, imonth, iday
187         ELSE
188            IF( kt > 999999999 ) THEN   ;   WRITE(clkt, *       ) kt
189            ELSE                        ;   WRITE(clkt, '(i8.8)') kt
190            ENDIF
191         ENDIF
192         IF( lk_mpp ) THEN
193            WRITE(cl_filename,'(A,"_icebergs_",A,"_restart_",I4.4,".nc")') TRIM(cexper), TRIM(ADJUSTL(clkt)), narea-1
194         ELSE
195            WRITE(cl_filename,'(A,"_icebergs_",A,"_restart.nc")') TRIM(cexper), TRIM(ADJUSTL(clkt))
196         ENDIF
197         IF ( lwp .AND. nn_verbose_level >= 0) WRITE(numout,'(2a)') 'icebergs, write_restart: creating ',  &
198           &                                                         TRIM(cl_path)//TRIM(cl_filename)
199   
200         nret = NF90_CREATE(TRIM(cl_path)//TRIM(cl_filename), NF90_CLOBBER, ncid)
201         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_create failed')
202   
203         ! Dimensions
204         nret = NF90_DEF_DIM(ncid, 'x', jpi, ix_dim)
205         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim x failed')
206   
207         nret = NF90_DEF_DIM(ncid, 'y', jpj, iy_dim)
208         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim y failed')
209   
210         nret = NF90_DEF_DIM(ncid, 'c', nclasses, nc_dim)
211         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim c failed')
212   
213         nret = NF90_DEF_DIM(ncid, 'k', nkounts, ik_dim)
214         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim k failed')
215   
216         ! global attributes
217         IF( lk_mpp ) THEN
218            ! Set domain parameters (assume jpdom_local_full)
219            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              )
220            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            )
221            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) )
222            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) )
223            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_size_local'     , (/jpi   , jpj   /) )
224            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_position_first' , (/nimpp , njmpp /) )
225            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_position_last'  , (/nimpp + jpi - 1 , njmpp + jpj - 1  /) )
226            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_halo_size_start', (/nldi - 1        , nldj - 1         /) )
227            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , (/jpi - nlei      , jpj - nlej       /) )
228            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              )
229         ENDIF
230         
231         IF (associated(first_berg)) then
232            nret = NF90_DEF_DIM(ncid, 'n', NF90_UNLIMITED, in_dim)
233            IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim n failed')
234         ENDIF
235   
236         ! Variables
237         nret = NF90_DEF_VAR(ncid, 'kount'       , NF90_INT   , (/ ik_dim /), nkountid)
238         nret = NF90_DEF_VAR(ncid, 'calving'     , NF90_DOUBLE, (/ ix_dim, iy_dim /), ncalvid)
239         nret = NF90_DEF_VAR(ncid, 'calving_hflx', NF90_DOUBLE, (/ ix_dim, iy_dim /), ncalvhid)
240         nret = NF90_DEF_VAR(ncid, 'stored_ice'  , NF90_DOUBLE, (/ ix_dim, iy_dim, nc_dim /), nsiceid)
241         nret = NF90_DEF_VAR(ncid, 'stored_heat' , NF90_DOUBLE, (/ ix_dim, iy_dim /), nsheatid)
242   
243         ! Attributes
244         nret = NF90_PUT_ATT(ncid, ncalvid , 'long_name', 'iceberg calving')
245         nret = NF90_PUT_ATT(ncid, ncalvid , 'units', 'some')
246         nret = NF90_PUT_ATT(ncid, ncalvhid, 'long_name', 'heat flux associated with iceberg calving')
247         nret = NF90_PUT_ATT(ncid, ncalvhid, 'units', 'some')
248         nret = NF90_PUT_ATT(ncid, nsiceid , 'long_name', 'stored ice used to calve icebergs')
249         nret = NF90_PUT_ATT(ncid, nsiceid , 'units', 'kg/s')
250         nret = NF90_PUT_ATT(ncid, nsheatid, 'long_name', 'heat in stored ice used to calve icebergs')
251         nret = NF90_PUT_ATT(ncid, nsheatid, 'units', 'J/kg/s')
252   
253         IF ( ASSOCIATED(first_berg) ) THEN
254   
255            ! Only add berg variables for this PE if we have anything to say
256   
257            ! Variables
258            nret = NF90_DEF_VAR(ncid, 'lon', NF90_DOUBLE, in_dim, nlonid)
259            nret = NF90_DEF_VAR(ncid, 'lat', NF90_DOUBLE, in_dim, nlatid)
260            nret = NF90_DEF_VAR(ncid, 'xi', NF90_DOUBLE, in_dim, nxid)
261            nret = NF90_DEF_VAR(ncid, 'yj', NF90_DOUBLE, in_dim, nyid)
262            nret = NF90_DEF_VAR(ncid, 'uvel', NF90_DOUBLE, in_dim, nuvelid)
263            nret = NF90_DEF_VAR(ncid, 'vvel', NF90_DOUBLE, in_dim, nvvelid)
264            nret = NF90_DEF_VAR(ncid, 'mass', NF90_DOUBLE, in_dim, nmassid)
265            nret = NF90_DEF_VAR(ncid, 'thickness', NF90_DOUBLE, in_dim, nthicknessid)
266            nret = NF90_DEF_VAR(ncid, 'width', NF90_DOUBLE, in_dim, nwidthid)
267            nret = NF90_DEF_VAR(ncid, 'length', NF90_DOUBLE, in_dim, nlengthid)
268            nret = NF90_DEF_VAR(ncid, 'number', NF90_INT, (/ik_dim,in_dim/), numberid)
269            nret = NF90_DEF_VAR(ncid, 'year', NF90_INT, in_dim, nyearid)
270            nret = NF90_DEF_VAR(ncid, 'day', NF90_DOUBLE, in_dim, ndayid)
271            nret = NF90_DEF_VAR(ncid, 'mass_scaling', NF90_DOUBLE, in_dim, nscaling_id)
272            nret = NF90_DEF_VAR(ncid, 'mass_of_bits', NF90_DOUBLE, in_dim, nmass_of_bits_id)
273            nret = NF90_DEF_VAR(ncid, 'heat_density', NF90_DOUBLE, in_dim, nheat_density_id)
274   
275            ! Attributes
276            nret = NF90_PUT_ATT(ncid, nlonid, 'long_name', 'longitude')
277            nret = NF90_PUT_ATT(ncid, nlonid, 'units', 'degrees_E')
278            nret = NF90_PUT_ATT(ncid, nlatid, 'long_name', 'latitude')
279            nret = NF90_PUT_ATT(ncid, nlatid, 'units', 'degrees_N')
280            nret = NF90_PUT_ATT(ncid, nxid, 'long_name', 'x grid box position')
281            nret = NF90_PUT_ATT(ncid, nxid, 'units', 'fractional')
282            nret = NF90_PUT_ATT(ncid, nyid, 'long_name', 'y grid box position')
283            nret = NF90_PUT_ATT(ncid, nyid, 'units', 'fractional')
284            nret = NF90_PUT_ATT(ncid, nuvelid, 'long_name', 'zonal velocity')
285            nret = NF90_PUT_ATT(ncid, nuvelid, 'units', 'm/s')
286            nret = NF90_PUT_ATT(ncid, nvvelid, 'long_name', 'meridional velocity')
287            nret = NF90_PUT_ATT(ncid, nvvelid, 'units', 'm/s')
288            nret = NF90_PUT_ATT(ncid, nmassid, 'long_name', 'mass')
289            nret = NF90_PUT_ATT(ncid, nmassid, 'units', 'kg')
290            nret = NF90_PUT_ATT(ncid, nthicknessid, 'long_name', 'thickness')
291            nret = NF90_PUT_ATT(ncid, nthicknessid, 'units', 'm')
292            nret = NF90_PUT_ATT(ncid, nwidthid, 'long_name', 'width')
293            nret = NF90_PUT_ATT(ncid, nwidthid, 'units', 'm')
294            nret = NF90_PUT_ATT(ncid, nlengthid, 'long_name', 'length')
295            nret = NF90_PUT_ATT(ncid, nlengthid, 'units', 'm')
296            nret = NF90_PUT_ATT(ncid, numberid, 'long_name', 'iceberg number on this processor')
297            nret = NF90_PUT_ATT(ncid, numberid, 'units', 'count')
298            nret = NF90_PUT_ATT(ncid, nyearid, 'long_name', 'calendar year of calving event')
299            nret = NF90_PUT_ATT(ncid, nyearid, 'units', 'years')
300            nret = NF90_PUT_ATT(ncid, ndayid, 'long_name', 'year day of calving event')
301            nret = NF90_PUT_ATT(ncid, ndayid, 'units', 'days')
302            nret = NF90_PUT_ATT(ncid, nscaling_id, 'long_name', 'scaling factor for mass of calving berg')
303            nret = NF90_PUT_ATT(ncid, nscaling_id, 'units', 'none')
304            nret = NF90_PUT_ATT(ncid, nmass_of_bits_id, 'long_name', 'mass of bergy bits')
305            nret = NF90_PUT_ATT(ncid, nmass_of_bits_id, 'units', 'kg')
306            nret = NF90_PUT_ATT(ncid, nheat_density_id, 'long_name', 'heat density')
307            nret = NF90_PUT_ATT(ncid, nheat_density_id, 'units', 'J/kg')
308   
309         ENDIF ! associated(first_berg)
310   
311         ! End define mode
312         nret = NF90_ENDDEF(ncid)
313   
314         ! --------------------------------
315         ! now write some data
316   
317         nstrt3(1) = 1
318         nstrt3(2) = 1
319         nlngth3(1) = jpi
320         nlngth3(2) = jpj
321         nlngth3(3) = 1
322   
323         DO jn=1,nclasses
324            griddata(:,:,1) = berg_grid%stored_ice(:,:,jn)
325            nstrt3(3) = jn
326            nret = NF90_PUT_VAR( ncid, nsiceid, griddata, nstrt3, nlngth3 )
327            IF (nret .ne. NF90_NOERR) THEN
328               IF( lwp ) WRITE(numout,*) TRIM(NF90_STRERROR( nret ))
329               CALL ctl_stop('icebergs, write_restart: nf_put_var stored_ice failed')
330            ENDIF
331         ENDDO
332         IF( lwp ) WRITE(numout,*) 'file: ',TRIM(cl_path)//TRIM(cl_filename),' var: stored_ice  written'
333   
334         nret = NF90_PUT_VAR( ncid, nkountid, num_bergs(:) )
335         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var kount failed')
336   
337         nret = NF90_PUT_VAR( ncid, nsheatid, berg_grid%stored_heat(:,:) )
338         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var stored_heat failed')
339         IF( lwp ) WRITE(numout,*) 'file: ',TRIM(cl_path)//TRIM(cl_filename),' var: stored_heat written'
340   
341         nret = NF90_PUT_VAR( ncid, ncalvid , src_calving(:,:) )
342         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var calving failed')
343         nret = NF90_PUT_VAR( ncid, ncalvhid, src_calving_hflx(:,:) )
344         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var calving_hflx failed')
345         IF( lwp ) WRITE(numout,*) 'file: ',TRIM(cl_path)//TRIM(cl_filename),' var: calving written'
346   
347         IF ( ASSOCIATED(first_berg) ) THEN
348   
349            ! Write variables
350            ! just write out the current point of the trajectory
351   
352            this => first_berg
353            jn = 0
354            DO WHILE (ASSOCIATED(this))
355               pt => this%current_point
356               jn=jn+1
357   
358               nret = NF90_PUT_VAR(ncid, numberid, this%number, (/1,jn/), (/nkounts,1/) )
359               nret = NF90_PUT_VAR(ncid, nscaling_id, this%mass_scaling, (/ jn /) )
360   
361               nret = NF90_PUT_VAR(ncid, nlonid, pt%lon, (/ jn /) )
362               nret = NF90_PUT_VAR(ncid, nlatid, pt%lat, (/ jn /) )
363               nret = NF90_PUT_VAR(ncid, nxid, pt%xi, (/ jn /) )
364               nret = NF90_PUT_VAR(ncid, nyid, pt%yj, (/ jn /) )
365               nret = NF90_PUT_VAR(ncid, nuvelid, pt%uvel, (/ jn /) )
366               nret = NF90_PUT_VAR(ncid, nvvelid, pt%vvel, (/ jn /) )
367               nret = NF90_PUT_VAR(ncid, nmassid, pt%mass, (/ jn /) )
368               nret = NF90_PUT_VAR(ncid, nthicknessid, pt%thickness, (/ jn /) )
369               nret = NF90_PUT_VAR(ncid, nwidthid, pt%width, (/ jn /) )
370               nret = NF90_PUT_VAR(ncid, nlengthid, pt%length, (/ jn /) )
371               nret = NF90_PUT_VAR(ncid, nyearid, pt%year, (/ jn /) )
372               nret = NF90_PUT_VAR(ncid, ndayid, pt%day, (/ jn /) )
373               nret = NF90_PUT_VAR(ncid, nmass_of_bits_id, pt%mass_of_bits, (/ jn /) )
374               nret = NF90_PUT_VAR(ncid, nheat_density_id, pt%heat_density, (/ jn /) )
375   
376               this=>this%next
377            END DO
378            !
379         ENDIF ! associated(first_berg)
380   
381         ! Finish up
382         nret = NF90_CLOSE(ncid)
383         IF (nret /= NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_close failed')
384   
385         ! Sanity check
386         jn = icb_utl_count()
387         IF ( lwp .AND. nn_verbose_level >= 0)   &
388            WRITE(numout,'(2(a,i5))') 'icebergs, icb_rst_write: # bergs =',jn,' on PE',narea-1
389         IF( lk_mpp ) THEN
390            CALL mpp_sum(jn)
391         ENDIF
392         IF(lwp)   WRITE(numout,'(a,i5,a,i5,a)') 'icebergs, icb_rst_write: ', jn,   &
393            &                                    ' bergs in total have been written at timestep ', kt
394         !
395         ! Finish up
396         !
397      ENDIF
398   END SUBROUTINE icb_rst_write
399   !
400   !!======================================================================
401END MODULE icbrst
Note: See TracBrowser for help on using the repository browser.