New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
diaharm.F90 in NEMO/branches/UKMO/NEMO_4.0_mirror_text_diagnostics/src/OCE/DIA – NEMO

source: NEMO/branches/UKMO/NEMO_4.0_mirror_text_diagnostics/src/OCE/DIA/diaharm.F90 @ 10986

Last change on this file since 10986 was 10986, checked in by andmirek, 5 years ago

GMED 462 add flush
File size: 19.1 KB
Line 
1MODULE diaharm 
2   !!======================================================================
3   !!                       ***  MODULE  diaharm  ***
4   !! Harmonic analysis of tidal constituents
5   !!======================================================================
6   !! History :  3.1  !  2007  (O. Le Galloudec, J. Chanut)  Original code
7   !!----------------------------------------------------------------------
8#if defined key_diaharm
9   !!----------------------------------------------------------------------
10   !!   'key_diaharm'
11   !!----------------------------------------------------------------------
12   USE oce             ! ocean dynamics and tracers variables
13   USE dom_oce         ! ocean space and time domain
14   USE phycst
15   USE daymod
16   USE tide_mod
17   USE sbctide         ! Tidal forcing or not
18   !
19   USE in_out_manager  ! I/O units
20   USE iom             ! I/0 library
21   USE ioipsl          ! NetCDF IPSL library
22   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
23   USE timing          ! preformance summary
24   USE lib_mpp           ! MPP library
25
26   IMPLICIT NONE
27   PRIVATE
28
29   LOGICAL, PUBLIC, PARAMETER :: lk_diaharm  = .TRUE.
30   
31   INTEGER, PARAMETER :: jpincomax    = 2.*jpmax_harmo
32   INTEGER, PARAMETER :: jpdimsparse  = jpincomax*300*24
33
34   !                         !!** namelist variables **
35   INTEGER ::   nit000_han    ! First time step used for harmonic analysis
36   INTEGER ::   nitend_han    ! Last time step used for harmonic analysis
37   INTEGER ::   nstep_han     ! Time step frequency for harmonic analysis
38   INTEGER ::   nb_ana        ! Number of harmonics to analyse
39
40   INTEGER , ALLOCATABLE, DIMENSION(:)       ::   name
41   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:,:) ::   ana_temp
42   REAL(wp), ALLOCATABLE, DIMENSION(:)       ::   ana_freq, ut   , vt   , ft
43   REAL(wp), ALLOCATABLE, DIMENSION(:,:,:)   ::   out_eta , out_u, out_v
44
45   INTEGER ::   ninco, nsparse
46   INTEGER ,       DIMENSION(jpdimsparse)         ::   njsparse, nisparse
47   INTEGER , SAVE, DIMENSION(jpincomax)           ::   ipos1
48   REAL(wp),       DIMENSION(jpdimsparse)         ::   valuesparse
49   REAL(wp),       DIMENSION(jpincomax)           ::   ztmp4 , ztmp7
50   REAL(wp), SAVE, DIMENSION(jpincomax,jpincomax) ::   ztmp3 , zpilier
51   REAL(wp), SAVE, DIMENSION(jpincomax)           ::   zpivot
52
53   CHARACTER (LEN=4), DIMENSION(jpmax_harmo) ::   tname   ! Names of tidal constituents ('M2', 'K1',...)
54
55   PUBLIC   dia_harm   ! routine called by step.F90
56
57   !!----------------------------------------------------------------------
58   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
59   !! $Id$
60   !! Software governed by the CeCILL license (see ./LICENSE)
61   !!----------------------------------------------------------------------
62CONTAINS
63
64   SUBROUTINE dia_harm_init 
65      !!----------------------------------------------------------------------
66      !!                 ***  ROUTINE dia_harm_init  ***
67      !!         
68      !! ** Purpose :   Initialization of tidal harmonic analysis
69      !!
70      !! ** Method  :   Initialize frequency array and  nodal factor for nit000_han
71      !!
72      !!--------------------------------------------------------------------
73      INTEGER :: jh, nhan, jk, ji
74      INTEGER ::   ios                 ! Local integer output status for namelist read
75
76      NAMELIST/nam_diaharm/ nit000_han, nitend_han, nstep_han, tname
77      !!----------------------------------------------------------------------
78
79      IF(lwp) THEN
80         WRITE(numout,*)
81         WRITE(numout,*) 'dia_harm_init: Tidal harmonic analysis initialization'
82         WRITE(numout,*) '~~~~~~~ '
83         IF(lflush) CALL FLUSH(numout)
84      ENDIF
85      !
86      IF( .NOT. ln_tide )   CALL ctl_stop( 'dia_harm_init : ln_tide must be true for harmonic analysis')
87      !
88      CALL tide_init_Wave
89      !
90      REWIND( numnam_ref )              ! Namelist nam_diaharm in reference namelist : Tidal harmonic analysis
91      READ  ( numnam_ref, nam_diaharm, IOSTAT = ios, ERR = 901)
92901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nam_diaharm in reference namelist', lwp )
93      REWIND( numnam_cfg )              ! Namelist nam_diaharm in configuration namelist : Tidal harmonic analysis
94      READ  ( numnam_cfg, nam_diaharm, IOSTAT = ios, ERR = 902 )
95902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nam_diaharm in configuration namelist', lwp )
96      IF(lwm .AND. nprint > 2) WRITE ( numond, nam_diaharm )
97      !
98      IF(lwp) THEN
99         WRITE(numout,*) 'First time step used for analysis:  nit000_han= ', nit000_han
100         WRITE(numout,*) 'Last  time step used for analysis:  nitend_han= ', nitend_han
101         WRITE(numout,*) 'Time step frequency for harmonic analysis:  nstep_han= ', nstep_han
102         IF(lflush) CALL FLUSH(numout)
103      ENDIF
104
105      ! Basic checks on harmonic analysis time window:
106      ! ----------------------------------------------
107      IF( nit000 > nit000_han )   CALL ctl_stop( 'dia_harm_init : nit000_han must be greater than nit000',   &
108         &                                       ' restart capability not implemented' )
109      IF( nitend < nitend_han )   CALL ctl_stop( 'dia_harm_init : nitend_han must be lower than nitend',   &
110         &                                       'restart capability not implemented' )
111
112      IF( MOD( nitend_han-nit000_han+1 , nstep_han ) /= 0 )   &
113         &                        CALL ctl_stop( 'dia_harm_init : analysis time span must be a multiple of nstep_han' )
114
115      nb_ana = 0
116      DO jk=1,jpmax_harmo
117         DO ji=1,jpmax_harmo
118            IF(TRIM(tname(jk)) == Wave(ji)%cname_tide) THEN
119               nb_ana=nb_ana+1
120            ENDIF
121         END DO
122      END DO
123      !
124      IF(lwp) THEN
125         WRITE(numout,*) '        Namelist nam_diaharm'
126         WRITE(numout,*) '        nb_ana    = ', nb_ana
127         IF(lflush) CALL FLUSH(numout)
128      ENDIF
129      !
130      IF (nb_ana > jpmax_harmo) THEN
131         WRITE(ctmp1,*) ' nb_ana must be lower than jpmax_harmo'
132         WRITE(ctmp2,*) ' jpmax_harmo= ', jpmax_harmo
133         CALL ctl_stop( 'dia_harm_init', ctmp1, ctmp2 )
134      ENDIF
135
136      ALLOCATE(name    (nb_ana))
137      DO jk=1,nb_ana
138       DO ji=1,jpmax_harmo
139          IF (TRIM(tname(jk)) ==  Wave(ji)%cname_tide) THEN
140             name(jk) = ji
141             EXIT
142          END IF
143       END DO
144      END DO
145
146      ! Initialize frequency array:
147      ! ---------------------------
148      ALLOCATE( ana_freq(nb_ana), ut(nb_ana), vt(nb_ana), ft(nb_ana) )
149
150      CALL tide_harmo( ana_freq, vt, ut, ft, name, nb_ana )
151
152      IF(lwp) THEN
153         WRITE(numout,*) 'Analysed frequency  : ',nb_ana ,'Frequency '
154         DO jh = 1, nb_ana
155            WRITE(numout,*) '                    : ',tname(jh),' ',ana_freq(jh)
156         END DO
157         IF(lflush) CALL FLUSH(numout)
158      ENDIF
159
160      ! Initialize temporary arrays:
161      ! ----------------------------
162      ALLOCATE( ana_temp(jpi,jpj,2*nb_ana,3) )
163      ana_temp(:,:,:,:) = 0._wp
164
165   END SUBROUTINE dia_harm_init
166
167
168   SUBROUTINE dia_harm ( kt )
169      !!----------------------------------------------------------------------
170      !!                 ***  ROUTINE dia_harm  ***
171      !!         
172      !! ** Purpose :   Tidal harmonic analysis main routine
173      !!
174      !! ** Action  :   Sums ssh/u/v over time analysis [nit000_han,nitend_han]
175      !!
176      !!--------------------------------------------------------------------
177      INTEGER, INTENT( IN ) :: kt
178      !
179      INTEGER  :: ji, jj, jh, jc, nhc
180      REAL(wp) :: ztime, ztemp
181      !!--------------------------------------------------------------------
182      IF( ln_timing )   CALL timing_start('dia_harm')
183      !
184      IF( kt == nit000 )   CALL dia_harm_init
185      !
186      IF( kt >= nit000_han .AND. kt <= nitend_han .AND. MOD(kt,nstep_han) == 0 ) THEN
187         !
188         ztime = (kt-nit000+1) * rdt 
189         !
190         nhc = 0
191         DO jh = 1, nb_ana
192            DO jc = 1, 2
193               nhc = nhc+1
194               ztemp =(     MOD(jc,2) * ft(jh) *COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))  &
195                  &    +(1.-MOD(jc,2))* ft(jh) *SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)))
196                  !
197               DO jj = 1,jpj
198                  DO ji = 1,jpi
199                     ! Elevation
200                     ana_temp(ji,jj,nhc,1) = ana_temp(ji,jj,nhc,1) + ztemp*sshn(ji,jj)*ssmask (ji,jj)       
201                     ana_temp(ji,jj,nhc,2) = ana_temp(ji,jj,nhc,2) + ztemp*un_b(ji,jj)*ssumask(ji,jj)
202                     ana_temp(ji,jj,nhc,3) = ana_temp(ji,jj,nhc,3) + ztemp*vn_b(ji,jj)*ssvmask(ji,jj)
203                  END DO
204               END DO
205               !
206            END DO
207         END DO
208         !       
209      END IF
210      !
211      IF( kt == nitend_han )   CALL dia_harm_end
212      !
213      IF( ln_timing )   CALL timing_stop('dia_harm')
214      !
215   END SUBROUTINE dia_harm
216
217
218   SUBROUTINE dia_harm_end
219      !!----------------------------------------------------------------------
220      !!                 ***  ROUTINE diaharm_end  ***
221      !!         
222      !! ** Purpose :  Compute the Real and Imaginary part of tidal constituents
223      !!
224      !! ** Action  :  Decompose the signal on the harmonic constituents
225      !!
226      !!--------------------------------------------------------------------
227      INTEGER :: ji, jj, jh, jc, jn, nhan, jl
228      INTEGER :: ksp, kun, keq
229      REAL(wp) :: ztime, ztime_ini, ztime_end
230      REAL(wp) :: X1, X2
231      REAL(wp), DIMENSION(jpi,jpj,jpmax_harmo,2) ::   ana_amp   ! workspace
232      !!--------------------------------------------------------------------
233      !
234      IF(lwp) THEN
235         WRITE(numout,*)
236         WRITE(numout,*) 'anharmo_end: kt=nitend_han: Perform harmonic analysis'
237         WRITE(numout,*) '~~~~~~~~~~~~'
238         IF(lflush) CALL FLUSH(numout)
239      ENDIF
240
241      ztime_ini = nit000_han*rdt                 ! Initial time in seconds at the beginning of analysis
242      ztime_end = nitend_han*rdt                 ! Final time in seconds at the end of analysis
243      nhan = (nitend_han-nit000_han+1)/nstep_han ! Number of dumps used for analysis
244
245      ninco = 2*nb_ana
246
247      ksp = 0
248      keq = 0       
249      DO jn = 1, nhan
250         ztime=( (nhan-jn)*ztime_ini + (jn-1)*ztime_end )/FLOAT(nhan-1)
251         keq = keq + 1
252         kun = 0
253         DO jh = 1, nb_ana
254            DO jc = 1, 2
255               kun = kun + 1
256               ksp = ksp + 1
257               nisparse(ksp) = keq
258               njsparse(ksp) = kun
259               valuesparse(ksp) = (   MOD(jc,2) * ft(jh) * COS(ana_freq(jh)*ztime + vt(jh) + ut(jh))   &
260                  &             + (1.-MOD(jc,2))* ft(jh) * SIN(ana_freq(jh)*ztime + vt(jh) + ut(jh)) )
261            END DO
262         END DO
263      END DO
264
265      nsparse = ksp
266
267      ! Elevation:
268      DO jj = 1, jpj
269         DO ji = 1, jpi
270            ! Fill input array
271            kun = 0
272            DO jh = 1, nb_ana
273               DO jc = 1, 2
274                  kun = kun + 1
275                  ztmp4(kun)=ana_temp(ji,jj,kun,1)
276               END DO
277            END DO
278
279            CALL SUR_DETERMINE(jj)
280
281            ! Fill output array
282            DO jh = 1, nb_ana
283               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
284               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
285            END DO
286         END DO
287      END DO
288
289      ALLOCATE( out_eta(jpi,jpj,2*nb_ana),   & 
290         &      out_u  (jpi,jpj,2*nb_ana),   &
291         &      out_v  (jpi,jpj,2*nb_ana)  )
292
293      DO jj = 1, jpj
294         DO ji = 1, jpi
295            DO jh = 1, nb_ana 
296               X1 = ana_amp(ji,jj,jh,1)
297               X2 =-ana_amp(ji,jj,jh,2)
298               out_eta(ji,jj,jh       ) = X1 * tmask_i(ji,jj)
299               out_eta(ji,jj,jh+nb_ana) = X2 * tmask_i(ji,jj)
300            END DO
301         END DO
302      END DO
303
304      ! ubar:
305      DO jj = 1, jpj
306         DO ji = 1, jpi
307            ! Fill input array
308            kun=0
309            DO jh = 1,nb_ana
310               DO jc = 1,2
311                  kun = kun + 1
312                  ztmp4(kun)=ana_temp(ji,jj,kun,2)
313               END DO
314            END DO
315
316            CALL SUR_DETERMINE(jj+1)
317
318            ! Fill output array
319            DO jh = 1, nb_ana
320               ana_amp(ji,jj,jh,1) = ztmp7((jh-1)*2+1)
321               ana_amp(ji,jj,jh,2) = ztmp7((jh-1)*2+2)
322            END DO
323
324         END DO
325      END DO
326
327      DO jj = 1, jpj
328         DO ji = 1, jpi
329            DO jh = 1, nb_ana 
330               X1= ana_amp(ji,jj,jh,1)
331               X2=-ana_amp(ji,jj,jh,2)
332               out_u(ji,jj,       jh) = X1 * ssumask(ji,jj)
333               out_u(ji,jj,nb_ana+jh) = X2 * ssumask(ji,jj)
334            ENDDO
335         ENDDO
336      ENDDO
337
338      ! vbar:
339      DO jj = 1, jpj
340         DO ji = 1, jpi
341            ! Fill input array
342            kun=0
343            DO jh = 1,nb_ana
344               DO jc = 1,2
345                  kun = kun + 1
346                  ztmp4(kun)=ana_temp(ji,jj,kun,3)
347               END DO
348            END DO
349
350            CALL SUR_DETERMINE(jj+1)
351
352            ! Fill output array
353            DO jh = 1, nb_ana
354               ana_amp(ji,jj,jh,1)=ztmp7((jh-1)*2+1)
355               ana_amp(ji,jj,jh,2)=ztmp7((jh-1)*2+2)
356            END DO
357
358         END DO
359      END DO
360
361      DO jj = 1, jpj
362         DO ji = 1, jpi
363            DO jh = 1, nb_ana 
364               X1=ana_amp(ji,jj,jh,1)
365               X2=-ana_amp(ji,jj,jh,2)
366               out_v(ji,jj,       jh)=X1 * ssvmask(ji,jj)
367               out_v(ji,jj,nb_ana+jh)=X2 * ssvmask(ji,jj)
368            END DO
369         END DO
370      END DO
371      !
372      CALL dia_wri_harm ! Write results in files
373      !
374   END SUBROUTINE dia_harm_end
375
376
377   SUBROUTINE dia_wri_harm
378      !!--------------------------------------------------------------------
379      !!                 ***  ROUTINE dia_wri_harm  ***
380      !!         
381      !! ** Purpose : Write tidal harmonic analysis results in a netcdf file
382      !!--------------------------------------------------------------------
383      CHARACTER(LEN=lc) :: cltext
384      CHARACTER(LEN=lc) ::   &
385         cdfile_name_T   ,   & ! name of the file created (T-points)
386         cdfile_name_U   ,   & ! name of the file created (U-points)
387         cdfile_name_V         ! name of the file created (V-points)
388      INTEGER  ::   jh
389      !!----------------------------------------------------------------------
390
391      IF(lwp) THEN
392         WRITE(numout,*) '  '
393         WRITE(numout,*) 'dia_wri_harm : Write harmonic analysis results'
394         WRITE(numout,*) '  '
395         IF(lflush) CALL FLUSH(numout)
396      ENDIF
397
398      ! A) Elevation
399      !/////////////
400      !
401      DO jh = 1, nb_ana
402      CALL iom_put( TRIM(tname(jh))//'x', out_eta(:,:,jh) )
403      CALL iom_put( TRIM(tname(jh))//'y', out_eta(:,:,nb_ana+jh) )
404      END DO
405
406      ! B) ubar
407      !/////////
408      !
409      DO jh = 1, nb_ana
410      CALL iom_put( TRIM(tname(jh))//'x_u', out_u(:,:,jh) )
411      CALL iom_put( TRIM(tname(jh))//'y_u', out_u(:,:,nb_ana+jh) )
412      END DO
413
414      ! C) vbar
415      !/////////
416      !
417      DO jh = 1, nb_ana
418         CALL iom_put( TRIM(tname(jh))//'x_v', out_v(:,:,jh       ) )
419         CALL iom_put( TRIM(tname(jh))//'y_v', out_v(:,:,jh+nb_ana) )
420      END DO
421      !
422   END SUBROUTINE dia_wri_harm
423
424
425   SUBROUTINE SUR_DETERMINE(init)
426      !!---------------------------------------------------------------------------------
427      !!                      *** ROUTINE SUR_DETERMINE ***
428      !!   
429      !!   
430      !!       
431      !!---------------------------------------------------------------------------------
432      INTEGER, INTENT(in) ::   init 
433      !
434      INTEGER                         :: ji_sd, jj_sd, ji1_sd, ji2_sd, jk1_sd, jk2_sd
435      REAL(wp)                        :: zval1, zval2, zx1
436      REAL(wp), DIMENSION(jpincomax) :: ztmpx, zcol1, zcol2
437      INTEGER , DIMENSION(jpincomax) :: ipos2, ipivot
438      !---------------------------------------------------------------------------------
439      !           
440      IF( init == 1 ) THEN
441         IF( nsparse > jpdimsparse )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : nsparse .GT. jpdimsparse')
442         IF( ninco   > jpincomax   )   CALL ctl_stop( 'STOP', 'SUR_DETERMINE : ninco .GT. jpincomax')
443         !
444         ztmp3(:,:) = 0._wp
445         !
446         DO jk1_sd = 1, nsparse
447            DO jk2_sd = 1, nsparse
448               nisparse(jk2_sd) = nisparse(jk2_sd)
449               njsparse(jk2_sd) = njsparse(jk2_sd)
450               IF( nisparse(jk2_sd) == nisparse(jk1_sd) ) THEN
451                  ztmp3(njsparse(jk1_sd),njsparse(jk2_sd)) = ztmp3(njsparse(jk1_sd),njsparse(jk2_sd))  &
452                     &                                     + valuesparse(jk1_sd)*valuesparse(jk2_sd)
453               ENDIF
454            END DO
455         END DO
456         !
457         DO jj_sd = 1 ,ninco
458            ipos1(jj_sd) = jj_sd
459            ipos2(jj_sd) = jj_sd
460         END DO
461         !
462         DO ji_sd = 1 , ninco
463            !
464            !find greatest non-zero pivot:
465            zval1 = ABS(ztmp3(ji_sd,ji_sd))
466            !
467            ipivot(ji_sd) = ji_sd
468            DO jj_sd = ji_sd, ninco
469               zval2 = ABS(ztmp3(ji_sd,jj_sd))
470               IF( zval2 >= zval1 )THEN
471                  ipivot(ji_sd) = jj_sd
472                  zval1         = zval2
473               ENDIF
474            END DO
475            !
476            DO ji1_sd = 1, ninco
477               zcol1(ji1_sd)               = ztmp3(ji1_sd,ji_sd)
478               zcol2(ji1_sd)               = ztmp3(ji1_sd,ipivot(ji_sd))
479               ztmp3(ji1_sd,ji_sd)         = zcol2(ji1_sd)
480               ztmp3(ji1_sd,ipivot(ji_sd)) = zcol1(ji1_sd)
481            END DO
482            !
483            ipos2(ji_sd)         = ipos1(ipivot(ji_sd))
484            ipos2(ipivot(ji_sd)) = ipos1(ji_sd)
485            ipos1(ji_sd)         = ipos2(ji_sd)
486            ipos1(ipivot(ji_sd)) = ipos2(ipivot(ji_sd))
487            zpivot(ji_sd)        = ztmp3(ji_sd,ji_sd)
488            DO jj_sd = 1, ninco
489               ztmp3(ji_sd,jj_sd) = ztmp3(ji_sd,jj_sd) / zpivot(ji_sd)
490            END DO
491            !
492            DO ji2_sd = ji_sd+1, ninco
493               zpilier(ji2_sd,ji_sd)=ztmp3(ji2_sd,ji_sd)
494               DO jj_sd=1,ninco
495                  ztmp3(ji2_sd,jj_sd)=  ztmp3(ji2_sd,jj_sd) - ztmp3(ji_sd,jj_sd) * zpilier(ji2_sd,ji_sd)
496               END DO
497            END DO
498            !
499         END DO
500         !
501      ENDIF ! End init==1
502
503      DO ji_sd = 1, ninco
504         ztmp4(ji_sd) = ztmp4(ji_sd) / zpivot(ji_sd)
505         DO ji2_sd = ji_sd+1, ninco
506            ztmp4(ji2_sd) = ztmp4(ji2_sd) - ztmp4(ji_sd) * zpilier(ji2_sd,ji_sd)
507         END DO
508      END DO
509
510      !system solving:
511      ztmpx(ninco) = ztmp4(ninco) / ztmp3(ninco,ninco)
512      ji_sd = ninco
513      DO ji_sd = ninco-1, 1, -1
514         zx1 = 0._wp
515         DO jj_sd = ji_sd+1, ninco
516            zx1 = zx1 + ztmpx(jj_sd) * ztmp3(ji_sd,jj_sd)
517         END DO
518         ztmpx(ji_sd) = ztmp4(ji_sd)-zx1
519      END DO
520
521      DO jj_sd =1, ninco
522         ztmp7(ipos1(jj_sd))=ztmpx(jj_sd)
523      END DO
524      !
525   END SUBROUTINE SUR_DETERMINE
526
527#else
528   !!----------------------------------------------------------------------
529   !!   Default case :   Empty module
530   !!----------------------------------------------------------------------
531   LOGICAL, PUBLIC, PARAMETER ::   lk_diaharm = .FALSE.
532CONTAINS
533   SUBROUTINE dia_harm ( kt )     ! Empty routine
534      INTEGER, INTENT( IN ) :: kt 
535      WRITE(*,*) 'dia_harm: you should not have seen this print'
536   END SUBROUTINE dia_harm
537#endif
538
539   !!======================================================================
540END MODULE diaharm
Note: See TracBrowser for help on using the repository browser.