| 1 | MODULE ldfslp |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE ldfslp *** |
|---|
| 4 | !! Ocean physics: slopes of neutral surfaces |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1994-12 (G. Madec, M. Imbard) Original code |
|---|
| 7 | !! 8.0 ! 1997-06 (G. Madec) optimization, lbc |
|---|
| 8 | !! 8.1 ! 1999-10 (A. Jouzeau) NEW profile in the mixed layer |
|---|
| 9 | !! NEMO 1.0 ! 2002-10 (G. Madec) Free form, F90 |
|---|
| 10 | !! - ! 2005-10 (A. Beckmann) correction for s-coordinates |
|---|
| 11 | !! 3.3 ! 2010-10 (G. Nurser, C. Harris, G. Madec) add Griffies operator |
|---|
| 12 | !! - ! 2010-11 (F. Dupond, G. Madec) bug correction in slopes just below the ML |
|---|
| 13 | !! 3.7 ! 2013-12 (F. Lemarie, G. Madec) add limiter on triad slopes |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | !! ldf_slp : calculates the slopes of neutral surface (Madec operator) |
|---|
| 18 | !! ldf_slp_mxl : calculates the slopes at the base of the mixed layer (Madec operator) |
|---|
| 19 | !!---------------------------------------------------------------------- |
|---|
| 20 | USE len_oce ! ocean sizes |
|---|
| 21 | USE phycst ! physical constants |
|---|
| 22 | USE in_out_manager ! I/O manager |
|---|
| 23 | ! mjb USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 24 | |
|---|
| 25 | IMPLICIT NONE |
|---|
| 26 | PRIVATE |
|---|
| 27 | |
|---|
| 28 | PUBLIC ldf_slp ! routine called by step.F90 |
|---|
| 29 | PUBLIC ldf_slp_mxl |
|---|
| 30 | |
|---|
| 31 | REAL(wp), PUBLIC :: rn_slpmax = 0.01_wp !: slope limit (nam_traldf namelist) |
|---|
| 32 | |
|---|
| 33 | !! * Substitutions |
|---|
| 34 | # include "vectopt_loop_substitute.h90" |
|---|
| 35 | !!---------------------------------------------------------------------- |
|---|
| 36 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 37 | !! $Id$ |
|---|
| 38 | !! Software governed by the CeCILL licence (./LICENSE) |
|---|
| 39 | !!---------------------------------------------------------------------- |
|---|
| 40 | CONTAINS |
|---|
| 41 | |
|---|
| 42 | SUBROUTINE ldf_slp( ln_zps, ln_isfcav, prd, pn2, tmask, umask, vmask, wmask, gru, grv, & |
|---|
| 43 | & e1t, e2t, r1_e1u, r1_e2v, e3u_n, e3v_n, e3w_n, gdept_n, gdepw_n, mbku, mbkv, & |
|---|
| 44 | & mikt, miku, mikv, nmln, hmlp, hmlpt, risfdep, & |
|---|
| 45 | & omlmask, uslpml, vslpml, wslpiml, wslpjml, uslp, vslp, wslpi, wslpj ) |
|---|
| 46 | |
|---|
| 47 | !!---------------------------------------------------------------------- |
|---|
| 48 | !! *** ROUTINE ldf_slp *** |
|---|
| 49 | !! |
|---|
| 50 | !! ** Purpose : Compute the slopes of neutral surface (slope of isopycnal |
|---|
| 51 | !! surfaces referenced locally) (ln_traldf_iso=T). |
|---|
| 52 | !! |
|---|
| 53 | !! ** Method : The slope in the i-direction is computed at U- and |
|---|
| 54 | !! W-points (uslp, wslpi) and the slope in the j-direction is |
|---|
| 55 | !! computed at V- and W-points (vslp, wslpj). |
|---|
| 56 | !! They are bounded by 1/100 over the whole ocean, and within the |
|---|
| 57 | !! surface layer they are bounded by the distance to the surface |
|---|
| 58 | !! ( slope<= depth/l where l is the length scale of horizontal |
|---|
| 59 | !! diffusion (here, aht=2000m2/s ==> l=20km with a typical velocity |
|---|
| 60 | !! of 10cm/s) |
|---|
| 61 | !! A horizontal shapiro filter is applied to the slopes |
|---|
| 62 | !! ln_sco=T, s-coordinate, add to the previously computed slopes |
|---|
| 63 | !! the slope of the model level surface. |
|---|
| 64 | !! macro-tasked on horizontal slab (jk-loop) (2, jpk-1) |
|---|
| 65 | !! [slopes already set to zero at level 1, and to zero or the ocean |
|---|
| 66 | !! bottom slope (ln_sco=T) at level jpk in inildf] |
|---|
| 67 | !! |
|---|
| 68 | !! ** Action : - uslp, wslpi, and vslp, wslpj, the i- and j-slopes |
|---|
| 69 | !! of now neutral surfaces at u-, w- and v- w-points, resp. |
|---|
| 70 | !!---------------------------------------------------------------------- |
|---|
| 71 | LOGICAL , INTENT(in) :: ln_zps, ln_isfcav |
|---|
| 72 | REAL(wp), INTENT(in), DIMENSION(:,:,:) :: prd ! in situ density |
|---|
| 73 | REAL(wp), INTENT(in), DIMENSION(:,:,:) :: pn2 ! Brunt-Vaisala frequency (locally ref.) |
|---|
| 74 | REAL(wp), INTENT(in), DIMENSION(:,:,:) :: tmask, umask, vmask, wmask |
|---|
| 75 | REAL(wp), INTENT(in), DIMENSION(:,:) :: gru, grv, e1t, e2t, r1_e1u, r1_e2v |
|---|
| 76 | REAL(wp), INTENT(in), DIMENSION(:,:,:) :: e3u_n, e3v_n, e3w_n, gdept_n, gdepw_n |
|---|
| 77 | INTEGER , INTENT(in), DIMENSION(:,:) :: mbku, mbkv, mikt, miku, mikv, nmln |
|---|
| 78 | REAL(wp), INTENT(in), DIMENSION(:,:) :: hmlp, hmlpt, risfdep |
|---|
| 79 | REAL(wp), INTENT(out),DIMENSION(:,:,:) :: omlmask |
|---|
| 80 | REAL(wp), INTENT(out),DIMENSION(:,:) :: uslpml, vslpml, wslpiml, wslpjml |
|---|
| 81 | REAL(wp), INTENT(out),DIMENSION(:,:,:) :: uslp, vslp, wslpi, wslpj |
|---|
| 82 | |
|---|
| 83 | !! |
|---|
| 84 | INTEGER :: ji , jj , jk ! dummy loop indices |
|---|
| 85 | INTEGER :: ii0, ii1 ! temporary integer |
|---|
| 86 | INTEGER :: ij0, ij1 ! temporary integer |
|---|
| 87 | REAL(wp) :: zeps, zm1_g, zm1_2g, z1_16, zcofw, z1_slpmax ! local scalars |
|---|
| 88 | REAL(wp) :: zci, zfi, zau, zbu, zai, zbi ! - - |
|---|
| 89 | REAL(wp) :: zcj, zfj, zav, zbv, zaj, zbj ! - - |
|---|
| 90 | REAL(wp) :: zck, zfk, zbw ! - - |
|---|
| 91 | REAL(wp) :: zdepu, zdepv ! - - |
|---|
| 92 | REAL(wp),ALLOCATABLE, DIMENSION(:,:) :: zslpml_hmlpu, zslpml_hmlpv ! Make global scratch at some point |
|---|
| 93 | REAL(wp),ALLOCATABLE, DIMENSION(:,:,:) :: zgru, zwz, zdzr |
|---|
| 94 | REAL(wp),ALLOCATABLE, DIMENSION(:,:,:) :: zgrv, zww |
|---|
| 95 | !!---------------------------------------------------------------------- |
|---|
| 96 | ! |
|---|
| 97 | ALLOCATE(zslpml_hmlpu(jpi,jpj)) |
|---|
| 98 | ALLOCATE(zslpml_hmlpv(jpi,jpj)) |
|---|
| 99 | ALLOCATE(zgru(jpi,jpj,jpk)) |
|---|
| 100 | ALLOCATE(zwz(jpi,jpj,jpk)) |
|---|
| 101 | ALLOCATE(zdzr(jpi,jpj,jpk)) |
|---|
| 102 | ALLOCATE(zgrv(jpi,jpj,jpk)) |
|---|
| 103 | ALLOCATE(zww(jpi,jpj,jpk)) |
|---|
| 104 | ! mjb IF( ln_timing ) CALL timing_start('ldf_slp') |
|---|
| 105 | ! |
|---|
| 106 | !$ACC KERNELS |
|---|
| 107 | zeps = 1.e-20_wp !== Local constant initialization ==! |
|---|
| 108 | z1_16 = 1.0_wp / 16._wp |
|---|
| 109 | zm1_g = -1.0_wp / grav |
|---|
| 110 | zm1_2g = -0.5_wp / grav |
|---|
| 111 | z1_slpmax = 1._wp / rn_slpmax |
|---|
| 112 | ! |
|---|
| 113 | zww(:,:,:) = 0._wp |
|---|
| 114 | zwz(:,:,:) = 0._wp |
|---|
| 115 | ! |
|---|
| 116 | DO jk = 1, jpk !== i- & j-gradient of density ==! |
|---|
| 117 | DO jj = 1, jpjm1 |
|---|
| 118 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 119 | zgru(ji,jj,jk) = umask(ji,jj,jk) * ( prd(ji+1,jj ,jk) - prd(ji,jj,jk) ) |
|---|
| 120 | zgrv(ji,jj,jk) = vmask(ji,jj,jk) * ( prd(ji ,jj+1,jk) - prd(ji,jj,jk) ) |
|---|
| 121 | END DO |
|---|
| 122 | END DO |
|---|
| 123 | END DO |
|---|
| 124 | IF( ln_zps ) THEN ! partial steps correction at the bottom ocean level |
|---|
| 125 | DO jj = 1, jpjm1 |
|---|
| 126 | DO ji = 1, jpim1 |
|---|
| 127 | zgru(ji,jj,mbku(ji,jj)) = gru(ji,jj) |
|---|
| 128 | zgrv(ji,jj,mbkv(ji,jj)) = grv(ji,jj) |
|---|
| 129 | END DO |
|---|
| 130 | END DO |
|---|
| 131 | ENDIF |
|---|
| 132 | |
|---|
| 133 | ! MJB next lines commented out for simplicity |
|---|
| 134 | ! IF( ln_zps .AND. ln_isfcav ) THEN ! partial steps correction at the bottom ocean level |
|---|
| 135 | ! DO jj = 1, jpjm1 |
|---|
| 136 | ! DO ji = 1, jpim1 |
|---|
| 137 | ! IF( miku(ji,jj) > 1 ) zgru(ji,jj,miku(ji,jj)) = grui(ji,jj) |
|---|
| 138 | ! IF( mikv(ji,jj) > 1 ) zgrv(ji,jj,mikv(ji,jj)) = grvi(ji,jj) |
|---|
| 139 | ! END DO |
|---|
| 140 | ! END DO |
|---|
| 141 | ! ENDIF |
|---|
| 142 | ! |
|---|
| 143 | zdzr(:,:,1) = 0._wp !== Local vertical density gradient at T-point == ! (evaluated from N^2) |
|---|
| 144 | DO jk = 2, jpkm1 |
|---|
| 145 | ! ! zdzr = d/dz(prd)= - ( prd ) / grav * mk(pn2) -- at t point |
|---|
| 146 | ! ! trick: tmask(ik ) = 0 => all pn2 = 0 => zdzr = 0 |
|---|
| 147 | ! ! else tmask(ik+1) = 0 => pn2(ik+1) = 0 => zdzr divides by 1 |
|---|
| 148 | ! ! umask(ik+1) /= 0 => all pn2 /= 0 => zdzr divides by 2 |
|---|
| 149 | ! ! NB: 1/(tmask+1) = (1-.5*tmask) substitute a / by a * ==> faster |
|---|
| 150 | zdzr(:,:,jk) = zm1_g * ( prd(:,:,jk) + 1._wp ) & |
|---|
| 151 | & * ( pn2(:,:,jk) + pn2(:,:,jk+1) ) * ( 1._wp - 0.5_wp * tmask(:,:,jk+1) ) |
|---|
| 152 | END DO |
|---|
| 153 | !$ACC END KERNELS |
|---|
| 154 | ! |
|---|
| 155 | ! !== Slopes just below the mixed layer ==! |
|---|
| 156 | CALL ldf_slp_mxl( prd, pn2, zgru, zgrv, zdzr, nmln, e1t, e2t, r1_e1u, r1_e2v, e3u_n, e3v_n, e3w_n, & |
|---|
| 157 | & tmask, umask, vmask, omlmask, uslpml, vslpml, wslpiml, wslpjml ) |
|---|
| 158 | |
|---|
| 159 | |
|---|
| 160 | ! I. slopes at u and v point | uslp = d/di( prd ) / d/dz( prd ) |
|---|
| 161 | ! =========================== | vslp = d/dj( prd ) / d/dz( prd ) |
|---|
| 162 | ! |
|---|
| 163 | |
|---|
| 164 | !$ACC KERNELS |
|---|
| 165 | IF ( ln_isfcav ) THEN |
|---|
| 166 | DO jj = 2, jpjm1 |
|---|
| 167 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 168 | zslpml_hmlpu(ji,jj) = uslpml(ji,jj) / ( MAX(hmlpt (ji,jj), hmlpt (ji+1,jj ), 5._wp) & |
|---|
| 169 | & - MAX(risfdep(ji,jj), risfdep(ji+1,jj ) ) ) |
|---|
| 170 | zslpml_hmlpv(ji,jj) = vslpml(ji,jj) / ( MAX(hmlpt (ji,jj), hmlpt (ji ,jj+1), 5._wp) & |
|---|
| 171 | & - MAX(risfdep(ji,jj), risfdep(ji ,jj+1) ) ) |
|---|
| 172 | END DO |
|---|
| 173 | END DO |
|---|
| 174 | ELSE |
|---|
| 175 | DO jj = 2, jpjm1 |
|---|
| 176 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 177 | zslpml_hmlpu(ji,jj) = uslpml(ji,jj) / MAX(hmlpt(ji,jj), hmlpt(ji+1,jj ), 5._wp) |
|---|
| 178 | zslpml_hmlpv(ji,jj) = vslpml(ji,jj) / MAX(hmlpt(ji,jj), hmlpt(ji ,jj+1), 5._wp) |
|---|
| 179 | END DO |
|---|
| 180 | END DO |
|---|
| 181 | END IF |
|---|
| 182 | |
|---|
| 183 | DO jk = 2, jpkm1 !* Slopes at u and v points |
|---|
| 184 | DO jj = 2, jpjm1 |
|---|
| 185 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 186 | ! ! horizontal and vertical density gradient at u- and v-points |
|---|
| 187 | zau = zgru(ji,jj,jk) * r1_e1u(ji,jj) |
|---|
| 188 | zav = zgrv(ji,jj,jk) * r1_e2v(ji,jj) |
|---|
| 189 | zbu = 0.5_wp * ( zdzr(ji,jj,jk) + zdzr(ji+1,jj ,jk) ) |
|---|
| 190 | zbv = 0.5_wp * ( zdzr(ji,jj,jk) + zdzr(ji ,jj+1,jk) ) |
|---|
| 191 | ! ! bound the slopes: abs(zw.)<= 1/100 and zb..<0 |
|---|
| 192 | ! ! + kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 193 | zbu = MIN( zbu, - z1_slpmax * ABS( zau ) , -7.e+3_wp/e3u_n(ji,jj,jk)* ABS( zau ) ) |
|---|
| 194 | zbv = MIN( zbv, - z1_slpmax * ABS( zav ) , -7.e+3_wp/e3v_n(ji,jj,jk)* ABS( zav ) ) |
|---|
| 195 | ! ! uslp and vslp output in zwz and zww, resp. |
|---|
| 196 | zfi = MAX( omlmask(ji,jj,jk), omlmask(ji+1,jj,jk) ) |
|---|
| 197 | zfj = MAX( omlmask(ji,jj,jk), omlmask(ji,jj+1,jk) ) |
|---|
| 198 | ! thickness of water column between surface and level k at u/v point |
|---|
| 199 | zdepu = 0.5_wp * ( ( gdept_n (ji,jj,jk) + gdept_n (ji+1,jj,jk) ) & |
|---|
| 200 | - 2 * MAX( risfdep(ji,jj), risfdep(ji+1,jj) ) - e3u_n(ji,jj,miku(ji,jj)) ) |
|---|
| 201 | zdepv = 0.5_wp * ( ( gdept_n (ji,jj,jk) + gdept_n (ji,jj+1,jk) ) & |
|---|
| 202 | - 2 * MAX( risfdep(ji,jj), risfdep(ji,jj+1) ) - e3v_n(ji,jj,mikv(ji,jj)) ) |
|---|
| 203 | ! |
|---|
| 204 | zwz(ji,jj,jk) = ( ( 1._wp - zfi) * zau / ( zbu - zeps ) & |
|---|
| 205 | & + zfi * zdepu * zslpml_hmlpu(ji,jj) ) * umask(ji,jj,jk) |
|---|
| 206 | zww(ji,jj,jk) = ( ( 1._wp - zfj) * zav / ( zbv - zeps ) & |
|---|
| 207 | & + zfj * zdepv * zslpml_hmlpv(ji,jj) ) * vmask(ji,jj,jk) |
|---|
| 208 | !!gm modif to suppress omlmask.... (as in Griffies case) |
|---|
| 209 | ! ! ! jk must be >= ML level for zf=1. otherwise zf=0. |
|---|
| 210 | ! zfi = REAL( 1 - 1/(1 + jk / MAX( nmln(ji+1,jj), nmln(ji,jj) ) ), wp ) |
|---|
| 211 | ! zfj = REAL( 1 - 1/(1 + jk / MAX( nmln(ji,jj+1), nmln(ji,jj) ) ), wp ) |
|---|
| 212 | ! zci = 0.5 * ( gdept_n(ji+1,jj,jk)+gdept_n(ji,jj,jk) ) / MAX( hmlpt(ji,jj), hmlpt(ji+1,jj), 10. ) ) |
|---|
| 213 | ! zcj = 0.5 * ( gdept_n(ji,jj+1,jk)+gdept_n(ji,jj,jk) ) / MAX( hmlpt(ji,jj), hmlpt(ji,jj+1), 10. ) ) |
|---|
| 214 | ! zwz(ji,jj,jk) = ( zfi * zai / ( zbi - zeps ) + ( 1._wp - zfi ) * wslpiml(ji,jj) * zci ) * tmask(ji,jj,jk) |
|---|
| 215 | ! zww(ji,jj,jk) = ( zfj * zaj / ( zbj - zeps ) + ( 1._wp - zfj ) * wslpjml(ji,jj) * zcj ) * tmask(ji,jj,jk) |
|---|
| 216 | !!gm end modif |
|---|
| 217 | END DO |
|---|
| 218 | END DO |
|---|
| 219 | END DO |
|---|
| 220 | !MJB CALL lbc_lnk_multi( zwz, 'U', -1., zww, 'V', -1. ) ! lateral boundary conditions |
|---|
| 221 | ! |
|---|
| 222 | ! !* horizontal Shapiro filter |
|---|
| 223 | DO jk = 2, jpkm1 |
|---|
| 224 | DO jj = 2, jpjm1, MAX(1, jpj-3) ! rows jj=2 and =jpjm1 only |
|---|
| 225 | DO ji = 2, jpim1 |
|---|
| 226 | uslp(ji,jj,jk) = z1_16 * ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 227 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 228 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 229 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 230 | & + 4.* zwz(ji ,jj ,jk) ) |
|---|
| 231 | vslp(ji,jj,jk) = z1_16 * ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 232 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 233 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 234 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 235 | & + 4.* zww(ji,jj ,jk) ) |
|---|
| 236 | END DO |
|---|
| 237 | END DO |
|---|
| 238 | DO jj = 3, jpj-2 ! other rows |
|---|
| 239 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 240 | uslp(ji,jj,jk) = z1_16 * ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 241 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 242 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 243 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 244 | & + 4.* zwz(ji ,jj ,jk) ) |
|---|
| 245 | vslp(ji,jj,jk) = z1_16 * ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 246 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 247 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 248 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 249 | & + 4.* zww(ji,jj ,jk) ) |
|---|
| 250 | END DO |
|---|
| 251 | END DO |
|---|
| 252 | ! !* decrease along coastal boundaries |
|---|
| 253 | DO jj = 2, jpjm1 |
|---|
| 254 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 255 | uslp(ji,jj,jk) = uslp(ji,jj,jk) * ( umask(ji,jj+1,jk) + umask(ji,jj-1,jk ) ) * 0.5_wp & |
|---|
| 256 | & * ( umask(ji,jj ,jk) + umask(ji,jj ,jk+1) ) * 0.5_wp |
|---|
| 257 | vslp(ji,jj,jk) = vslp(ji,jj,jk) * ( vmask(ji+1,jj,jk) + vmask(ji-1,jj,jk ) ) * 0.5_wp & |
|---|
| 258 | & * ( vmask(ji ,jj,jk) + vmask(ji ,jj,jk+1) ) * 0.5_wp |
|---|
| 259 | END DO |
|---|
| 260 | END DO |
|---|
| 261 | END DO |
|---|
| 262 | |
|---|
| 263 | |
|---|
| 264 | ! II. slopes at w point | wslpi = mij( d/di( prd ) / d/dz( prd ) |
|---|
| 265 | ! =========================== | wslpj = mij( d/dj( prd ) / d/dz( prd ) |
|---|
| 266 | ! |
|---|
| 267 | DO jk = 2, jpkm1 |
|---|
| 268 | DO jj = 2, jpjm1 |
|---|
| 269 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 270 | ! !* Local vertical density gradient evaluated from N^2 |
|---|
| 271 | zbw = zm1_2g * pn2 (ji,jj,jk) * ( prd (ji,jj,jk) + prd (ji,jj,jk-1) + 2. ) |
|---|
| 272 | ! !* Slopes at w point |
|---|
| 273 | ! ! i- & j-gradient of density at w-points |
|---|
| 274 | zci = MAX( umask(ji-1,jj,jk ) + umask(ji,jj,jk ) & |
|---|
| 275 | & + umask(ji-1,jj,jk-1) + umask(ji,jj,jk-1) , zeps ) * e1t(ji,jj) |
|---|
| 276 | zcj = MAX( vmask(ji,jj-1,jk ) + vmask(ji,jj,jk-1) & |
|---|
| 277 | & + vmask(ji,jj-1,jk-1) + vmask(ji,jj,jk ) , zeps ) * e2t(ji,jj) |
|---|
| 278 | zai = ( zgru (ji-1,jj,jk ) + zgru (ji,jj,jk-1) & |
|---|
| 279 | & + zgru (ji-1,jj,jk-1) + zgru (ji,jj,jk ) ) / zci * wmask (ji,jj,jk) |
|---|
| 280 | zaj = ( zgrv (ji,jj-1,jk ) + zgrv (ji,jj,jk-1) & |
|---|
| 281 | & + zgrv (ji,jj-1,jk-1) + zgrv (ji,jj,jk ) ) / zcj * wmask (ji,jj,jk) |
|---|
| 282 | ! ! bound the slopes: abs(zw.)<= 1/100 and zb..<0. |
|---|
| 283 | ! ! + kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 284 | zbi = MIN( zbw ,- 100._wp* ABS( zai ) , -7.e+3_wp/e3w_n(ji,jj,jk)* ABS( zai ) ) |
|---|
| 285 | zbj = MIN( zbw , -100._wp* ABS( zaj ) , -7.e+3_wp/e3w_n(ji,jj,jk)* ABS( zaj ) ) |
|---|
| 286 | ! ! wslpi and wslpj with ML flattening (output in zwz and zww, resp.) |
|---|
| 287 | zfk = MAX( omlmask(ji,jj,jk), omlmask(ji,jj,jk-1) ) ! zfk=1 in the ML otherwise zfk=0 |
|---|
| 288 | zck = ( gdepw_n(ji,jj,jk) - gdepw_n(ji,jj,mikt(ji,jj) ) ) / MAX( hmlp(ji,jj) - gdepw_n(ji,jj,mikt(ji,jj)), 10._wp ) |
|---|
| 289 | zwz(ji,jj,jk) = ( zai / ( zbi - zeps ) * ( 1._wp - zfk ) + zck * wslpiml(ji,jj) * zfk ) * wmask(ji,jj,jk) |
|---|
| 290 | zww(ji,jj,jk) = ( zaj / ( zbj - zeps ) * ( 1._wp - zfk ) + zck * wslpjml(ji,jj) * zfk ) * wmask(ji,jj,jk) |
|---|
| 291 | |
|---|
| 292 | !!gm modif to suppress omlmask.... (as in Griffies operator) |
|---|
| 293 | ! ! ! jk must be >= ML level for zfk=1. otherwise zfk=0. |
|---|
| 294 | ! zfk = REAL( 1 - 1/(1 + jk / nmln(ji+1,jj)), wp ) |
|---|
| 295 | ! zck = gdepw(ji,jj,jk) / MAX( hmlp(ji,jj), 10. ) |
|---|
| 296 | ! zwz(ji,jj,jk) = ( zfk * zai / ( zbi - zeps ) + ( 1._wp - zfk ) * wslpiml(ji,jj) * zck ) * tmask(ji,jj,jk) |
|---|
| 297 | ! zww(ji,jj,jk) = ( zfk * zaj / ( zbj - zeps ) + ( 1._wp - zfk ) * wslpjml(ji,jj) * zck ) * tmask(ji,jj,jk) |
|---|
| 298 | !!gm end modif |
|---|
| 299 | END DO |
|---|
| 300 | END DO |
|---|
| 301 | END DO |
|---|
| 302 | ! MJB CALL lbc_lnk_multi( zwz, 'T', -1., zww, 'T', -1. ) ! lateral boundary conditions |
|---|
| 303 | ! |
|---|
| 304 | ! !* horizontal Shapiro filter |
|---|
| 305 | DO jk = 2, jpkm1 |
|---|
| 306 | DO jj = 2, jpjm1, MAX(1, jpj-3) ! rows jj=2 and =jpjm1 only |
|---|
| 307 | DO ji = 2, jpim1 |
|---|
| 308 | zcofw = wmask(ji,jj,jk) * z1_16 |
|---|
| 309 | wslpi(ji,jj,jk) = ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 310 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 311 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 312 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 313 | & + 4.* zwz(ji ,jj ,jk) ) * zcofw |
|---|
| 314 | |
|---|
| 315 | wslpj(ji,jj,jk) = ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 316 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 317 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 318 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 319 | & + 4.* zww(ji ,jj ,jk) ) * zcofw |
|---|
| 320 | END DO |
|---|
| 321 | END DO |
|---|
| 322 | DO jj = 3, jpj-2 ! other rows |
|---|
| 323 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 324 | zcofw = wmask(ji,jj,jk) * z1_16 |
|---|
| 325 | wslpi(ji,jj,jk) = ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 326 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 327 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 328 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 329 | & + 4.* zwz(ji ,jj ,jk) ) * zcofw |
|---|
| 330 | |
|---|
| 331 | wslpj(ji,jj,jk) = ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 332 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 333 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 334 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 335 | & + 4.* zww(ji ,jj ,jk) ) * zcofw |
|---|
| 336 | END DO |
|---|
| 337 | END DO |
|---|
| 338 | ! !* decrease in vicinity of topography |
|---|
| 339 | DO jj = 2, jpjm1 |
|---|
| 340 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 341 | zck = ( umask(ji,jj,jk) + umask(ji-1,jj,jk) ) & |
|---|
| 342 | & * ( vmask(ji,jj,jk) + vmask(ji,jj-1,jk) ) * 0.25 |
|---|
| 343 | wslpi(ji,jj,jk) = wslpi(ji,jj,jk) * zck |
|---|
| 344 | wslpj(ji,jj,jk) = wslpj(ji,jj,jk) * zck |
|---|
| 345 | END DO |
|---|
| 346 | END DO |
|---|
| 347 | END DO |
|---|
| 348 | |
|---|
| 349 | !$ACC END KERNELS |
|---|
| 350 | |
|---|
| 351 | ! IV. Lateral boundary conditions |
|---|
| 352 | ! =============================== |
|---|
| 353 | ! mjb CALL lbc_lnk_multi( uslp , 'U', -1. , vslp , 'V', -1. , wslpi, 'W', -1., wslpj, 'W', -1. ) |
|---|
| 354 | |
|---|
| 355 | ! mjb IF( ln_timing ) CALL timing_stop('ldf_slp') |
|---|
| 356 | ! |
|---|
| 357 | END SUBROUTINE ldf_slp |
|---|
| 358 | |
|---|
| 359 | SUBROUTINE ldf_slp_mxl( prd, pn2, p_gru, p_grv, p_dzr, nmln, e1t, e2t, r1_e1u, r1_e2v, e3u_n, e3v_n, e3w_n, & |
|---|
| 360 | & tmask, umask, vmask, omlmask, uslpml, vslpml, wslpiml, wslpjml ) |
|---|
| 361 | !!---------------------------------------------------------------------- |
|---|
| 362 | !! *** ROUTINE ldf_slp_mxl *** |
|---|
| 363 | !! |
|---|
| 364 | !! ** Purpose : Compute the slopes of iso-neutral surface just below |
|---|
| 365 | !! the mixed layer. |
|---|
| 366 | !! |
|---|
| 367 | !! ** Method : The slope in the i-direction is computed at u- & w-points |
|---|
| 368 | !! (uslpml, wslpiml) and the slope in the j-direction is computed |
|---|
| 369 | !! at v- and w-points (vslpml, wslpjml) with the same bounds as |
|---|
| 370 | !! in ldf_slp. |
|---|
| 371 | !! |
|---|
| 372 | !! ** Action : uslpml, wslpiml : i- & j-slopes of neutral surfaces |
|---|
| 373 | !! vslpml, wslpjml just below the mixed layer |
|---|
| 374 | !! omlmask : mixed layer mask |
|---|
| 375 | !!---------------------------------------------------------------------- |
|---|
| 376 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: prd ! in situ density |
|---|
| 377 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: pn2 ! Brunt-Vaisala frequency (locally ref.) |
|---|
| 378 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: p_gru, p_grv ! i- & j-gradient of density (u- & v-pts) |
|---|
| 379 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: p_dzr ! z-gradient of density (T-point) |
|---|
| 380 | INTEGER, DIMENSION(:,:) , INTENT(in) :: nmln |
|---|
| 381 | REAL(wp), DIMENSION(:,:), INTENT(in) :: e1t, e2t, r1_e1u, r1_e2v |
|---|
| 382 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: e3u_n, e3v_n, e3w_n, tmask, umask, vmask |
|---|
| 383 | REAL(wp), DIMENSION(:,:,:), INTENT(out):: omlmask |
|---|
| 384 | REAL(wp), DIMENSION(:,:), INTENT(out):: uslpml, vslpml, wslpiml, wslpjml |
|---|
| 385 | |
|---|
| 386 | !! |
|---|
| 387 | INTEGER :: ji , jj , jk ! dummy loop indices |
|---|
| 388 | INTEGER :: iku, ikv, ik, ikm1 ! local integers |
|---|
| 389 | REAL(wp) :: zeps, zm1_g, zm1_2g, z1_slpmax ! local scalars |
|---|
| 390 | REAL(wp) :: zci, zfi, zau, zbu, zai, zbi ! - - |
|---|
| 391 | REAL(wp) :: zcj, zfj, zav, zbv, zaj, zbj ! - - |
|---|
| 392 | REAL(wp) :: zck, zfk, zbw ! - - |
|---|
| 393 | !!---------------------------------------------------------------------- |
|---|
| 394 | ! |
|---|
| 395 | !$ACC KERNELS |
|---|
| 396 | zeps = 1.e-20_wp !== Local constant initialization ==! |
|---|
| 397 | zm1_g = -1.0_wp / grav |
|---|
| 398 | zm1_2g = -0.5_wp / grav |
|---|
| 399 | z1_slpmax = 1._wp / rn_slpmax |
|---|
| 400 | ! |
|---|
| 401 | uslpml (1,:) = 0._wp ; uslpml (jpi,:) = 0._wp |
|---|
| 402 | vslpml (1,:) = 0._wp ; vslpml (jpi,:) = 0._wp |
|---|
| 403 | wslpiml(1,:) = 0._wp ; wslpiml(jpi,:) = 0._wp |
|---|
| 404 | wslpjml(1,:) = 0._wp ; wslpjml(jpi,:) = 0._wp |
|---|
| 405 | ! |
|---|
| 406 | ! !== surface mixed layer mask ! |
|---|
| 407 | DO jk = 1, jpk ! =1 inside the mixed layer, =0 otherwise |
|---|
| 408 | DO jj = 1, jpj |
|---|
| 409 | DO ji = 1, jpi |
|---|
| 410 | ik = nmln(ji,jj) - 1 |
|---|
| 411 | IF( jk <= ik ) THEN ; omlmask(ji,jj,jk) = 1._wp |
|---|
| 412 | ELSE ; omlmask(ji,jj,jk) = 0._wp |
|---|
| 413 | ENDIF |
|---|
| 414 | END DO |
|---|
| 415 | END DO |
|---|
| 416 | END DO |
|---|
| 417 | |
|---|
| 418 | |
|---|
| 419 | ! Slopes of isopycnal surfaces just before bottom of mixed layer |
|---|
| 420 | ! -------------------------------------------------------------- |
|---|
| 421 | ! The slope are computed as in the 3D case. |
|---|
| 422 | ! A key point here is the definition of the mixed layer at u- and v-points. |
|---|
| 423 | ! It is assumed to be the maximum of the two neighbouring T-point mixed layer depth. |
|---|
| 424 | ! Otherwise, a n2 value inside the mixed layer can be involved in the computation |
|---|
| 425 | ! of the slope, resulting in a too steep diagnosed slope and thus a spurious eddy |
|---|
| 426 | ! induce velocity field near the base of the mixed layer. |
|---|
| 427 | !----------------------------------------------------------------------- |
|---|
| 428 | ! |
|---|
| 429 | DO jj = 2, jpjm1 |
|---|
| 430 | DO ji = 2, jpim1 |
|---|
| 431 | ! !== Slope at u- & v-points just below the Mixed Layer ==! |
|---|
| 432 | ! |
|---|
| 433 | ! !- vertical density gradient for u- and v-slopes (from dzr at T-point) |
|---|
| 434 | iku = MIN( MAX( 1, nmln(ji,jj) , nmln(ji+1,jj) ) , jpkm1 ) ! ML (MAX of T-pts, bound by jpkm1) |
|---|
| 435 | ikv = MIN( MAX( 1, nmln(ji,jj) , nmln(ji,jj+1) ) , jpkm1 ) ! |
|---|
| 436 | zbu = 0.5_wp * ( p_dzr(ji,jj,iku) + p_dzr(ji+1,jj ,iku) ) |
|---|
| 437 | zbv = 0.5_wp * ( p_dzr(ji,jj,ikv) + p_dzr(ji ,jj+1,ikv) ) |
|---|
| 438 | ! !- horizontal density gradient at u- & v-points |
|---|
| 439 | zau = p_gru(ji,jj,iku) * r1_e1u(ji,jj) |
|---|
| 440 | zav = p_grv(ji,jj,ikv) * r1_e2v(ji,jj) |
|---|
| 441 | ! !- bound the slopes: abs(zw.)<= 1/100 and zb..<0 |
|---|
| 442 | ! kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 443 | zbu = MIN( zbu , - z1_slpmax * ABS( zau ) , -7.e+3_wp/e3u_n(ji,jj,iku)* ABS( zau ) ) |
|---|
| 444 | zbv = MIN( zbv , - z1_slpmax * ABS( zav ) , -7.e+3_wp/e3v_n(ji,jj,ikv)* ABS( zav ) ) |
|---|
| 445 | ! !- Slope at u- & v-points (uslpml, vslpml) |
|---|
| 446 | uslpml(ji,jj) = zau / ( zbu - zeps ) * umask(ji,jj,iku) |
|---|
| 447 | vslpml(ji,jj) = zav / ( zbv - zeps ) * vmask(ji,jj,ikv) |
|---|
| 448 | ! |
|---|
| 449 | ! !== i- & j-slopes at w-points just below the Mixed Layer ==! |
|---|
| 450 | ! |
|---|
| 451 | ik = MIN( nmln(ji,jj) + 1, jpk ) |
|---|
| 452 | ikm1 = MAX( 1, ik-1 ) |
|---|
| 453 | ! !- vertical density gradient for w-slope (from N^2) |
|---|
| 454 | zbw = zm1_2g * pn2 (ji,jj,ik) * ( prd (ji,jj,ik) + prd (ji,jj,ikm1) + 2. ) |
|---|
| 455 | ! !- horizontal density i- & j-gradient at w-points |
|---|
| 456 | zci = MAX( umask(ji-1,jj,ik ) + umask(ji,jj,ik ) & |
|---|
| 457 | & + umask(ji-1,jj,ikm1) + umask(ji,jj,ikm1) , zeps ) * e1t(ji,jj) |
|---|
| 458 | zcj = MAX( vmask(ji,jj-1,ik ) + vmask(ji,jj,ik ) & |
|---|
| 459 | & + vmask(ji,jj-1,ikm1) + vmask(ji,jj,ikm1) , zeps ) * e2t(ji,jj) |
|---|
| 460 | zai = ( p_gru(ji-1,jj,ik ) + p_gru(ji,jj,ik) & |
|---|
| 461 | & + p_gru(ji-1,jj,ikm1) + p_gru(ji,jj,ikm1 ) ) / zci * tmask(ji,jj,ik) |
|---|
| 462 | zaj = ( p_grv(ji,jj-1,ik ) + p_grv(ji,jj,ik ) & |
|---|
| 463 | & + p_grv(ji,jj-1,ikm1) + p_grv(ji,jj,ikm1) ) / zcj * tmask(ji,jj,ik) |
|---|
| 464 | ! !- bound the slopes: abs(zw.)<= 1/100 and zb..<0. |
|---|
| 465 | ! kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 466 | zbi = MIN( zbw , -100._wp* ABS( zai ) , -7.e+3_wp/e3w_n(ji,jj,ik)* ABS( zai ) ) |
|---|
| 467 | zbj = MIN( zbw , -100._wp* ABS( zaj ) , -7.e+3_wp/e3w_n(ji,jj,ik)* ABS( zaj ) ) |
|---|
| 468 | ! !- i- & j-slope at w-points (wslpiml, wslpjml) |
|---|
| 469 | wslpiml(ji,jj) = zai / ( zbi - zeps ) * tmask (ji,jj,ik) |
|---|
| 470 | wslpjml(ji,jj) = zaj / ( zbj - zeps ) * tmask (ji,jj,ik) |
|---|
| 471 | END DO |
|---|
| 472 | END DO |
|---|
| 473 | !$ACC END KERNELS |
|---|
| 474 | !!gm this lbc_lnk should be useless.... |
|---|
| 475 | ! MJB CALL lbc_lnk_multi( uslpml , 'U', -1. , vslpml , 'V', -1. , wslpiml, 'W', -1. , wslpjml, 'W', -1. ) |
|---|
| 476 | ! |
|---|
| 477 | END SUBROUTINE ldf_slp_mxl |
|---|
| 478 | |
|---|
| 479 | |
|---|
| 480 | |
|---|
| 481 | !!====================================================================== |
|---|
| 482 | END MODULE ldfslp |
|---|
