| 1 | MODULE ldfslp |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE ldfslp *** |
|---|
| 4 | !! Ocean physics: slopes of neutral surfaces |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : OPA ! 1994-12 (G. Madec, M. Imbard) Original code |
|---|
| 7 | !! 8.0 ! 1997-06 (G. Madec) optimization, lbc |
|---|
| 8 | !! 8.1 ! 1999-10 (A. Jouzeau) NEW profile in the mixed layer |
|---|
| 9 | !! NEMO 1.0 ! 2002-10 (G. Madec) Free form, F90 |
|---|
| 10 | !! - ! 2005-10 (A. Beckmann) correction for s-coordinates |
|---|
| 11 | !! 3.3 ! 2010-10 (G. Nurser, C. Harris, G. Madec) add Griffies operator |
|---|
| 12 | !! - ! 2010-11 (F. Dupond, G. Madec) bug correction in slopes just below the ML |
|---|
| 13 | !! 3.7 ! 2013-12 (F. Lemarie, G. Madec) add limiter on triad slopes |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | !! ldf_slp : calculates the slopes of neutral surface (Madec operator) |
|---|
| 18 | !! ldf_slp_triad : calculates the triads of isoneutral slopes (Griffies operator) |
|---|
| 19 | !! ldf_slp_mxl : calculates the slopes at the base of the mixed layer (Madec operator) |
|---|
| 20 | !! ldf_slp_init : initialization of the slopes computation |
|---|
| 21 | !!---------------------------------------------------------------------- |
|---|
| 22 | USE oce ! ocean dynamics and tracers |
|---|
| 23 | USE dom_oce ! ocean space and time domain |
|---|
| 24 | ! USE ldfdyn ! lateral diffusion: eddy viscosity coef. |
|---|
| 25 | USE phycst ! physical constants |
|---|
| 26 | USE zdfmxl ! mixed layer depth |
|---|
| 27 | USE eosbn2 ! equation of states |
|---|
| 28 | ! |
|---|
| 29 | USE in_out_manager ! I/O manager |
|---|
| 30 | USE prtctl ! Print control |
|---|
| 31 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 32 | USE lib_mpp ! distribued memory computing library |
|---|
| 33 | USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined) |
|---|
| 34 | USE timing ! Timing |
|---|
| 35 | |
|---|
| 36 | IMPLICIT NONE |
|---|
| 37 | PRIVATE |
|---|
| 38 | |
|---|
| 39 | PUBLIC ldf_slp ! routine called by step.F90 |
|---|
| 40 | PUBLIC ldf_slp_triad ! routine called by step.F90 |
|---|
| 41 | PUBLIC ldf_slp_init ! routine called by nemogcm.F90 |
|---|
| 42 | |
|---|
| 43 | LOGICAL , PUBLIC :: l_ldfslp = .FALSE. !: slopes flag |
|---|
| 44 | |
|---|
| 45 | LOGICAL , PUBLIC :: ln_traldf_iso = .TRUE. !: iso-neutral direction (nam_traldf namelist) |
|---|
| 46 | LOGICAL , PUBLIC :: ln_traldf_triad = .FALSE. !: griffies triad scheme (nam_traldf namelist) |
|---|
| 47 | LOGICAL , PUBLIC :: ln_dynldf_iso !: iso-neutral direction (nam_dynldf namelist) |
|---|
| 48 | |
|---|
| 49 | LOGICAL , PUBLIC :: ln_triad_iso = .FALSE. !: pure horizontal mixing in ML (nam_traldf namelist) |
|---|
| 50 | LOGICAL , PUBLIC :: ln_botmix_triad = .FALSE. !: mixing on bottom (nam_traldf namelist) |
|---|
| 51 | REAL(wp), PUBLIC :: rn_sw_triad = 1._wp !: =1 switching triads ; =0 all four triads used (nam_traldf namelist) |
|---|
| 52 | REAL(wp), PUBLIC :: rn_slpmax = 0.01_wp !: slope limit (nam_traldf namelist) |
|---|
| 53 | |
|---|
| 54 | LOGICAL , PUBLIC :: l_grad_zps = .FALSE. !: special treatment for Horz Tgradients w partial steps (triad operator) |
|---|
| 55 | |
|---|
| 56 | ! !! Classic operator (Madec) |
|---|
| 57 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: uslp, wslpi !: i_slope at U- and W-points |
|---|
| 58 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: vslp, wslpj !: j-slope at V- and W-points |
|---|
| 59 | ! !! triad operator (Griffies) |
|---|
| 60 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: wslp2 !: wslp**2 from Griffies quarter cells |
|---|
| 61 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:,:,:) :: triadi_g, triadj_g !: skew flux slopes relative to geopotentials |
|---|
| 62 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:,:,:) :: triadi , triadj !: isoneutral slopes relative to model-coordinate |
|---|
| 63 | ! !! both operators |
|---|
| 64 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: ah_wslp2 !: ah * slope^2 at w-point |
|---|
| 65 | REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: akz !: stabilizing vertical diffusivity |
|---|
| 66 | |
|---|
| 67 | ! !! Madec operator |
|---|
| 68 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) :: omlmask ! mask of the surface mixed layer at T-pt |
|---|
| 69 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: uslpml, wslpiml ! i_slope at U- and W-points just below the mixed layer |
|---|
| 70 | REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:) :: vslpml, wslpjml ! j_slope at V- and W-points just below the mixed layer |
|---|
| 71 | |
|---|
| 72 | REAL(wp) :: repsln = 1.e-25_wp ! tiny value used as minium of di(rho), dj(rho) and dk(rho) |
|---|
| 73 | |
|---|
| 74 | !! * Substitutions |
|---|
| 75 | # include "vectopt_loop_substitute.h90" |
|---|
| 76 | !!---------------------------------------------------------------------- |
|---|
| 77 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 78 | !! $Id$ |
|---|
| 79 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 80 | !!---------------------------------------------------------------------- |
|---|
| 81 | CONTAINS |
|---|
| 82 | |
|---|
| 83 | SUBROUTINE ldf_slp( kt, prd, pn2 ) |
|---|
| 84 | !!---------------------------------------------------------------------- |
|---|
| 85 | !! *** ROUTINE ldf_slp *** |
|---|
| 86 | !! |
|---|
| 87 | !! ** Purpose : Compute the slopes of neutral surface (slope of isopycnal |
|---|
| 88 | !! surfaces referenced locally) (ln_traldf_iso=T). |
|---|
| 89 | !! |
|---|
| 90 | !! ** Method : The slope in the i-direction is computed at U- and |
|---|
| 91 | !! W-points (uslp, wslpi) and the slope in the j-direction is |
|---|
| 92 | !! computed at V- and W-points (vslp, wslpj). |
|---|
| 93 | !! They are bounded by 1/100 over the whole ocean, and within the |
|---|
| 94 | !! surface layer they are bounded by the distance to the surface |
|---|
| 95 | !! ( slope<= depth/l where l is the length scale of horizontal |
|---|
| 96 | !! diffusion (here, aht=2000m2/s ==> l=20km with a typical velocity |
|---|
| 97 | !! of 10cm/s) |
|---|
| 98 | !! A horizontal shapiro filter is applied to the slopes |
|---|
| 99 | !! ln_sco=T, s-coordinate, add to the previously computed slopes |
|---|
| 100 | !! the slope of the model level surface. |
|---|
| 101 | !! macro-tasked on horizontal slab (jk-loop) (2, jpk-1) |
|---|
| 102 | !! [slopes already set to zero at level 1, and to zero or the ocean |
|---|
| 103 | !! bottom slope (ln_sco=T) at level jpk in inildf] |
|---|
| 104 | !! |
|---|
| 105 | !! ** Action : - uslp, wslpi, and vslp, wslpj, the i- and j-slopes |
|---|
| 106 | !! of now neutral surfaces at u-, w- and v- w-points, resp. |
|---|
| 107 | !!---------------------------------------------------------------------- |
|---|
| 108 | INTEGER , INTENT(in) :: kt ! ocean time-step index |
|---|
| 109 | REAL(wp), INTENT(in), DIMENSION(:,:,:) :: prd ! in situ density |
|---|
| 110 | REAL(wp), INTENT(in), DIMENSION(:,:,:) :: pn2 ! Brunt-Vaisala frequency (locally ref.) |
|---|
| 111 | !! |
|---|
| 112 | INTEGER :: ji , jj , jk ! dummy loop indices |
|---|
| 113 | INTEGER :: ii0, ii1 ! temporary integer |
|---|
| 114 | INTEGER :: ij0, ij1 ! temporary integer |
|---|
| 115 | REAL(wp) :: zeps, zm1_g, zm1_2g, z1_16, zcofw, z1_slpmax ! local scalars |
|---|
| 116 | REAL(wp) :: zci, zfi, zau, zbu, zai, zbi ! - - |
|---|
| 117 | REAL(wp) :: zcj, zfj, zav, zbv, zaj, zbj ! - - |
|---|
| 118 | REAL(wp) :: zck, zfk, zbw ! - - |
|---|
| 119 | REAL(wp) :: zdepu, zdepv ! - - |
|---|
| 120 | REAL(wp), DIMENSION(jpi,jpj) :: zslpml_hmlpu, zslpml_hmlpv |
|---|
| 121 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgru, zwz, zdzr |
|---|
| 122 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrv, zww |
|---|
| 123 | !!---------------------------------------------------------------------- |
|---|
| 124 | ! |
|---|
| 125 | IF( ln_timing ) CALL timing_start('ldf_slp') |
|---|
| 126 | ! |
|---|
| 127 | zeps = 1.e-20_wp !== Local constant initialization ==! |
|---|
| 128 | z1_16 = 1.0_wp / 16._wp |
|---|
| 129 | zm1_g = -1.0_wp / grav |
|---|
| 130 | zm1_2g = -0.5_wp / grav |
|---|
| 131 | z1_slpmax = 1._wp / rn_slpmax |
|---|
| 132 | ! |
|---|
| 133 | zww(:,:,:) = 0._wp |
|---|
| 134 | zwz(:,:,:) = 0._wp |
|---|
| 135 | ! |
|---|
| 136 | DO jk = 1, jpk !== i- & j-gradient of density ==! |
|---|
| 137 | DO jj = 1, jpjm1 |
|---|
| 138 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 139 | zgru(ji,jj,jk) = umask(ji,jj,jk) * ( prd(ji+1,jj ,jk) - prd(ji,jj,jk) ) |
|---|
| 140 | zgrv(ji,jj,jk) = vmask(ji,jj,jk) * ( prd(ji ,jj+1,jk) - prd(ji,jj,jk) ) |
|---|
| 141 | END DO |
|---|
| 142 | END DO |
|---|
| 143 | END DO |
|---|
| 144 | IF( ln_zps ) THEN ! partial steps correction at the bottom ocean level |
|---|
| 145 | DO jj = 1, jpjm1 |
|---|
| 146 | DO ji = 1, jpim1 |
|---|
| 147 | zgru(ji,jj,mbku(ji,jj)) = gru(ji,jj) |
|---|
| 148 | zgrv(ji,jj,mbkv(ji,jj)) = grv(ji,jj) |
|---|
| 149 | END DO |
|---|
| 150 | END DO |
|---|
| 151 | ENDIF |
|---|
| 152 | IF( ln_zps .AND. ln_isfcav ) THEN ! partial steps correction at the bottom ocean level |
|---|
| 153 | DO jj = 1, jpjm1 |
|---|
| 154 | DO ji = 1, jpim1 |
|---|
| 155 | IF( miku(ji,jj) > 1 ) zgru(ji,jj,miku(ji,jj)) = grui(ji,jj) |
|---|
| 156 | IF( mikv(ji,jj) > 1 ) zgrv(ji,jj,mikv(ji,jj)) = grvi(ji,jj) |
|---|
| 157 | END DO |
|---|
| 158 | END DO |
|---|
| 159 | ENDIF |
|---|
| 160 | ! |
|---|
| 161 | zdzr(:,:,1) = 0._wp !== Local vertical density gradient at T-point == ! (evaluated from N^2) |
|---|
| 162 | DO jk = 2, jpkm1 |
|---|
| 163 | ! ! zdzr = d/dz(prd)= - ( prd ) / grav * mk(pn2) -- at t point |
|---|
| 164 | ! ! trick: tmask(ik ) = 0 => all pn2 = 0 => zdzr = 0 |
|---|
| 165 | ! ! else tmask(ik+1) = 0 => pn2(ik+1) = 0 => zdzr divides by 1 |
|---|
| 166 | ! ! umask(ik+1) /= 0 => all pn2 /= 0 => zdzr divides by 2 |
|---|
| 167 | ! ! NB: 1/(tmask+1) = (1-.5*tmask) substitute a / by a * ==> faster |
|---|
| 168 | zdzr(:,:,jk) = zm1_g * ( prd(:,:,jk) + 1._wp ) & |
|---|
| 169 | & * ( pn2(:,:,jk) + pn2(:,:,jk+1) ) * ( 1._wp - 0.5_wp * tmask(:,:,jk+1) ) |
|---|
| 170 | END DO |
|---|
| 171 | ! |
|---|
| 172 | ! !== Slopes just below the mixed layer ==! |
|---|
| 173 | CALL ldf_slp_mxl( prd, pn2, zgru, zgrv, zdzr ) ! output: uslpml, vslpml, wslpiml, wslpjml |
|---|
| 174 | |
|---|
| 175 | |
|---|
| 176 | ! I. slopes at u and v point | uslp = d/di( prd ) / d/dz( prd ) |
|---|
| 177 | ! =========================== | vslp = d/dj( prd ) / d/dz( prd ) |
|---|
| 178 | ! |
|---|
| 179 | IF ( ln_isfcav ) THEN |
|---|
| 180 | DO jj = 2, jpjm1 |
|---|
| 181 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 182 | zslpml_hmlpu(ji,jj) = uslpml(ji,jj) / ( MAX(hmlpt (ji,jj), hmlpt (ji+1,jj ), 5._wp) & |
|---|
| 183 | & - MAX(risfdep(ji,jj), risfdep(ji+1,jj ) ) ) |
|---|
| 184 | zslpml_hmlpv(ji,jj) = vslpml(ji,jj) / ( MAX(hmlpt (ji,jj), hmlpt (ji ,jj+1), 5._wp) & |
|---|
| 185 | & - MAX(risfdep(ji,jj), risfdep(ji ,jj+1) ) ) |
|---|
| 186 | END DO |
|---|
| 187 | END DO |
|---|
| 188 | ELSE |
|---|
| 189 | DO jj = 2, jpjm1 |
|---|
| 190 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 191 | zslpml_hmlpu(ji,jj) = uslpml(ji,jj) / MAX(hmlpt(ji,jj), hmlpt(ji+1,jj ), 5._wp) |
|---|
| 192 | zslpml_hmlpv(ji,jj) = vslpml(ji,jj) / MAX(hmlpt(ji,jj), hmlpt(ji ,jj+1), 5._wp) |
|---|
| 193 | END DO |
|---|
| 194 | END DO |
|---|
| 195 | END IF |
|---|
| 196 | |
|---|
| 197 | DO jk = 2, jpkm1 !* Slopes at u and v points |
|---|
| 198 | DO jj = 2, jpjm1 |
|---|
| 199 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 200 | ! ! horizontal and vertical density gradient at u- and v-points |
|---|
| 201 | zau = zgru(ji,jj,jk) * r1_e1u(ji,jj) |
|---|
| 202 | zav = zgrv(ji,jj,jk) * r1_e2v(ji,jj) |
|---|
| 203 | zbu = 0.5_wp * ( zdzr(ji,jj,jk) + zdzr(ji+1,jj ,jk) ) |
|---|
| 204 | zbv = 0.5_wp * ( zdzr(ji,jj,jk) + zdzr(ji ,jj+1,jk) ) |
|---|
| 205 | ! ! bound the slopes: abs(zw.)<= 1/100 and zb..<0 |
|---|
| 206 | ! ! + kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 207 | zbu = MIN( zbu, - z1_slpmax * ABS( zau ) , -7.e+3_wp/e3u_n(ji,jj,jk)* ABS( zau ) ) |
|---|
| 208 | zbv = MIN( zbv, - z1_slpmax * ABS( zav ) , -7.e+3_wp/e3v_n(ji,jj,jk)* ABS( zav ) ) |
|---|
| 209 | ! ! Fred Dupont: add a correction for bottom partial steps: |
|---|
| 210 | ! ! max slope = 1/2 * e3 / e1 |
|---|
| 211 | IF (ln_zps .AND. jk==mbku(ji,jj)) & |
|---|
| 212 | zbu = MIN( zbu, - z1_slpmax * ABS( zau ) , - 2._wp * e1u(ji,jj) / e3u_n(ji,jj,jk)* ABS( zau ) ) |
|---|
| 213 | IF (ln_zps .AND. jk==mbkv(ji,jj)) & |
|---|
| 214 | zbv = MIN( zbv, - z1_slpmax * ABS( zav ) , - 2._wp * e2v(ji,jj) / e3v_n(ji,jj,jk)* ABS( zav ) ) |
|---|
| 215 | ! ! uslp and vslp output in zwz and zww, resp. |
|---|
| 216 | zfi = MAX( omlmask(ji,jj,jk), omlmask(ji+1,jj,jk) ) |
|---|
| 217 | zfj = MAX( omlmask(ji,jj,jk), omlmask(ji,jj+1,jk) ) |
|---|
| 218 | ! thickness of water column between surface and level k at u/v point |
|---|
| 219 | zdepu = 0.5_wp * ( ( gdept_n (ji,jj,jk) + gdept_n (ji+1,jj,jk) ) & |
|---|
| 220 | - 2 * MAX( risfdep(ji,jj), risfdep(ji+1,jj) ) - e3u_n(ji,jj,miku(ji,jj)) ) |
|---|
| 221 | zdepv = 0.5_wp * ( ( gdept_n (ji,jj,jk) + gdept_n (ji,jj+1,jk) ) & |
|---|
| 222 | - 2 * MAX( risfdep(ji,jj), risfdep(ji,jj+1) ) - e3v_n(ji,jj,mikv(ji,jj)) ) |
|---|
| 223 | ! |
|---|
| 224 | zwz(ji,jj,jk) = ( ( 1._wp - zfi) * zau / ( zbu - zeps ) & |
|---|
| 225 | & + zfi * zdepu * zslpml_hmlpu(ji,jj) ) * umask(ji,jj,jk) |
|---|
| 226 | zww(ji,jj,jk) = ( ( 1._wp - zfj) * zav / ( zbv - zeps ) & |
|---|
| 227 | & + zfj * zdepv * zslpml_hmlpv(ji,jj) ) * vmask(ji,jj,jk) |
|---|
| 228 | !!gm modif to suppress omlmask.... (as in Griffies case) |
|---|
| 229 | ! ! ! jk must be >= ML level for zf=1. otherwise zf=0. |
|---|
| 230 | ! zfi = REAL( 1 - 1/(1 + jk / MAX( nmln(ji+1,jj), nmln(ji,jj) ) ), wp ) |
|---|
| 231 | ! zfj = REAL( 1 - 1/(1 + jk / MAX( nmln(ji,jj+1), nmln(ji,jj) ) ), wp ) |
|---|
| 232 | ! zci = 0.5 * ( gdept_n(ji+1,jj,jk)+gdept_n(ji,jj,jk) ) / MAX( hmlpt(ji,jj), hmlpt(ji+1,jj), 10. ) ) |
|---|
| 233 | ! zcj = 0.5 * ( gdept_n(ji,jj+1,jk)+gdept_n(ji,jj,jk) ) / MAX( hmlpt(ji,jj), hmlpt(ji,jj+1), 10. ) ) |
|---|
| 234 | ! zwz(ji,jj,jk) = ( zfi * zai / ( zbi - zeps ) + ( 1._wp - zfi ) * wslpiml(ji,jj) * zci ) * tmask(ji,jj,jk) |
|---|
| 235 | ! zww(ji,jj,jk) = ( zfj * zaj / ( zbj - zeps ) + ( 1._wp - zfj ) * wslpjml(ji,jj) * zcj ) * tmask(ji,jj,jk) |
|---|
| 236 | !!gm end modif |
|---|
| 237 | END DO |
|---|
| 238 | END DO |
|---|
| 239 | END DO |
|---|
| 240 | CALL lbc_lnk_multi( 'ldfslp', zwz, 'U', -1., zww, 'V', -1. ) ! lateral boundary conditions |
|---|
| 241 | ! |
|---|
| 242 | ! !* horizontal Shapiro filter |
|---|
| 243 | DO jk = 2, jpkm1 |
|---|
| 244 | DO jj = 2, jpjm1, MAX(1, jpj-3) ! rows jj=2 and =jpjm1 only |
|---|
| 245 | DO ji = 2, jpim1 |
|---|
| 246 | uslp(ji,jj,jk) = z1_16 * ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 247 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 248 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 249 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 250 | & + 4.* zwz(ji ,jj ,jk) ) |
|---|
| 251 | vslp(ji,jj,jk) = z1_16 * ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 252 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 253 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 254 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 255 | & + 4.* zww(ji,jj ,jk) ) |
|---|
| 256 | END DO |
|---|
| 257 | END DO |
|---|
| 258 | DO jj = 3, jpj-2 ! other rows |
|---|
| 259 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 260 | uslp(ji,jj,jk) = z1_16 * ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 261 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 262 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 263 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 264 | & + 4.* zwz(ji ,jj ,jk) ) |
|---|
| 265 | vslp(ji,jj,jk) = z1_16 * ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 266 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 267 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 268 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 269 | & + 4.* zww(ji,jj ,jk) ) |
|---|
| 270 | END DO |
|---|
| 271 | END DO |
|---|
| 272 | ! !* decrease along coastal boundaries |
|---|
| 273 | DO jj = 2, jpjm1 |
|---|
| 274 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 275 | uslp(ji,jj,jk) = uslp(ji,jj,jk) * ( umask(ji,jj+1,jk) + umask(ji,jj-1,jk ) ) * 0.5_wp & |
|---|
| 276 | & * ( umask(ji,jj ,jk) + umask(ji,jj ,jk+1) ) * 0.5_wp |
|---|
| 277 | vslp(ji,jj,jk) = vslp(ji,jj,jk) * ( vmask(ji+1,jj,jk) + vmask(ji-1,jj,jk ) ) * 0.5_wp & |
|---|
| 278 | & * ( vmask(ji ,jj,jk) + vmask(ji ,jj,jk+1) ) * 0.5_wp |
|---|
| 279 | END DO |
|---|
| 280 | END DO |
|---|
| 281 | END DO |
|---|
| 282 | |
|---|
| 283 | |
|---|
| 284 | ! II. slopes at w point | wslpi = mij( d/di( prd ) / d/dz( prd ) |
|---|
| 285 | ! =========================== | wslpj = mij( d/dj( prd ) / d/dz( prd ) |
|---|
| 286 | ! |
|---|
| 287 | DO jk = 2, jpkm1 |
|---|
| 288 | DO jj = 2, jpjm1 |
|---|
| 289 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 290 | ! !* Local vertical density gradient evaluated from N^2 |
|---|
| 291 | zbw = zm1_2g * pn2 (ji,jj,jk) * ( prd (ji,jj,jk) + prd (ji,jj,jk-1) + 2. ) |
|---|
| 292 | ! !* Slopes at w point |
|---|
| 293 | ! ! i- & j-gradient of density at w-points |
|---|
| 294 | zci = MAX( umask(ji-1,jj,jk ) + umask(ji,jj,jk ) & |
|---|
| 295 | & + umask(ji-1,jj,jk-1) + umask(ji,jj,jk-1) , zeps ) * e1t(ji,jj) |
|---|
| 296 | zcj = MAX( vmask(ji,jj-1,jk ) + vmask(ji,jj,jk-1) & |
|---|
| 297 | & + vmask(ji,jj-1,jk-1) + vmask(ji,jj,jk ) , zeps ) * e2t(ji,jj) |
|---|
| 298 | zai = ( zgru (ji-1,jj,jk ) + zgru (ji,jj,jk-1) & |
|---|
| 299 | & + zgru (ji-1,jj,jk-1) + zgru (ji,jj,jk ) ) / zci * wmask (ji,jj,jk) |
|---|
| 300 | zaj = ( zgrv (ji,jj-1,jk ) + zgrv (ji,jj,jk-1) & |
|---|
| 301 | & + zgrv (ji,jj-1,jk-1) + zgrv (ji,jj,jk ) ) / zcj * wmask (ji,jj,jk) |
|---|
| 302 | ! ! bound the slopes: abs(zw.)<= 1/100 and zb..<0. |
|---|
| 303 | ! ! + kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 304 | zbi = MIN( zbw ,- 100._wp* ABS( zai ) , -7.e+3_wp/e3w_n(ji,jj,jk)* ABS( zai ) ) |
|---|
| 305 | zbj = MIN( zbw , -100._wp* ABS( zaj ) , -7.e+3_wp/e3w_n(ji,jj,jk)* ABS( zaj ) ) |
|---|
| 306 | ! ! wslpi and wslpj with ML flattening (output in zwz and zww, resp.) |
|---|
| 307 | zfk = MAX( omlmask(ji,jj,jk), omlmask(ji,jj,jk-1) ) ! zfk=1 in the ML otherwise zfk=0 |
|---|
| 308 | zck = ( gdepw_n(ji,jj,jk) - gdepw_n(ji,jj,mikt(ji,jj) ) ) / MAX( hmlp(ji,jj) - gdepw_n(ji,jj,mikt(ji,jj)), 10._wp ) |
|---|
| 309 | zwz(ji,jj,jk) = ( zai / ( zbi - zeps ) * ( 1._wp - zfk ) + zck * wslpiml(ji,jj) * zfk ) * wmask(ji,jj,jk) |
|---|
| 310 | zww(ji,jj,jk) = ( zaj / ( zbj - zeps ) * ( 1._wp - zfk ) + zck * wslpjml(ji,jj) * zfk ) * wmask(ji,jj,jk) |
|---|
| 311 | |
|---|
| 312 | !!gm modif to suppress omlmask.... (as in Griffies operator) |
|---|
| 313 | ! ! ! jk must be >= ML level for zfk=1. otherwise zfk=0. |
|---|
| 314 | ! zfk = REAL( 1 - 1/(1 + jk / nmln(ji+1,jj)), wp ) |
|---|
| 315 | ! zck = gdepw(ji,jj,jk) / MAX( hmlp(ji,jj), 10. ) |
|---|
| 316 | ! zwz(ji,jj,jk) = ( zfk * zai / ( zbi - zeps ) + ( 1._wp - zfk ) * wslpiml(ji,jj) * zck ) * tmask(ji,jj,jk) |
|---|
| 317 | ! zww(ji,jj,jk) = ( zfk * zaj / ( zbj - zeps ) + ( 1._wp - zfk ) * wslpjml(ji,jj) * zck ) * tmask(ji,jj,jk) |
|---|
| 318 | !!gm end modif |
|---|
| 319 | END DO |
|---|
| 320 | END DO |
|---|
| 321 | END DO |
|---|
| 322 | CALL lbc_lnk_multi( 'ldfslp', zwz, 'T', -1., zww, 'T', -1. ) ! lateral boundary conditions |
|---|
| 323 | ! |
|---|
| 324 | ! !* horizontal Shapiro filter |
|---|
| 325 | DO jk = 2, jpkm1 |
|---|
| 326 | DO jj = 2, jpjm1, MAX(1, jpj-3) ! rows jj=2 and =jpjm1 only |
|---|
| 327 | DO ji = 2, jpim1 |
|---|
| 328 | zcofw = wmask(ji,jj,jk) * z1_16 |
|---|
| 329 | wslpi(ji,jj,jk) = ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 330 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 331 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 332 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 333 | & + 4.* zwz(ji ,jj ,jk) ) * zcofw |
|---|
| 334 | |
|---|
| 335 | wslpj(ji,jj,jk) = ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 336 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 337 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 338 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 339 | & + 4.* zww(ji ,jj ,jk) ) * zcofw |
|---|
| 340 | END DO |
|---|
| 341 | END DO |
|---|
| 342 | DO jj = 3, jpj-2 ! other rows |
|---|
| 343 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 344 | zcofw = wmask(ji,jj,jk) * z1_16 |
|---|
| 345 | wslpi(ji,jj,jk) = ( zwz(ji-1,jj-1,jk) + zwz(ji+1,jj-1,jk) & |
|---|
| 346 | & + zwz(ji-1,jj+1,jk) + zwz(ji+1,jj+1,jk) & |
|---|
| 347 | & + 2.*( zwz(ji ,jj-1,jk) + zwz(ji-1,jj ,jk) & |
|---|
| 348 | & + zwz(ji+1,jj ,jk) + zwz(ji ,jj+1,jk) ) & |
|---|
| 349 | & + 4.* zwz(ji ,jj ,jk) ) * zcofw |
|---|
| 350 | |
|---|
| 351 | wslpj(ji,jj,jk) = ( zww(ji-1,jj-1,jk) + zww(ji+1,jj-1,jk) & |
|---|
| 352 | & + zww(ji-1,jj+1,jk) + zww(ji+1,jj+1,jk) & |
|---|
| 353 | & + 2.*( zww(ji ,jj-1,jk) + zww(ji-1,jj ,jk) & |
|---|
| 354 | & + zww(ji+1,jj ,jk) + zww(ji ,jj+1,jk) ) & |
|---|
| 355 | & + 4.* zww(ji ,jj ,jk) ) * zcofw |
|---|
| 356 | END DO |
|---|
| 357 | END DO |
|---|
| 358 | ! !* decrease in vicinity of topography |
|---|
| 359 | DO jj = 2, jpjm1 |
|---|
| 360 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 361 | zck = ( umask(ji,jj,jk) + umask(ji-1,jj,jk) ) & |
|---|
| 362 | & * ( vmask(ji,jj,jk) + vmask(ji,jj-1,jk) ) * 0.25 |
|---|
| 363 | wslpi(ji,jj,jk) = wslpi(ji,jj,jk) * zck |
|---|
| 364 | wslpj(ji,jj,jk) = wslpj(ji,jj,jk) * zck |
|---|
| 365 | END DO |
|---|
| 366 | END DO |
|---|
| 367 | END DO |
|---|
| 368 | |
|---|
| 369 | ! IV. Lateral boundary conditions |
|---|
| 370 | ! =============================== |
|---|
| 371 | CALL lbc_lnk_multi( 'ldfslp', uslp , 'U', -1. , vslp , 'V', -1. , wslpi, 'W', -1., wslpj, 'W', -1. ) |
|---|
| 372 | |
|---|
| 373 | IF(ln_ctl) THEN |
|---|
| 374 | CALL prt_ctl(tab3d_1=uslp , clinfo1=' slp - u : ', tab3d_2=vslp, clinfo2=' v : ', kdim=jpk) |
|---|
| 375 | CALL prt_ctl(tab3d_1=wslpi, clinfo1=' slp - wi: ', tab3d_2=wslpj, clinfo2=' wj: ', kdim=jpk) |
|---|
| 376 | ENDIF |
|---|
| 377 | ! |
|---|
| 378 | IF( ln_timing ) CALL timing_stop('ldf_slp') |
|---|
| 379 | ! |
|---|
| 380 | END SUBROUTINE ldf_slp |
|---|
| 381 | |
|---|
| 382 | |
|---|
| 383 | SUBROUTINE ldf_slp_triad ( kt ) |
|---|
| 384 | !!---------------------------------------------------------------------- |
|---|
| 385 | !! *** ROUTINE ldf_slp_triad *** |
|---|
| 386 | !! |
|---|
| 387 | !! ** Purpose : Compute the squared slopes of neutral surfaces (slope |
|---|
| 388 | !! of iso-pycnal surfaces referenced locally) (ln_traldf_triad=T) |
|---|
| 389 | !! at W-points using the Griffies quarter-cells. |
|---|
| 390 | !! |
|---|
| 391 | !! ** Method : calculates alpha and beta at T-points |
|---|
| 392 | !! |
|---|
| 393 | !! ** Action : - triadi_g, triadj_g T-pts i- and j-slope triads relative to geopot. (used for eiv) |
|---|
| 394 | !! - triadi , triadj T-pts i- and j-slope triads relative to model-coordinate |
|---|
| 395 | !! - wslp2 squared slope of neutral surfaces at w-points. |
|---|
| 396 | !!---------------------------------------------------------------------- |
|---|
| 397 | INTEGER, INTENT( in ) :: kt ! ocean time-step index |
|---|
| 398 | !! |
|---|
| 399 | INTEGER :: ji, jj, jk, jl, ip, jp, kp ! dummy loop indices |
|---|
| 400 | INTEGER :: iku, ikv ! local integer |
|---|
| 401 | REAL(wp) :: zfacti, zfactj ! local scalars |
|---|
| 402 | REAL(wp) :: znot_thru_surface ! local scalars |
|---|
| 403 | REAL(wp) :: zdit, zdis, zdkt, zbu, zbti, zisw |
|---|
| 404 | REAL(wp) :: zdjt, zdjs, zdks, zbv, zbtj, zjsw |
|---|
| 405 | REAL(wp) :: zdxrho_raw, zti_coord, zti_raw, zti_lim, zti_g_raw, zti_g_lim |
|---|
| 406 | REAL(wp) :: zdyrho_raw, ztj_coord, ztj_raw, ztj_lim, ztj_g_raw, ztj_g_lim |
|---|
| 407 | REAL(wp) :: zdzrho_raw |
|---|
| 408 | REAL(wp) :: zbeta0, ze3_e1, ze3_e2 |
|---|
| 409 | REAL(wp), DIMENSION(jpi,jpj) :: z1_mlbw |
|---|
| 410 | REAL(wp), DIMENSION(jpi,jpj,jpk,0:1) :: zdxrho , zdyrho, zdzrho ! Horizontal and vertical density gradients |
|---|
| 411 | REAL(wp), DIMENSION(jpi,jpj,0:1,0:1) :: zti_mlb, ztj_mlb ! for Griffies operator only |
|---|
| 412 | !!---------------------------------------------------------------------- |
|---|
| 413 | ! |
|---|
| 414 | IF( ln_timing ) CALL timing_start('ldf_slp_triad') |
|---|
| 415 | ! |
|---|
| 416 | !--------------------------------! |
|---|
| 417 | ! Some preliminary calculation ! |
|---|
| 418 | !--------------------------------! |
|---|
| 419 | ! |
|---|
| 420 | DO jl = 0, 1 !== unmasked before density i- j-, k-gradients ==! |
|---|
| 421 | ! |
|---|
| 422 | ip = jl ; jp = jl ! guaranteed nonzero gradients ( absolute value larger than repsln) |
|---|
| 423 | DO jk = 1, jpkm1 ! done each pair of triad |
|---|
| 424 | DO jj = 1, jpjm1 ! NB: not masked ==> a minimum value is set |
|---|
| 425 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 426 | zdit = ( tsb(ji+1,jj,jk,jp_tem) - tsb(ji,jj,jk,jp_tem) ) ! i-gradient of T & S at u-point |
|---|
| 427 | zdis = ( tsb(ji+1,jj,jk,jp_sal) - tsb(ji,jj,jk,jp_sal) ) |
|---|
| 428 | zdjt = ( tsb(ji,jj+1,jk,jp_tem) - tsb(ji,jj,jk,jp_tem) ) ! j-gradient of T & S at v-point |
|---|
| 429 | zdjs = ( tsb(ji,jj+1,jk,jp_sal) - tsb(ji,jj,jk,jp_sal) ) |
|---|
| 430 | zdxrho_raw = ( - rab_b(ji+ip,jj ,jk,jp_tem) * zdit + rab_b(ji+ip,jj ,jk,jp_sal) * zdis ) * r1_e1u(ji,jj) |
|---|
| 431 | zdyrho_raw = ( - rab_b(ji ,jj+jp,jk,jp_tem) * zdjt + rab_b(ji ,jj+jp,jk,jp_sal) * zdjs ) * r1_e2v(ji,jj) |
|---|
| 432 | zdxrho(ji+ip,jj ,jk,1-ip) = SIGN( MAX( repsln, ABS( zdxrho_raw ) ), zdxrho_raw ) ! keep the sign |
|---|
| 433 | zdyrho(ji ,jj+jp,jk,1-jp) = SIGN( MAX( repsln, ABS( zdyrho_raw ) ), zdyrho_raw ) |
|---|
| 434 | END DO |
|---|
| 435 | END DO |
|---|
| 436 | END DO |
|---|
| 437 | ! |
|---|
| 438 | IF( ln_zps .AND. l_grad_zps ) THEN ! partial steps: correction of i- & j-grad on bottom |
|---|
| 439 | DO jj = 1, jpjm1 |
|---|
| 440 | DO ji = 1, jpim1 |
|---|
| 441 | iku = mbku(ji,jj) ; ikv = mbkv(ji,jj) ! last ocean level (u- & v-points) |
|---|
| 442 | zdit = gtsu(ji,jj,jp_tem) ; zdjt = gtsv(ji,jj,jp_tem) ! i- & j-gradient of Temperature |
|---|
| 443 | zdis = gtsu(ji,jj,jp_sal) ; zdjs = gtsv(ji,jj,jp_sal) ! i- & j-gradient of Salinity |
|---|
| 444 | zdxrho_raw = ( - rab_b(ji+ip,jj ,iku,jp_tem) * zdit + rab_b(ji+ip,jj ,iku,jp_sal) * zdis ) * r1_e1u(ji,jj) |
|---|
| 445 | zdyrho_raw = ( - rab_b(ji ,jj+jp,ikv,jp_tem) * zdjt + rab_b(ji ,jj+jp,ikv,jp_sal) * zdjs ) * r1_e2v(ji,jj) |
|---|
| 446 | zdxrho(ji+ip,jj ,iku,1-ip) = SIGN( MAX( repsln, ABS( zdxrho_raw ) ), zdxrho_raw ) ! keep the sign |
|---|
| 447 | zdyrho(ji ,jj+jp,ikv,1-jp) = SIGN( MAX( repsln, ABS( zdyrho_raw ) ), zdyrho_raw ) |
|---|
| 448 | END DO |
|---|
| 449 | END DO |
|---|
| 450 | ENDIF |
|---|
| 451 | ! |
|---|
| 452 | END DO |
|---|
| 453 | |
|---|
| 454 | DO kp = 0, 1 !== unmasked before density i- j-, k-gradients ==! |
|---|
| 455 | DO jk = 1, jpkm1 ! done each pair of triad |
|---|
| 456 | DO jj = 1, jpj ! NB: not masked ==> a minimum value is set |
|---|
| 457 | DO ji = 1, jpi ! vector opt. |
|---|
| 458 | IF( jk+kp > 1 ) THEN ! k-gradient of T & S a jk+kp |
|---|
| 459 | zdkt = ( tsb(ji,jj,jk+kp-1,jp_tem) - tsb(ji,jj,jk+kp,jp_tem) ) |
|---|
| 460 | zdks = ( tsb(ji,jj,jk+kp-1,jp_sal) - tsb(ji,jj,jk+kp,jp_sal) ) |
|---|
| 461 | ELSE |
|---|
| 462 | zdkt = 0._wp ! 1st level gradient set to zero |
|---|
| 463 | zdks = 0._wp |
|---|
| 464 | ENDIF |
|---|
| 465 | zdzrho_raw = ( - rab_b(ji,jj,jk ,jp_tem) * zdkt & |
|---|
| 466 | & + rab_b(ji,jj,jk ,jp_sal) * zdks & |
|---|
| 467 | & ) / e3w_n(ji,jj,jk+kp) |
|---|
| 468 | zdzrho(ji,jj,jk,kp) = - MIN( - repsln , zdzrho_raw ) ! force zdzrho >= repsln |
|---|
| 469 | END DO |
|---|
| 470 | END DO |
|---|
| 471 | END DO |
|---|
| 472 | END DO |
|---|
| 473 | ! |
|---|
| 474 | DO jj = 1, jpj !== Reciprocal depth of the w-point below ML base ==! |
|---|
| 475 | DO ji = 1, jpi |
|---|
| 476 | jk = MIN( nmln(ji,jj), mbkt(ji,jj) ) + 1 ! MIN in case ML depth is the ocean depth |
|---|
| 477 | z1_mlbw(ji,jj) = 1._wp / gdepw_n(ji,jj,jk) |
|---|
| 478 | END DO |
|---|
| 479 | END DO |
|---|
| 480 | ! |
|---|
| 481 | ! !== intialisations to zero ==! |
|---|
| 482 | ! |
|---|
| 483 | wslp2 (:,:,:) = 0._wp ! wslp2 will be cumulated 3D field set to zero |
|---|
| 484 | triadi_g(:,:,1,:,:) = 0._wp ; triadi_g(:,:,jpk,:,:) = 0._wp ! set surface and bottom slope to zero |
|---|
| 485 | triadj_g(:,:,1,:,:) = 0._wp ; triadj_g(:,:,jpk,:,:) = 0._wp |
|---|
| 486 | !!gm _iso set to zero missing |
|---|
| 487 | triadi (:,:,1,:,:) = 0._wp ; triadj (:,:,jpk,:,:) = 0._wp ! set surface and bottom slope to zero |
|---|
| 488 | triadj (:,:,1,:,:) = 0._wp ; triadj (:,:,jpk,:,:) = 0._wp |
|---|
| 489 | |
|---|
| 490 | !-------------------------------------! |
|---|
| 491 | ! Triads just below the Mixed Layer ! |
|---|
| 492 | !-------------------------------------! |
|---|
| 493 | ! |
|---|
| 494 | DO jl = 0, 1 ! calculate slope of the 4 triads immediately ONE level below mixed-layer base |
|---|
| 495 | DO kp = 0, 1 ! with only the slope-max limit and MASKED |
|---|
| 496 | DO jj = 1, jpjm1 |
|---|
| 497 | DO ji = 1, fs_jpim1 |
|---|
| 498 | ip = jl ; jp = jl |
|---|
| 499 | ! |
|---|
| 500 | jk = nmln(ji+ip,jj) + 1 |
|---|
| 501 | IF( jk > mbkt(ji+ip,jj) ) THEN ! ML reaches bottom |
|---|
| 502 | zti_mlb(ji+ip,jj ,1-ip,kp) = 0.0_wp |
|---|
| 503 | ELSE |
|---|
| 504 | ! Add s-coordinate slope at t-points (do this by *subtracting* gradient of depth) |
|---|
| 505 | zti_g_raw = ( zdxrho(ji+ip,jj,jk-kp,1-ip) / zdzrho(ji+ip,jj,jk-kp,kp) & |
|---|
| 506 | & - ( gdept_n(ji+1,jj,jk-kp) - gdept_n(ji,jj,jk-kp) ) * r1_e1u(ji,jj) ) * umask(ji,jj,jk) |
|---|
| 507 | ze3_e1 = e3w_n(ji+ip,jj,jk-kp) * r1_e1u(ji,jj) |
|---|
| 508 | zti_mlb(ji+ip,jj ,1-ip,kp) = SIGN( MIN( rn_slpmax, 5.0_wp * ze3_e1 , ABS( zti_g_raw ) ), zti_g_raw ) |
|---|
| 509 | ENDIF |
|---|
| 510 | ! |
|---|
| 511 | jk = nmln(ji,jj+jp) + 1 |
|---|
| 512 | IF( jk > mbkt(ji,jj+jp) ) THEN !ML reaches bottom |
|---|
| 513 | ztj_mlb(ji ,jj+jp,1-jp,kp) = 0.0_wp |
|---|
| 514 | ELSE |
|---|
| 515 | ztj_g_raw = ( zdyrho(ji,jj+jp,jk-kp,1-jp) / zdzrho(ji,jj+jp,jk-kp,kp) & |
|---|
| 516 | & - ( gdept_n(ji,jj+1,jk-kp) - gdept_n(ji,jj,jk-kp) ) / e2v(ji,jj) ) * vmask(ji,jj,jk) |
|---|
| 517 | ze3_e2 = e3w_n(ji,jj+jp,jk-kp) / e2v(ji,jj) |
|---|
| 518 | ztj_mlb(ji ,jj+jp,1-jp,kp) = SIGN( MIN( rn_slpmax, 5.0_wp * ze3_e2 , ABS( ztj_g_raw ) ), ztj_g_raw ) |
|---|
| 519 | ENDIF |
|---|
| 520 | END DO |
|---|
| 521 | END DO |
|---|
| 522 | END DO |
|---|
| 523 | END DO |
|---|
| 524 | |
|---|
| 525 | !-------------------------------------! |
|---|
| 526 | ! Triads with surface limits ! |
|---|
| 527 | !-------------------------------------! |
|---|
| 528 | ! |
|---|
| 529 | DO kp = 0, 1 ! k-index of triads |
|---|
| 530 | DO jl = 0, 1 |
|---|
| 531 | ip = jl ; jp = jl ! i- and j-indices of triads (i-k and j-k planes) |
|---|
| 532 | DO jk = 1, jpkm1 |
|---|
| 533 | ! Must mask contribution to slope from dz/dx at constant s for triads jk=1,kp=0 that poke up though ocean surface |
|---|
| 534 | znot_thru_surface = REAL( 1-1/(jk+kp), wp ) !jk+kp=1,=0.; otherwise=1.0 |
|---|
| 535 | DO jj = 1, jpjm1 |
|---|
| 536 | DO ji = 1, fs_jpim1 ! vector opt. |
|---|
| 537 | ! |
|---|
| 538 | ! Calculate slope relative to geopotentials used for GM skew fluxes |
|---|
| 539 | ! Add s-coordinate slope at t-points (do this by *subtracting* gradient of depth) |
|---|
| 540 | ! Limit by slope *relative to geopotentials* by rn_slpmax, and mask by psi-point |
|---|
| 541 | ! masked by umask taken at the level of dz(rho) |
|---|
| 542 | ! |
|---|
| 543 | ! raw slopes: unmasked unbounded slopes (relative to geopotential (zti_g) and model surface (zti) |
|---|
| 544 | ! |
|---|
| 545 | zti_raw = zdxrho(ji+ip,jj ,jk,1-ip) / zdzrho(ji+ip,jj ,jk,kp) ! unmasked |
|---|
| 546 | ztj_raw = zdyrho(ji ,jj+jp,jk,1-jp) / zdzrho(ji ,jj+jp,jk,kp) |
|---|
| 547 | ! |
|---|
| 548 | ! Must mask contribution to slope for triad jk=1,kp=0 that poke up though ocean surface |
|---|
| 549 | zti_coord = znot_thru_surface * ( gdept_n(ji+1,jj ,jk) - gdept_n(ji,jj,jk) ) * r1_e1u(ji,jj) |
|---|
| 550 | ztj_coord = znot_thru_surface * ( gdept_n(ji ,jj+1,jk) - gdept_n(ji,jj,jk) ) * r1_e2v(ji,jj) ! unmasked |
|---|
| 551 | zti_g_raw = zti_raw - zti_coord ! ref to geopot surfaces |
|---|
| 552 | ztj_g_raw = ztj_raw - ztj_coord |
|---|
| 553 | ! additional limit required in bilaplacian case |
|---|
| 554 | ze3_e1 = e3w_n(ji+ip,jj ,jk+kp) * r1_e1u(ji,jj) |
|---|
| 555 | ze3_e2 = e3w_n(ji ,jj+jp,jk+kp) * r1_e2v(ji,jj) |
|---|
| 556 | ! NB: hard coded factor 5 (can be a namelist parameter...) |
|---|
| 557 | zti_g_lim = SIGN( MIN( rn_slpmax, 5.0_wp * ze3_e1, ABS( zti_g_raw ) ), zti_g_raw ) |
|---|
| 558 | ztj_g_lim = SIGN( MIN( rn_slpmax, 5.0_wp * ze3_e2, ABS( ztj_g_raw ) ), ztj_g_raw ) |
|---|
| 559 | ! |
|---|
| 560 | ! Below ML use limited zti_g as is & mask |
|---|
| 561 | ! Inside ML replace by linearly reducing sx_mlb towards surface & mask |
|---|
| 562 | ! |
|---|
| 563 | zfacti = REAL( 1 - 1/(1 + (jk+kp-1)/nmln(ji+ip,jj)), wp ) ! k index of uppermost point(s) of triad is jk+kp-1 |
|---|
| 564 | zfactj = REAL( 1 - 1/(1 + (jk+kp-1)/nmln(ji,jj+jp)), wp ) ! must be .ge. nmln(ji,jj) for zfact=1 |
|---|
| 565 | ! ! otherwise zfact=0 |
|---|
| 566 | zti_g_lim = ( zfacti * zti_g_lim & |
|---|
| 567 | & + ( 1._wp - zfacti ) * zti_mlb(ji+ip,jj,1-ip,kp) & |
|---|
| 568 | & * gdepw_n(ji+ip,jj,jk+kp) * z1_mlbw(ji+ip,jj) ) * umask(ji,jj,jk+kp) |
|---|
| 569 | ztj_g_lim = ( zfactj * ztj_g_lim & |
|---|
| 570 | & + ( 1._wp - zfactj ) * ztj_mlb(ji,jj+jp,1-jp,kp) & |
|---|
| 571 | & * gdepw_n(ji,jj+jp,jk+kp) * z1_mlbw(ji,jj+jp) ) * vmask(ji,jj,jk+kp) |
|---|
| 572 | ! |
|---|
| 573 | triadi_g(ji+ip,jj ,jk,1-ip,kp) = zti_g_lim |
|---|
| 574 | triadj_g(ji ,jj+jp,jk,1-jp,kp) = ztj_g_lim |
|---|
| 575 | ! |
|---|
| 576 | ! Get coefficients of isoneutral diffusion tensor |
|---|
| 577 | ! 1. Utilise gradients *relative* to s-coordinate, so add t-point slopes (*subtract* depth gradients) |
|---|
| 578 | ! 2. We require that isoneutral diffusion gives no vertical buoyancy flux |
|---|
| 579 | ! i.e. 33 term = (real slope* 31, 13 terms) |
|---|
| 580 | ! To do this, retain limited sx**2 in vertical flux, but divide by real slope for 13/31 terms |
|---|
| 581 | ! Equivalent to tapering A_iso = sx_limited**2/(real slope)**2 |
|---|
| 582 | ! |
|---|
| 583 | zti_lim = ( zti_g_lim + zti_coord ) * umask(ji,jj,jk+kp) ! remove coordinate slope => relative to coordinate surfaces |
|---|
| 584 | ztj_lim = ( ztj_g_lim + ztj_coord ) * vmask(ji,jj,jk+kp) |
|---|
| 585 | ! |
|---|
| 586 | IF( ln_triad_iso ) THEN |
|---|
| 587 | zti_raw = zti_lim*zti_lim / zti_raw |
|---|
| 588 | ztj_raw = ztj_lim*ztj_lim / ztj_raw |
|---|
| 589 | zti_raw = SIGN( MIN( ABS(zti_lim), ABS( zti_raw ) ), zti_raw ) |
|---|
| 590 | ztj_raw = SIGN( MIN( ABS(ztj_lim), ABS( ztj_raw ) ), ztj_raw ) |
|---|
| 591 | zti_lim = zfacti * zti_lim + ( 1._wp - zfacti ) * zti_raw |
|---|
| 592 | ztj_lim = zfactj * ztj_lim + ( 1._wp - zfactj ) * ztj_raw |
|---|
| 593 | ENDIF |
|---|
| 594 | ! ! switching triad scheme |
|---|
| 595 | zisw = (1._wp - rn_sw_triad ) + rn_sw_triad & |
|---|
| 596 | & * 2._wp * ABS( 0.5_wp - kp - ( 0.5_wp - ip ) * SIGN( 1._wp , zdxrho(ji+ip,jj,jk,1-ip) ) ) |
|---|
| 597 | zjsw = (1._wp - rn_sw_triad ) + rn_sw_triad & |
|---|
| 598 | & * 2._wp * ABS( 0.5_wp - kp - ( 0.5_wp - jp ) * SIGN( 1._wp , zdyrho(ji,jj+jp,jk,1-jp) ) ) |
|---|
| 599 | ! |
|---|
| 600 | triadi(ji+ip,jj ,jk,1-ip,kp) = zti_lim * zisw |
|---|
| 601 | triadj(ji ,jj+jp,jk,1-jp,kp) = ztj_lim * zjsw |
|---|
| 602 | ! |
|---|
| 603 | zbu = e1e2u(ji ,jj ) * e3u_n(ji ,jj ,jk ) |
|---|
| 604 | zbv = e1e2v(ji ,jj ) * e3v_n(ji ,jj ,jk ) |
|---|
| 605 | zbti = e1e2t(ji+ip,jj ) * e3w_n(ji+ip,jj ,jk+kp) |
|---|
| 606 | zbtj = e1e2t(ji ,jj+jp) * e3w_n(ji ,jj+jp,jk+kp) |
|---|
| 607 | ! |
|---|
| 608 | wslp2(ji+ip,jj,jk+kp) = wslp2(ji+ip,jj,jk+kp) + 0.25_wp * zbu / zbti * zti_g_lim*zti_g_lim ! masked |
|---|
| 609 | wslp2(ji,jj+jp,jk+kp) = wslp2(ji,jj+jp,jk+kp) + 0.25_wp * zbv / zbtj * ztj_g_lim*ztj_g_lim |
|---|
| 610 | END DO |
|---|
| 611 | END DO |
|---|
| 612 | END DO |
|---|
| 613 | END DO |
|---|
| 614 | END DO |
|---|
| 615 | ! |
|---|
| 616 | wslp2(:,:,1) = 0._wp ! force the surface wslp to zero |
|---|
| 617 | |
|---|
| 618 | CALL lbc_lnk( 'ldfslp', wslp2, 'W', 1. ) ! lateral boundary confition on wslp2 only ==>>> gm : necessary ? to be checked |
|---|
| 619 | ! |
|---|
| 620 | IF( ln_timing ) CALL timing_stop('ldf_slp_triad') |
|---|
| 621 | ! |
|---|
| 622 | END SUBROUTINE ldf_slp_triad |
|---|
| 623 | |
|---|
| 624 | |
|---|
| 625 | SUBROUTINE ldf_slp_mxl( prd, pn2, p_gru, p_grv, p_dzr ) |
|---|
| 626 | !!---------------------------------------------------------------------- |
|---|
| 627 | !! *** ROUTINE ldf_slp_mxl *** |
|---|
| 628 | !! |
|---|
| 629 | !! ** Purpose : Compute the slopes of iso-neutral surface just below |
|---|
| 630 | !! the mixed layer. |
|---|
| 631 | !! |
|---|
| 632 | !! ** Method : The slope in the i-direction is computed at u- & w-points |
|---|
| 633 | !! (uslpml, wslpiml) and the slope in the j-direction is computed |
|---|
| 634 | !! at v- and w-points (vslpml, wslpjml) with the same bounds as |
|---|
| 635 | !! in ldf_slp. |
|---|
| 636 | !! |
|---|
| 637 | !! ** Action : uslpml, wslpiml : i- & j-slopes of neutral surfaces |
|---|
| 638 | !! vslpml, wslpjml just below the mixed layer |
|---|
| 639 | !! omlmask : mixed layer mask |
|---|
| 640 | !!---------------------------------------------------------------------- |
|---|
| 641 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: prd ! in situ density |
|---|
| 642 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: pn2 ! Brunt-Vaisala frequency (locally ref.) |
|---|
| 643 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: p_gru, p_grv ! i- & j-gradient of density (u- & v-pts) |
|---|
| 644 | REAL(wp), DIMENSION(:,:,:), INTENT(in) :: p_dzr ! z-gradient of density (T-point) |
|---|
| 645 | !! |
|---|
| 646 | INTEGER :: ji , jj , jk ! dummy loop indices |
|---|
| 647 | INTEGER :: iku, ikv, ik, ikm1 ! local integers |
|---|
| 648 | REAL(wp) :: zeps, zm1_g, zm1_2g, z1_slpmax ! local scalars |
|---|
| 649 | REAL(wp) :: zci, zfi, zau, zbu, zai, zbi ! - - |
|---|
| 650 | REAL(wp) :: zcj, zfj, zav, zbv, zaj, zbj ! - - |
|---|
| 651 | REAL(wp) :: zck, zfk, zbw ! - - |
|---|
| 652 | !!---------------------------------------------------------------------- |
|---|
| 653 | ! |
|---|
| 654 | zeps = 1.e-20_wp !== Local constant initialization ==! |
|---|
| 655 | zm1_g = -1.0_wp / grav |
|---|
| 656 | zm1_2g = -0.5_wp / grav |
|---|
| 657 | z1_slpmax = 1._wp / rn_slpmax |
|---|
| 658 | ! |
|---|
| 659 | uslpml (1,:) = 0._wp ; uslpml (jpi,:) = 0._wp |
|---|
| 660 | vslpml (1,:) = 0._wp ; vslpml (jpi,:) = 0._wp |
|---|
| 661 | wslpiml(1,:) = 0._wp ; wslpiml(jpi,:) = 0._wp |
|---|
| 662 | wslpjml(1,:) = 0._wp ; wslpjml(jpi,:) = 0._wp |
|---|
| 663 | ! |
|---|
| 664 | ! !== surface mixed layer mask ! |
|---|
| 665 | DO jk = 1, jpk ! =1 inside the mixed layer, =0 otherwise |
|---|
| 666 | DO jj = 1, jpj |
|---|
| 667 | DO ji = 1, jpi |
|---|
| 668 | ik = nmln(ji,jj) - 1 |
|---|
| 669 | IF( jk <= ik ) THEN ; omlmask(ji,jj,jk) = 1._wp |
|---|
| 670 | ELSE ; omlmask(ji,jj,jk) = 0._wp |
|---|
| 671 | ENDIF |
|---|
| 672 | END DO |
|---|
| 673 | END DO |
|---|
| 674 | END DO |
|---|
| 675 | |
|---|
| 676 | |
|---|
| 677 | ! Slopes of isopycnal surfaces just before bottom of mixed layer |
|---|
| 678 | ! -------------------------------------------------------------- |
|---|
| 679 | ! The slope are computed as in the 3D case. |
|---|
| 680 | ! A key point here is the definition of the mixed layer at u- and v-points. |
|---|
| 681 | ! It is assumed to be the maximum of the two neighbouring T-point mixed layer depth. |
|---|
| 682 | ! Otherwise, a n2 value inside the mixed layer can be involved in the computation |
|---|
| 683 | ! of the slope, resulting in a too steep diagnosed slope and thus a spurious eddy |
|---|
| 684 | ! induce velocity field near the base of the mixed layer. |
|---|
| 685 | !----------------------------------------------------------------------- |
|---|
| 686 | ! |
|---|
| 687 | DO jj = 2, jpjm1 |
|---|
| 688 | DO ji = 2, jpim1 |
|---|
| 689 | ! !== Slope at u- & v-points just below the Mixed Layer ==! |
|---|
| 690 | ! |
|---|
| 691 | ! !- vertical density gradient for u- and v-slopes (from dzr at T-point) |
|---|
| 692 | iku = MIN( MAX( 1, nmln(ji,jj) , nmln(ji+1,jj) ) , jpkm1 ) ! ML (MAX of T-pts, bound by jpkm1) |
|---|
| 693 | ikv = MIN( MAX( 1, nmln(ji,jj) , nmln(ji,jj+1) ) , jpkm1 ) ! |
|---|
| 694 | zbu = 0.5_wp * ( p_dzr(ji,jj,iku) + p_dzr(ji+1,jj ,iku) ) |
|---|
| 695 | zbv = 0.5_wp * ( p_dzr(ji,jj,ikv) + p_dzr(ji ,jj+1,ikv) ) |
|---|
| 696 | ! !- horizontal density gradient at u- & v-points |
|---|
| 697 | zau = p_gru(ji,jj,iku) * r1_e1u(ji,jj) |
|---|
| 698 | zav = p_grv(ji,jj,ikv) * r1_e2v(ji,jj) |
|---|
| 699 | ! !- bound the slopes: abs(zw.)<= 1/100 and zb..<0 |
|---|
| 700 | ! kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 701 | zbu = MIN( zbu , - z1_slpmax * ABS( zau ) , -7.e+3_wp/e3u_n(ji,jj,iku)* ABS( zau ) ) |
|---|
| 702 | zbv = MIN( zbv , - z1_slpmax * ABS( zav ) , -7.e+3_wp/e3v_n(ji,jj,ikv)* ABS( zav ) ) |
|---|
| 703 | ! !- Slope at u- & v-points (uslpml, vslpml) |
|---|
| 704 | uslpml(ji,jj) = zau / ( zbu - zeps ) * umask(ji,jj,iku) |
|---|
| 705 | vslpml(ji,jj) = zav / ( zbv - zeps ) * vmask(ji,jj,ikv) |
|---|
| 706 | ! |
|---|
| 707 | ! !== i- & j-slopes at w-points just below the Mixed Layer ==! |
|---|
| 708 | ! |
|---|
| 709 | ik = MIN( nmln(ji,jj) + 1, jpk ) |
|---|
| 710 | ikm1 = MAX( 1, ik-1 ) |
|---|
| 711 | ! !- vertical density gradient for w-slope (from N^2) |
|---|
| 712 | zbw = zm1_2g * pn2 (ji,jj,ik) * ( prd (ji,jj,ik) + prd (ji,jj,ikm1) + 2. ) |
|---|
| 713 | ! !- horizontal density i- & j-gradient at w-points |
|---|
| 714 | zci = MAX( umask(ji-1,jj,ik ) + umask(ji,jj,ik ) & |
|---|
| 715 | & + umask(ji-1,jj,ikm1) + umask(ji,jj,ikm1) , zeps ) * e1t(ji,jj) |
|---|
| 716 | zcj = MAX( vmask(ji,jj-1,ik ) + vmask(ji,jj,ik ) & |
|---|
| 717 | & + vmask(ji,jj-1,ikm1) + vmask(ji,jj,ikm1) , zeps ) * e2t(ji,jj) |
|---|
| 718 | zai = ( p_gru(ji-1,jj,ik ) + p_gru(ji,jj,ik) & |
|---|
| 719 | & + p_gru(ji-1,jj,ikm1) + p_gru(ji,jj,ikm1 ) ) / zci * tmask(ji,jj,ik) |
|---|
| 720 | zaj = ( p_grv(ji,jj-1,ik ) + p_grv(ji,jj,ik ) & |
|---|
| 721 | & + p_grv(ji,jj-1,ikm1) + p_grv(ji,jj,ikm1) ) / zcj * tmask(ji,jj,ik) |
|---|
| 722 | ! !- bound the slopes: abs(zw.)<= 1/100 and zb..<0. |
|---|
| 723 | ! kxz max= ah slope max =< e1 e3 /(pi**2 2 dt) |
|---|
| 724 | zbi = MIN( zbw , -100._wp* ABS( zai ) , -7.e+3_wp/e3w_n(ji,jj,ik)* ABS( zai ) ) |
|---|
| 725 | zbj = MIN( zbw , -100._wp* ABS( zaj ) , -7.e+3_wp/e3w_n(ji,jj,ik)* ABS( zaj ) ) |
|---|
| 726 | ! !- i- & j-slope at w-points (wslpiml, wslpjml) |
|---|
| 727 | wslpiml(ji,jj) = zai / ( zbi - zeps ) * tmask (ji,jj,ik) |
|---|
| 728 | wslpjml(ji,jj) = zaj / ( zbj - zeps ) * tmask (ji,jj,ik) |
|---|
| 729 | END DO |
|---|
| 730 | END DO |
|---|
| 731 | !!gm this lbc_lnk should be useless.... |
|---|
| 732 | CALL lbc_lnk_multi( 'ldfslp', uslpml , 'U', -1. , vslpml , 'V', -1. , wslpiml, 'W', -1. , wslpjml, 'W', -1. ) |
|---|
| 733 | ! |
|---|
| 734 | END SUBROUTINE ldf_slp_mxl |
|---|
| 735 | |
|---|
| 736 | |
|---|
| 737 | SUBROUTINE ldf_slp_init |
|---|
| 738 | !!---------------------------------------------------------------------- |
|---|
| 739 | !! *** ROUTINE ldf_slp_init *** |
|---|
| 740 | !! |
|---|
| 741 | !! ** Purpose : Initialization for the isopycnal slopes computation |
|---|
| 742 | !! |
|---|
| 743 | !! ** Method : |
|---|
| 744 | !!---------------------------------------------------------------------- |
|---|
| 745 | INTEGER :: ji, jj, jk ! dummy loop indices |
|---|
| 746 | INTEGER :: ierr ! local integer |
|---|
| 747 | !!---------------------------------------------------------------------- |
|---|
| 748 | ! |
|---|
| 749 | IF(lwp) THEN |
|---|
| 750 | WRITE(numout,*) |
|---|
| 751 | WRITE(numout,*) 'ldf_slp_init : direction of lateral mixing' |
|---|
| 752 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 753 | ENDIF |
|---|
| 754 | ! |
|---|
| 755 | ALLOCATE( ah_wslp2(jpi,jpj,jpk) , akz(jpi,jpj,jpk) , STAT=ierr ) |
|---|
| 756 | IF( ierr > 0 ) CALL ctl_stop( 'STOP', 'ldf_slp_init : unable to allocate ah_slp2 or akz' ) |
|---|
| 757 | ! |
|---|
| 758 | IF( ln_traldf_triad ) THEN ! Griffies operator : triad of slopes |
|---|
| 759 | IF(lwp) WRITE(numout,*) ' ==>>> triad) operator (Griffies)' |
|---|
| 760 | ALLOCATE( triadi_g(jpi,jpj,jpk,0:1,0:1) , triadj_g(jpi,jpj,jpk,0:1,0:1) , & |
|---|
| 761 | & triadi (jpi,jpj,jpk,0:1,0:1) , triadj (jpi,jpj,jpk,0:1,0:1) , & |
|---|
| 762 | & wslp2 (jpi,jpj,jpk) , STAT=ierr ) |
|---|
| 763 | IF( ierr > 0 ) CALL ctl_stop( 'STOP', 'ldf_slp_init : unable to allocate Griffies operator slope' ) |
|---|
| 764 | IF( ln_dynldf_iso ) CALL ctl_stop( 'ldf_slp_init: Griffies operator on momentum not supported' ) |
|---|
| 765 | ! |
|---|
| 766 | ELSE ! Madec operator : slopes at u-, v-, and w-points |
|---|
| 767 | IF(lwp) WRITE(numout,*) ' ==>>> iso operator (Madec)' |
|---|
| 768 | ALLOCATE( omlmask(jpi,jpj,jpk) , & |
|---|
| 769 | & uslp(jpi,jpj,jpk) , uslpml(jpi,jpj) , wslpi(jpi,jpj,jpk) , wslpiml(jpi,jpj) , & |
|---|
| 770 | & vslp(jpi,jpj,jpk) , vslpml(jpi,jpj) , wslpj(jpi,jpj,jpk) , wslpjml(jpi,jpj) , STAT=ierr ) |
|---|
| 771 | IF( ierr > 0 ) CALL ctl_stop( 'STOP', 'ldf_slp_init : unable to allocate Madec operator slope ' ) |
|---|
| 772 | |
|---|
| 773 | ! Direction of lateral diffusion (tracers and/or momentum) |
|---|
| 774 | ! ------------------------------ |
|---|
| 775 | uslp (:,:,:) = 0._wp ; uslpml (:,:) = 0._wp ! set the slope to zero (even in s-coordinates) |
|---|
| 776 | vslp (:,:,:) = 0._wp ; vslpml (:,:) = 0._wp |
|---|
| 777 | wslpi(:,:,:) = 0._wp ; wslpiml(:,:) = 0._wp |
|---|
| 778 | wslpj(:,:,:) = 0._wp ; wslpjml(:,:) = 0._wp |
|---|
| 779 | |
|---|
| 780 | !!gm I no longer understand this..... |
|---|
| 781 | !!gm IF( (ln_traldf_hor .OR. ln_dynldf_hor) .AND. .NOT. (.NOT.ln_linssh .AND. ln_rstart) ) THEN |
|---|
| 782 | ! IF(lwp) WRITE(numout,*) ' Horizontal mixing in s-coordinate: slope = slope of s-surfaces' |
|---|
| 783 | ! |
|---|
| 784 | ! ! geopotential diffusion in s-coordinates on tracers and/or momentum |
|---|
| 785 | ! ! The slopes of s-surfaces are computed once (no call to ldfslp in step) |
|---|
| 786 | ! ! The slopes for momentum diffusion are i- or j- averaged of those on tracers |
|---|
| 787 | ! |
|---|
| 788 | ! ! set the slope of diffusion to the slope of s-surfaces |
|---|
| 789 | ! ! ( c a u t i o n : minus sign as dep has positive value ) |
|---|
| 790 | ! DO jk = 1, jpk |
|---|
| 791 | ! DO jj = 2, jpjm1 |
|---|
| 792 | ! DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 793 | ! uslp (ji,jj,jk) = - ( gdept_n(ji+1,jj,jk) - gdept_n(ji ,jj ,jk) ) * r1_e1u(ji,jj) * umask(ji,jj,jk) |
|---|
| 794 | ! vslp (ji,jj,jk) = - ( gdept_n(ji,jj+1,jk) - gdept_n(ji ,jj ,jk) ) * r1_e2v(ji,jj) * vmask(ji,jj,jk) |
|---|
| 795 | ! wslpi(ji,jj,jk) = - ( gdepw_n(ji+1,jj,jk) - gdepw_n(ji-1,jj,jk) ) * r1_e1t(ji,jj) * wmask(ji,jj,jk) * 0.5 |
|---|
| 796 | ! wslpj(ji,jj,jk) = - ( gdepw_n(ji,jj+1,jk) - gdepw_n(ji,jj-1,jk) ) * r1_e2t(ji,jj) * wmask(ji,jj,jk) * 0.5 |
|---|
| 797 | ! END DO |
|---|
| 798 | ! END DO |
|---|
| 799 | ! END DO |
|---|
| 800 | ! CALL lbc_lnk_multi( 'ldfslp', uslp , 'U', -1. ; CALL lbc_lnk( 'ldfslp', vslp , 'V', -1., wslpi, 'W', -1., wslpj, 'W', -1. ) |
|---|
| 801 | !!gm ENDIF |
|---|
| 802 | ENDIF |
|---|
| 803 | ! |
|---|
| 804 | END SUBROUTINE ldf_slp_init |
|---|
| 805 | |
|---|
| 806 | !!====================================================================== |
|---|
| 807 | END MODULE ldfslp |
|---|
