New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icbrst.F90 in NEMO/branches/UKMO/NEMO4_beta_mirror/src/OCE/ICB – NEMO

source: NEMO/branches/UKMO/NEMO4_beta_mirror/src/OCE/ICB/icbrst.F90 @ 9950

Last change on this file since 9950 was 9950, checked in by davestorkey, 6 years ago

UKMO/NEMO4_beta_mirror branch: remove SVN keywords
File size: 20.4 KB
Line 
1MODULE icbrst
2   !!======================================================================
3   !!                       ***  MODULE  icbrst  ***
4   !! Ocean physics:  read and write iceberg restart files
5   !!======================================================================
6   !! History : 3.3.1 !  2010-01  (Martin&Adcroft) Original code
7   !!            -    !  2011-03  (Madec)          Part conversion to NEMO form
8   !!            -    !                            Removal of mapping from another grid
9   !!            -    !  2011-04  (Alderson)       Split into separate modules
10   !!            -    !  2011-04  (Alderson)       Restore restart routine
11   !!            -    !                            Currently needs a fixed processor
12   !!            -    !                            layout between restarts
13   !!            -    !  2015-11  Dave Storkey     Convert icb_rst_read to use IOM so can
14   !!                                              read single restart files
15   !!----------------------------------------------------------------------
16
17   !!----------------------------------------------------------------------
18   !!   icb_rst_read    : read restart file
19   !!   icb_rst_write   : write restart file
20   !!----------------------------------------------------------------------
21   USE par_oce        ! NEMO parameters
22   USE dom_oce        ! NEMO domain
23   USE in_out_manager ! NEMO IO routines
24   USE lib_mpp        ! NEMO MPI library, lk_mpp in particular
25   USE netcdf         ! netcdf routines for IO
26   USE iom
27   USE icb_oce        ! define iceberg arrays
28   USE icbutl         ! iceberg utility routines
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   icb_rst_read    ! routine called in icbini.F90 module
34   PUBLIC   icb_rst_write   ! routine called in icbstp.F90 module
35   
36   INTEGER ::   nlonid, nlatid, nxid, nyid, nuvelid, nvvelid
37   INTEGER ::   nmassid, nthicknessid, nwidthid, nlengthid
38   INTEGER ::   nyearid, ndayid
39   INTEGER ::   nscaling_id, nmass_of_bits_id, nheat_density_id, numberid
40   INTEGER ::   nsiceid, nsheatid, ncalvid, ncalvhid, nkountid
41   INTEGER ::   nret, ncid, nc_dim
42   
43   INTEGER,  DIMENSION(3)                  :: nstrt3, nlngth3
44
45   !!----------------------------------------------------------------------
46   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
47   !! $Id$
48   !! Software governed by the CeCILL licence     (./LICENSE)
49   !!----------------------------------------------------------------------
50CONTAINS
51
52   SUBROUTINE icb_rst_read()
53      !!----------------------------------------------------------------------
54      !!                 ***  SUBROUTINE icb_rst_read  ***
55      !!
56      !! ** Purpose :   read a iceberg restart file
57      !!      NB: for this version, we just read back in the restart for this processor
58      !!      so we cannot change the processor layout currently with iceberg code
59      !!----------------------------------------------------------------------
60      INTEGER                      ::   idim, ivar, iatt
61      INTEGER                      ::   jn, iunlim_dim, ibergs_in_file
62      INTEGER                      ::   ii,ij,iclass
63      REAL(wp), DIMENSION(nkounts) ::   zdata     
64      LOGICAL                      ::   ll_found_restart
65      CHARACTER(len=256)           ::   cl_path
66      CHARACTER(len=256)           ::   cl_filename
67      CHARACTER(len=NF90_MAX_NAME) ::   cl_dname
68      TYPE(iceberg)                ::   localberg ! NOT a pointer but an actual local variable
69      TYPE(point)                  ::   localpt   ! NOT a pointer but an actual local variable
70      !!----------------------------------------------------------------------
71
72      ! Find a restart file. Assume iceberg restarts in same directory as ocean restarts
73      ! and are called TRIM(cn_ocerst)//'_icebergs'
74      cl_path = TRIM(cn_ocerst_indir)
75      IF( cl_path(LEN_TRIM(cl_path):) /= '/' ) cl_path = TRIM(cl_path) // '/'
76      cl_filename = TRIM(cn_ocerst_in)//'_icebergs'
77      CALL iom_open( TRIM(cl_path)//cl_filename, ncid )
78
79      IF( iom_file(ncid)%iduld .GE. 0) THEN
80
81         ibergs_in_file = iom_file(ncid)%lenuld
82         DO jn = 1,ibergs_in_file
83
84            ! iom_get treats the unlimited dimension as time. Here the unlimited dimension
85            ! is the iceberg index, but we can still use the ktime keyword to get the iceberg we want.
86
87            CALL iom_get( ncid, 'xi'     ,localpt%xi  , ktime=jn )
88            CALL iom_get( ncid, 'yj'     ,localpt%yj  , ktime=jn )
89
90            ii = INT( localpt%xi + 0.5 )
91            ij = INT( localpt%yj + 0.5 )
92            ! Only proceed if this iceberg is on the local processor (excluding halos).
93            IF ( ii .GE. nldi+nimpp-1 .AND. ii .LE. nlei+nimpp-1 .AND. &
94           &     ij .GE. nldj+njmpp-1 .AND. ij .LE. nlej+njmpp-1 ) THEN           
95
96               CALL iom_get( ncid, jpdom_unknown, 'number'       , zdata(:) , ktime=jn, kstart=(/1/), kcount=(/nkounts/) )
97               localberg%number(:) = INT(zdata(:))
98               CALL iom_get( ncid, 'mass_scaling' , localberg%mass_scaling, ktime=jn )
99               CALL iom_get( ncid, 'lon'          , localpt%lon           , ktime=jn )
100               CALL iom_get( ncid, 'lat'          , localpt%lat           , ktime=jn )
101               CALL iom_get( ncid, 'uvel'         , localpt%uvel          , ktime=jn )
102               CALL iom_get( ncid, 'vvel'         , localpt%vvel          , ktime=jn )
103               CALL iom_get( ncid, 'mass'         , localpt%mass          , ktime=jn )
104               CALL iom_get( ncid, 'thickness'    , localpt%thickness     , ktime=jn )
105               CALL iom_get( ncid, 'width'        , localpt%width         , ktime=jn )
106               CALL iom_get( ncid, 'length'       , localpt%length        , ktime=jn )
107               CALL iom_get( ncid, 'year'         , zdata(1)              , ktime=jn )
108               localpt%year = INT(zdata(1))
109               CALL iom_get( ncid, 'day'          , localpt%day           , ktime=jn )
110               CALL iom_get( ncid, 'mass_of_bits' , localpt%mass_of_bits  , ktime=jn )
111               CALL iom_get( ncid, 'heat_density' , localpt%heat_density  , ktime=jn )
112               !
113               CALL icb_utl_add( localberg, localpt )
114               !
115            ENDIF
116            !
117         END DO
118         !
119      ELSE
120         ibergs_in_file = 0
121      ENDIF 
122
123      ! Gridded variables
124      CALL iom_get( ncid, jpdom_autoglo,    'calving'     , src_calving  )
125      CALL iom_get( ncid, jpdom_autoglo,    'calving_hflx', src_calving_hflx  )
126      CALL iom_get( ncid, jpdom_autoglo,    'stored_heat' , berg_grid%stored_heat  )
127      CALL iom_get( ncid, jpdom_autoglo_xy, 'stored_ice'  , berg_grid%stored_ice, kstart=(/1,1,1/), kcount=(/1,1,nclasses/) )
128     
129      CALL iom_get( ncid, jpdom_unknown, 'kount' , zdata(:) )
130      num_bergs(:) = INT(zdata(:))
131
132      ! Sanity check
133      jn = icb_utl_count()
134      IF ( lwp .AND. nn_verbose_level >= 0 )   &
135         WRITE(numout,'(2(a,i5))') 'icebergs, read_restart_bergs: # bergs =',jn,' on PE',narea-1
136      IF( lk_mpp ) THEN
137         ! Only mpp_sum ibergs_in_file if we are reading from multiple restart files.
138         IF( INDEX(iom_file(ncid)%name,'icebergs.nc' ) .EQ. 0 ) CALL mpp_sum(ibergs_in_file)
139         CALL mpp_sum(jn)
140      ENDIF
141      IF( lwp )   WRITE(numout,'(a,i5,a,i5,a)') 'icebergs, icb_rst_read: there were',ibergs_in_file,   &
142         &                                    ' bergs in the restart file and', jn,' bergs have been read'
143      !
144      ! Finish up
145      CALL iom_close( ncid )
146      !
147      IF( lwp .AND. nn_verbose_level >= 0 )  WRITE(numout,'(a)') 'icebergs, icb_rst_read: completed'
148      !
149   END SUBROUTINE icb_rst_read
150
151
152   SUBROUTINE icb_rst_write( kt )
153      !!----------------------------------------------------------------------
154      !!                 ***  SUBROUTINE icb_rst_write  ***
155      !!
156      !!----------------------------------------------------------------------
157      INTEGER, INTENT( in ) :: kt
158      !
159      INTEGER ::   jn   ! dummy loop index
160      INTEGER ::   ix_dim, iy_dim, ik_dim, in_dim
161      CHARACTER(len=256)     :: cl_path
162      CHARACTER(len=256)     :: cl_filename
163      TYPE(iceberg), POINTER :: this
164      TYPE(point)  , POINTER :: pt
165      !!----------------------------------------------------------------------
166
167      ! Following the normal restart procedure, this routine will be called
168      ! the timestep before a restart stage as well as the restart timestep.
169      ! This is a performance step enabling the file to be opened and contents
170      ! defined in advance of the write. This is not possible with icebergs
171      ! since the number of bergs to be written could change between timesteps
172      IF( kt == nitrst ) THEN
173         ! Only operate on the restart timestep itself.
174         ! Assume we write iceberg restarts to same directory as ocean restarts.
175         cl_path = TRIM(cn_ocerst_outdir)
176         IF( cl_path(LEN_TRIM(cl_path):) /= '/' ) cl_path = TRIM(cl_path) // '/'
177         IF( lk_mpp ) THEN
178            WRITE(cl_filename,'(A,"_icebergs_",I8.8,"_restart_",I4.4,".nc")') TRIM(cexper), kt, narea-1
179         ELSE
180            WRITE(cl_filename,'(A,"_icebergs_",I8.8,"_restart.nc")') TRIM(cexper), kt
181         ENDIF
182         IF ( lwp .AND. nn_verbose_level >= 0) WRITE(numout,'(2a)') 'icebergs, write_restart: creating ',  &
183           &                                                         TRIM(cl_path)//TRIM(cl_filename)
184   
185         nret = NF90_CREATE(TRIM(cl_path)//TRIM(cl_filename), NF90_CLOBBER, ncid)
186         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_create failed')
187   
188         ! Dimensions
189         nret = NF90_DEF_DIM(ncid, 'x', jpi, ix_dim)
190         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim x failed')
191   
192         nret = NF90_DEF_DIM(ncid, 'y', jpj, iy_dim)
193         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim y failed')
194   
195         nret = NF90_DEF_DIM(ncid, 'c', nclasses, nc_dim)
196         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim c failed')
197   
198         nret = NF90_DEF_DIM(ncid, 'k', nkounts, ik_dim)
199         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim k failed')
200   
201         ! global attributes
202         IF( lk_mpp ) THEN
203            ! Set domain parameters (assume jpdom_local_full)
204            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_number_total'   , jpnij              )
205            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_number'         , narea-1            )
206            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_dimensions_ids' , (/1     , 2     /) )
207            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_size_global'    , (/jpiglo, jpjglo/) )
208            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_size_local'     , (/jpi   , jpj   /) )
209            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_position_first' , (/nimpp , njmpp /) )
210            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_position_last'  , (/nimpp + jpi - 1 , njmpp + jpj - 1  /) )
211            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_halo_size_start', (/nldi - 1        , nldj - 1         /) )
212            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_halo_size_end'  , (/jpi - nlei      , jpj - nlej       /) )
213            nret = NF90_PUT_ATT( ncid, NF90_GLOBAL, 'DOMAIN_type'           , 'BOX'              )
214         ENDIF
215         
216         IF (associated(first_berg)) then
217            nret = NF90_DEF_DIM(ncid, 'n', NF90_UNLIMITED, in_dim)
218            IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_def_dim n failed')
219         ENDIF
220   
221         ! Variables
222         nret = NF90_DEF_VAR(ncid, 'kount'       , NF90_INT   , (/ ik_dim /), nkountid)
223         nret = NF90_DEF_VAR(ncid, 'calving'     , NF90_DOUBLE, (/ ix_dim, iy_dim /), ncalvid)
224         nret = NF90_DEF_VAR(ncid, 'calving_hflx', NF90_DOUBLE, (/ ix_dim, iy_dim /), ncalvhid)
225         nret = NF90_DEF_VAR(ncid, 'stored_ice'  , NF90_DOUBLE, (/ ix_dim, iy_dim, nc_dim /), nsiceid)
226         nret = NF90_DEF_VAR(ncid, 'stored_heat' , NF90_DOUBLE, (/ ix_dim, iy_dim /), nsheatid)
227   
228         ! Attributes
229         nret = NF90_PUT_ATT(ncid, ncalvid , 'long_name', 'iceberg calving')
230         nret = NF90_PUT_ATT(ncid, ncalvid , 'units', 'some')
231         nret = NF90_PUT_ATT(ncid, ncalvhid, 'long_name', 'heat flux associated with iceberg calving')
232         nret = NF90_PUT_ATT(ncid, ncalvhid, 'units', 'some')
233         nret = NF90_PUT_ATT(ncid, nsiceid , 'long_name', 'stored ice used to calve icebergs')
234         nret = NF90_PUT_ATT(ncid, nsiceid , 'units', 'kg/s')
235         nret = NF90_PUT_ATT(ncid, nsheatid, 'long_name', 'heat in stored ice used to calve icebergs')
236         nret = NF90_PUT_ATT(ncid, nsheatid, 'units', 'J/kg/s')
237   
238         IF ( ASSOCIATED(first_berg) ) THEN
239   
240            ! Only add berg variables for this PE if we have anything to say
241   
242            ! Variables
243            nret = NF90_DEF_VAR(ncid, 'lon', NF90_DOUBLE, in_dim, nlonid)
244            nret = NF90_DEF_VAR(ncid, 'lat', NF90_DOUBLE, in_dim, nlatid)
245            nret = NF90_DEF_VAR(ncid, 'xi', NF90_DOUBLE, in_dim, nxid)
246            nret = NF90_DEF_VAR(ncid, 'yj', NF90_DOUBLE, in_dim, nyid)
247            nret = NF90_DEF_VAR(ncid, 'uvel', NF90_DOUBLE, in_dim, nuvelid)
248            nret = NF90_DEF_VAR(ncid, 'vvel', NF90_DOUBLE, in_dim, nvvelid)
249            nret = NF90_DEF_VAR(ncid, 'mass', NF90_DOUBLE, in_dim, nmassid)
250            nret = NF90_DEF_VAR(ncid, 'thickness', NF90_DOUBLE, in_dim, nthicknessid)
251            nret = NF90_DEF_VAR(ncid, 'width', NF90_DOUBLE, in_dim, nwidthid)
252            nret = NF90_DEF_VAR(ncid, 'length', NF90_DOUBLE, in_dim, nlengthid)
253            nret = NF90_DEF_VAR(ncid, 'number', NF90_INT, (/ik_dim,in_dim/), numberid)
254            nret = NF90_DEF_VAR(ncid, 'year', NF90_INT, in_dim, nyearid)
255            nret = NF90_DEF_VAR(ncid, 'day', NF90_DOUBLE, in_dim, ndayid)
256            nret = NF90_DEF_VAR(ncid, 'mass_scaling', NF90_DOUBLE, in_dim, nscaling_id)
257            nret = NF90_DEF_VAR(ncid, 'mass_of_bits', NF90_DOUBLE, in_dim, nmass_of_bits_id)
258            nret = NF90_DEF_VAR(ncid, 'heat_density', NF90_DOUBLE, in_dim, nheat_density_id)
259   
260            ! Attributes
261            nret = NF90_PUT_ATT(ncid, nlonid, 'long_name', 'longitude')
262            nret = NF90_PUT_ATT(ncid, nlonid, 'units', 'degrees_E')
263            nret = NF90_PUT_ATT(ncid, nlatid, 'long_name', 'latitude')
264            nret = NF90_PUT_ATT(ncid, nlatid, 'units', 'degrees_N')
265            nret = NF90_PUT_ATT(ncid, nxid, 'long_name', 'x grid box position')
266            nret = NF90_PUT_ATT(ncid, nxid, 'units', 'fractional')
267            nret = NF90_PUT_ATT(ncid, nyid, 'long_name', 'y grid box position')
268            nret = NF90_PUT_ATT(ncid, nyid, 'units', 'fractional')
269            nret = NF90_PUT_ATT(ncid, nuvelid, 'long_name', 'zonal velocity')
270            nret = NF90_PUT_ATT(ncid, nuvelid, 'units', 'm/s')
271            nret = NF90_PUT_ATT(ncid, nvvelid, 'long_name', 'meridional velocity')
272            nret = NF90_PUT_ATT(ncid, nvvelid, 'units', 'm/s')
273            nret = NF90_PUT_ATT(ncid, nmassid, 'long_name', 'mass')
274            nret = NF90_PUT_ATT(ncid, nmassid, 'units', 'kg')
275            nret = NF90_PUT_ATT(ncid, nthicknessid, 'long_name', 'thickness')
276            nret = NF90_PUT_ATT(ncid, nthicknessid, 'units', 'm')
277            nret = NF90_PUT_ATT(ncid, nwidthid, 'long_name', 'width')
278            nret = NF90_PUT_ATT(ncid, nwidthid, 'units', 'm')
279            nret = NF90_PUT_ATT(ncid, nlengthid, 'long_name', 'length')
280            nret = NF90_PUT_ATT(ncid, nlengthid, 'units', 'm')
281            nret = NF90_PUT_ATT(ncid, numberid, 'long_name', 'iceberg number on this processor')
282            nret = NF90_PUT_ATT(ncid, numberid, 'units', 'count')
283            nret = NF90_PUT_ATT(ncid, nyearid, 'long_name', 'calendar year of calving event')
284            nret = NF90_PUT_ATT(ncid, nyearid, 'units', 'years')
285            nret = NF90_PUT_ATT(ncid, ndayid, 'long_name', 'year day of calving event')
286            nret = NF90_PUT_ATT(ncid, ndayid, 'units', 'days')
287            nret = NF90_PUT_ATT(ncid, nscaling_id, 'long_name', 'scaling factor for mass of calving berg')
288            nret = NF90_PUT_ATT(ncid, nscaling_id, 'units', 'none')
289            nret = NF90_PUT_ATT(ncid, nmass_of_bits_id, 'long_name', 'mass of bergy bits')
290            nret = NF90_PUT_ATT(ncid, nmass_of_bits_id, 'units', 'kg')
291            nret = NF90_PUT_ATT(ncid, nheat_density_id, 'long_name', 'heat density')
292            nret = NF90_PUT_ATT(ncid, nheat_density_id, 'units', 'J/kg')
293   
294         ENDIF ! associated(first_berg)
295   
296         ! End define mode
297         nret = NF90_ENDDEF(ncid)
298   
299         ! --------------------------------
300         ! now write some data
301   
302         nstrt3(1) = 1
303         nstrt3(2) = 1
304         nlngth3(1) = jpi
305         nlngth3(2) = jpj
306         nlngth3(3) = 1
307   
308         DO jn=1,nclasses
309            griddata(:,:,1) = berg_grid%stored_ice(:,:,jn)
310            nstrt3(3) = jn
311            nret = NF90_PUT_VAR( ncid, nsiceid, griddata, nstrt3, nlngth3 )
312            IF (nret .ne. NF90_NOERR) THEN
313               IF( lwp ) WRITE(numout,*) TRIM(NF90_STRERROR( nret ))
314               CALL ctl_stop('icebergs, write_restart: nf_put_var stored_ice failed')
315            ENDIF
316         ENDDO
317         IF( lwp ) WRITE(numout,*) 'file: ',TRIM(cl_path)//TRIM(cl_filename),' var: stored_ice  written'
318   
319         nret = NF90_PUT_VAR( ncid, nkountid, num_bergs(:) )
320         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var kount failed')
321   
322         nret = NF90_PUT_VAR( ncid, nsheatid, berg_grid%stored_heat(:,:) )
323         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var stored_heat failed')
324         IF( lwp ) WRITE(numout,*) 'file: ',TRIM(cl_path)//TRIM(cl_filename),' var: stored_heat written'
325   
326         nret = NF90_PUT_VAR( ncid, ncalvid , src_calving(:,:) )
327         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var calving failed')
328         nret = NF90_PUT_VAR( ncid, ncalvhid, src_calving_hflx(:,:) )
329         IF (nret .ne. NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_put_var calving_hflx failed')
330         IF( lwp ) WRITE(numout,*) 'file: ',TRIM(cl_path)//TRIM(cl_filename),' var: calving written'
331   
332         IF ( ASSOCIATED(first_berg) ) THEN
333   
334            ! Write variables
335            ! just write out the current point of the trajectory
336   
337            this => first_berg
338            jn = 0
339            DO WHILE (ASSOCIATED(this))
340               pt => this%current_point
341               jn=jn+1
342   
343               nret = NF90_PUT_VAR(ncid, numberid, this%number, (/1,jn/), (/nkounts,1/) )
344               nret = NF90_PUT_VAR(ncid, nscaling_id, this%mass_scaling, (/ jn /) )
345   
346               nret = NF90_PUT_VAR(ncid, nlonid, pt%lon, (/ jn /) )
347               nret = NF90_PUT_VAR(ncid, nlatid, pt%lat, (/ jn /) )
348               nret = NF90_PUT_VAR(ncid, nxid, pt%xi, (/ jn /) )
349               nret = NF90_PUT_VAR(ncid, nyid, pt%yj, (/ jn /) )
350               nret = NF90_PUT_VAR(ncid, nuvelid, pt%uvel, (/ jn /) )
351               nret = NF90_PUT_VAR(ncid, nvvelid, pt%vvel, (/ jn /) )
352               nret = NF90_PUT_VAR(ncid, nmassid, pt%mass, (/ jn /) )
353               nret = NF90_PUT_VAR(ncid, nthicknessid, pt%thickness, (/ jn /) )
354               nret = NF90_PUT_VAR(ncid, nwidthid, pt%width, (/ jn /) )
355               nret = NF90_PUT_VAR(ncid, nlengthid, pt%length, (/ jn /) )
356               nret = NF90_PUT_VAR(ncid, nyearid, pt%year, (/ jn /) )
357               nret = NF90_PUT_VAR(ncid, ndayid, pt%day, (/ jn /) )
358               nret = NF90_PUT_VAR(ncid, nmass_of_bits_id, pt%mass_of_bits, (/ jn /) )
359               nret = NF90_PUT_VAR(ncid, nheat_density_id, pt%heat_density, (/ jn /) )
360   
361               this=>this%next
362            END DO
363            !
364         ENDIF ! associated(first_berg)
365   
366         ! Finish up
367         nret = NF90_CLOSE(ncid)
368         IF (nret /= NF90_NOERR) CALL ctl_stop('icebergs, write_restart: nf_close failed')
369   
370         ! Sanity check
371         jn = icb_utl_count()
372         IF ( lwp .AND. nn_verbose_level >= 0)   &
373            WRITE(numout,'(2(a,i5))') 'icebergs, icb_rst_write: # bergs =',jn,' on PE',narea-1
374         IF( lk_mpp ) THEN
375            CALL mpp_sum(jn)
376         ENDIF
377         IF(lwp)   WRITE(numout,'(a,i5,a,i5,a)') 'icebergs, icb_rst_write: ', jn,   &
378            &                                    ' bergs in total have been written at timestep ', kt
379         !
380         ! Finish up
381         !
382      ENDIF
383   END SUBROUTINE icb_rst_write
384   !
385   !!======================================================================
386END MODULE icbrst
Note: See TracBrowser for help on using the repository browser.