| 1 | MODULE icedyn |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE icedyn *** |
|---|
| 4 | !! Sea-Ice dynamics : master routine for sea ice dynamics |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! history : 4.0 ! 2018 (C. Rousset) original code SI3 [aka Sea Ice cube] |
|---|
| 7 | !!---------------------------------------------------------------------- |
|---|
| 8 | #if defined key_si3 |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | !! 'key_si3' SI3 sea-ice model |
|---|
| 11 | !!---------------------------------------------------------------------- |
|---|
| 12 | !! ice_dyn : dynamics of sea ice |
|---|
| 13 | !! ice_dyn_init : initialization and namelist read |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | USE phycst ! physical constants |
|---|
| 16 | USE dom_oce ! ocean space and time domain |
|---|
| 17 | USE ice ! sea-ice: variables |
|---|
| 18 | USE icedyn_rhg ! sea-ice: rheology |
|---|
| 19 | USE icedyn_adv ! sea-ice: advection |
|---|
| 20 | USE icedyn_rdgrft ! sea-ice: ridging/rafting |
|---|
| 21 | USE icecor ! sea-ice: corrections |
|---|
| 22 | USE icevar ! sea-ice: operations |
|---|
| 23 | USE icectl ! sea-ice: control prints |
|---|
| 24 | ! |
|---|
| 25 | USE in_out_manager ! I/O manager |
|---|
| 26 | USE iom ! I/O manager library |
|---|
| 27 | USE lib_mpp ! MPP library |
|---|
| 28 | USE lib_fortran ! fortran utilities (glob_sum + no signed zero) |
|---|
| 29 | USE lbclnk ! lateral boundary conditions (or mpp links) |
|---|
| 30 | USE timing ! Timing |
|---|
| 31 | |
|---|
| 32 | IMPLICIT NONE |
|---|
| 33 | PRIVATE |
|---|
| 34 | |
|---|
| 35 | PUBLIC ice_dyn ! called by icestp.F90 |
|---|
| 36 | PUBLIC ice_dyn_init ! called by icestp.F90 |
|---|
| 37 | |
|---|
| 38 | INTEGER :: nice_dyn ! choice of the type of dynamics |
|---|
| 39 | ! ! associated indices: |
|---|
| 40 | INTEGER, PARAMETER :: np_dynALL = 1 ! full ice dynamics (rheology + advection + ridging/rafting + correction) |
|---|
| 41 | INTEGER, PARAMETER :: np_dynRHGADV = 2 ! pure dynamics (rheology + advection) |
|---|
| 42 | INTEGER, PARAMETER :: np_dynADV1D = 3 ! only advection 1D - test case from Schar & Smolarkiewicz 1996 |
|---|
| 43 | INTEGER, PARAMETER :: np_dynADV2D = 4 ! only advection 2D w prescribed vel.(rn_uvice + advection) |
|---|
| 44 | ! |
|---|
| 45 | ! ** namelist (namdyn) ** |
|---|
| 46 | LOGICAL :: ln_dynALL ! full ice dynamics (rheology + advection + ridging/rafting + correction) |
|---|
| 47 | LOGICAL :: ln_dynRHGADV ! no ridge/raft & no corrections (rheology + advection) |
|---|
| 48 | LOGICAL :: ln_dynADV1D ! only advection in 1D w ice convergence (test case from Schar & Smolarkiewicz 1996) |
|---|
| 49 | LOGICAL :: ln_dynADV2D ! only advection in 2D w prescribed vel. (rn_uvice + advection) |
|---|
| 50 | REAL(wp) :: rn_uice ! prescribed u-vel (case np_dynADV1D & np_dynADV2D) |
|---|
| 51 | REAL(wp) :: rn_vice ! prescribed v-vel (case np_dynADV1D & np_dynADV2D) |
|---|
| 52 | |
|---|
| 53 | !! * Substitutions |
|---|
| 54 | # include "vectopt_loop_substitute.h90" |
|---|
| 55 | !!---------------------------------------------------------------------- |
|---|
| 56 | !! NEMO/ICE 4.0 , NEMO Consortium (2018) |
|---|
| 57 | !! $Id$ |
|---|
| 58 | !! Software governed by the CeCILL licence (./LICENSE) |
|---|
| 59 | !!---------------------------------------------------------------------- |
|---|
| 60 | CONTAINS |
|---|
| 61 | |
|---|
| 62 | SUBROUTINE ice_dyn( kt ) |
|---|
| 63 | !!------------------------------------------------------------------- |
|---|
| 64 | !! *** ROUTINE ice_dyn *** |
|---|
| 65 | !! |
|---|
| 66 | !! ** Purpose : this routine manages sea ice dynamics |
|---|
| 67 | !! |
|---|
| 68 | !! ** Action : - calculation of friction in case of landfast ice |
|---|
| 69 | !! - call ice_dyn_rhg = rheology |
|---|
| 70 | !! - call ice_dyn_adv = advection |
|---|
| 71 | !! - call ice_dyn_rdgrft = ridging/rafting |
|---|
| 72 | !! - call ice_cor = corrections if fields are out of bounds |
|---|
| 73 | !!-------------------------------------------------------------------- |
|---|
| 74 | INTEGER, INTENT(in) :: kt ! ice time step |
|---|
| 75 | !! |
|---|
| 76 | INTEGER :: ji, jj ! dummy loop indices |
|---|
| 77 | REAL(wp) :: zcoefu, zcoefv |
|---|
| 78 | REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zdivu_i |
|---|
| 79 | !!-------------------------------------------------------------------- |
|---|
| 80 | ! |
|---|
| 81 | ! controls |
|---|
| 82 | IF( ln_timing ) CALL timing_start('icedyn') |
|---|
| 83 | ! |
|---|
| 84 | IF( kt == nit000 .AND. lwp ) THEN |
|---|
| 85 | WRITE(numout,*) |
|---|
| 86 | WRITE(numout,*)'ice_dyn: sea-ice dynamics' |
|---|
| 87 | WRITE(numout,*)'~~~~~~~' |
|---|
| 88 | ENDIF |
|---|
| 89 | ! |
|---|
| 90 | ! retrieve thickness from volume for landfast param. and UMx advection scheme |
|---|
| 91 | WHERE( a_i(:,:,:) >= epsi20 ) |
|---|
| 92 | h_i(:,:,:) = v_i(:,:,:) / a_i_b(:,:,:) |
|---|
| 93 | h_s(:,:,:) = v_s(:,:,:) / a_i_b(:,:,:) |
|---|
| 94 | ELSEWHERE |
|---|
| 95 | h_i(:,:,:) = 0._wp |
|---|
| 96 | h_s(:,:,:) = 0._wp |
|---|
| 97 | END WHERE |
|---|
| 98 | ! |
|---|
| 99 | WHERE( a_ip(:,:,:) >= epsi20 ) |
|---|
| 100 | h_ip(:,:,:) = v_ip(:,:,:) / a_ip(:,:,:) |
|---|
| 101 | ELSEWHERE |
|---|
| 102 | h_ip(:,:,:) = 0._wp |
|---|
| 103 | END WHERE |
|---|
| 104 | ! |
|---|
| 105 | ! |
|---|
| 106 | SELECT CASE( nice_dyn ) !-- Set which dynamics is running |
|---|
| 107 | |
|---|
| 108 | CASE ( np_dynALL ) !== all dynamical processes ==! |
|---|
| 109 | |
|---|
| 110 | IF(narea == 68) THEN |
|---|
| 111 | WRITE(968,*) 'in icedyn before ice_dyn_rhg: u_ice = ',SUM(u_ice) |
|---|
| 112 | WRITE(968,*) 'v_ice(54,0:2) = ',SUM(v_ice) |
|---|
| 113 | WRITE(968,*) 'h_i(54,0:2) = ',SUM(h_i) |
|---|
| 114 | WRITE(968,*) 'h_s(54,0:2) = ',SUM(h_s) |
|---|
| 115 | WRITE(968,*) 'v_i(54,0:2) = ',SUM(v_i) |
|---|
| 116 | WRITE(968,*) 'sv_i(54,0:2) = ',SUM(sv_i) |
|---|
| 117 | WRITE(968,*) 'e_s(54,0:2) = ',SUM(e_s) |
|---|
| 118 | WRITE(968,*) 'e_i(54,0:2) = ',SUM(e_i) |
|---|
| 119 | ENDIF |
|---|
| 120 | |
|---|
| 121 | ! |
|---|
| 122 | CALL ice_dyn_rhg ( kt ) ! -- rheology |
|---|
| 123 | |
|---|
| 124 | IF(narea == 68) THEN |
|---|
| 125 | WRITE(968,*) 'in icedyn before ice_dyn_adv: u_ice = ',SUM(u_ice) |
|---|
| 126 | WRITE(968,*) 'v_ice(54,0:2) = ',SUM(v_ice) |
|---|
| 127 | WRITE(968,*) 'h_i(54,0:2) = ',SUM(h_i) |
|---|
| 128 | WRITE(968,*) 'h_s(54,0:2) = ',SUM(h_s) |
|---|
| 129 | WRITE(968,*) 'v_i(54,0:2) = ',SUM(v_i) |
|---|
| 130 | WRITE(968,*) 'sv_i(54,0:2) = ',SUM(sv_i) |
|---|
| 131 | WRITE(968,*) 'e_s(54,0:2) = ',SUM(e_s) |
|---|
| 132 | WRITE(968,*) 'e_i(54,0:2) = ',SUM(e_i) |
|---|
| 133 | ENDIF |
|---|
| 134 | |
|---|
| 135 | CALL ice_dyn_adv ( kt ) ! -- advection of ice |
|---|
| 136 | |
|---|
| 137 | IF(narea == 68) THEN |
|---|
| 138 | WRITE(968,*) 'a_i after ice_dyn_adv = ',a_i(54,1) |
|---|
| 139 | ENDIF |
|---|
| 140 | |
|---|
| 141 | CALL ice_dyn_rdgrft( kt ) ! -- ridging/rafting |
|---|
| 142 | |
|---|
| 143 | IF(narea == 68) THEN |
|---|
| 144 | WRITE(968,*) 'a_i after ice_dyn_rdgrft = ',a_i(54,1) |
|---|
| 145 | ENDIF |
|---|
| 146 | |
|---|
| 147 | CALL ice_cor ( kt , 1 ) ! -- Corrections |
|---|
| 148 | |
|---|
| 149 | IF(narea == 68) THEN |
|---|
| 150 | WRITE(968,*) 'a_i after ice_cor = ',a_i(54,1) |
|---|
| 151 | ENDIF |
|---|
| 152 | |
|---|
| 153 | ! |
|---|
| 154 | CASE ( np_dynRHGADV ) !== no ridge/raft & no corrections ==! |
|---|
| 155 | ! |
|---|
| 156 | CALL ice_dyn_rhg ( kt ) ! -- rheology |
|---|
| 157 | CALL ice_dyn_adv ( kt ) ! -- advection of ice |
|---|
| 158 | CALL Hpiling ! -- simple pile-up (replaces ridging/rafting) |
|---|
| 159 | CALL ice_var_zapsmall ! -- zap small areas |
|---|
| 160 | ! |
|---|
| 161 | CASE ( np_dynADV1D ) !== pure advection ==! (1D) |
|---|
| 162 | ! |
|---|
| 163 | ! --- monotonicity test from Schar & Smolarkiewicz 1996 --- ! |
|---|
| 164 | ! CFL = 0.5 at a distance from the bound of 1/6 of the basin length |
|---|
| 165 | ! Then for dx = 2m and dt = 1s => rn_uice = u (1/6th) = 1m/s |
|---|
| 166 | DO jj = 1, jpj |
|---|
| 167 | DO ji = 1, jpi |
|---|
| 168 | zcoefu = ( REAL(jpiglo+1)*0.5 - REAL(ji+nimpp-1) ) / ( REAL(jpiglo+1)*0.5 - 1. ) |
|---|
| 169 | zcoefv = ( REAL(jpjglo+1)*0.5 - REAL(jj+njmpp-1) ) / ( REAL(jpjglo+1)*0.5 - 1. ) |
|---|
| 170 | u_ice(ji,jj) = rn_uice * 1.5 * SIGN( 1., zcoefu ) * ABS( zcoefu ) * umask(ji,jj,1) |
|---|
| 171 | v_ice(ji,jj) = rn_vice * 1.5 * SIGN( 1., zcoefv ) * ABS( zcoefv ) * vmask(ji,jj,1) |
|---|
| 172 | END DO |
|---|
| 173 | END DO |
|---|
| 174 | ! --- |
|---|
| 175 | CALL ice_dyn_adv ( kt ) ! -- advection of ice |
|---|
| 176 | ! |
|---|
| 177 | CASE ( np_dynADV2D ) !== pure advection ==! (2D w prescribed velocities) |
|---|
| 178 | ! |
|---|
| 179 | u_ice(:,:) = rn_uice * umask(:,:,1) |
|---|
| 180 | v_ice(:,:) = rn_vice * vmask(:,:,1) |
|---|
| 181 | !CALL RANDOM_NUMBER(u_ice(:,:)) ; u_ice(:,:) = u_ice(:,:) * 0.1 + rn_uice * 0.9 * umask(:,:,1) |
|---|
| 182 | !CALL RANDOM_NUMBER(v_ice(:,:)) ; v_ice(:,:) = v_ice(:,:) * 0.1 + rn_vice * 0.9 * vmask(:,:,1) |
|---|
| 183 | ! --- |
|---|
| 184 | CALL ice_dyn_adv ( kt ) ! -- advection of ice |
|---|
| 185 | |
|---|
| 186 | END SELECT |
|---|
| 187 | ! |
|---|
| 188 | ! |
|---|
| 189 | ! diagnostics: divergence at T points |
|---|
| 190 | IF( iom_use('icediv') ) THEN |
|---|
| 191 | ! |
|---|
| 192 | SELECT CASE( nice_dyn ) |
|---|
| 193 | |
|---|
| 194 | CASE ( np_dynADV1D , np_dynADV2D ) |
|---|
| 195 | |
|---|
| 196 | ALLOCATE( zdivu_i(jpi,jpj) ) |
|---|
| 197 | DO jj = 2, jpjm1 |
|---|
| 198 | DO ji = 2, jpim1 |
|---|
| 199 | zdivu_i(ji,jj) = ( e2u(ji,jj) * u_ice(ji,jj) - e2u(ji-1,jj) * u_ice(ji-1,jj) & |
|---|
| 200 | & + e1v(ji,jj) * v_ice(ji,jj) - e1v(ji,jj-1) * v_ice(ji,jj-1) ) * r1_e1e2t(ji,jj) |
|---|
| 201 | END DO |
|---|
| 202 | END DO |
|---|
| 203 | CALL lbc_lnk( 'icedyn', zdivu_i, 'T', 1. ) |
|---|
| 204 | CALL iom_put( "icediv" , zdivu_i(:,:) ) |
|---|
| 205 | DEALLOCATE( zdivu_i ) |
|---|
| 206 | |
|---|
| 207 | END SELECT |
|---|
| 208 | ! |
|---|
| 209 | ENDIF |
|---|
| 210 | ! |
|---|
| 211 | ! controls |
|---|
| 212 | IF( ln_timing ) CALL timing_stop ('icedyn') |
|---|
| 213 | ! |
|---|
| 214 | END SUBROUTINE ice_dyn |
|---|
| 215 | |
|---|
| 216 | |
|---|
| 217 | SUBROUTINE Hpiling |
|---|
| 218 | !!------------------------------------------------------------------- |
|---|
| 219 | !! *** ROUTINE Hpiling *** |
|---|
| 220 | !! |
|---|
| 221 | !! ** Purpose : Simple conservative piling comparable with 1-cat models |
|---|
| 222 | !! |
|---|
| 223 | !! ** Method : pile-up ice when no ridging/rafting |
|---|
| 224 | !! |
|---|
| 225 | !! ** input : a_i |
|---|
| 226 | !!------------------------------------------------------------------- |
|---|
| 227 | INTEGER :: jl ! dummy loop indices |
|---|
| 228 | !!------------------------------------------------------------------- |
|---|
| 229 | ! controls |
|---|
| 230 | IF( ln_icediachk ) CALL ice_cons_hsm(0, 'Hpiling', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation |
|---|
| 231 | ! |
|---|
| 232 | at_i(:,:) = SUM( a_i(:,:,:), dim=3 ) |
|---|
| 233 | DO jl = 1, jpl |
|---|
| 234 | WHERE( at_i(:,:) > epsi20 ) |
|---|
| 235 | a_i(:,:,jl) = a_i(:,:,jl) * ( 1._wp + MIN( rn_amax_2d(:,:) - at_i(:,:) , 0._wp ) / at_i(:,:) ) |
|---|
| 236 | END WHERE |
|---|
| 237 | END DO |
|---|
| 238 | ! controls |
|---|
| 239 | IF( ln_icediachk ) CALL ice_cons_hsm(1, 'Hpiling', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft) ! conservation |
|---|
| 240 | ! |
|---|
| 241 | END SUBROUTINE Hpiling |
|---|
| 242 | |
|---|
| 243 | |
|---|
| 244 | SUBROUTINE ice_dyn_init |
|---|
| 245 | !!------------------------------------------------------------------- |
|---|
| 246 | !! *** ROUTINE ice_dyn_init *** |
|---|
| 247 | !! |
|---|
| 248 | !! ** Purpose : Physical constants and parameters linked to the ice |
|---|
| 249 | !! dynamics |
|---|
| 250 | !! |
|---|
| 251 | !! ** Method : Read the namdyn namelist and check the ice-dynamic |
|---|
| 252 | !! parameter values called at the first timestep (nit000) |
|---|
| 253 | !! |
|---|
| 254 | !! ** input : Namelist namdyn |
|---|
| 255 | !!------------------------------------------------------------------- |
|---|
| 256 | INTEGER :: ios, ioptio ! Local integer output status for namelist read |
|---|
| 257 | !! |
|---|
| 258 | NAMELIST/namdyn/ ln_dynALL, ln_dynRHGADV, ln_dynADV1D, ln_dynADV2D, rn_uice, rn_vice, & |
|---|
| 259 | & rn_ishlat , & |
|---|
| 260 | & ln_landfast_L16, ln_landfast_home, rn_depfra, rn_icebfr, rn_lfrelax, rn_tensile |
|---|
| 261 | !!------------------------------------------------------------------- |
|---|
| 262 | ! |
|---|
| 263 | REWIND( numnam_ice_ref ) ! Namelist namdyn in reference namelist : Ice dynamics |
|---|
| 264 | READ ( numnam_ice_ref, namdyn, IOSTAT = ios, ERR = 901) |
|---|
| 265 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn in reference namelist', lwp ) |
|---|
| 266 | REWIND( numnam_ice_cfg ) ! Namelist namdyn in configuration namelist : Ice dynamics |
|---|
| 267 | READ ( numnam_ice_cfg, namdyn, IOSTAT = ios, ERR = 902 ) |
|---|
| 268 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namdyn in configuration namelist', lwp ) |
|---|
| 269 | IF(lwm) WRITE( numoni, namdyn ) |
|---|
| 270 | ! |
|---|
| 271 | IF(lwp) THEN ! control print |
|---|
| 272 | WRITE(numout,*) |
|---|
| 273 | WRITE(numout,*) 'ice_dyn_init: ice parameters for ice dynamics ' |
|---|
| 274 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 275 | WRITE(numout,*) ' Namelist namdyn:' |
|---|
| 276 | WRITE(numout,*) ' Full ice dynamics (rhg + adv + ridge/raft + corr) ln_dynALL = ', ln_dynALL |
|---|
| 277 | WRITE(numout,*) ' No ridge/raft & No cor (rhg + adv) ln_dynRHGADV = ', ln_dynRHGADV |
|---|
| 278 | WRITE(numout,*) ' Advection 1D only (Schar & Smolarkiewicz 1996) ln_dynADV1D = ', ln_dynADV1D |
|---|
| 279 | WRITE(numout,*) ' Advection 2D only (rn_uvice + adv) ln_dynADV2D = ', ln_dynADV2D |
|---|
| 280 | WRITE(numout,*) ' with prescribed velocity given by (u,v)_ice = (rn_uice,rn_vice) = (', rn_uice,',',rn_vice,')' |
|---|
| 281 | WRITE(numout,*) ' lateral boundary condition for sea ice dynamics rn_ishlat = ', rn_ishlat |
|---|
| 282 | WRITE(numout,*) ' Landfast: param from Lemieux 2016 ln_landfast_L16 = ', ln_landfast_L16 |
|---|
| 283 | WRITE(numout,*) ' Landfast: param from home made ln_landfast_home= ', ln_landfast_home |
|---|
| 284 | WRITE(numout,*) ' fraction of ocean depth that ice must reach rn_depfra = ', rn_depfra |
|---|
| 285 | WRITE(numout,*) ' maximum bottom stress per unit area of contact rn_icebfr = ', rn_icebfr |
|---|
| 286 | WRITE(numout,*) ' relax time scale (s-1) to reach static friction rn_lfrelax = ', rn_lfrelax |
|---|
| 287 | WRITE(numout,*) ' isotropic tensile strength rn_tensile = ', rn_tensile |
|---|
| 288 | WRITE(numout,*) |
|---|
| 289 | ENDIF |
|---|
| 290 | ! !== set the choice of ice dynamics ==! |
|---|
| 291 | ioptio = 0 |
|---|
| 292 | ! !--- full dynamics (rheology + advection + ridging/rafting + correction) |
|---|
| 293 | IF( ln_dynALL ) THEN ; ioptio = ioptio + 1 ; nice_dyn = np_dynALL ; ENDIF |
|---|
| 294 | ! !--- dynamics without ridging/rafting and corr (rheology + advection) |
|---|
| 295 | IF( ln_dynRHGADV ) THEN ; ioptio = ioptio + 1 ; nice_dyn = np_dynRHGADV ; ENDIF |
|---|
| 296 | ! !--- advection 1D only - test case from Schar & Smolarkiewicz 1996 |
|---|
| 297 | IF( ln_dynADV1D ) THEN ; ioptio = ioptio + 1 ; nice_dyn = np_dynADV1D ; ENDIF |
|---|
| 298 | ! !--- advection 2D only with prescribed ice velocities (from namelist) |
|---|
| 299 | IF( ln_dynADV2D ) THEN ; ioptio = ioptio + 1 ; nice_dyn = np_dynADV2D ; ENDIF |
|---|
| 300 | ! |
|---|
| 301 | IF( ioptio /= 1 ) CALL ctl_stop( 'ice_dyn_init: one and only one ice dynamics option has to be defined ' ) |
|---|
| 302 | ! |
|---|
| 303 | ! !--- Lateral boundary conditions |
|---|
| 304 | IF ( rn_ishlat == 0. ) THEN ; IF(lwp) WRITE(numout,*) ' ===>>> ice lateral free-slip' |
|---|
| 305 | ELSEIF ( rn_ishlat == 2. ) THEN ; IF(lwp) WRITE(numout,*) ' ===>>> ice lateral no-slip' |
|---|
| 306 | ELSEIF ( 0. < rn_ishlat .AND. rn_ishlat < 2. ) THEN ; IF(lwp) WRITE(numout,*) ' ===>>> ice lateral partial-slip' |
|---|
| 307 | ELSEIF ( 2. < rn_ishlat ) THEN ; IF(lwp) WRITE(numout,*) ' ===>>> ice lateral strong-slip' |
|---|
| 308 | ENDIF |
|---|
| 309 | ! !--- Landfast ice |
|---|
| 310 | IF( .NOT.ln_landfast_L16 .AND. .NOT.ln_landfast_home ) tau_icebfr(:,:) = 0._wp |
|---|
| 311 | ! |
|---|
| 312 | IF ( ln_landfast_L16 .AND. ln_landfast_home ) THEN |
|---|
| 313 | CALL ctl_stop( 'ice_dyn_init: choose one and only one landfast parameterization (ln_landfast_L16 or ln_landfast_home)' ) |
|---|
| 314 | ENDIF |
|---|
| 315 | ! |
|---|
| 316 | CALL ice_dyn_rdgrft_init ! set ice ridging/rafting parameters |
|---|
| 317 | CALL ice_dyn_rhg_init ! set ice rheology parameters |
|---|
| 318 | CALL ice_dyn_adv_init ! set ice advection parameters |
|---|
| 319 | ! |
|---|
| 320 | END SUBROUTINE ice_dyn_init |
|---|
| 321 | |
|---|
| 322 | #else |
|---|
| 323 | !!---------------------------------------------------------------------- |
|---|
| 324 | !! Default option Empty module NO SI3 sea-ice model |
|---|
| 325 | !!---------------------------------------------------------------------- |
|---|
| 326 | #endif |
|---|
| 327 | |
|---|
| 328 | !!====================================================================== |
|---|
| 329 | END MODULE icedyn |
|---|
