New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dtauvd.F90 in NEMO/branches/UKMO/NEMO_4.0_mirror_text_diagnostics/src/OCE/C1D – NEMO

source: NEMO/branches/UKMO/NEMO_4.0_mirror_text_diagnostics/src/OCE/C1D/dtauvd.F90 @ 10986

Last change on this file since 10986 was 10986, checked in by andmirek, 5 years ago

GMED 462 add flush

File size: 11.5 KB
Line 
1MODULE dtauvd
2   !!======================================================================
3   !!                     ***  MODULE  dtauvd  ***
4   !! Ocean data  :  read ocean U & V current data from gridded data
5   !!======================================================================
6   !! History :  3.5  ! 2013-08  (D. Calvert)  Original code
7   !!----------------------------------------------------------------------
8
9   !!----------------------------------------------------------------------
10   !!   dta_uvd_init  : read namelist and allocate data structures
11   !!   dta_uvd       : read and time-interpolate ocean U & V current data
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and tracers
14   USE phycst         ! physical constants
15   USE dom_oce        ! ocean space and time domain
16   !
17   USE in_out_manager ! I/O manager
18   USE fldread        ! read input fields
19   USE lib_mpp        ! MPP library
20   USE timing         ! Timing
21
22   IMPLICIT NONE
23   PRIVATE
24
25   PUBLIC   dta_uvd_init   ! called by nemogcm.F90
26   PUBLIC   dta_uvd        ! called by istate.F90 and dyndmp.90
27
28   LOGICAL , PUBLIC ::   ln_uvd_init     ! Flag to initialise with U & V current data
29   LOGICAL , PUBLIC ::   ln_uvd_dyndmp   ! Flag for Newtonian damping toward U & V current data
30
31   TYPE(FLD), ALLOCATABLE, DIMENSION(:) ::   sf_uvd   ! structure for input U & V current (file information and data)
32
33   !!----------------------------------------------------------------------
34   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
35   !! $Id$
36   !! Software governed by the CeCILL license (see ./LICENSE)
37   !!----------------------------------------------------------------------
38CONTAINS
39
40   SUBROUTINE dta_uvd_init( ld_dyndmp )
41      !!----------------------------------------------------------------------
42      !!                   ***  ROUTINE dta_uvd_init  ***
43      !!                   
44      !! ** Purpose :   initialization of U & V current input data
45      !!
46      !! ** Method  : - read namc1d_uvd namelist
47      !!              - allocate U & V current data structure
48      !!              - fld_fill data structure with namelist information
49      !!----------------------------------------------------------------------
50      LOGICAL, INTENT(in), OPTIONAL ::   ld_dyndmp   ! force the initialization when dyndmp is used
51      !
52      INTEGER ::   ios, ierr0, ierr1, ierr2, ierr3     ! local integers
53      CHARACTER(len=100)        ::   cn_dir            ! Root directory for location of files to be used
54      TYPE(FLD_N), DIMENSION(2) ::   suv_i             ! Combined U & V namelist information
55      TYPE(FLD_N)               ::   sn_ucur, sn_vcur  ! U & V data namelist information
56      !!
57      NAMELIST/namc1d_uvd/ ln_uvd_init, ln_uvd_dyndmp, cn_dir, sn_ucur, sn_vcur
58      !!----------------------------------------------------------------------
59      !
60      ierr0 = 0   ;   ierr1 = 0   ;   ierr2 = 0  ;   ierr3 = 0
61
62      REWIND( numnam_ref )              ! Namelist namc1d_uvd in reference namelist :
63      READ  ( numnam_ref, namc1d_uvd, IOSTAT = ios, ERR = 901)
64901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namc1d_uvd in reference namelist', lwp )
65      !
66      REWIND( numnam_cfg )              ! Namelist namc1d_uvd in configuration namelist : Parameters of the run
67      READ  ( numnam_cfg, namc1d_uvd, IOSTAT = ios, ERR = 902 )
68902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namc1d_uvd in configuration namelist', lwp )
69      IF(lwm .AND. nprint > 2) WRITE ( numond, namc1d_uvd )
70
71      !                             ! force the initialization when dyndmp is used
72      IF( PRESENT( ld_dyndmp ) )   ln_uvd_dyndmp = .TRUE.
73     
74      IF(lwp) THEN                  ! control print
75         WRITE(numout,*)
76         WRITE(numout,*) 'dta_uvd_init : U & V current data '
77         WRITE(numout,*) '~~~~~~~~~~~~ '
78         WRITE(numout,*) '   Namelist namc1d_uvd : Set flags'
79         WRITE(numout,*) '      Initialization of ocean U & V current with input data   ln_uvd_init   = ', ln_uvd_init
80         WRITE(numout,*) '      Damping of ocean U & V current toward input data        ln_uvd_dyndmp = ', ln_uvd_dyndmp
81         WRITE(numout,*)
82         IF( .NOT. ln_uvd_init .AND. .NOT. ln_uvd_dyndmp ) THEN
83            WRITE(numout,*)
84            WRITE(numout,*) '   U & V current data not used'
85         ENDIF
86         IF(lflush) CALL FLUSH(numout)
87      ENDIF
88      !                             ! no initialization when restarting
89      IF( ln_rstart .AND. ln_uvd_init ) THEN
90         CALL ctl_warn( 'dta_uvd_init: ocean restart and U & V current data initialization, ',   &
91            &           'we keep the restart U & V current values and set ln_uvd_init to FALSE' )
92         ln_uvd_init = .FALSE.
93      ENDIF
94
95      !
96      IF(  ln_uvd_init .OR. ln_uvd_dyndmp  ) THEN
97         !                          !==   allocate the data arrays   ==!
98         ALLOCATE( sf_uvd(2), STAT=ierr0 )
99         IF( ierr0 > 0 ) THEN
100            CALL ctl_stop( 'dta_uvd_init: unable to allocate sf_uvd structure' )             ;   RETURN
101         ENDIF
102         !
103                                 ALLOCATE( sf_uvd(1)%fnow(jpi,jpj,jpk)   , STAT=ierr0 )
104         IF( sn_ucur%ln_tint )   ALLOCATE( sf_uvd(1)%fdta(jpi,jpj,jpk,2) , STAT=ierr1 )
105                                 ALLOCATE( sf_uvd(2)%fnow(jpi,jpj,jpk)   , STAT=ierr2 )
106         IF( sn_vcur%ln_tint )   ALLOCATE( sf_uvd(2)%fdta(jpi,jpj,jpk,2) , STAT=ierr3 )
107         !
108         IF( ierr0 + ierr1 + ierr2 + ierr3 > 0 ) THEN
109            CALL ctl_stop( 'dta_uvd_init : unable to allocate U & V current data arrays' )   ;   RETURN
110         ENDIF
111         !                          !==   fill sf_uvd with sn_ucur, sn_vcur and control print   ==!
112         suv_i(1) = sn_ucur   ;   suv_i(2) = sn_vcur
113         CALL fld_fill( sf_uvd, suv_i, cn_dir, 'dta_uvd', 'U & V current data', 'namc1d_uvd' )
114         !
115      ENDIF
116      !
117   END SUBROUTINE dta_uvd_init
118
119
120   SUBROUTINE dta_uvd( kt, puvd )
121      !!----------------------------------------------------------------------
122      !!                   ***  ROUTINE dta_uvd  ***
123      !!                   
124      !! ** Purpose :   provides U & V current data at time step kt
125      !!
126      !! ** Method  : - call fldread routine
127      !!              - ORCA_R2: make some hand made alterations to the data (EMPTY)
128      !!              - s- or mixed s-zps coordinate: vertical interpolation onto model mesh
129      !!              - zps coordinate: vertical interpolation onto last partial level
130      !!              - ln_uvd_dyndmp=False: deallocate the U & V current data structure,
131      !!                                     as the data is no longer used
132      !!
133      !! ** Action  :   puvd,  U & V current data interpolated onto model mesh at time-step kt
134      !!----------------------------------------------------------------------
135      INTEGER                           , INTENT(in   ) ::   kt     ! ocean time-step
136      REAL(wp), DIMENSION(jpi,jpj,jpk,2), INTENT(  out) ::   puvd   ! U & V current data
137      !
138      INTEGER ::   ji, jj, jk, jl, jkk               ! dummy loop indicies
139      INTEGER ::   ik, il0, il1, ii0, ii1, ij0, ij1  ! local integers
140      REAL(wp)::   zl, zi                            ! local floats
141      REAL(wp), ALLOCATABLE, DIMENSION(:) ::  zup, zvp   ! 1D workspace
142      !!----------------------------------------------------------------------
143      !
144      IF( ln_timing )   CALL timing_start('dta_uvd')
145      !
146      CALL fld_read( kt, 1, sf_uvd )      !==   read U & V current data at time step kt   ==!
147      !
148      puvd(:,:,:,1) = sf_uvd(1)%fnow(:,:,:)                 ! NO mask
149      puvd(:,:,:,2) = sf_uvd(2)%fnow(:,:,:) 
150      !
151      IF( ln_sco ) THEN                   !==   s- or mixed s-zps-coordinate   ==!
152         !
153         ALLOCATE( zup(jpk), zvp(jpk) )
154         !
155         IF( kt == nit000 .AND. lwp )THEN
156            WRITE(numout,*)
157            WRITE(numout,*) 'dta_uvd: interpolate U & V current data onto the s- or mixed s-z-coordinate mesh'
158            IF(lflush) CALL FLUSH(numout)
159         ENDIF
160         !
161         DO jj = 1, jpj                   ! vertical interpolation of U & V current:
162            DO ji = 1, jpi                ! determines the interpolated U & V current profiles at each (i,j) point
163               DO jk = 1, jpk
164                  zl = gdept_n(ji,jj,jk)
165                  IF    ( zl < gdept_1d(1  ) ) THEN          ! extrapolate above the first level of data
166                     zup(jk) =  puvd(ji,jj,1    ,1)
167                     zvp(jk) =  puvd(ji,jj,1    ,2)
168                  ELSEIF( zl > gdept_1d(jpk) ) THEN          ! extrapolate below the last level of data
169                     zup(jk) =  puvd(ji,jj,jpkm1,1)
170                     zvp(jk) =  puvd(ji,jj,jpkm1,2)
171                  ELSE                                      ! inbetween : vertical interpolation between jkk & jkk+1
172                     DO jkk = 1, jpkm1                      ! when  gdept(jkk) < zl < gdept(jkk+1)
173                        IF( (zl-gdept_1d(jkk)) * (zl-gdept_1d(jkk+1)) <= 0._wp ) THEN
174                           zi = ( zl - gdept_1d(jkk) ) / (gdept_1d(jkk+1)-gdept_1d(jkk))
175                           zup(jk) = puvd(ji,jj,jkk,1) + ( puvd(ji,jj,jkk+1,1 ) - puvd(ji,jj,jkk,1) ) * zi 
176                           zvp(jk) = puvd(ji,jj,jkk,2) + ( puvd(ji,jj,jkk+1,2 ) - puvd(ji,jj,jkk,2) ) * zi
177                        ENDIF
178                     END DO
179                  ENDIF
180               END DO
181               DO jk = 1, jpkm1           ! apply mask
182                  puvd(ji,jj,jk,1) = zup(jk) * umask(ji,jj,jk)
183                  puvd(ji,jj,jk,2) = zvp(jk) * vmask(ji,jj,jk)
184               END DO
185               puvd(ji,jj,jpk,1) = 0._wp
186               puvd(ji,jj,jpk,2) = 0._wp
187            END DO
188         END DO
189         !
190         DEALLOCATE( zup, zvp )
191         !
192      ELSE                                !==   z- or zps- coordinate   ==!
193         !                             
194         puvd(:,:,:,1) = puvd(:,:,:,1) * umask(:,:,:)       ! apply mask
195         puvd(:,:,:,2) = puvd(:,:,:,2) * vmask(:,:,:)
196         !
197         IF( ln_zps ) THEN                ! zps-coordinate (partial steps) interpolation at the last ocean level
198            DO jj = 1, jpj
199               DO ji = 1, jpi
200                  ik = mbkt(ji,jj) 
201                  IF( ik > 1 ) THEN
202                     zl = ( gdept_1d(ik) - gdept_0(ji,jj,ik) ) / ( gdept_1d(ik) - gdept_1d(ik-1) )
203                     puvd(ji,jj,ik,1) = (1.-zl) * puvd(ji,jj,ik,1) + zl * puvd(ji,jj,ik-1,1)
204                     puvd(ji,jj,ik,2) = (1.-zl) * puvd(ji,jj,ik,2) + zl * puvd(ji,jj,ik-1,2)
205                  ENDIF
206               END DO
207            END DO
208         ENDIF
209         !
210      ENDIF
211      !
212      IF( .NOT. ln_uvd_dyndmp    ) THEN   !==   deallocate U & V current structure   ==!
213         !                                !==   (data used only for initialization)  ==!
214         IF(lwp) THEN
215            WRITE(numout,*) 'dta_uvd: deallocate U & V current arrays as they are only used to initialize the run'
216            IF(lflush) CALL FLUSH(numout)
217         ENDIF
218                                   DEALLOCATE( sf_uvd(1)%fnow )     ! U current arrays in the structure
219         IF( sf_uvd(1)%ln_tint )   DEALLOCATE( sf_uvd(1)%fdta )
220                                   DEALLOCATE( sf_uvd(2)%fnow )     ! V current arrays in the structure
221         IF( sf_uvd(2)%ln_tint )   DEALLOCATE( sf_uvd(2)%fdta )
222                                   DEALLOCATE( sf_uvd         )     ! the structure itself
223      ENDIF
224      !
225      IF( ln_timing )   CALL timing_stop('dta_uvd')
226      !
227   END SUBROUTINE dta_uvd
228
229   !!======================================================================
230END MODULE dtauvd
Note: See TracBrowser for help on using the repository browser.