New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
restart.F90 in NEMO/branches/UKMO/NEMO_4.0.1_GO8_package/src/OCE/IOM – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.1_GO8_package/src/OCE/IOM/restart.F90 @ 11717

Last change on this file since 11717 was 11717, checked in by davestorkey, 5 years ago

UKMO/NEMO_4.0.1_GO8_package: copy over changes from NEMO_4.0_GO8_package branch.
File size: 16.5 KB
Line 
1MODULE restart
2   !!======================================================================
3   !!                     ***  MODULE  restart  ***
4   !! Ocean restart :  write the ocean restart file
5   !!======================================================================
6   !! History :  OPA  !  1999-11  (M. Imbard)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec)  F90: Free form
8   !!            2.0  !  2006-07  (S. Masson)  use IOM for restart
9   !!            3.3  !  2010-04  (M. Leclair, G. Madec)  modified LF-RA
10   !!            - -  !  2010-10  (C. Ethe, G. Madec) TRC-TRA merge (T-S in 4D)
11   !!            3.7  !  2014-01  (G. Madec) suppression of curl and hdiv from the restart
12   !!             -   !  2014-12  (G. Madec) remove KPP scheme
13   !!----------------------------------------------------------------------
14
15   !!----------------------------------------------------------------------
16   !!   rst_opn    : open the ocean restart file
17   !!   rst_write  : write the ocean restart file
18   !!   rst_read   : read the ocean restart file
19   !!----------------------------------------------------------------------
20   USE oce             ! ocean dynamics and tracers
21   USE dom_oce         ! ocean space and time domain
22   USE sbc_ice         ! only lk_si3
23   USE phycst          ! physical constants
24   USE eosbn2          ! equation of state            (eos bn2 routine)
25   USE trdmxl_oce      ! ocean active mixed layer tracers trends variables
26   !
27   USE in_out_manager  ! I/O manager
28   USE iom             ! I/O module
29   USE ioipsl, ONLY : ju2ymds    ! for calendar
30   USE diurnal_bulk
31   USE lib_mpp         ! distribued memory computing library
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   rst_opn         ! routine called by step module
37   PUBLIC   rst_write       ! routine called by step module
38   PUBLIC   rst_read        ! routine called by istate module
39   PUBLIC   rst_read_open   ! routine called in rst_read and (possibly) in dom_vvl_init
40
41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
45   !! $Id$
46   !! Software governed by the CeCILL license (see ./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50   SUBROUTINE rst_opn( kt )
51      !!---------------------------------------------------------------------
52      !!                   ***  ROUTINE rst_opn  ***
53      !!                     
54      !! ** Purpose : + initialization (should be read in the namelist) of nitrst
55      !!              + open the restart when we are one time step before nitrst
56      !!                   - restart header is defined when kt = nitrst-1
57      !!                   - restart data  are written when kt = nitrst
58      !!              + define lrst_oce to .TRUE. when we need to define or write the restart
59      !!----------------------------------------------------------------------
60      INTEGER, INTENT(in) ::   kt     ! ocean time-step
61      !!
62      INTEGER             ::   iyear, imonth, iday
63      REAL (wp)           ::   zsec
64      REAL (wp)           ::   zfjulday
65      CHARACTER(LEN=20)   ::   clkt     ! ocean time-step deine as a character
66      CHARACTER(LEN=50)   ::   clname   ! ocean output restart file name
67      CHARACTER(lc)       ::   clpath   ! full path to ocean output restart file
68      CHARACTER(LEN=52)   ::   clpname   ! ocean output restart file name including prefix for AGRIF
69      CHARACTER(LEN=256)  ::   clinfo    ! info character
70      !!----------------------------------------------------------------------
71      !
72      IF( kt == nit000 ) THEN   ! default definitions
73         lrst_oce = .FALSE.   
74         IF( ln_rst_list ) THEN
75            nrst_lst = 1
76            nitrst = nn_stocklist( nrst_lst )
77         ELSE
78            nitrst = nitend
79         ENDIF
80      ENDIF
81     
82      IF( .NOT. ln_rst_list .AND. nn_stock == -1 )   RETURN   ! we will never do any restart
83
84      ! frequency-based restart dumping (nn_stock)
85      IF( .NOT. ln_rst_list .AND. MOD( kt - 1, nn_stock ) == 0 ) THEN   
86         ! we use kt - 1 and not kt - nit000 to keep the same periodicity from the beginning of the experiment
87         nitrst = kt + nn_stock - 1                  ! define the next value of nitrst for restart writing
88         IF( nitrst > nitend )   nitrst = nitend   ! make sure we write a restart at the end of the run
89      ENDIF
90      ! to get better performances with NetCDF format:
91      ! we open and define the ocean restart file one time step before writing the data (-> at nitrst - 1)
92      ! except if we write ocean restart files every time step or if an ocean restart file was writen at nitend - 1
93      IF( kt == nitrst - 1 .OR. nn_stock == 1 .OR. ( kt == nitend .AND. .NOT. lrst_oce ) ) THEN
94         IF( nitrst <= nitend .AND. nitrst > 0 ) THEN 
95            ! beware of the format used to write kt (default is i8.8, that should be large enough...)
96            IF ( ln_rstdate ) THEN
97               zfjulday = fjulday + rdt / rday
98               IF( ABS(zfjulday - REAL(NINT(zfjulday),wp)) < 0.1 / rday )   zfjulday = REAL(NINT(zfjulday),wp)   ! avoid truncation error
99               CALL ju2ymds( zfjulday, iyear, imonth, iday, zsec )           
100               WRITE(clkt, '(i4.4,2i2.2)') iyear, imonth, iday
101            ELSE
102               IF( nitrst > 999999999 ) THEN   ;   WRITE(clkt, *       ) nitrst
103               ELSE                            ;   WRITE(clkt, '(i8.8)') nitrst
104               ENDIF
105            ENDIF
106            ! create the file
107            clname = TRIM(cexper)//"_"//TRIM(ADJUSTL(clkt))//"_"//TRIM(cn_ocerst_out)
108            clpath = TRIM(cn_ocerst_outdir)
109            IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
110            IF(lwp) THEN
111               WRITE(numout,*)
112               IF(.NOT.lwxios) THEN
113                  WRITE(numout,*) '             open ocean restart NetCDF file: ',TRIM(clpath)//TRIM(clname)
114                  IF ( snc4set%luse )      WRITE(numout,*) '             opened for NetCDF4 chunking and compression'
115                  IF( kt == nitrst - 1 ) THEN   ;   WRITE(numout,*) '             kt = nitrst - 1 = ', kt
116                  ELSE                          ;   WRITE(numout,*) '             kt = '             , kt
117                  ENDIF
118               ENDIF
119            ENDIF
120            !
121            IF(.NOT.lwxios) THEN
122               CALL iom_open( TRIM(clpath)//TRIM(clname), numrow, ldwrt = .TRUE. )
123            ELSE
124#if defined key_iomput
125               cwxios_context = "rstw_"//TRIM(ADJUSTL(clkt))
126               IF( TRIM(Agrif_CFixed()) == '0' ) THEN
127                  clpname = clname
128               ELSE
129                  clpname = TRIM(Agrif_CFixed())//"_"//clname   
130               ENDIF
131               CALL iom_init( cwxios_context, TRIM(clpath)//TRIM(clpname), .false. )
132               CALL xios_update_calendar(nitrst)
133               CALL iom_swap(      cxios_context          )
134#else
135               clinfo = 'Can not use XIOS in rst_opn'
136               CALL ctl_stop(TRIM(clinfo))
137#endif
138            ENDIF
139            lrst_oce = .TRUE.
140         ENDIF
141      ENDIF
142      !
143   END SUBROUTINE rst_opn
144
145
146   SUBROUTINE rst_write( kt )
147      !!---------------------------------------------------------------------
148      !!                   ***  ROUTINE rstwrite  ***
149      !!                     
150      !! ** Purpose :   Write restart fields in NetCDF format
151      !!
152      !! ** Method  :   Write in numrow when kt == nitrst in NetCDF
153      !!              file, save fields which are necessary for restart
154      !!----------------------------------------------------------------------
155      INTEGER, INTENT(in) ::   kt   ! ocean time-step
156      !!----------------------------------------------------------------------
157                     IF(lwxios) CALL iom_swap(      cwxios_context          )
158                     CALL iom_rstput( kt, nitrst, numrow, 'rdt'    , rdt       , ldxios = lwxios)   ! dynamics time step
159                     CALL iom_delay_rst( 'WRITE', 'OCE', numrow )   ! save only ocean delayed global communication variables
160
161      IF ( .NOT. ln_diurnal_only ) THEN
162                     CALL iom_rstput( kt, nitrst, numrow, 'ub'     , ub, ldxios = lwxios        )     ! before fields
163                     CALL iom_rstput( kt, nitrst, numrow, 'vb'     , vb, ldxios = lwxios        )
164                     CALL iom_rstput( kt, nitrst, numrow, 'tb'     , tsb(:,:,:,jp_tem), ldxios = lwxios )
165                     CALL iom_rstput( kt, nitrst, numrow, 'sb'     , tsb(:,:,:,jp_sal), ldxios = lwxios )
166                     CALL iom_rstput( kt, nitrst, numrow, 'sshb'   , sshb, ldxios = lwxios      )
167                     !
168                     CALL iom_rstput( kt, nitrst, numrow, 'un'     , un, ldxios = lwxios        )     ! now fields
169                     CALL iom_rstput( kt, nitrst, numrow, 'vn'     , vn, ldxios = lwxios        )
170                     CALL iom_rstput( kt, nitrst, numrow, 'tn'     , tsn(:,:,:,jp_tem), ldxios = lwxios )
171                     CALL iom_rstput( kt, nitrst, numrow, 'sn'     , tsn(:,:,:,jp_sal), ldxios = lwxios )
172                     CALL iom_rstput( kt, nitrst, numrow, 'sshn'   , sshn, ldxios = lwxios      )
173                     CALL iom_rstput( kt, nitrst, numrow, 'rhop'   , rhop, ldxios = lwxios      )
174                  ! extra variable needed for the ice sheet coupling
175                  IF ( ln_iscpl ) THEN
176                     CALL iom_rstput( kt, nitrst, numrow, 'tmask'  , tmask, ldxios = lwxios ) ! need to extrapolate T/S
177                     CALL iom_rstput( kt, nitrst, numrow, 'umask'  , umask, ldxios = lwxios ) ! need to correct barotropic velocity
178                     CALL iom_rstput( kt, nitrst, numrow, 'vmask'  , vmask, ldxios = lwxios ) ! need to correct barotropic velocity
179                     CALL iom_rstput( kt, nitrst, numrow, 'smask'  , ssmask, ldxios = lwxios) ! need to correct barotropic velocity
180                     CALL iom_rstput( kt, nitrst, numrow, 'e3t_n', e3t_n(:,:,:), ldxios = lwxios )   ! need to compute temperature correction
181                     CALL iom_rstput( kt, nitrst, numrow, 'e3u_n', e3u_n(:,:,:), ldxios = lwxios )   ! need to compute bt conservation
182                     CALL iom_rstput( kt, nitrst, numrow, 'e3v_n', e3v_n(:,:,:), ldxios = lwxios )   ! need to compute bt conservation
183                     CALL iom_rstput( kt, nitrst, numrow, 'gdepw_n', gdepw_n(:,:,:), ldxios = lwxios ) ! need to compute extrapolation if vvl
184                  END IF
185      ENDIF
186     
187      IF (ln_diurnal) CALL iom_rstput( kt, nitrst, numrow, 'Dsst', x_dsst, ldxios = lwxios ) 
188      IF(lwxios) CALL iom_swap(      cxios_context          )
189      IF( kt == nitrst ) THEN
190         IF(.NOT.lwxios) THEN
191            CALL iom_close( numrow )     ! close the restart file (only at last time step)
192         ELSE
193            CALL iom_context_finalize(      cwxios_context          )
194         ENDIF
195!!gm         IF( .NOT. lk_trdmld )   lrst_oce = .FALSE.
196!!gm  not sure what to do here   ===>>>  ask to Sebastian
197         lrst_oce = .FALSE.
198            IF( ln_rst_list ) THEN
199               nrst_lst = MIN(nrst_lst + 1, SIZE(nn_stocklist,1))
200               nitrst = nn_stocklist( nrst_lst )
201            ENDIF
202      ENDIF
203      !
204   END SUBROUTINE rst_write
205
206
207   SUBROUTINE rst_read_open
208      !!----------------------------------------------------------------------
209      !!                   ***  ROUTINE rst_read_open  ***
210      !!
211      !! ** Purpose :   Open read files for NetCDF restart
212      !!
213      !! ** Method  :   Use a non-zero, positive value of numror to assess whether or not
214      !!                the file has already been opened
215      !!----------------------------------------------------------------------
216      LOGICAL        ::   llok
217      CHARACTER(lc)  ::   clpath   ! full path to ocean output restart file
218      !!----------------------------------------------------------------------
219      !
220      IF( numror <= 0 ) THEN
221         IF(lwp) THEN                                             ! Contol prints
222            WRITE(numout,*)
223            WRITE(numout,*) 'rst_read : read oce NetCDF restart file'
224            IF ( snc4set%luse )      WRITE(numout,*) 'rst_read : configured with NetCDF4 support'
225            WRITE(numout,*) '~~~~~~~~'
226         ENDIF
227         lxios_sini = .FALSE.
228         clpath = TRIM(cn_ocerst_indir)
229         IF( clpath(LEN_TRIM(clpath):) /= '/' ) clpath = TRIM(clpath) // '/'
230         CALL iom_open( TRIM(clpath)//cn_ocerst_in, numror )
231! are we using XIOS to read the data? Part above will have to modified once XIOS
232! can handle checking if variable is in the restart file (there will be no need to open
233! restart)
234         IF(.NOT.lxios_set) lrxios = lrxios.AND.lxios_sini
235         IF( lrxios) THEN
236             crxios_context = 'nemo_rst'
237             IF( .NOT.lxios_set ) THEN
238                 IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS'
239                 CALL iom_init( crxios_context, ld_tmppatch = .false. )
240                 lxios_set = .TRUE.
241             ENDIF
242         ENDIF
243         IF( TRIM(Agrif_CFixed()) /= '0' .AND. lrxios) THEN
244             CALL iom_init( crxios_context, ld_tmppatch = .false. )
245             IF(lwp) WRITE(numout,*) 'Enable restart reading by XIOS for AGRIF'
246             lxios_set = .TRUE.
247         ENDIF
248      ENDIF
249
250   END SUBROUTINE rst_read_open
251
252
253   SUBROUTINE rst_read
254      !!----------------------------------------------------------------------
255      !!                   ***  ROUTINE rst_read  ***
256      !!
257      !! ** Purpose :   Read files for NetCDF restart
258      !!
259      !! ** Method  :   Read in restart.nc file fields which are necessary for restart
260      !!----------------------------------------------------------------------
261      REAL(wp) ::   zrdt
262      INTEGER  ::   jk
263      REAL(wp), DIMENSION(jpi, jpj, jpk) :: w3d
264      !!----------------------------------------------------------------------
265
266      CALL rst_read_open           ! open restart for reading (if not already opened)
267
268      ! Check dynamics and tracer time-step consistency and force Euler restart if changed
269      IF( iom_varid( numror, 'rdt', ldstop = .FALSE. ) > 0 )   THEN
270         CALL iom_get( numror, 'rdt', zrdt, ldxios = lrxios )
271         IF( zrdt /= rdt )   neuler = 0
272      ENDIF
273
274      CALL iom_delay_rst( 'READ', 'OCE', numror )   ! read only ocean delayed global communication variables
275     
276      ! Diurnal DSST
277      IF( ln_diurnal ) CALL iom_get( numror, jpdom_autoglo, 'Dsst' , x_dsst, ldxios = lrxios ) 
278      IF ( ln_diurnal_only ) THEN
279         IF(lwp) WRITE( numout, * ) &
280         &   "rst_read:- ln_diurnal_only set, setting rhop=rau0" 
281         rhop = rau0
282         CALL iom_get( numror, jpdom_autoglo, 'tn'     , w3d, ldxios = lrxios ) 
283         tsn(:,:,1,jp_tem) = w3d(:,:,1)
284         RETURN
285      ENDIF 
286     
287      IF( iom_varid( numror, 'ub', ldstop = .FALSE. ) > 0 ) THEN
288         CALL iom_get( numror, jpdom_autoglo, 'ub'     , ub, ldxios = lrxios                )   ! before fields
289         CALL iom_get( numror, jpdom_autoglo, 'vb'     , vb, ldxios = lrxios                )
290         CALL iom_get( numror, jpdom_autoglo, 'tb'     , tsb(:,:,:,jp_tem), ldxios = lrxios )
291         CALL iom_get( numror, jpdom_autoglo, 'sb'     , tsb(:,:,:,jp_sal), ldxios = lrxios )
292         CALL iom_get( numror, jpdom_autoglo, 'sshb'   , sshb, ldxios = lrxios              )
293      ELSE
294         neuler = 0
295      ENDIF
296      !
297      CALL iom_get( numror, jpdom_autoglo, 'un'     , un, ldxios = lrxios )   ! now    fields
298      CALL iom_get( numror, jpdom_autoglo, 'vn'     , vn, ldxios = lrxios )
299      CALL iom_get( numror, jpdom_autoglo, 'tn'     , tsn(:,:,:,jp_tem), ldxios = lrxios )
300      CALL iom_get( numror, jpdom_autoglo, 'sn'     , tsn(:,:,:,jp_sal), ldxios = lrxios )
301      CALL iom_get( numror, jpdom_autoglo, 'sshn'   , sshn, ldxios = lrxios )
302      IF( iom_varid( numror, 'rhop', ldstop = .FALSE. ) > 0 ) THEN
303         CALL iom_get( numror, jpdom_autoglo, 'rhop'   , rhop, ldxios = lrxios )   ! now    potential density
304      ELSE
305         CALL eos( tsn, rhd, rhop, gdept_n(:,:,:) )   
306      ENDIF
307      !
308      IF( neuler == 0 ) THEN                                  ! Euler restart (neuler=0)
309         tsb  (:,:,:,:) = tsn  (:,:,:,:)                             ! all before fields set to now values
310         ub   (:,:,:)   = un   (:,:,:)
311         vb   (:,:,:)   = vn   (:,:,:)
312         sshb (:,:)     = sshn (:,:)
313         !
314         IF( .NOT.ln_linssh ) THEN
315            DO jk = 1, jpk
316               e3t_b(:,:,jk) = e3t_n(:,:,jk)
317            END DO
318         ENDIF
319         !
320      ENDIF
321      !
322   END SUBROUTINE rst_read
323
324   !!=====================================================================
325END MODULE restart
Note: See TracBrowser for help on using the repository browser.