New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcnxt.F90 in NEMO/branches/UKMO/NEMO_4.0.2_mirror/src/TOP/TRP – NEMO

source: NEMO/branches/UKMO/NEMO_4.0.2_mirror/src/TOP/TRP/trcnxt.F90 @ 12658

Last change on this file since 12658 was 12658, checked in by cguiavarch, 4 years ago

UKMO/NEMO_4.0.2_mirror : Remove SVN keywords.

File size: 12.7 KB
Line 
1MODULE trcnxt
2   !!======================================================================
3   !!                       ***  MODULE  trcnxt  ***
4   !! Ocean passive tracers:  time stepping on passives tracers
5   !!======================================================================
6   !! History :  7.0  !  1991-11  (G. Madec)  Original code
7   !!                 !  1993-03  (M. Guyon)  symetrical conditions
8   !!                 !  1995-02  (M. Levy)   passive tracers
9   !!                 !  1996-02  (G. Madec & M. Imbard)  opa release 8.0
10   !!            8.0  !  1996-04  (A. Weaver)  Euler forward step
11   !!            8.2  !  1999-02  (G. Madec, N. Grima)  semi-implicit pressure grad.
12   !!  NEMO      1.0  !  2002-08  (G. Madec)  F90: Free form and module
13   !!                 !  2002-08  (G. Madec)  F90: Free form and module
14   !!                 !  2002-11  (C. Talandier, A-M Treguier) Open boundaries
15   !!                 !  2004-03  (C. Ethe) passive tracers
16   !!                 !  2007-02  (C. Deltel) Diagnose ML trends for passive tracers
17   !!            2.0  !  2006-02  (L. Debreu, C. Mazauric) Agrif implementation
18   !!            3.0  !  2008-06  (G. Madec)  time stepping always done in trazdf
19   !!            3.1  !  2009-02  (G. Madec, R. Benshila)  re-introduce the vvl option
20   !!            3.3  !  2010-06  (C. Ethe, G. Madec) Merge TRA-TRC
21   !!----------------------------------------------------------------------
22#if defined key_top
23   !!----------------------------------------------------------------------
24   !!   'key_top'                                                TOP models
25   !!----------------------------------------------------------------------
26   !!   trc_nxt     : time stepping on passive tracers
27   !!----------------------------------------------------------------------
28   USE oce_trc         ! ocean dynamics and tracers variables
29   USE trc             ! ocean passive tracers variables
30   USE trd_oce
31   USE trdtra
32   USE tranxt
33   USE bdy_oce   , ONLY: ln_bdy
34   USE trcbdy          ! BDY open boundaries
35# if defined key_agrif
36   USE agrif_top_interp
37# endif
38   !
39   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
40   USE prtctl_trc      ! Print control for debbuging
41
42   IMPLICIT NONE
43   PRIVATE
44
45   PUBLIC   trc_nxt   ! routine called by step.F90
46
47   REAL(wp) ::   rfact1, rfact2
48
49   !!----------------------------------------------------------------------
50   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE trc_nxt( kt )
57      !!----------------------------------------------------------------------
58      !!                   ***  ROUTINE trcnxt  ***
59      !!
60      !! ** Purpose :   Compute the passive tracers fields at the
61      !!      next time-step from their temporal trends and swap the fields.
62      !!
63      !! ** Method  :   Apply lateral boundary conditions on (ua,va) through
64      !!      call to lbc_lnk routine
65      !!   default:
66      !!      arrays swap
67      !!         (trn) = (tra) ; (tra) = (0,0)
68      !!         (trb) = (trn)
69      !!
70      !!   For Arakawa or TVD Scheme :
71      !!      A Asselin time filter applied on now tracers (trn) to avoid
72      !!      the divergence of two consecutive time-steps and tr arrays
73      !!      to prepare the next time_step:
74      !!         (trb) = (trn) + atfp [ (trb) + (tra) - 2 (trn) ]
75      !!         (trn) = (tra) ; (tra) = (0,0)
76      !!
77      !!
78      !! ** Action  : - update trb, trn
79      !!----------------------------------------------------------------------
80      INTEGER, INTENT( in ) ::   kt     ! ocean time-step index
81      !
82      INTEGER  ::   jk, jn   ! dummy loop indices
83      REAL(wp) ::   zfact            ! temporary scalar
84      CHARACTER (len=22) :: charout
85      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ztrdt    ! 4D workspace
86      !!----------------------------------------------------------------------
87      !
88      IF( ln_timing )   CALL timing_start('trc_nxt')
89      !
90      IF( kt == nittrc000 .AND. lwp ) THEN
91         WRITE(numout,*)
92         WRITE(numout,*) 'trc_nxt : time stepping on passive tracers'
93      ENDIF
94      !
95#if defined key_agrif
96      CALL Agrif_trc                   ! AGRIF zoom boundaries
97#endif
98      ! Update after tracer on domain lateral boundaries
99      CALL lbc_lnk( 'trcnxt', tra(:,:,:,:), 'T', 1. )   
100
101      IF( ln_bdy )  CALL trc_bdy( kt )
102
103      IF( l_trdtrc )  THEN             ! trends: store now fields before the Asselin filter application
104         ALLOCATE( ztrdt(jpi,jpj,jpk,jptra) )
105         ztrdt(:,:,:,:)  = 0._wp
106         IF( ln_traldf_iso ) THEN                       ! diagnose the "pure" Kz diffusive trend
107            DO jn = 1, jptra
108               CALL trd_tra( kt, 'TRC', jn, jptra_zdfp, ztrdt(:,:,:,jn) )
109            ENDDO
110         ENDIF
111
112         ! total trend for the non-time-filtered variables.
113         zfact = 1.0 / rdttrc
114         ! G Nurser 23 Mar 2017. Recalculate trend as Delta(e3t*T)/e3tn; e3tn cancel from tsn terms
115         IF( ln_linssh ) THEN       ! linear sea surface height only
116            DO jn = 1, jptra
117               DO jk = 1, jpkm1
118                  ztrdt(:,:,jk,jn) = ( tra(:,:,jk,jn)*e3t_a(:,:,jk) / e3t_n(:,:,jk) - trn(:,:,jk,jn)) * zfact
119               END DO
120            END DO
121         ELSE
122            DO jn = 1, jptra
123               DO jk = 1, jpkm1
124                  ztrdt(:,:,jk,jn) = ( tra(:,:,jk,jn) - trn(:,:,jk,jn) ) * zfact
125               END DO
126            END DO
127         ENDIF
128         !
129         DO jn = 1, jptra
130            CALL trd_tra( kt, 'TRC', jn, jptra_tot, ztrdt(:,:,:,jn) )
131         ENDDO
132         !
133         IF( ln_linssh ) THEN       ! linear sea surface height only
134            ! Store now fields before applying the Asselin filter
135            ! in order to calculate Asselin filter trend later.
136            ztrdt(:,:,:,:) = trn(:,:,:,:) 
137         ENDIF
138
139      ENDIF
140      !                                ! Leap-Frog + Asselin filter time stepping
141      IF( (neuler == 0 .AND. kt == nittrc000) ) THEN
142         ! set up for leapfrog on second timestep
143         DO jn = 1, jptra
144            DO jk = 1, jpkm1
145               trb(:,:,jk,jn) = trn(:,:,jk,jn) 
146               trn(:,:,jk,jn) = tra(:,:,jk,jn)
147            END DO
148         END DO
149      ELSE IF( ln_top_euler ) THEN
150         ! always doing euler timestepping
151         DO jn = 1, jptra
152            DO jk = 1, jpkm1
153               trn(:,:,jk,jn) = tra(:,:,jk,jn)
154               trb(:,:,jk,jn) = trn(:,:,jk,jn) 
155            END DO
156         END DO
157      ENDIF
158      IF( (neuler == 0 .AND. kt == nittrc000) .OR. ln_top_euler ) THEN    ! Euler time-stepping (only swap)
159         IF (l_trdtrc .AND. .NOT. ln_linssh ) THEN   ! Zero Asselin filter contribution must be explicitly written out since for vvl
160            !                                        ! Asselin filter is output by tra_nxt_vvl that is not called on this time step
161            ztrdt(:,:,:,:) = 0._wp           
162            DO jn = 1, jptra
163               CALL trd_tra( kt, 'TRC', jn, jptra_atf, ztrdt(:,:,:,jn) )
164            ENDDO
165         END IF
166         !
167      ELSE     
168         IF( .NOT. l_offline ) THEN ! Leap-Frog + Asselin filter time stepping
169            IF( ln_linssh ) THEN   ;   CALL tra_nxt_fix( kt, nittrc000,         'TRC', trb, trn, tra, jptra )  !     linear ssh
170            ELSE                   ;   CALL tra_nxt_vvl( kt, nittrc000, rdttrc, 'TRC', trb, trn, tra,      &
171              &                                                                   sbc_trc, sbc_trc_b, jptra )  ! non-linear ssh
172            ENDIF
173         ELSE
174                                       CALL trc_nxt_off( kt )       ! offline
175         ENDIF
176         !
177         CALL lbc_lnk_multi( 'trcnxt', trb(:,:,:,:), 'T', 1._wp, trn(:,:,:,:), 'T', 1._wp, tra(:,:,:,:), 'T', 1._wp )
178      ENDIF
179      !
180      IF( l_trdtrc .AND. ln_linssh ) THEN      ! trend of the Asselin filter (tb filtered - tb)/dt )
181         DO jn = 1, jptra
182            DO jk = 1, jpkm1
183               zfact = 1._wp / r2dttrc 
184               ztrdt(:,:,jk,jn) = ( trb(:,:,jk,jn) - ztrdt(:,:,jk,jn) ) * zfact 
185            END DO
186            CALL trd_tra( kt, 'TRC', jn, jptra_atf, ztrdt(:,:,:,jn) )
187         END DO
188      END IF
189      IF( l_trdtrc ) DEALLOCATE( ztrdt ) 
190      !
191      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
192         WRITE(charout, FMT="('nxt')")
193         CALL prt_ctl_trc_info(charout)
194         CALL prt_ctl_trc(tab4d=trn, mask=tmask, clinfo=ctrcnm)
195      ENDIF
196      !
197      IF( ln_timing )   CALL timing_stop('trc_nxt')
198      !
199   END SUBROUTINE trc_nxt
200
201
202   SUBROUTINE trc_nxt_off( kt )
203      !!----------------------------------------------------------------------
204      !!                   ***  ROUTINE tra_nxt_vvl  ***
205      !!
206      !! ** Purpose :   Time varying volume: apply the Asselin time filter 
207      !!                and swap the tracer fields.
208      !!
209      !! ** Method  : - Apply a thickness weighted Asselin time filter on now fields.
210      !!              - save in (ta,sa) a thickness weighted average over the three
211      !!             time levels which will be used to compute rdn and thus the semi-
212      !!             implicit hydrostatic pressure gradient (ln_dynhpg_imp = T)
213      !!              - swap tracer fields to prepare the next time_step.
214      !!                This can be summurized for tempearture as:
215      !!             ztm = ( e3t_n*tn + rbcp*[ e3t_b*tb - 2 e3t_n*tn + e3t_a*ta ] )   ln_dynhpg_imp = T
216      !!                  /( e3t_n    + rbcp*[ e3t_b    - 2 e3t_n    + e3t_a    ] )   
217      !!             ztm = 0                                                       otherwise
218      !!             tb  = ( e3t_n*tn + atfp*[ e3t_b*tb - 2 e3t_n*tn + e3t_a*ta ] )
219      !!                  /( e3t_n    + atfp*[ e3t_b    - 2 e3t_n    + e3t_a    ] )
220      !!             tn  = ta
221      !!             ta  = zt        (NB: reset to 0 after eos_bn2 call)
222      !!
223      !! ** Action  : - (tb,sb) and (tn,sn) ready for the next time step
224      !!              - (ta,sa) time averaged (t,s)   (ln_dynhpg_imp = T)
225      !!----------------------------------------------------------------------
226      INTEGER , INTENT(in   )   ::  kt       ! ocean time-step index
227      !!     
228      INTEGER  ::   ji, jj, jk, jn              ! dummy loop indices
229      REAL(wp) ::   ztc_a , ztc_n , ztc_b , ztc_f , ztc_d    ! local scalar
230      REAL(wp) ::   ze3t_b, ze3t_n, ze3t_a, ze3t_f, ze3t_d   !   -      -
231      !!----------------------------------------------------------------------
232      !
233      IF( kt == nittrc000 )  THEN
234         IF(lwp) WRITE(numout,*)
235         IF(lwp) WRITE(numout,*) 'trc_nxt_off : time stepping'
236         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~'
237         IF( .NOT. ln_linssh ) THEN
238            rfact1 = atfp * rdttrc
239            rfact2 = rfact1 / rau0
240         ENDIF
241       
242      ENDIF
243      !
244      DO jn = 1, jptra     
245         DO jk = 1, jpkm1
246            DO jj = 1, jpj
247               DO ji = 1, jpi
248                  ze3t_b = e3t_b(ji,jj,jk)
249                  ze3t_n = e3t_n(ji,jj,jk)
250                  ze3t_a = e3t_a(ji,jj,jk)
251                  !                                         ! tracer content at Before, now and after
252                  ztc_b  = trb(ji,jj,jk,jn) * ze3t_b
253                  ztc_n  = trn(ji,jj,jk,jn) * ze3t_n
254                  ztc_a  = tra(ji,jj,jk,jn) * ze3t_a
255                  !
256                  ze3t_d = ze3t_a - 2. * ze3t_n + ze3t_b
257                  ztc_d  = ztc_a  - 2. * ztc_n  + ztc_b
258                  !
259                  ze3t_f = ze3t_n + atfp * ze3t_d
260                  ztc_f  = ztc_n  + atfp * ztc_d
261                  !
262                  IF( .NOT. ln_linssh .AND. jk == mikt(ji,jj) ) THEN           ! first level
263                     ze3t_f = ze3t_f - rfact2 * ( emp_b(ji,jj)      - emp(ji,jj)   ) 
264                     ztc_f  = ztc_f  - rfact1 * ( sbc_trc(ji,jj,jn) - sbc_trc_b(ji,jj,jn) )
265                  ENDIF
266
267                  ze3t_f = 1.e0 / ze3t_f
268                  trb(ji,jj,jk,jn) = ztc_f * ze3t_f       ! ptb <-- ptn filtered
269                  trn(ji,jj,jk,jn) = tra(ji,jj,jk,jn)     ! ptn <-- pta
270                  !
271               END DO
272            END DO
273         END DO
274         !
275      END DO
276      !
277   END SUBROUTINE trc_nxt_off
278
279#else
280   !!----------------------------------------------------------------------
281   !!   Default option                                         Empty module
282   !!----------------------------------------------------------------------
283CONTAINS
284   SUBROUTINE trc_nxt( kt ) 
285      INTEGER, INTENT(in) :: kt
286      WRITE(*,*) 'trc_nxt: You should not have seen this print! error?', kt
287   END SUBROUTINE trc_nxt
288#endif
289   !!======================================================================
290END MODULE trcnxt
Note: See TracBrowser for help on using the repository browser.