New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in NEMO/branches/UKMO/NEMO_4.0.2_GO8_package/src/OCE/SBC – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.2_GO8_package/src/OCE/SBC/sbcssm.F90 @ 12660

Last change on this file since 12660 was 12660, checked in by cguiavarch, 4 years ago

UKMO/NEMO_4.0.2_GO8_package: copy over changes from NEMO_4.0.1_GO8_package branch.
File size: 14.6 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!            3.7  ! 2015-11  (G. Madec)  non linear free surface by default: e3t_m always computed
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_ssm       : calculate sea surface mean currents, temperature, 
13   !!                   and salinity over nn_fsbc time-step
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean fields
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE eosbn2         ! equation of state and related derivatives
20   USE traqsr, ONLY: ln_traqsr
21   !
22   USE in_out_manager ! I/O manager
23   USE prtctl         ! Print control
24   USE iom            ! IOM library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   sbc_ssm        ! routine called by step.F90
30   PUBLIC   sbc_ssm_init   ! routine called by sbcmod.F90
31
32   LOGICAL, SAVE ::   l_ssm_mean = .FALSE.   ! keep track of whether means have been read from restart file
33   
34   !!----------------------------------------------------------------------
35   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
36   !! $Id$
37   !! Software governed by the CeCILL license (see ./LICENSE)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE sbc_ssm( kt )
42      !!---------------------------------------------------------------------
43      !!                     ***  ROUTINE sbc_oce  ***
44      !!                     
45      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
46      !!                condition computation
47      !!               
48      !! ** Method  :   compute mean surface velocity (2 components at U and
49      !!      V-points) [m/s], temperature [Celsius] and salinity [psu] over
50      !!      the periode (kt - nn_fsbc) to kt
51      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
52      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
53      !!---------------------------------------------------------------------
54      INTEGER, INTENT(in) ::   kt   ! ocean time step
55      !
56      INTEGER  ::   ji, jj               ! loop index
57      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
58      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
59      CHARACTER(len=4),SAVE :: stype
60      !!---------------------------------------------------------------------
61      IF( kt == nit000 ) THEN
62         IF( ln_TEOS10 ) THEN
63            stype='abs'   ! teos-10: using absolute salinity (sst is converted to potential temperature for the surface module)
64         ELSE IF( ln_EOS80  ) THEN
65            stype='pra'   ! eos-80: using practical salinity
66         ELSE IF ( ln_SEOS) THEN
67            stype='seos' ! seos using Simplified Equation of state (sst is converted to potential temperature for the surface module)
68         ENDIF
69      ENDIF
70      !
71      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
72      DO jj = 1, jpj
73         DO ji = 1, jpi
74            zts(ji,jj,jp_tem) = tsn(ji,jj,mikt(ji,jj),jp_tem)
75            zts(ji,jj,jp_sal) = tsn(ji,jj,mikt(ji,jj),jp_sal)
76         END DO
77      END DO
78      !
79      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
80         !                                                ! ---------------------------------------- !
81         ssu_m(:,:) = ub(:,:,1)
82         ssv_m(:,:) = vb(:,:,1)
83         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
84         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
85         ENDIF
86         sss_m(:,:) = zts(:,:,jp_sal)
87         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
88         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
89         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
90         ENDIF
91         !
92         e3t_m(:,:) = e3t_n(:,:,1)
93         !
94         frq_m(:,:) = fraqsr_1lev(:,:)
95         !
96      ELSE
97         !                                                ! ----------------------------------------------- !
98         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
99            !                                             ! ----------------------------------------------- !
100            IF(lwp) WRITE(numout,*)
101            IF(lwp) WRITE(numout,*) 'sbc_ssm : mean fields initialised to instantaneous values'
102            IF(lwp) WRITE(numout,*) '~~~~~~~   '
103            zcoef = REAL( nn_fsbc - 1, wp )
104            ssu_m(:,:) = zcoef * ub(:,:,1)
105            ssv_m(:,:) = zcoef * vb(:,:,1)
106            IF( l_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
107            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
108            ENDIF
109            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
110            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
111            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
112            ELSE                    ;   ssh_m(:,:) = zcoef * sshn(:,:)
113            ENDIF
114            !
115            e3t_m(:,:) = zcoef * e3t_n(:,:,1)
116            !
117            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
118            !                                             ! ---------------------------------------- !
119         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
120            !                                             ! ---------------------------------------- !
121            ssu_m(:,:) = 0._wp     ! reset to zero ocean mean sbc fields
122            ssv_m(:,:) = 0._wp
123            sst_m(:,:) = 0._wp
124            sss_m(:,:) = 0._wp
125            ssh_m(:,:) = 0._wp
126            e3t_m(:,:) = 0._wp
127            frq_m(:,:) = 0._wp
128         ENDIF
129         !                                                ! ---------------------------------------- !
130         !                                                !        Cumulate at each time step        !
131         !                                                ! ---------------------------------------- !
132         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
133         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
134         IF( l_useCT )  THEN     ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
135         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
136         ENDIF
137         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
138         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
139         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
140         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
141         ENDIF
142         !
143         e3t_m(:,:) = e3t_m(:,:) + e3t_n(:,:,1)
144         !
145         frq_m(:,:) = frq_m(:,:) + fraqsr_1lev(:,:)
146
147         !                                                ! ---------------------------------------- !
148         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
149            !                                             ! ---------------------------------------- !
150            zcoef = 1. / REAL( nn_fsbc, wp )
151            sst_m(:,:) = sst_m(:,:) * zcoef     ! mean SST             [Celsius]
152            sss_m(:,:) = sss_m(:,:) * zcoef     ! mean SSS             [psu]
153            ssu_m(:,:) = ssu_m(:,:) * zcoef     ! mean suface current  [m/s]
154            ssv_m(:,:) = ssv_m(:,:) * zcoef     !
155            ssh_m(:,:) = ssh_m(:,:) * zcoef     ! mean SSH             [m]
156            e3t_m(:,:) = e3t_m(:,:) * zcoef     ! mean vertical scale factor [m]
157            frq_m(:,:) = frq_m(:,:) * zcoef     ! mean fraction of solar net radiation absorbed in the 1st T level [-]
158            !
159         ENDIF
160         !                                                ! ---------------------------------------- !
161         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
162            !                                             ! ---------------------------------------- !
163            IF(lwp) WRITE(numout,*)
164            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
165               &                    'at it= ', kt,' date= ', ndastp
166            IF(lwp) WRITE(numout,*) '~~~~~~~'
167            zf_sbc = REAL( nn_fsbc, wp )
168            IF( lwxios ) CALL iom_swap(      cwxios_context          )
169            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc, ldxios = lwxios )    ! sbc frequency
170            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m, ldxios = lwxios  )    ! sea surface mean fields
171            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m, ldxios = lwxios  )
172            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m, ldxios = lwxios  )
173            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m, ldxios = lwxios  )
174            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m, ldxios = lwxios  )
175            CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m, ldxios = lwxios  )
176            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m, ldxios = lwxios  )
177            !
178            IF( lwxios ) CALL iom_swap(      cxios_context          )
179         ENDIF
180         !
181      ENDIF
182      !
183      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
184         CALL iom_put( 'ssu_m', ssu_m )
185         CALL iom_put( 'ssv_m', ssv_m )
186         CALL iom_put( 'sst_m_pot', sst_m )
187         CALL iom_put( 'sss_m_'//stype, sss_m )
188         CALL iom_put( 'ssh_m', ssh_m )
189         CALL iom_put( 'e3t_m', e3t_m )
190         CALL iom_put( 'frq_m', frq_m )
191      ENDIF
192      !
193   END SUBROUTINE sbc_ssm
194
195
196   SUBROUTINE sbc_ssm_init
197      !!----------------------------------------------------------------------
198      !!                  ***  ROUTINE sbc_ssm_init  ***
199      !!
200      !! ** Purpose :   Initialisation of the sbc data
201      !!
202      !! ** Action  : - read parameters
203      !!----------------------------------------------------------------------
204      REAL(wp) ::   zcoef, zf_sbc   ! local scalar
205      !!----------------------------------------------------------------------
206      !
207      IF( nn_fsbc == 1 ) THEN
208         !
209         IF(lwp) WRITE(numout,*)
210         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields, nn_fsbc=1 : instantaneous values'
211         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
212         !
213      ELSE
214         !               
215         IF(lwp) WRITE(numout,*)
216         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields'
217         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
218         !
219         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
220            l_ssm_mean = .TRUE.
221            CALL iom_get( numror               , 'nn_fsbc', zf_sbc, ldxios = lrxios )    ! sbc frequency of previous run
222            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m, ldxios = lrxios  )    ! sea surface mean velocity    (U-point)
223            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m, ldxios = lrxios  )    !   "         "    velocity    (V-point)
224            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m, ldxios = lrxios  )    !   "         "    temperature (T-point)
225            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m, ldxios = lrxios  )    !   "         "    salinity    (T-point)
226            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m, ldxios = lrxios  )    !   "         "    height      (T-point)
227            CALL iom_get( numror, jpdom_autoglo, 'e3t_m'  , e3t_m, ldxios = lrxios  )    ! 1st level thickness          (T-point)
228            ! fraction of solar net radiation absorbed in 1st T level
229            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
230               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m, ldxios = lrxios  )
231            ELSE
232               frq_m(:,:) = 1._wp   ! default definition
233            ENDIF
234            !
235            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
236               IF(lwp) WRITE(numout,*) '   restart with a change in the frequency of mean from ', zf_sbc, ' to ', nn_fsbc 
237               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
238               ssu_m(:,:) = zcoef * ssu_m(:,:) 
239               ssv_m(:,:) = zcoef * ssv_m(:,:)
240               sst_m(:,:) = zcoef * sst_m(:,:)
241               sss_m(:,:) = zcoef * sss_m(:,:)
242               ssh_m(:,:) = zcoef * ssh_m(:,:)
243               e3t_m(:,:) = zcoef * e3t_m(:,:)
244               frq_m(:,:) = zcoef * frq_m(:,:)
245            ELSE
246               IF(lwp) WRITE(numout,*) '   mean fields read in the ocean restart file'
247            ENDIF
248         ENDIF
249      ENDIF
250      !
251      IF( .NOT.l_ssm_mean ) THEN   ! default initialisation. needed by iceistate
252         !
253         IF(lwp) WRITE(numout,*) '   default initialisation of ss._m arrays'
254         ssu_m(:,:) = ub(:,:,1)
255         ssv_m(:,:) = vb(:,:,1)
256         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
257         ELSE                   ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
258         ENDIF
259         sss_m(:,:) = tsn  (:,:,1,jp_sal)
260         ssh_m(:,:) = sshn (:,:)
261         e3t_m(:,:) = e3t_n(:,:,1)
262         frq_m(:,:) = 1._wp
263         !
264      ENDIF
265      !
266      IF( .NOT. ln_traqsr )   fraqsr_1lev(:,:) = 1._wp   ! default definition: qsr 100% in the fisrt level
267      !
268      IF( lwxios.AND.nn_fsbc > 1 ) THEN
269         CALL iom_set_rstw_var_active('nn_fsbc')
270         CALL iom_set_rstw_var_active('ssu_m')
271         CALL iom_set_rstw_var_active('ssv_m')
272         CALL iom_set_rstw_var_active('sst_m')
273         CALL iom_set_rstw_var_active('sss_m')
274         CALL iom_set_rstw_var_active('ssh_m')
275         CALL iom_set_rstw_var_active('e3t_m')
276         CALL iom_set_rstw_var_active('frq_m')
277      ENDIF
278
279   END SUBROUTINE sbc_ssm_init
280
281   !!======================================================================
282END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.