| 1 | MODULE icesbc |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE icesbc *** |
|---|
| 4 | !! Sea-Ice : air-ice sbc fields |
|---|
| 5 | !!===================================================================== |
|---|
| 6 | !! History : 4.0 ! 2017-08 (C. Rousset) Original code |
|---|
| 7 | !! 4.0 ! 2018 (many people) SI3 [aka Sea Ice cube] |
|---|
| 8 | !!---------------------------------------------------------------------- |
|---|
| 9 | #if defined key_si3 |
|---|
| 10 | !!---------------------------------------------------------------------- |
|---|
| 11 | !! 'key_si3' : SI3 sea-ice model |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce ! ocean dynamics and tracers |
|---|
| 14 | USE dom_oce ! ocean space and time domain |
|---|
| 15 | USE ice ! sea-ice: variables |
|---|
| 16 | USE sbc_oce ! Surface boundary condition: ocean fields |
|---|
| 17 | USE sbc_ice ! Surface boundary condition: ice fields |
|---|
| 18 | USE usrdef_sbc ! Surface boundary condition: user defined |
|---|
| 19 | USE sbcblk ! Surface boundary condition: bulk |
|---|
| 20 | USE sbccpl ! Surface boundary condition: coupled interface |
|---|
| 21 | USE icealb ! sea-ice: albedo |
|---|
| 22 | ! |
|---|
| 23 | USE in_out_manager ! I/O manager |
|---|
| 24 | USE iom ! I/O manager library |
|---|
| 25 | USE lib_mpp ! MPP library |
|---|
| 26 | USE lib_fortran ! fortran utilities (glob_sum + no signed zero) |
|---|
| 27 | USE lbclnk ! lateral boundary conditions (or mpp links) |
|---|
| 28 | USE timing ! Timing |
|---|
| 29 | |
|---|
| 30 | IMPLICIT NONE |
|---|
| 31 | PRIVATE |
|---|
| 32 | |
|---|
| 33 | PUBLIC ice_sbc_tau ! called by icestp.F90 |
|---|
| 34 | PUBLIC ice_sbc_flx ! called by icestp.F90 |
|---|
| 35 | PUBLIC ice_sbc_init ! called by icestp.F90 |
|---|
| 36 | |
|---|
| 37 | !! * Substitutions |
|---|
| 38 | # include "vectopt_loop_substitute.h90" |
|---|
| 39 | !!---------------------------------------------------------------------- |
|---|
| 40 | !! NEMO/ICE 4.0 , NEMO Consortium (2018) |
|---|
| 41 | !! $Id$ |
|---|
| 42 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 43 | !!---------------------------------------------------------------------- |
|---|
| 44 | CONTAINS |
|---|
| 45 | |
|---|
| 46 | SUBROUTINE ice_sbc_tau( kt, ksbc, utau_ice, vtau_ice ) |
|---|
| 47 | !!------------------------------------------------------------------- |
|---|
| 48 | !! *** ROUTINE ice_sbc_tau *** |
|---|
| 49 | !! |
|---|
| 50 | !! ** Purpose : provide surface boundary condition for sea ice (momentum) |
|---|
| 51 | !! |
|---|
| 52 | !! ** Action : It provides the following fields: |
|---|
| 53 | !! utau_ice, vtau_ice : surface ice stress (U- & V-points) [N/m2] |
|---|
| 54 | !!------------------------------------------------------------------- |
|---|
| 55 | INTEGER , INTENT(in ) :: kt ! ocean time step |
|---|
| 56 | INTEGER , INTENT(in ) :: ksbc ! type of sbc flux |
|---|
| 57 | REAL(wp), DIMENSION(jpi,jpj), INTENT( out) :: utau_ice, vtau_ice ! air-ice stress [N/m2] |
|---|
| 58 | !! |
|---|
| 59 | INTEGER :: ji, jj ! dummy loop index |
|---|
| 60 | REAL(wp), DIMENSION(jpi,jpj) :: zutau_ice, zvtau_ice |
|---|
| 61 | !!------------------------------------------------------------------- |
|---|
| 62 | ! |
|---|
| 63 | IF( ln_timing ) CALL timing_start('ice_sbc') |
|---|
| 64 | ! |
|---|
| 65 | IF( kt == nit000 .AND. lwp ) THEN |
|---|
| 66 | WRITE(numout,*) |
|---|
| 67 | WRITE(numout,*)'ice_sbc_tau: Surface boundary condition for sea ice (momentum)' |
|---|
| 68 | WRITE(numout,*)'~~~~~~~~~~~~~~~' |
|---|
| 69 | ENDIF |
|---|
| 70 | ! |
|---|
| 71 | SELECT CASE( ksbc ) |
|---|
| 72 | CASE( jp_usr ) ; CALL usrdef_sbc_ice_tau( kt ) ! user defined formulation |
|---|
| 73 | CASE( jp_blk ) ; CALL blk_ice_tau ! Bulk formulation |
|---|
| 74 | CASE( jp_purecpl ) ; CALL sbc_cpl_ice_tau( utau_ice , vtau_ice ) ! Coupled formulation |
|---|
| 75 | END SELECT |
|---|
| 76 | ! |
|---|
| 77 | IF( ln_mixcpl) THEN ! Case of a mixed Bulk/Coupled formulation |
|---|
| 78 | CALL sbc_cpl_ice_tau( zutau_ice , zvtau_ice ) |
|---|
| 79 | DO jj = 2, jpjm1 |
|---|
| 80 | DO ji = 2, jpim1 |
|---|
| 81 | utau_ice(ji,jj) = utau_ice(ji,jj) * xcplmask(ji,jj,0) + zutau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) ) |
|---|
| 82 | vtau_ice(ji,jj) = vtau_ice(ji,jj) * xcplmask(ji,jj,0) + zvtau_ice(ji,jj) * ( 1. - xcplmask(ji,jj,0) ) |
|---|
| 83 | END DO |
|---|
| 84 | END DO |
|---|
| 85 | CALL lbc_lnk_multi( 'icesbc', utau_ice, 'U', -1., vtau_ice, 'V', -1. ) |
|---|
| 86 | ENDIF |
|---|
| 87 | ! |
|---|
| 88 | IF( ln_timing ) CALL timing_stop('ice_sbc') |
|---|
| 89 | ! |
|---|
| 90 | END SUBROUTINE ice_sbc_tau |
|---|
| 91 | |
|---|
| 92 | |
|---|
| 93 | SUBROUTINE ice_sbc_flx( kt, ksbc ) |
|---|
| 94 | !!------------------------------------------------------------------- |
|---|
| 95 | !! *** ROUTINE ice_sbc_flx *** |
|---|
| 96 | !! |
|---|
| 97 | !! ** Purpose : provide surface boundary condition for sea ice (flux) |
|---|
| 98 | !! |
|---|
| 99 | !! ** Action : It provides the following fields used in sea ice model: |
|---|
| 100 | !! emp_oce , emp_ice = E-P over ocean and sea ice [Kg/m2/s] |
|---|
| 101 | !! sprecip = solid precipitation [Kg/m2/s] |
|---|
| 102 | !! evap_ice = sublimation [Kg/m2/s] |
|---|
| 103 | !! qsr_tot , qns_tot = solar & non solar heat flux (total) [W/m2] |
|---|
| 104 | !! qsr_ice , qns_ice = solar & non solar heat flux over ice [W/m2] |
|---|
| 105 | !! dqns_ice = non solar heat sensistivity [W/m2] |
|---|
| 106 | !! qemp_oce, qemp_ice, qprec_ice, qevap_ice = sensible heat (associated with evap & precip) [W/m2] |
|---|
| 107 | !! + some fields that are not used outside this module: |
|---|
| 108 | !! qla_ice = latent heat flux over ice [W/m2] |
|---|
| 109 | !! dqla_ice = latent heat sensistivity [W/m2] |
|---|
| 110 | !! tprecip = total precipitation [Kg/m2/s] |
|---|
| 111 | !! alb_ice = albedo above sea ice |
|---|
| 112 | !!------------------------------------------------------------------- |
|---|
| 113 | INTEGER, INTENT(in) :: kt ! ocean time step |
|---|
| 114 | INTEGER, INTENT(in) :: ksbc ! flux formulation (user defined, bulk or Pure Coupled) |
|---|
| 115 | ! |
|---|
| 116 | INTEGER :: ji, jj, jl ! dummy loop index |
|---|
| 117 | REAL(wp) :: zmiss_val ! missing value retrieved from xios |
|---|
| 118 | REAL(wp), DIMENSION(jpi,jpj,jpl) :: zalb_os, zalb_cs ! ice albedo under overcast/clear sky |
|---|
| 119 | REAL(wp), DIMENSION(:,:) , ALLOCATABLE :: zalb, zmsk00 ! 2D workspace |
|---|
| 120 | !!-------------------------------------------------------------------- |
|---|
| 121 | ! |
|---|
| 122 | IF( ln_timing ) CALL timing_start('ice_sbc_flx') |
|---|
| 123 | |
|---|
| 124 | IF( kt == nit000 .AND. lwp ) THEN |
|---|
| 125 | WRITE(numout,*) |
|---|
| 126 | WRITE(numout,*)'ice_sbc_flx: Surface boundary condition for sea ice (flux)' |
|---|
| 127 | WRITE(numout,*)'~~~~~~~~~~~~~~~' |
|---|
| 128 | ENDIF |
|---|
| 129 | |
|---|
| 130 | ! get missing value from xml |
|---|
| 131 | CALL iom_miss_val( "icetemp", zmiss_val ) |
|---|
| 132 | |
|---|
| 133 | ! --- cloud-sky and overcast-sky ice albedos --- ! |
|---|
| 134 | CALL ice_alb( t_su, h_i, h_s, ln_pnd_alb, a_ip_frac, h_ip, zalb_cs, zalb_os ) |
|---|
| 135 | |
|---|
| 136 | ! albedo depends on cloud fraction because of non-linear spectral effects |
|---|
| 137 | !!gm cldf_ice is a real, DOCTOR naming rule: start with cd means CHARACTER passed in argument ! |
|---|
| 138 | alb_ice(:,:,:) = ( 1. - cldf_ice ) * zalb_cs(:,:,:) + cldf_ice * zalb_os(:,:,:) |
|---|
| 139 | ! |
|---|
| 140 | |
|---|
| 141 | ! Apply a limit to the ice fraction to avoid NANs being generated in ice_thd_snwblow |
|---|
| 142 | ! (negative number to power of 0.66) |
|---|
| 143 | WHERE( at_i_b(:,:) > 1._wp ) at_i_b(:,:) = 1._wp |
|---|
| 144 | |
|---|
| 145 | ! |
|---|
| 146 | SELECT CASE( ksbc ) !== fluxes over sea ice ==! |
|---|
| 147 | ! |
|---|
| 148 | CASE( jp_usr ) !--- user defined formulation |
|---|
| 149 | CALL usrdef_sbc_ice_flx( kt, h_s, h_i ) |
|---|
| 150 | CASE( jp_blk ) !--- bulk formulation |
|---|
| 151 | CALL blk_ice_flx ( t_su, h_s, h_i, alb_ice ) ! |
|---|
| 152 | IF( ln_mixcpl ) CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i ) |
|---|
| 153 | IF( nn_flxdist /= -1 ) CALL ice_flx_dist ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist ) |
|---|
| 154 | ! ! compute conduction flux and surface temperature (as in Jules surface module) |
|---|
| 155 | IF( ln_cndflx .AND. .NOT.ln_cndemulate ) & |
|---|
| 156 | & CALL blk_ice_qcn ( ln_virtual_itd, t_su, t_bo, h_s, h_i ) |
|---|
| 157 | CASE ( jp_purecpl ) !--- coupled formulation |
|---|
| 158 | CALL sbc_cpl_ice_flx( picefr=at_i_b, palbi=alb_ice, psst=sst_m, pist=t_su, phs=h_s, phi=h_i ) |
|---|
| 159 | IF( nn_flxdist /= -1 ) CALL ice_flx_dist ( t_su, alb_ice, qns_ice, qsr_ice, dqns_ice, evap_ice, devap_ice, nn_flxdist ) |
|---|
| 160 | END SELECT |
|---|
| 161 | |
|---|
| 162 | !--- output ice albedo and surface albedo ---! |
|---|
| 163 | IF( iom_use('icealb') .OR. iom_use('albedo') ) THEN |
|---|
| 164 | |
|---|
| 165 | ALLOCATE( zalb(jpi,jpj), zmsk00(jpi,jpj) ) |
|---|
| 166 | |
|---|
| 167 | WHERE( at_i_b < 1.e-03 ) |
|---|
| 168 | zmsk00(:,:) = 0._wp |
|---|
| 169 | zalb (:,:) = rn_alb_oce |
|---|
| 170 | ELSEWHERE |
|---|
| 171 | zmsk00(:,:) = 1._wp |
|---|
| 172 | zalb (:,:) = SUM( alb_ice * a_i_b, dim=3 ) / at_i_b |
|---|
| 173 | END WHERE |
|---|
| 174 | ! ice albedo |
|---|
| 175 | CALL iom_put( 'icealb' , zalb * zmsk00 + zmiss_val * ( 1._wp - zmsk00 ) ) |
|---|
| 176 | ! ice+ocean albedo |
|---|
| 177 | zalb(:,:) = SUM( alb_ice * a_i_b, dim=3 ) + rn_alb_oce * ( 1._wp - at_i_b ) |
|---|
| 178 | CALL iom_put( 'albedo' , zalb ) |
|---|
| 179 | |
|---|
| 180 | DEALLOCATE( zalb, zmsk00 ) |
|---|
| 181 | |
|---|
| 182 | ENDIF |
|---|
| 183 | ! |
|---|
| 184 | IF( ln_timing ) CALL timing_stop('ice_sbc_flx') |
|---|
| 185 | ! |
|---|
| 186 | END SUBROUTINE ice_sbc_flx |
|---|
| 187 | |
|---|
| 188 | |
|---|
| 189 | SUBROUTINE ice_flx_dist( ptn_ice, palb_ice, pqns_ice, pqsr_ice, pdqn_ice, pevap_ice, pdevap_ice, k_flxdist ) |
|---|
| 190 | !!------------------------------------------------------------------- |
|---|
| 191 | !! *** ROUTINE ice_flx_dist *** |
|---|
| 192 | !! |
|---|
| 193 | !! ** Purpose : update the ice surface boundary condition by averaging |
|---|
| 194 | !! and/or redistributing fluxes on ice categories |
|---|
| 195 | !! |
|---|
| 196 | !! ** Method : average then redistribute |
|---|
| 197 | !! |
|---|
| 198 | !! ** Action : depends on k_flxdist |
|---|
| 199 | !! = -1 Do nothing (needs N(cat) fluxes) |
|---|
| 200 | !! = 0 Average N(cat) fluxes then apply the average over the N(cat) ice |
|---|
| 201 | !! = 1 Average N(cat) fluxes then redistribute over the N(cat) ice |
|---|
| 202 | !! using T-ice and albedo sensitivity |
|---|
| 203 | !! = 2 Redistribute a single flux over categories |
|---|
| 204 | !!------------------------------------------------------------------- |
|---|
| 205 | INTEGER , INTENT(in ) :: k_flxdist ! redistributor |
|---|
| 206 | REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: ptn_ice ! ice surface temperature |
|---|
| 207 | REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: palb_ice ! ice albedo |
|---|
| 208 | REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqns_ice ! non solar flux |
|---|
| 209 | REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pqsr_ice ! net solar flux |
|---|
| 210 | REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdqn_ice ! non solar flux sensitivity |
|---|
| 211 | REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pevap_ice ! sublimation |
|---|
| 212 | REAL(wp), DIMENSION(:,:,:), INTENT(inout) :: pdevap_ice ! sublimation sensitivity |
|---|
| 213 | ! |
|---|
| 214 | INTEGER :: jl ! dummy loop index |
|---|
| 215 | ! |
|---|
| 216 | REAL(wp), DIMENSION(jpi,jpj) :: z1_at_i ! inverse of concentration |
|---|
| 217 | ! |
|---|
| 218 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: z_qsr_m ! Mean solar heat flux over all categories |
|---|
| 219 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: z_qns_m ! Mean non solar heat flux over all categories |
|---|
| 220 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: z_evap_m ! Mean sublimation over all categories |
|---|
| 221 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: z_dqn_m ! Mean d(qns)/dT over all categories |
|---|
| 222 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: z_devap_m ! Mean d(evap)/dT over all categories |
|---|
| 223 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zalb_m ! Mean albedo over all categories |
|---|
| 224 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: ztem_m ! Mean temperature over all categories |
|---|
| 225 | !!---------------------------------------------------------------------- |
|---|
| 226 | ! |
|---|
| 227 | WHERE ( at_i (:,:) > 0._wp ) ; z1_at_i(:,:) = 1._wp / at_i (:,:) |
|---|
| 228 | ELSEWHERE ; z1_at_i(:,:) = 0._wp |
|---|
| 229 | END WHERE |
|---|
| 230 | |
|---|
| 231 | SELECT CASE( k_flxdist ) !== averaged on all ice categories ==! |
|---|
| 232 | ! |
|---|
| 233 | CASE( 0 , 1 ) |
|---|
| 234 | ! |
|---|
| 235 | ALLOCATE( z_qns_m(jpi,jpj), z_qsr_m(jpi,jpj), z_dqn_m(jpi,jpj), z_evap_m(jpi,jpj), z_devap_m(jpi,jpj) ) |
|---|
| 236 | ! |
|---|
| 237 | z_qns_m (:,:) = SUM( a_i(:,:,:) * pqns_ice (:,:,:) , dim=3 ) * z1_at_i(:,:) |
|---|
| 238 | z_qsr_m (:,:) = SUM( a_i(:,:,:) * pqsr_ice (:,:,:) , dim=3 ) * z1_at_i(:,:) |
|---|
| 239 | z_dqn_m (:,:) = SUM( a_i(:,:,:) * pdqn_ice (:,:,:) , dim=3 ) * z1_at_i(:,:) |
|---|
| 240 | z_evap_m (:,:) = SUM( a_i(:,:,:) * pevap_ice (:,:,:) , dim=3 ) * z1_at_i(:,:) |
|---|
| 241 | z_devap_m(:,:) = SUM( a_i(:,:,:) * pdevap_ice(:,:,:) , dim=3 ) * z1_at_i(:,:) |
|---|
| 242 | DO jl = 1, jpl |
|---|
| 243 | pqns_ice (:,:,jl) = z_qns_m (:,:) |
|---|
| 244 | pqsr_ice (:,:,jl) = z_qsr_m (:,:) |
|---|
| 245 | pdqn_ice (:,:,jl) = z_dqn_m (:,:) |
|---|
| 246 | pevap_ice (:,:,jl) = z_evap_m(:,:) |
|---|
| 247 | pdevap_ice(:,:,jl) = z_devap_m(:,:) |
|---|
| 248 | END DO |
|---|
| 249 | ! |
|---|
| 250 | DEALLOCATE( z_qns_m, z_qsr_m, z_dqn_m, z_evap_m, z_devap_m ) |
|---|
| 251 | ! |
|---|
| 252 | END SELECT |
|---|
| 253 | ! |
|---|
| 254 | SELECT CASE( k_flxdist ) !== redistribution on all ice categories ==! |
|---|
| 255 | ! |
|---|
| 256 | CASE( 1 , 2 ) |
|---|
| 257 | ! |
|---|
| 258 | ALLOCATE( zalb_m(jpi,jpj), ztem_m(jpi,jpj) ) |
|---|
| 259 | ! |
|---|
| 260 | zalb_m(:,:) = SUM( a_i(:,:,:) * palb_ice(:,:,:) , dim=3 ) * z1_at_i(:,:) |
|---|
| 261 | ztem_m(:,:) = SUM( a_i(:,:,:) * ptn_ice (:,:,:) , dim=3 ) * z1_at_i(:,:) |
|---|
| 262 | DO jl = 1, jpl |
|---|
| 263 | pqns_ice (:,:,jl) = pqns_ice (:,:,jl) + pdqn_ice (:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) ) |
|---|
| 264 | pevap_ice(:,:,jl) = pevap_ice(:,:,jl) + pdevap_ice(:,:,jl) * ( ptn_ice(:,:,jl) - ztem_m(:,:) ) |
|---|
| 265 | pqsr_ice (:,:,jl) = pqsr_ice (:,:,jl) * ( 1._wp - palb_ice(:,:,jl) ) / ( 1._wp - zalb_m(:,:) ) |
|---|
| 266 | END DO |
|---|
| 267 | ! |
|---|
| 268 | DEALLOCATE( zalb_m, ztem_m ) |
|---|
| 269 | ! |
|---|
| 270 | END SELECT |
|---|
| 271 | ! |
|---|
| 272 | END SUBROUTINE ice_flx_dist |
|---|
| 273 | |
|---|
| 274 | |
|---|
| 275 | SUBROUTINE ice_sbc_init |
|---|
| 276 | !!------------------------------------------------------------------- |
|---|
| 277 | !! *** ROUTINE ice_sbc_init *** |
|---|
| 278 | !! |
|---|
| 279 | !! ** Purpose : Physical constants and parameters linked to the ice dynamics |
|---|
| 280 | !! |
|---|
| 281 | !! ** Method : Read the namsbc namelist and check the ice-dynamic |
|---|
| 282 | !! parameter values called at the first timestep (nit000) |
|---|
| 283 | !! |
|---|
| 284 | !! ** input : Namelist namsbc |
|---|
| 285 | !!------------------------------------------------------------------- |
|---|
| 286 | INTEGER :: ios, ioptio ! Local integer |
|---|
| 287 | !! |
|---|
| 288 | NAMELIST/namsbc/ rn_cio, rn_blow_s, nn_flxdist, ln_cndflx, ln_cndemulate |
|---|
| 289 | !!------------------------------------------------------------------- |
|---|
| 290 | ! |
|---|
| 291 | REWIND( numnam_ice_ref ) ! Namelist namsbc in reference namelist : Ice dynamics |
|---|
| 292 | READ ( numnam_ice_ref, namsbc, IOSTAT = ios, ERR = 901) |
|---|
| 293 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namsbc in reference namelist' ) |
|---|
| 294 | REWIND( numnam_ice_cfg ) ! Namelist namsbc in configuration namelist : Ice dynamics |
|---|
| 295 | READ ( numnam_ice_cfg, namsbc, IOSTAT = ios, ERR = 902 ) |
|---|
| 296 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namsbc in configuration namelist' ) |
|---|
| 297 | IF(lwm) WRITE( numoni, namsbc ) |
|---|
| 298 | ! |
|---|
| 299 | IF(lwp) THEN ! control print |
|---|
| 300 | WRITE(numout,*) |
|---|
| 301 | WRITE(numout,*) 'ice_sbc_init: ice parameters for ice dynamics ' |
|---|
| 302 | WRITE(numout,*) '~~~~~~~~~~~~~~~~' |
|---|
| 303 | WRITE(numout,*) ' Namelist namsbc:' |
|---|
| 304 | WRITE(numout,*) ' drag coefficient for oceanic stress rn_cio = ', rn_cio |
|---|
| 305 | WRITE(numout,*) ' coefficient for ice-lead partition of snowfall rn_blow_s = ', rn_blow_s |
|---|
| 306 | WRITE(numout,*) ' Multicategory heat flux formulation nn_flxdist = ', nn_flxdist |
|---|
| 307 | WRITE(numout,*) ' Use conduction flux as surface condition ln_cndflx = ', ln_cndflx |
|---|
| 308 | WRITE(numout,*) ' emulate conduction flux ln_cndemulate = ', ln_cndemulate |
|---|
| 309 | ENDIF |
|---|
| 310 | ! |
|---|
| 311 | IF(lwp) WRITE(numout,*) |
|---|
| 312 | SELECT CASE( nn_flxdist ) ! SI3 Multi-category heat flux formulation |
|---|
| 313 | CASE( -1 ) |
|---|
| 314 | IF(lwp) WRITE(numout,*) ' SI3: use per-category fluxes (nn_flxdist = -1) ' |
|---|
| 315 | CASE( 0 ) |
|---|
| 316 | IF(lwp) WRITE(numout,*) ' SI3: use average per-category fluxes (nn_flxdist = 0) ' |
|---|
| 317 | CASE( 1 ) |
|---|
| 318 | IF(lwp) WRITE(numout,*) ' SI3: use average then redistribute per-category fluxes (nn_flxdist = 1) ' |
|---|
| 319 | IF( ln_cpl ) CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in coupled mode must be /=1' ) |
|---|
| 320 | CASE( 2 ) |
|---|
| 321 | IF(lwp) WRITE(numout,*) ' SI3: Redistribute a single flux over categories (nn_flxdist = 2) ' |
|---|
| 322 | IF( .NOT. ln_cpl ) CALL ctl_stop( 'ice_thd_init: the chosen nn_flxdist for SI3 in forced mode must be /=2' ) |
|---|
| 323 | CASE DEFAULT |
|---|
| 324 | CALL ctl_stop( 'ice_thd_init: SI3 option, nn_flxdist, should be between -1 and 2' ) |
|---|
| 325 | END SELECT |
|---|
| 326 | ! |
|---|
| 327 | END SUBROUTINE ice_sbc_init |
|---|
| 328 | |
|---|
| 329 | #else |
|---|
| 330 | !!---------------------------------------------------------------------- |
|---|
| 331 | !! Default option : Empty module NO SI3 sea-ice model |
|---|
| 332 | !!---------------------------------------------------------------------- |
|---|
| 333 | #endif |
|---|
| 334 | |
|---|
| 335 | !!====================================================================== |
|---|
| 336 | END MODULE icesbc |
|---|
