New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
iceistate.F90 in NEMO/branches/UKMO/NEMO_4.0.1_fix_cpl/src/ICE – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.1_fix_cpl/src/ICE/iceistate.F90 @ 12402

Last change on this file since 12402 was 12402, checked in by dancopsey, 4 years ago

Add melt pond lid code.
File size: 27.3 KB
Line 
1MODULE iceistate
2   !!======================================================================
3   !!                     ***  MODULE  iceistate  ***
4   !!   sea-ice : Initialization of ice variables
5   !!======================================================================
6   !! History :  2.0  !  2004-01  (C. Ethe, G. Madec) Original code
7   !!            3.0  !  2007     (M. Vancoppenolle)  Rewrite for ice cats
8   !!            4.0  !  2018     (many people)       SI3 [aka Sea Ice cube]
9   !!----------------------------------------------------------------------
10#if defined key_si3
11   !!----------------------------------------------------------------------
12   !!   'key_si3'                                       SI3 sea-ice model
13   !!----------------------------------------------------------------------
14   !!   ice_istate       :  initialization of diagnostics ice variables
15   !!   ice_istate_init  :  initialization of ice state and namelist read
16   !!----------------------------------------------------------------------
17   USE phycst         ! physical constant
18   USE oce            ! dynamics and tracers variables
19   USE dom_oce        ! ocean domain
20   USE sbc_oce , ONLY : sst_m, sss_m, ln_ice_embd 
21   USE sbc_ice , ONLY : tn_ice, snwice_mass, snwice_mass_b
22   USE eosbn2         ! equation of state
23   USE domvvl         ! Variable volume
24   USE ice            ! sea-ice: variables
25   USE ice1D          ! sea-ice: thermodynamics variables
26   USE icetab         ! sea-ice: 1D <==> 2D transformation
27   USE icevar         ! sea-ice: operations
28   !
29   USE in_out_manager ! I/O manager
30   USE iom            ! I/O manager library
31   USE lib_mpp        ! MPP library
32   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
33   USE fldread        ! read input fields
34
35   IMPLICIT NONE
36   PRIVATE
37
38   PUBLIC   ice_istate        ! called by icestp.F90
39   PUBLIC   ice_istate_init   ! called by icestp.F90
40   !
41   !                             !! ** namelist (namini) **
42   LOGICAL, PUBLIC  ::   ln_iceini        !: Ice initialization or not
43   INTEGER, PUBLIC  ::   nn_iceini_file   ! Ice initialization:
44                                  !        0 = Initialise sea ice based on SSTs
45                                  !        1 = Initialise sea ice from single category netcdf file
46                                  !        2 = Initialise sea ice from multi category restart file
47   REAL(wp) ::   rn_thres_sst
48   REAL(wp) ::   rn_hti_ini_n, rn_hts_ini_n, rn_ati_ini_n, rn_smi_ini_n, rn_tmi_ini_n, rn_tsu_ini_n, rn_tms_ini_n
49   REAL(wp) ::   rn_hti_ini_s, rn_hts_ini_s, rn_ati_ini_s, rn_smi_ini_s, rn_tmi_ini_s, rn_tsu_ini_s, rn_tms_ini_s
50   REAL(wp) ::   rn_apd_ini_n, rn_hpd_ini_n
51   REAL(wp) ::   rn_apd_ini_s, rn_hpd_ini_s
52   !
53   !                              ! if nn_iceini_file = 1
54   INTEGER , PARAMETER ::   jpfldi = 9           ! maximum number of files to read
55   INTEGER , PARAMETER ::   jp_hti = 1           ! index of ice thickness    (m)
56   INTEGER , PARAMETER ::   jp_hts = 2           ! index of snw thickness    (m)
57   INTEGER , PARAMETER ::   jp_ati = 3           ! index of ice fraction     (-)
58   INTEGER , PARAMETER ::   jp_smi = 4           ! index of ice salinity     (g/kg)
59   INTEGER , PARAMETER ::   jp_tmi = 5           ! index of ice temperature  (K)
60   INTEGER , PARAMETER ::   jp_tsu = 6           ! index of ice surface temp (K)
61   INTEGER , PARAMETER ::   jp_tms = 7           ! index of snw temperature  (K)
62   INTEGER , PARAMETER ::   jp_apd = 8           ! index of pnd fraction     (-)
63   INTEGER , PARAMETER ::   jp_hpd = 9           ! index of pnd depth        (m)
64   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   si  ! structure of input fields (file informations, fields read)
65   !   
66   !!----------------------------------------------------------------------
67   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
68   !! $Id$
69   !! Software governed by the CeCILL licence (modipsl/doc/NEMO_CeCILL.txt)
70   !!----------------------------------------------------------------------
71CONTAINS
72
73   SUBROUTINE ice_istate( kt )
74      !!-------------------------------------------------------------------
75      !!                    ***  ROUTINE ice_istate  ***
76      !!
77      !! ** Purpose :   defined the sea-ice initial state
78      !!
79      !! ** Method  :   This routine will put some ice where ocean
80      !!                is at the freezing point, then fill in ice
81      !!                state variables using prescribed initial
82      !!                values in the namelist           
83      !!
84      !! ** Steps   :   1) Set initial surface and basal temperatures
85      !!                2) Recompute or read sea ice state variables
86      !!                3) Fill in the ice thickness distribution using gaussian
87      !!                4) Fill in space-dependent arrays for state variables
88      !!                5) snow-ice mass computation
89      !!                6) store before fields
90      !!
91      !! ** Notes   : o_i, t_su, t_s, t_i, sz_i must be filled everywhere, even
92      !!              where there is no ice
93      !!--------------------------------------------------------------------
94      INTEGER, INTENT(in) ::   kt   ! time step
95      !!
96      INTEGER  ::   ji, jj, jk, jl         ! dummy loop indices
97      REAL(wp) ::   ztmelts
98      INTEGER , DIMENSION(4)           ::   itest
99      REAL(wp), DIMENSION(jpi,jpj)     ::   z2d
100      REAL(wp), DIMENSION(jpi,jpj)     ::   zswitch    ! ice indicator
101      REAL(wp), DIMENSION(jpi,jpj)     ::   zht_i_ini, zat_i_ini, ztm_s_ini            !data from namelist or nc file
102      REAL(wp), DIMENSION(jpi,jpj)     ::   zt_su_ini, zht_s_ini, zsm_i_ini, ztm_i_ini !data from namelist or nc file
103      REAL(wp), DIMENSION(jpi,jpj)     ::   zapnd_ini, zhpnd_ini                       !data from namelist or nc file
104      REAL(wp), DIMENSION(jpi,jpj,jpl) ::   zti_3d , zts_3d                            !temporary arrays
105      !!
106      REAL(wp), DIMENSION(:,:), ALLOCATABLE ::   zhi_2d, zhs_2d, zai_2d, zti_2d, zts_2d, ztsu_2d, zsi_2d, zaip_2d, zhip_2d
107      !--------------------------------------------------------------------
108
109      IF(lwp) WRITE(numout,*)
110      IF(lwp) WRITE(numout,*) 'ice_istate: sea-ice initialization '
111      IF(lwp) WRITE(numout,*) '~~~~~~~~~~'
112
113      !---------------------------
114      ! 1) 1st init. of the fields
115      !---------------------------
116      !
117      ! basal temperature (considered at freezing point)   [Kelvin]
118      CALL eos_fzp( sss_m(:,:), t_bo(:,:) )
119      t_bo(:,:) = ( t_bo(:,:) + rt0 ) * tmask(:,:,1) 
120      !
121      ! surface temperature and conductivity
122      DO jl = 1, jpl
123         t_su   (:,:,jl) = rt0 * tmask(:,:,1)  ! temp at the surface
124         cnd_ice(:,:,jl) = 0._wp               ! initialisation of the effective conductivity at the top of ice/snow (ln_cndflx=T)
125      END DO
126      !
127      ! ice and snw temperatures
128      DO jl = 1, jpl
129         DO jk = 1, nlay_i
130            t_i(:,:,jk,jl) = rt0 * tmask(:,:,1)
131         END DO
132         DO jk = 1, nlay_s
133            t_s(:,:,jk,jl) = rt0 * tmask(:,:,1)
134         END DO
135      END DO
136      !
137      ! specific temperatures for coupled runs
138      tn_ice (:,:,:) = t_i (:,:,1,:)
139      t1_ice (:,:,:) = t_i (:,:,1,:)
140
141      ! heat contents
142      e_i (:,:,:,:) = 0._wp
143      e_s (:,:,:,:) = 0._wp
144     
145      ! general fields
146      a_i (:,:,:) = 0._wp
147      v_i (:,:,:) = 0._wp
148      v_s (:,:,:) = 0._wp
149      sv_i(:,:,:) = 0._wp
150      oa_i(:,:,:) = 0._wp
151      !
152      h_i (:,:,:) = 0._wp
153      h_s (:,:,:) = 0._wp
154      s_i (:,:,:) = 0._wp
155      o_i (:,:,:) = 0._wp
156      !
157      ! melt ponds
158      a_ip     (:,:,:) = 0._wp
159      v_ip     (:,:,:) = 0._wp
160      lh_ip    (:,:,:) = 0._wp
161      a_ip_frac(:,:,:) = 0._wp
162      h_ip     (:,:,:) = 0._wp
163      !
164      ! ice velocities
165      u_ice (:,:) = 0._wp
166      v_ice (:,:) = 0._wp
167      !
168      !------------------------------------------------------------------------
169      ! 2) overwrite some of the fields with namelist parameters or netcdf file
170      !------------------------------------------------------------------------
171      IF( ln_iceini ) THEN
172         !                             !---------------!
173         IF( nn_iceini_file == 1 )THEN      ! Read a file   !
174            !                          !---------------!
175            WHERE( ff_t(:,:) >= 0._wp )   ;   zswitch(:,:) = 1._wp
176            ELSEWHERE                     ;   zswitch(:,:) = 0._wp
177            END WHERE
178            !
179            CALL fld_read( kt, 1, si ) ! input fields provided at the current time-step
180            !
181            ! -- mandatory fields -- !
182            zht_i_ini(:,:) = si(jp_hti)%fnow(:,:,1)
183            zht_s_ini(:,:) = si(jp_hts)%fnow(:,:,1)
184            zat_i_ini(:,:) = si(jp_ati)%fnow(:,:,1)
185
186            ! -- optional fields -- !
187            !    if fields do not exist then set them to the values present in the namelist (except for snow and surface temperature)
188            !
189            ! ice salinity
190            IF( TRIM(si(jp_smi)%clrootname) == 'NOT USED' ) &
191               &     si(jp_smi)%fnow(:,:,1) = ( rn_smi_ini_n * zswitch + rn_smi_ini_s * (1._wp - zswitch) ) * tmask(:,:,1)
192            zsm_i_ini(:,:) = si(jp_smi)%fnow(:,:,1)
193            !
194            ! ice temperature
195            IF( TRIM(si(jp_tmi)%clrootname) == 'NOT USED' ) &
196               &     si(jp_tmi)%fnow(:,:,1) = ( rn_tmi_ini_n * zswitch + rn_tmi_ini_s * (1._wp - zswitch) ) * tmask(:,:,1)
197            ztm_i_ini(:,:) = si(jp_tmi)%fnow(:,:,1)
198            !
199            ! surface temperature => set to ice temperature if it exists
200            IF    ( TRIM(si(jp_tsu)%clrootname) == 'NOT USED' .AND. TRIM(si(jp_tmi)%clrootname) == 'NOT USED' ) THEN
201                     si(jp_tsu)%fnow(:,:,1) = ( rn_tsu_ini_n * zswitch + rn_tsu_ini_s * (1._wp - zswitch) ) * tmask(:,:,1)
202            ELSEIF( TRIM(si(jp_tsu)%clrootname) == 'NOT USED' .AND. TRIM(si(jp_tmi)%clrootname) /= 'NOT USED' ) THEN
203                     si(jp_tsu)%fnow(:,:,1) = si(jp_tmi)%fnow(:,:,1)
204            ENDIF
205            zt_su_ini(:,:) = si(jp_tsu)%fnow(:,:,1)
206            !
207            ! snow temperature => set to ice temperature if it exists
208            IF    ( TRIM(si(jp_tms)%clrootname) == 'NOT USED' .AND. TRIM(si(jp_tmi)%clrootname) == 'NOT USED' ) THEN
209                     si(jp_tms)%fnow(:,:,1) = ( rn_tms_ini_n * zswitch + rn_tms_ini_s * (1._wp - zswitch) ) * tmask(:,:,1)
210            ELSEIF( TRIM(si(jp_tms)%clrootname) == 'NOT USED' .AND. TRIM(si(jp_tmi)%clrootname) /= 'NOT USED' ) THEN
211                     si(jp_tms)%fnow(:,:,1) = si(jp_tmi)%fnow(:,:,1)
212            ENDIF
213            ztm_s_ini(:,:) = si(jp_tms)%fnow(:,:,1)
214            !
215            ! pond concentration
216            IF( TRIM(si(jp_apd)%clrootname) == 'NOT USED' ) &
217               &     si(jp_apd)%fnow(:,:,1) = ( rn_apd_ini_n * zswitch + rn_apd_ini_s * (1._wp - zswitch) ) * tmask(:,:,1) & ! rn_apd = pond fraction => rn_apnd * a_i = pond conc.
218               &                              * si(jp_ati)%fnow(:,:,1) 
219            zapnd_ini(:,:) = si(jp_apd)%fnow(:,:,1)
220            !
221            ! pond depth
222            IF( TRIM(si(jp_hpd)%clrootname) == 'NOT USED' ) &
223               &     si(jp_hpd)%fnow(:,:,1) = ( rn_hpd_ini_n * zswitch + rn_hpd_ini_s * (1._wp - zswitch) ) * tmask(:,:,1)
224            zhpnd_ini(:,:) = si(jp_hpd)%fnow(:,:,1)
225            !
226            ! change the switch for the following
227            WHERE( zat_i_ini(:,:) > 0._wp )   ;   zswitch(:,:) = tmask(:,:,1) 
228            ELSEWHERE                         ;   zswitch(:,:) = 0._wp
229            END WHERE
230            !                          !---------------!
231         ELSE                          ! Read namelist !
232            !                          !---------------!
233            ! no ice if (sst - Tfreez) >= thresold
234            WHERE( ( sst_m(:,:) - (t_bo(:,:) - rt0) ) * tmask(:,:,1) >= rn_thres_sst )   ;   zswitch(:,:) = 0._wp 
235            ELSEWHERE                                                                    ;   zswitch(:,:) = tmask(:,:,1)
236            END WHERE
237            !
238            ! assign initial thickness, concentration, snow depth and salinity to an hemisphere-dependent array
239            WHERE( ff_t(:,:) >= 0._wp )
240               zht_i_ini(:,:) = rn_hti_ini_n * zswitch(:,:)
241               zht_s_ini(:,:) = rn_hts_ini_n * zswitch(:,:)
242               zat_i_ini(:,:) = rn_ati_ini_n * zswitch(:,:)
243               zsm_i_ini(:,:) = rn_smi_ini_n * zswitch(:,:)
244               ztm_i_ini(:,:) = rn_tmi_ini_n * zswitch(:,:)
245               zt_su_ini(:,:) = rn_tsu_ini_n * zswitch(:,:)
246               ztm_s_ini(:,:) = rn_tms_ini_n * zswitch(:,:)
247               zapnd_ini(:,:) = rn_apd_ini_n * zswitch(:,:) * zat_i_ini(:,:) ! rn_apd = pond fraction => rn_apd * a_i = pond conc.
248               zhpnd_ini(:,:) = rn_hpd_ini_n * zswitch(:,:)
249            ELSEWHERE
250               zht_i_ini(:,:) = rn_hti_ini_s * zswitch(:,:)
251               zht_s_ini(:,:) = rn_hts_ini_s * zswitch(:,:)
252               zat_i_ini(:,:) = rn_ati_ini_s * zswitch(:,:)
253               zsm_i_ini(:,:) = rn_smi_ini_s * zswitch(:,:)
254               ztm_i_ini(:,:) = rn_tmi_ini_s * zswitch(:,:)
255               zt_su_ini(:,:) = rn_tsu_ini_s * zswitch(:,:)
256               ztm_s_ini(:,:) = rn_tms_ini_s * zswitch(:,:)
257               zapnd_ini(:,:) = rn_apd_ini_s * zswitch(:,:) * zat_i_ini(:,:) ! rn_apd = pond fraction => rn_apd * a_i = pond conc.
258               zhpnd_ini(:,:) = rn_hpd_ini_s * zswitch(:,:)
259            END WHERE
260            !
261         ENDIF
262
263         ! make sure ponds = 0 if no ponds scheme
264         IF ( .NOT.ln_pnd ) THEN
265            zapnd_ini(:,:) = 0._wp
266            zhpnd_ini(:,:) = 0._wp
267         ENDIF
268         
269         !-------------!
270         ! fill fields !
271         !-------------!
272         ! select ice covered grid points
273         npti = 0 ; nptidx(:) = 0
274         DO jj = 1, jpj
275            DO ji = 1, jpi
276               IF ( zht_i_ini(ji,jj) > 0._wp ) THEN
277                  npti         = npti  + 1
278                  nptidx(npti) = (jj - 1) * jpi + ji
279               ENDIF
280            END DO
281         END DO
282
283         ! move to 1D arrays: (jpi,jpj) -> (jpi*jpj)
284         CALL tab_2d_1d( npti, nptidx(1:npti), h_i_1d (1:npti)  , zht_i_ini )
285         CALL tab_2d_1d( npti, nptidx(1:npti), h_s_1d (1:npti)  , zht_s_ini )
286         CALL tab_2d_1d( npti, nptidx(1:npti), at_i_1d(1:npti)  , zat_i_ini )
287         CALL tab_2d_1d( npti, nptidx(1:npti), t_i_1d (1:npti,1), ztm_i_ini )
288         CALL tab_2d_1d( npti, nptidx(1:npti), t_s_1d (1:npti,1), ztm_s_ini )
289         CALL tab_2d_1d( npti, nptidx(1:npti), t_su_1d(1:npti)  , zt_su_ini )
290         CALL tab_2d_1d( npti, nptidx(1:npti), s_i_1d (1:npti)  , zsm_i_ini )
291         CALL tab_2d_1d( npti, nptidx(1:npti), a_ip_1d(1:npti)  , zapnd_ini )
292         CALL tab_2d_1d( npti, nptidx(1:npti), h_ip_1d(1:npti)  , zhpnd_ini )
293
294         ! allocate temporary arrays
295         ALLOCATE( zhi_2d(npti,jpl), zhs_2d(npti,jpl), zai_2d (npti,jpl), &
296            &      zti_2d(npti,jpl), zts_2d(npti,jpl), ztsu_2d(npti,jpl), zsi_2d(npti,jpl), zaip_2d(npti,jpl), zhip_2d(npti,jpl) )
297         
298         ! distribute 1-cat into jpl-cat: (jpi*jpj) -> (jpi*jpj,jpl)
299         CALL ice_var_itd( h_i_1d(1:npti)  , h_s_1d(1:npti)  , at_i_1d(1:npti),                                                   &
300            &              zhi_2d          , zhs_2d          , zai_2d         ,                                                   &
301            &              t_i_1d(1:npti,1), t_s_1d(1:npti,1), t_su_1d(1:npti), s_i_1d(1:npti), a_ip_1d(1:npti), h_ip_1d(1:npti), &
302            &              zti_2d          , zts_2d          , ztsu_2d        , zsi_2d        , zaip_2d        , zhip_2d )
303
304         ! move to 3D arrays: (jpi*jpj,jpl) -> (jpi,jpj,jpl)
305         DO jl = 1, jpl
306            zti_3d(:,:,jl) = rt0 * tmask(:,:,1)
307            zts_3d(:,:,jl) = rt0 * tmask(:,:,1)
308         END DO
309         CALL tab_2d_3d( npti, nptidx(1:npti), zhi_2d   , h_i    )
310         CALL tab_2d_3d( npti, nptidx(1:npti), zhs_2d   , h_s    )
311         CALL tab_2d_3d( npti, nptidx(1:npti), zai_2d   , a_i    )
312         CALL tab_2d_3d( npti, nptidx(1:npti), zti_2d   , zti_3d )
313         CALL tab_2d_3d( npti, nptidx(1:npti), zts_2d   , zts_3d )
314         CALL tab_2d_3d( npti, nptidx(1:npti), ztsu_2d  , t_su   )
315         CALL tab_2d_3d( npti, nptidx(1:npti), zsi_2d   , s_i    )
316         CALL tab_2d_3d( npti, nptidx(1:npti), zaip_2d  , a_ip   )
317         CALL tab_2d_3d( npti, nptidx(1:npti), zhip_2d  , h_ip   )
318
319         ! deallocate temporary arrays
320         DEALLOCATE( zhi_2d, zhs_2d, zai_2d , &
321            &        zti_2d, zts_2d, ztsu_2d, zsi_2d, zaip_2d, zhip_2d )
322
323         ! calculate extensive and intensive variables
324         CALL ice_var_salprof ! for sz_i
325         DO jl = 1, jpl
326            DO jj = 1, jpj
327               DO ji = 1, jpi
328                  v_i (ji,jj,jl) = h_i(ji,jj,jl) * a_i(ji,jj,jl)
329                  v_s (ji,jj,jl) = h_s(ji,jj,jl) * a_i(ji,jj,jl)
330                  sv_i(ji,jj,jl) = MIN( MAX( rn_simin , s_i(ji,jj,jl) ) , rn_simax ) * v_i(ji,jj,jl)
331               END DO
332            END DO
333         END DO
334         !
335         DO jl = 1, jpl
336            DO jk = 1, nlay_s
337               DO jj = 1, jpj
338                  DO ji = 1, jpi
339                     t_s(ji,jj,jk,jl) = zts_3d(ji,jj,jl)
340                     e_s(ji,jj,jk,jl) = zswitch(ji,jj) * v_s(ji,jj,jl) * r1_nlay_s * &
341                        &               rhos * ( rcpi * ( rt0 - t_s(ji,jj,jk,jl) ) + rLfus )
342                  END DO
343               END DO
344            END DO
345         END DO
346         !
347         DO jl = 1, jpl
348            DO jk = 1, nlay_i
349               DO jj = 1, jpj
350                  DO ji = 1, jpi
351                     t_i (ji,jj,jk,jl) = zti_3d(ji,jj,jl) 
352                     ztmelts          = - rTmlt * sz_i(ji,jj,jk,jl) + rt0 ! melting temperature in K
353                     e_i(ji,jj,jk,jl) = zswitch(ji,jj) * v_i(ji,jj,jl) * r1_nlay_i * &
354                        &               rhoi * (  rcpi  * ( ztmelts - t_i(ji,jj,jk,jl) ) + &
355                        &                         rLfus * ( 1._wp - (ztmelts-rt0) / MIN( (t_i(ji,jj,jk,jl)-rt0), -epsi20 ) ) &
356                        &                       - rcp   * ( ztmelts - rt0 ) )
357                  END DO
358               END DO
359            END DO
360         END DO
361
362         ! Melt ponds
363         WHERE( a_i > epsi10 )
364            a_ip_frac(:,:,:) = a_ip(:,:,:) / a_i(:,:,:)
365         ELSEWHERE
366            a_ip_frac(:,:,:) = 0._wp
367         END WHERE
368         v_ip(:,:,:) = h_ip(:,:,:) * a_ip(:,:,:)
369         
370         ! specific temperatures for coupled runs
371         tn_ice(:,:,:) = t_su(:,:,:)
372         t1_ice(:,:,:) = t_i (:,:,1,:)
373         !
374      ENDIF ! ln_iceini
375      !
376      at_i(:,:) = SUM( a_i, dim=3 )
377      !
378      !----------------------------------------------
379      ! 3) Snow-ice mass (case ice is fully embedded)
380      !----------------------------------------------
381      snwice_mass  (:,:) = tmask(:,:,1) * SUM( rhos * v_s(:,:,:) + rhoi * v_i(:,:,:), dim=3  )   ! snow+ice mass
382      snwice_mass_b(:,:) = snwice_mass(:,:)
383      !
384      IF( ln_ice_embd ) THEN            ! embedded sea-ice: deplete the initial ssh below sea-ice area
385         !
386         sshn(:,:) = sshn(:,:) - snwice_mass(:,:) * r1_rau0
387         sshb(:,:) = sshb(:,:) - snwice_mass(:,:) * r1_rau0
388         !
389         IF( .NOT.ln_linssh ) THEN
390            !
391            WHERE( ht_0(:,:) > 0 )   ;   z2d(:,:) = 1._wp + sshn(:,:)*tmask(:,:,1) / ht_0(:,:)
392            ELSEWHERE                ;   z2d(:,:) = 1._wp   ;   END WHERE
393            !
394            DO jk = 1,jpkm1                     ! adjust initial vertical scale factors               
395               e3t_n(:,:,jk) = e3t_0(:,:,jk) * z2d(:,:)
396               e3t_b(:,:,jk) = e3t_n(:,:,jk)
397               e3t_a(:,:,jk) = e3t_n(:,:,jk)
398            END DO
399            !
400            ! Reconstruction of all vertical scale factors at now and before time-steps
401            ! =========================================================================
402            ! Horizontal scale factor interpolations
403            ! --------------------------------------
404            CALL dom_vvl_interpol( e3t_b(:,:,:), e3u_b(:,:,:), 'U' )
405            CALL dom_vvl_interpol( e3t_b(:,:,:), e3v_b(:,:,:), 'V' )
406            CALL dom_vvl_interpol( e3t_n(:,:,:), e3u_n(:,:,:), 'U' )
407            CALL dom_vvl_interpol( e3t_n(:,:,:), e3v_n(:,:,:), 'V' )
408            CALL dom_vvl_interpol( e3u_n(:,:,:), e3f_n(:,:,:), 'F' )
409            ! Vertical scale factor interpolations
410            ! ------------------------------------
411            CALL dom_vvl_interpol( e3t_n(:,:,:), e3w_n (:,:,:), 'W'  )
412            CALL dom_vvl_interpol( e3u_n(:,:,:), e3uw_n(:,:,:), 'UW' )
413            CALL dom_vvl_interpol( e3v_n(:,:,:), e3vw_n(:,:,:), 'VW' )
414            CALL dom_vvl_interpol( e3u_b(:,:,:), e3uw_b(:,:,:), 'UW' )
415            CALL dom_vvl_interpol( e3v_b(:,:,:), e3vw_b(:,:,:), 'VW' )
416            ! t- and w- points depth
417            ! ----------------------
418            !!gm not sure of that....
419            gdept_n(:,:,1) = 0.5_wp * e3w_n(:,:,1)
420            gdepw_n(:,:,1) = 0.0_wp
421            gde3w_n(:,:,1) = gdept_n(:,:,1) - sshn(:,:)
422            DO jk = 2, jpk
423               gdept_n(:,:,jk) = gdept_n(:,:,jk-1) + e3w_n(:,:,jk  )
424               gdepw_n(:,:,jk) = gdepw_n(:,:,jk-1) + e3t_n(:,:,jk-1)
425               gde3w_n(:,:,jk) = gdept_n(:,:,jk  ) - sshn (:,:)
426            END DO
427         ENDIF
428      ENDIF
429     
430      !------------------------------------
431      ! 4) store fields at before time-step
432      !------------------------------------
433      ! it is only necessary for the 1st interpolation by Agrif
434      a_i_b  (:,:,:)   = a_i  (:,:,:)
435      e_i_b  (:,:,:,:) = e_i  (:,:,:,:)
436      v_i_b  (:,:,:)   = v_i  (:,:,:)
437      v_s_b  (:,:,:)   = v_s  (:,:,:)
438      e_s_b  (:,:,:,:) = e_s  (:,:,:,:)
439      sv_i_b (:,:,:)   = sv_i (:,:,:)
440      oa_i_b (:,:,:)   = oa_i (:,:,:)
441      u_ice_b(:,:)     = u_ice(:,:)
442      v_ice_b(:,:)     = v_ice(:,:)
443      ! total concentration is needed for Lupkes parameterizations
444      at_i_b (:,:)     = at_i (:,:) 
445
446!!clem: output of initial state should be written here but it is impossible because
447!!      the ocean and ice are in the same file
448!!      CALL dia_wri_state( 'output.init' )
449      !
450   END SUBROUTINE ice_istate
451
452
453   SUBROUTINE ice_istate_init
454      !!-------------------------------------------------------------------
455      !!                   ***  ROUTINE ice_istate_init  ***
456      !!       
457      !! ** Purpose :   Definition of initial state of the ice
458      !!
459      !! ** Method  :   Read the namini namelist and check the parameter
460      !!              values called at the first timestep (nit000)
461      !!
462      !! ** input   :  Namelist namini
463      !!
464      !!-----------------------------------------------------------------------------
465      INTEGER ::   ios   ! Local integer output status for namelist read
466      INTEGER ::   ifpr, ierror
467      !
468      CHARACTER(len=256) ::  cn_dir          ! Root directory for location of ice files
469      TYPE(FLD_N)                    ::   sn_hti, sn_hts, sn_ati, sn_smi, sn_tmi, sn_tsu, sn_tms, sn_apd, sn_hpd
470      TYPE(FLD_N), DIMENSION(jpfldi) ::   slf_i                 ! array of namelist informations on the fields to read
471      !
472      NAMELIST/namini/ ln_iceini, nn_iceini_file, rn_thres_sst, &
473         &             rn_hti_ini_n, rn_hti_ini_s, rn_hts_ini_n, rn_hts_ini_s, &
474         &             rn_ati_ini_n, rn_ati_ini_s, rn_smi_ini_n, rn_smi_ini_s, &
475         &             rn_tmi_ini_n, rn_tmi_ini_s, rn_tsu_ini_n, rn_tsu_ini_s, rn_tms_ini_n, rn_tms_ini_s, &
476         &             rn_apd_ini_n, rn_apd_ini_s, rn_hpd_ini_n, rn_hpd_ini_s, &
477         &             sn_hti, sn_hts, sn_ati, sn_tsu, sn_tmi, sn_smi, sn_tms, sn_apd, sn_hpd, cn_dir
478      !!-----------------------------------------------------------------------------
479      !
480      REWIND( numnam_ice_ref )              ! Namelist namini in reference namelist : Ice initial state
481      READ  ( numnam_ice_ref, namini, IOSTAT = ios, ERR = 901)
482901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namini in reference namelist' )
483      REWIND( numnam_ice_cfg )              ! Namelist namini in configuration namelist : Ice initial state
484      READ  ( numnam_ice_cfg, namini, IOSTAT = ios, ERR = 902 )
485902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namini in configuration namelist' )
486      IF(lwm) WRITE ( numoni, namini )
487      !
488      slf_i(jp_hti) = sn_hti  ;  slf_i(jp_hts) = sn_hts
489      slf_i(jp_ati) = sn_ati  ;  slf_i(jp_smi) = sn_smi
490      slf_i(jp_tmi) = sn_tmi  ;  slf_i(jp_tsu) = sn_tsu   ;   slf_i(jp_tms) = sn_tms
491      slf_i(jp_apd) = sn_apd  ;  slf_i(jp_hpd) = sn_hpd
492      !
493      IF(lwp) THEN                          ! control print
494         WRITE(numout,*)
495         WRITE(numout,*) 'ice_istate_init: ice parameters inititialisation '
496         WRITE(numout,*) '~~~~~~~~~~~~~~~'
497         WRITE(numout,*) '   Namelist namini:'
498         WRITE(numout,*) '      ice initialization (T) or not (F)                ln_iceini      = ', ln_iceini
499         WRITE(numout,*) '      ice initialization from a netcdf file            nn_iceini_file = ', nn_iceini_file
500         WRITE(numout,*) '      max ocean temp. above Tfreeze with initial ice   rn_thres_sst   = ', rn_thres_sst
501         IF( ln_iceini .AND. nn_iceini_file == 0 ) THEN
502            WRITE(numout,*) '      initial snw thickness in the north-south         rn_hts_ini     = ', rn_hts_ini_n,rn_hts_ini_s 
503            WRITE(numout,*) '      initial ice thickness in the north-south         rn_hti_ini     = ', rn_hti_ini_n,rn_hti_ini_s
504            WRITE(numout,*) '      initial ice concentr  in the north-south         rn_ati_ini     = ', rn_ati_ini_n,rn_ati_ini_s
505            WRITE(numout,*) '      initial ice salinity  in the north-south         rn_smi_ini     = ', rn_smi_ini_n,rn_smi_ini_s
506            WRITE(numout,*) '      initial surf temperat in the north-south         rn_tsu_ini     = ', rn_tsu_ini_n,rn_tsu_ini_s
507            WRITE(numout,*) '      initial ice temperat  in the north-south         rn_tmi_ini     = ', rn_tmi_ini_n,rn_tmi_ini_s
508            WRITE(numout,*) '      initial snw temperat  in the north-south         rn_tms_ini     = ', rn_tms_ini_n,rn_tms_ini_s
509            WRITE(numout,*) '      initial pnd fraction  in the north-south         rn_apd_ini     = ', rn_apd_ini_n,rn_apd_ini_s
510            WRITE(numout,*) '      initial pnd depth     in the north-south         rn_hpd_ini     = ', rn_hpd_ini_n,rn_hpd_ini_s
511         ENDIF
512      ENDIF
513      !
514      IF( nn_iceini_file == 1 ) THEN                      ! Ice initialization using input file
515         !
516         ! set si structure
517         ALLOCATE( si(jpfldi), STAT=ierror )
518         IF( ierror > 0 ) THEN
519            CALL ctl_stop( 'ice_istate_ini in iceistate: unable to allocate si structure' )   ;   RETURN
520         ENDIF
521         !
522         DO ifpr = 1, jpfldi
523            ALLOCATE( si(ifpr)%fnow(jpi,jpj,1) )
524            IF( slf_i(ifpr)%ln_tint )  ALLOCATE( si(ifpr)%fdta(jpi,jpj,1,2) )
525         END DO
526         !
527         ! fill si with slf_i and control print
528         CALL fld_fill( si, slf_i, cn_dir, 'ice_istate_ini', 'initialization of sea ice fields', 'numnam_ice' )
529         !
530      ENDIF
531      !
532      IF( .NOT.ln_pnd ) THEN
533         rn_apd_ini_n = 0. ; rn_apd_ini_s = 0.
534         rn_hpd_ini_n = 0. ; rn_hpd_ini_s = 0.
535         CALL ctl_warn( 'rn_apd_ini & rn_hpd_ini = 0 when no ponds' )
536      ENDIF
537      !
538   END SUBROUTINE ice_istate_init
539
540#else
541   !!----------------------------------------------------------------------
542   !!   Default option :         Empty module         NO SI3 sea-ice model
543   !!----------------------------------------------------------------------
544#endif
545
546   !!======================================================================
547END MODULE iceistate
Note: See TracBrowser for help on using the repository browser.