New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcssm.F90 in NEMO/branches/UKMO/NEMO_4.0.2_GO8_package_ENHANCE-02_ISF_nemo/src/OCE/SBC – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.2_GO8_package_ENHANCE-02_ISF_nemo/src/OCE/SBC/sbcssm.F90 @ 12721

Last change on this file since 12721 was 12721, checked in by mathiot, 4 years ago

NEMO_4.0.2_GO8_package_ENHANCE-02_ISF_nemo: add last year isf dev

File size: 14.5 KB
Line 
1MODULE sbcssm
2   !!======================================================================
3   !!                       ***  MODULE  sbcssm  ***
4   !! Surface module :  provide time-mean ocean surface variables
5   !!======================================================================
6   !! History :  9.0  ! 2006-07  (G. Madec)  Original code
7   !!            3.3  ! 2010-10  (C. Bricaud, G. Madec)  add the Patm forcing for sea-ice
8   !!            3.7  ! 2015-11  (G. Madec)  non linear free surface by default: e3t_m always computed
9   !!----------------------------------------------------------------------
10
11   !!----------------------------------------------------------------------
12   !!   sbc_ssm       : calculate sea surface mean currents, temperature, 
13   !!                   and salinity over nn_fsbc time-step
14   !!----------------------------------------------------------------------
15   USE oce            ! ocean dynamics and tracers
16   USE dom_oce        ! ocean space and time domain
17   USE sbc_oce        ! surface boundary condition: ocean fields
18   USE sbcapr         ! surface boundary condition: atmospheric pressure
19   USE eosbn2         ! equation of state and related derivatives
20   USE traqsr, ONLY: ln_traqsr
21   !
22   USE in_out_manager ! I/O manager
23   USE prtctl         ! Print control
24   USE iom            ! IOM library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   sbc_ssm        ! routine called by step.F90
30   PUBLIC   sbc_ssm_init   ! routine called by sbcmod.F90
31
32   LOGICAL, SAVE ::   l_ssm_mean = .FALSE.   ! keep track of whether means have been read from restart file
33   
34   !!----------------------------------------------------------------------
35   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
36   !! $Id$
37   !! Software governed by the CeCILL license (see ./LICENSE)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE sbc_ssm( kt )
42      !!---------------------------------------------------------------------
43      !!                     ***  ROUTINE sbc_oce  ***
44      !!                     
45      !! ** Purpose :   provide ocean surface variable to sea-surface boundary
46      !!                condition computation
47      !!               
48      !! ** Method  :   compute mean surface velocity (2 components at U and
49      !!      V-points) [m/s], temperature [Celsius] and salinity [psu] over
50      !!      the periode (kt - nn_fsbc) to kt
51      !!         Note that the inverse barometer ssh (i.e. ssh associated with Patm)
52      !!      is add to ssh_m when ln_apr_dyn = T. Required for sea-ice dynamics.
53      !!---------------------------------------------------------------------
54      INTEGER, INTENT(in) ::   kt   ! ocean time step
55      !
56      INTEGER  ::   ji, jj               ! loop index
57      REAL(wp) ::   zcoef, zf_sbc       ! local scalar
58      REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts
59      CHARACTER(len=4),SAVE :: stype
60      !!---------------------------------------------------------------------
61      IF( kt == nit000 ) THEN
62         IF( ln_TEOS10 ) THEN
63            stype='abs'   ! teos-10: using absolute salinity (sst is converted to potential temperature for the surface module)
64         ELSE IF( ln_EOS80  ) THEN
65            stype='pra'   ! eos-80: using practical salinity
66         ELSE IF ( ln_SEOS) THEN
67            stype='seos' ! seos using Simplified Equation of state (sst is converted to potential temperature for the surface module)
68         ENDIF
69      ENDIF
70      !
71      !                                        !* surface T-, U-, V- ocean level variables (T, S, depth, velocity)
72      zts(:,:,jp_tem) = tsn(:,:,1,jp_tem)
73      zts(:,:,jp_sal) = tsn(:,:,1,jp_sal)
74      !
75      IF( nn_fsbc == 1 ) THEN                             !   Instantaneous surface fields        !
76         !                                                ! ---------------------------------------- !
77         ssu_m(:,:) = ub(:,:,1)
78         ssv_m(:,:) = vb(:,:,1)
79         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
80         ELSE                    ;   sst_m(:,:) = zts(:,:,jp_tem)
81         ENDIF
82         sss_m(:,:) = zts(:,:,jp_sal)
83         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
84         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
85         ELSE                    ;   ssh_m(:,:) = sshn(:,:)
86         ENDIF
87         !
88         e3t_m(:,:) = e3t_n(:,:,1)
89         !
90         frq_m(:,:) = fraqsr_1lev(:,:)
91         !
92      ELSE
93         !                                                ! ----------------------------------------------- !
94         IF( kt == nit000 .AND. .NOT. l_ssm_mean ) THEN   !   Initialisation: 1st time-step, no input means !
95            !                                             ! ----------------------------------------------- !
96            IF(lwp) WRITE(numout,*)
97            IF(lwp) WRITE(numout,*) 'sbc_ssm : mean fields initialised to instantaneous values'
98            IF(lwp) WRITE(numout,*) '~~~~~~~   '
99            zcoef = REAL( nn_fsbc - 1, wp )
100            ssu_m(:,:) = zcoef * ub(:,:,1)
101            ssv_m(:,:) = zcoef * vb(:,:,1)
102            IF( l_useCT )  THEN    ;   sst_m(:,:) = zcoef * eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
103            ELSE                    ;   sst_m(:,:) = zcoef * zts(:,:,jp_tem)
104            ENDIF
105            sss_m(:,:) = zcoef * zts(:,:,jp_sal)
106            !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
107            IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = zcoef * ( sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) ) )
108            ELSE                    ;   ssh_m(:,:) = zcoef * sshn(:,:)
109            ENDIF
110            !
111            e3t_m(:,:) = zcoef * e3t_n(:,:,1)
112            !
113            frq_m(:,:) = zcoef * fraqsr_1lev(:,:)
114            !                                             ! ---------------------------------------- !
115         ELSEIF( MOD( kt - 2 , nn_fsbc ) == 0 ) THEN      !   Initialisation: New mean computation   !
116            !                                             ! ---------------------------------------- !
117            ssu_m(:,:) = 0._wp     ! reset to zero ocean mean sbc fields
118            ssv_m(:,:) = 0._wp
119            sst_m(:,:) = 0._wp
120            sss_m(:,:) = 0._wp
121            ssh_m(:,:) = 0._wp
122            e3t_m(:,:) = 0._wp
123            frq_m(:,:) = 0._wp
124         ENDIF
125         !                                                ! ---------------------------------------- !
126         !                                                !        Cumulate at each time step        !
127         !                                                ! ---------------------------------------- !
128         ssu_m(:,:) = ssu_m(:,:) + ub(:,:,1)
129         ssv_m(:,:) = ssv_m(:,:) + vb(:,:,1)
130         IF( l_useCT )  THEN     ;   sst_m(:,:) = sst_m(:,:) + eos_pt_from_ct( zts(:,:,jp_tem), zts(:,:,jp_sal) )
131         ELSE                    ;   sst_m(:,:) = sst_m(:,:) + zts(:,:,jp_tem)
132         ENDIF
133         sss_m(:,:) = sss_m(:,:) + zts(:,:,jp_sal)
134         !                          ! removed inverse barometer ssh when Patm forcing is used (for sea-ice dynamics)
135         IF( ln_apr_dyn ) THEN   ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:) - 0.5 * ( ssh_ib(:,:) + ssh_ibb(:,:) )
136         ELSE                    ;   ssh_m(:,:) = ssh_m(:,:) + sshn(:,:)
137         ENDIF
138         !
139         e3t_m(:,:) = e3t_m(:,:) + e3t_n(:,:,1)
140         !
141         frq_m(:,:) = frq_m(:,:) + fraqsr_1lev(:,:)
142
143         !                                                ! ---------------------------------------- !
144         IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
145            !                                             ! ---------------------------------------- !
146            zcoef = 1. / REAL( nn_fsbc, wp )
147            sst_m(:,:) = sst_m(:,:) * zcoef     ! mean SST             [Celsius]
148            sss_m(:,:) = sss_m(:,:) * zcoef     ! mean SSS             [psu]
149            ssu_m(:,:) = ssu_m(:,:) * zcoef     ! mean suface current  [m/s]
150            ssv_m(:,:) = ssv_m(:,:) * zcoef     !
151            ssh_m(:,:) = ssh_m(:,:) * zcoef     ! mean SSH             [m]
152            e3t_m(:,:) = e3t_m(:,:) * zcoef     ! mean vertical scale factor [m]
153            frq_m(:,:) = frq_m(:,:) * zcoef     ! mean fraction of solar net radiation absorbed in the 1st T level [-]
154            !
155         ENDIF
156         !                                                ! ---------------------------------------- !
157         IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
158            !                                             ! ---------------------------------------- !
159            IF(lwp) WRITE(numout,*)
160            IF(lwp) WRITE(numout,*) 'sbc_ssm : sea surface mean fields written in ocean restart file ',   &
161               &                    'at it= ', kt,' date= ', ndastp
162            IF(lwp) WRITE(numout,*) '~~~~~~~'
163            zf_sbc = REAL( nn_fsbc, wp )
164            IF( lwxios ) CALL iom_swap(      cwxios_context          )
165            CALL iom_rstput( kt, nitrst, numrow, 'nn_fsbc', zf_sbc, ldxios = lwxios )    ! sbc frequency
166            CALL iom_rstput( kt, nitrst, numrow, 'ssu_m'  , ssu_m, ldxios = lwxios  )    ! sea surface mean fields
167            CALL iom_rstput( kt, nitrst, numrow, 'ssv_m'  , ssv_m, ldxios = lwxios  )
168            CALL iom_rstput( kt, nitrst, numrow, 'sst_m'  , sst_m, ldxios = lwxios  )
169            CALL iom_rstput( kt, nitrst, numrow, 'sss_m'  , sss_m, ldxios = lwxios  )
170            CALL iom_rstput( kt, nitrst, numrow, 'ssh_m'  , ssh_m, ldxios = lwxios  )
171            CALL iom_rstput( kt, nitrst, numrow, 'e3t_m'  , e3t_m, ldxios = lwxios  )
172            CALL iom_rstput( kt, nitrst, numrow, 'frq_m'  , frq_m, ldxios = lwxios  )
173            !
174            IF( lwxios ) CALL iom_swap(      cxios_context          )
175         ENDIF
176         !
177      ENDIF
178      !
179      IF( MOD( kt - 1 , nn_fsbc ) == 0 ) THEN          !   Mean value at each nn_fsbc time-step   !
180         CALL iom_put( 'ssu_m', ssu_m )
181         CALL iom_put( 'ssv_m', ssv_m )
182         CALL iom_put( 'sst_m_pot', sst_m )
183         CALL iom_put( 'sss_m_'//stype, sss_m )
184         CALL iom_put( 'ssh_m', ssh_m )
185         CALL iom_put( 'e3t_m', e3t_m )
186         CALL iom_put( 'frq_m', frq_m )
187      ENDIF
188      !
189   END SUBROUTINE sbc_ssm
190
191
192   SUBROUTINE sbc_ssm_init
193      !!----------------------------------------------------------------------
194      !!                  ***  ROUTINE sbc_ssm_init  ***
195      !!
196      !! ** Purpose :   Initialisation of the sbc data
197      !!
198      !! ** Action  : - read parameters
199      !!----------------------------------------------------------------------
200      REAL(wp) ::   zcoef, zf_sbc   ! local scalar
201      !!----------------------------------------------------------------------
202      !
203      IF( nn_fsbc == 1 ) THEN
204         !
205         IF(lwp) WRITE(numout,*)
206         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields, nn_fsbc=1 : instantaneous values'
207         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ '
208         !
209      ELSE
210         !               
211         IF(lwp) WRITE(numout,*)
212         IF(lwp) WRITE(numout,*) 'sbc_ssm_init : sea surface mean fields'
213         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~ '
214         !
215         IF( ln_rstart .AND. iom_varid( numror, 'nn_fsbc', ldstop = .FALSE. ) > 0 ) THEN
216            l_ssm_mean = .TRUE.
217            CALL iom_get( numror               , 'nn_fsbc', zf_sbc, ldxios = lrxios )    ! sbc frequency of previous run
218            CALL iom_get( numror, jpdom_autoglo, 'ssu_m'  , ssu_m, ldxios = lrxios  )    ! sea surface mean velocity    (U-point)
219            CALL iom_get( numror, jpdom_autoglo, 'ssv_m'  , ssv_m, ldxios = lrxios  )    !   "         "    velocity    (V-point)
220            CALL iom_get( numror, jpdom_autoglo, 'sst_m'  , sst_m, ldxios = lrxios  )    !   "         "    temperature (T-point)
221            CALL iom_get( numror, jpdom_autoglo, 'sss_m'  , sss_m, ldxios = lrxios  )    !   "         "    salinity    (T-point)
222            CALL iom_get( numror, jpdom_autoglo, 'ssh_m'  , ssh_m, ldxios = lrxios  )    !   "         "    height      (T-point)
223            CALL iom_get( numror, jpdom_autoglo, 'e3t_m'  , e3t_m, ldxios = lrxios  )    ! 1st level thickness          (T-point)
224            ! fraction of solar net radiation absorbed in 1st T level
225            IF( iom_varid( numror, 'frq_m', ldstop = .FALSE. ) > 0 ) THEN
226               CALL iom_get( numror, jpdom_autoglo, 'frq_m'  , frq_m, ldxios = lrxios  )
227            ELSE
228               frq_m(:,:) = 1._wp   ! default definition
229            ENDIF
230            !
231            IF( zf_sbc /= REAL( nn_fsbc, wp ) ) THEN      ! nn_fsbc has changed between 2 runs
232               IF(lwp) WRITE(numout,*) '   restart with a change in the frequency of mean from ', zf_sbc, ' to ', nn_fsbc 
233               zcoef = REAL( nn_fsbc - 1, wp ) / zf_sbc 
234               ssu_m(:,:) = zcoef * ssu_m(:,:) 
235               ssv_m(:,:) = zcoef * ssv_m(:,:)
236               sst_m(:,:) = zcoef * sst_m(:,:)
237               sss_m(:,:) = zcoef * sss_m(:,:)
238               ssh_m(:,:) = zcoef * ssh_m(:,:)
239               e3t_m(:,:) = zcoef * e3t_m(:,:)
240               frq_m(:,:) = zcoef * frq_m(:,:)
241            ELSE
242               IF(lwp) WRITE(numout,*) '   mean fields read in the ocean restart file'
243            ENDIF
244         ENDIF
245      ENDIF
246      !
247      IF( .NOT.l_ssm_mean ) THEN   ! default initialisation. needed by iceistate
248         !
249         IF(lwp) WRITE(numout,*) '   default initialisation of ss._m arrays'
250         ssu_m(:,:) = ub(:,:,1)
251         ssv_m(:,:) = vb(:,:,1)
252         IF( l_useCT )  THEN    ;   sst_m(:,:) = eos_pt_from_ct( tsn(:,:,1,jp_tem), tsn(:,:,1,jp_sal) )
253         ELSE                   ;   sst_m(:,:) = tsn(:,:,1,jp_tem)
254         ENDIF
255         sss_m(:,:) = tsn  (:,:,1,jp_sal)
256         ssh_m(:,:) = sshn (:,:)
257         e3t_m(:,:) = e3t_n(:,:,1)
258         frq_m(:,:) = 1._wp
259         !
260      ENDIF
261      !
262      IF( .NOT. ln_traqsr )   fraqsr_1lev(:,:) = 1._wp   ! default definition: qsr 100% in the fisrt level
263      !
264      IF( lwxios.AND.nn_fsbc > 1 ) THEN
265         CALL iom_set_rstw_var_active('nn_fsbc')
266         CALL iom_set_rstw_var_active('ssu_m')
267         CALL iom_set_rstw_var_active('ssv_m')
268         CALL iom_set_rstw_var_active('sst_m')
269         CALL iom_set_rstw_var_active('sss_m')
270         CALL iom_set_rstw_var_active('ssh_m')
271         CALL iom_set_rstw_var_active('e3t_m')
272         CALL iom_set_rstw_var_active('frq_m')
273      ENDIF
274
275   END SUBROUTINE sbc_ssm_init
276
277   !!======================================================================
278END MODULE sbcssm
Note: See TracBrowser for help on using the repository browser.