New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p2zexp.F90 in NEMO/branches/UKMO/NEMO_4.0.2_mirror/src/TOP/PISCES/P2Z – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.2_mirror/src/TOP/PISCES/P2Z/p2zexp.F90 @ 12658

Last change on this file since 12658 was 12658, checked in by cguiavarch, 4 years ago

UKMO/NEMO_4.0.2_mirror : Remove SVN keywords.

File size: 10.2 KB
Line 
1MODULE p2zexp
2   !!======================================================================
3   !!                         ***  MODULE p2zsed  ***
4   !! TOP :   LOBSTER Compute loss of organic matter in the sediments
5   !!======================================================================
6   !! History :    -   !  1999    (O. Aumont, C. Le Quere)  original code
7   !!              -   !  2001-05 (O. Aumont, E. Kestenare) add sediment computations
8   !!             1.0  !  2005-06 (A.-S. Kremeur) new temporal integration for sedpoc
9   !!             2.0  !  2007-12  (C. Deltel, G. Madec)  F90
10   !!             3.5  !  2012-03  (C. Ethe)  Merge PISCES-LOBSTER
11   !!----------------------------------------------------------------------
12   !!   p2z_exp        :  Compute loss of organic matter in the sediments
13   !!----------------------------------------------------------------------
14   USE oce_trc         !
15   USE trc
16   USE sms_pisces
17   USE p2zsed
18   USE lbclnk
19   USE prtctl_trc      ! Print control for debbuging
20   USE trd_oce
21   USE trdtrc
22   USE iom
23
24   IMPLICIT NONE
25   PRIVATE
26
27   PUBLIC   p2z_exp   
28   PUBLIC   p2z_exp_init 
29   PUBLIC   p2z_exp_alloc
30
31   !
32   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   dminl     !: fraction of sinking POC released in sediments
33   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) ::   dmin3     !: fraction of sinking POC released at each level
34   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   sedpocb   !: mass of POC in sediments
35   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   sedpocn   !: mass of POC in sediments
36   REAL(wp), ALLOCATABLE, DIMENSION(:,:)   ::   cmask     !: Coastal mask area
37   REAL(wp)                                ::   areacot   !: surface coastal area
38
39   !! * Substitutions
40#  include "vectopt_loop_substitute.h90"
41   !!----------------------------------------------------------------------
42   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE p2z_exp( kt )
49      !!---------------------------------------------------------------------
50      !!                     ***  ROUTINE p2z_exp  ***
51      !!
52      !! ** Purpose :   MODELS EXPORT OF BIOGENIC MATTER (POC ''SOFT
53      !!              TISSUE'') AND ITS DISTRIBUTION IN WATER COLUMN
54      !!
55      !! ** Method  : - IN THE SURFACE LAYER POC IS PRODUCED ACCORDING TO
56      !!              NURTRIENTS AVAILABLE AND GROWTH CONDITIONS. NUTRIENT UPTAKE
57      !!              KINETICS FOLLOW MICHAELIS-MENTON FORMULATION.
58      !!              THE TOTAL PARTICLE AMOUNT PRODUCED, IS DISTRIBUTED IN THE WATER
59      !!              COLUMN BELOW THE SURFACE LAYER.
60      !!---------------------------------------------------------------------
61      !!
62      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index     
63      !!
64      INTEGER  ::   ji, jj, jk, jl, ikt
65      REAL(wp) ::   zgeolpoc, zfact, zwork, ze3t, zsedpocd, zmaskt
66      REAL(wp), DIMENSION(jpi,jpj)   ::  zsedpoca
67      CHARACTER (len=25) :: charout
68      !!---------------------------------------------------------------------
69      !
70      IF( ln_timing )   CALL timing_start('p2z_exp')
71      !
72      IF( kt == nittrc000 )   CALL p2z_exp_init
73
74      zsedpoca(:,:) = 0.
75
76
77      ! VERTICAL DISTRIBUTION OF NEWLY PRODUCED BIOGENIC
78      ! POC IN THE WATER COLUMN
79      ! (PARTS OF NEWLY FORMED MATTER REMAINING IN THE DIFFERENT
80      ! LAYERS IS DETERMINED BY DMIN3 DEFINED IN sms_p2z.F90
81      ! ----------------------------------------------------------------------
82      DO jk = 1, jpkm1
83         DO jj = 2, jpjm1
84            DO ji = fs_2, fs_jpim1
85               ze3t = 1. / e3t_n(ji,jj,jk)
86               tra(ji,jj,jk,jpno3) = tra(ji,jj,jk,jpno3) + ze3t * dmin3(ji,jj,jk) * xksi(ji,jj)
87            END DO
88         END DO
89      END DO
90
91      ! Find the last level of the water column
92      ! Compute fluxes due to sinking particles (slow)
93   
94
95      zgeolpoc = 0.e0         !     Initialization
96      ! Release of nutrients from the "simple" sediment
97      DO jj = 2, jpjm1
98         DO ji = fs_2, fs_jpim1
99            ikt = mbkt(ji,jj) 
100            tra(ji,jj,ikt,jpno3) = tra(ji,jj,ikt,jpno3) + sedlam * sedpocn(ji,jj) / e3t_n(ji,jj,ikt) 
101            ! Deposition of organic matter in the sediment
102            zwork = vsed * trn(ji,jj,ikt,jpdet)
103            zsedpoca(ji,jj) = ( zwork + dminl(ji,jj) * xksi(ji,jj)   &
104               &           - sedlam * sedpocn(ji,jj) - sedlostpoc * sedpocn(ji,jj) ) * rdt
105            zgeolpoc = zgeolpoc + sedlostpoc * sedpocn(ji,jj) * e1e2t(ji,jj)
106         END DO
107      END DO
108
109      DO jj = 2, jpjm1
110         DO ji = fs_2, fs_jpim1
111            tra(ji,jj,1,jpno3) = tra(ji,jj,1,jpno3) + zgeolpoc * cmask(ji,jj) / areacot / e3t_n(ji,jj,1)
112         END DO
113      END DO
114
115      CALL lbc_lnk( 'p2zexp', sedpocn, 'T', 1. )
116 
117      ! Oa & Ek: diagnostics depending on jpdia2d !          left as example
118      IF( lk_iomput )  CALL iom_put( "SEDPOC" , sedpocn )
119
120     
121      ! Time filter and swap of arrays
122      ! ------------------------------
123      IF( neuler == 0 .AND. kt == nittrc000 ) THEN        ! Euler time-stepping at first time-step
124        !                                             ! (only swap)
125        sedpocn(:,:) = zsedpoca(:,:)
126        !                                             
127      ELSE
128        !
129        DO jj = 1, jpj
130           DO ji = 1, jpi
131              zsedpocd = zsedpoca(ji,jj) - 2. * sedpocn(ji,jj) + sedpocb(ji,jj)      ! time laplacian on tracers
132              sedpocb(ji,jj) = sedpocn(ji,jj) + atfp * zsedpocd                     ! sedpocb <-- filtered sedpocn
133              sedpocn(ji,jj) = zsedpoca(ji,jj)                                       ! sedpocn <-- sedpoca
134           END DO
135        END DO
136        !
137      ENDIF
138      !
139      IF( lrst_trc ) THEN
140         IF(lwp) WRITE(numout,*)
141         IF(lwp) WRITE(numout,*) 'p2z_exp : POC in sediment fields written in ocean restart file ',   &
142            &                    'at it= ', kt,' date= ', ndastp
143         IF(lwp) WRITE(numout,*) '~~~~'
144         CALL iom_rstput( kt, nitrst, numrtw, 'SEDB'//ctrcnm(jpdet), sedpocb(:,:) )
145         CALL iom_rstput( kt, nitrst, numrtw, 'SEDN'//ctrcnm(jpdet), sedpocn(:,:) )
146      ENDIF
147      !
148      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
149         WRITE(charout, FMT="('exp')")
150         CALL prt_ctl_trc_info(charout)
151         CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
152      ENDIF
153      !
154      IF( ln_timing )  CALL timing_stop('p2z_exp')
155      !
156   END SUBROUTINE p2z_exp
157
158
159   SUBROUTINE p2z_exp_init
160      !!----------------------------------------------------------------------
161      !!                    ***  ROUTINE p4z_exp_init  ***
162      !! ** purpose :   specific initialisation for export
163      !!----------------------------------------------------------------------
164      INTEGER  ::   ji, jj, jk
165      REAL(wp) ::   zmaskt, zfluo, zfluu
166      REAL(wp), DIMENSION(jpi,jpj    ) :: zrro
167      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zdm0
168      !!---------------------------------------------------------------------
169      !
170      IF(lwp) THEN
171         WRITE(numout,*)
172         WRITE(numout,*) ' p2z_exp: LOBSTER export'
173         WRITE(numout,*) ' ~~~~~~~'
174         WRITE(numout,*) '  compute remineralisation-damping arrays for tracers'
175      ENDIF
176      !
177
178      ! Calculate vertical distribution of newly formed biogenic poc
179      ! in the water column in the case of max. possible bottom depth
180      ! ------------------------------------------------------------
181      zdm0 = 0._wp
182      zrro = 1._wp
183      DO jk = jpkb, jpkm1
184         DO jj = 1, jpj
185            DO ji = 1, jpi
186               zfluo = ( gdepw_n(ji,jj,jk  ) / gdepw_n(ji,jj,jpkb) )**xhr
187               zfluu = ( gdepw_n(ji,jj,jk+1) / gdepw_n(ji,jj,jpkb) )**xhr
188               IF( zfluo.GT.1. )   zfluo = 1._wp
189               zdm0(ji,jj,jk) = zfluo - zfluu
190               IF( jk <= jpkb-1 )   zdm0(ji,jj,jk) = 0._wp
191               zrro(ji,jj) = zrro(ji,jj) - zdm0(ji,jj,jk)
192            END DO
193         END DO
194      END DO
195      !
196      zdm0(:,:,jpk) = zrro(:,:)
197
198      ! Calculate vertical distribution of newly formed biogenic poc
199      ! in the water column with realistic topography (first "dry" layer
200      ! contains total fraction, which has passed to the upper layers)
201      ! ----------------------------------------------------------------------
202      dminl(:,:)   = 0._wp
203      dmin3(:,:,:) = zdm0
204      DO jk = 1, jpk
205         DO jj = 1, jpj
206            DO ji = 1, jpi
207               IF( tmask(ji,jj,jk) == 0._wp ) THEN
208                  dminl(ji,jj) = dminl(ji,jj) + dmin3(ji,jj,jk)
209                  dmin3(ji,jj,jk) = 0._wp
210               ENDIF
211            END DO
212         END DO
213      END DO
214
215      DO jj = 1, jpj
216         DO ji = 1, jpi
217            IF( tmask(ji,jj,1) == 0 )   dmin3(ji,jj,1) = 0._wp
218         END DO
219      END DO
220
221      ! Coastal mask
222      cmask(:,:) = 0._wp
223      DO jj = 2, jpjm1
224         DO ji = fs_2, fs_jpim1
225            IF( tmask(ji,jj,1) /= 0. ) THEN
226               zmaskt = tmask(ji+1,jj,1) * tmask(ji-1,jj,1) * tmask(ji,jj+1,1) * tmask(ji,jj-1,1) 
227               IF( zmaskt == 0. )   cmask(ji,jj) = 1._wp
228            END IF
229         END DO
230      END DO
231      CALL lbc_lnk( 'p2zexp', cmask , 'T', 1. )      ! lateral boundary conditions on cmask   (sign unchanged)
232      areacot = glob_sum( 'p2zexp', e1e2t(:,:) * cmask(:,:) )
233      !
234      IF( ln_rsttr ) THEN
235         CALL iom_get( numrtr, jpdom_autoglo, 'SEDB'//ctrcnm(jpdet), sedpocb(:,:) )
236         CALL iom_get( numrtr, jpdom_autoglo, 'SEDN'//ctrcnm(jpdet), sedpocn(:,:) )
237      ELSE
238         sedpocb(:,:) = 0._wp
239         sedpocn(:,:) = 0._wp
240      ENDIF
241      !
242   END SUBROUTINE p2z_exp_init
243
244   INTEGER FUNCTION p2z_exp_alloc()
245      !!----------------------------------------------------------------------
246      !!                     ***  ROUTINE p2z_exp_alloc  ***
247      !!----------------------------------------------------------------------
248      ALLOCATE( cmask(jpi,jpj) , dminl(jpi,jpj) , dmin3(jpi,jpj,jpk), &
249         &      sedpocb(jpi,jpj) , sedpocn(jpi,jpj),   STAT=p2z_exp_alloc )
250      IF( p2z_exp_alloc /= 0 ) CALL ctl_stop( 'STOP', 'p2z_exp_alloc : failed to allocate arrays.' )
251      !
252   END FUNCTION p2z_exp_alloc
253
254   !!======================================================================
255END MODULE p2zexp
Note: See TracBrowser for help on using the repository browser.