New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
ldftra.F90 in NEMO/branches/UKMO/NEMO_4.0_mirror_text_diagnostics/src/OCE/LDF – NEMO

source: NEMO/branches/UKMO/NEMO_4.0_mirror_text_diagnostics/src/OCE/LDF/ldftra.F90 @ 10986

Last change on this file since 10986 was 10986, checked in by andmirek, 5 years ago

GMED 462 add flush
File size: 53.5 KB
Line 
1MODULE ldftra
2   !!======================================================================
3   !!                       ***  MODULE  ldftra  ***
4   !! Ocean physics:  lateral diffusivity coefficients
5   !!=====================================================================
6   !! History :       ! 1997-07  (G. Madec)  from inimix.F split in 2 routines
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            2.0  ! 2005-11  (G. Madec) 
9   !!            3.7  ! 2013-12  (F. Lemarie, G. Madec)  restructuration/simplification of aht/aeiv specification,
10   !!                 !                                  add velocity dependent coefficient and optional read in file
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   ldf_tra_init : initialization, namelist read, and parameters control
15   !!   ldf_tra      : update lateral eddy diffusivity coefficients at each time step
16   !!   ldf_eiv_init : initialization of the eiv coeff. from namelist choices
17   !!   ldf_eiv      : time evolution of the eiv coefficients (function of the growth rate of baroclinic instability)
18   !!   ldf_eiv_trp  : add to the input ocean transport the contribution of the EIV parametrization
19   !!   ldf_eiv_dia  : diagnose the eddy induced velocity from the eiv streamfunction
20   !!----------------------------------------------------------------------
21   USE oce             ! ocean dynamics and tracers
22   USE dom_oce         ! ocean space and time domain
23   USE phycst          ! physical constants
24   USE ldfslp          ! lateral diffusion: slope of iso-neutral surfaces
25   USE ldfc1d_c2d      ! lateral diffusion: 1D & 2D cases
26   USE diaptr
27   !
28   USE in_out_manager  ! I/O manager
29   USE iom             ! I/O module for ehanced bottom friction file
30   USE lib_mpp         ! distribued memory computing library
31   USE lbclnk          ! ocean lateral boundary conditions (or mpp link)
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   ldf_tra_init   ! called by nemogcm.F90
37   PUBLIC   ldf_tra        ! called by step.F90
38   PUBLIC   ldf_eiv_init   ! called by nemogcm.F90
39   PUBLIC   ldf_eiv        ! called by step.F90
40   PUBLIC   ldf_eiv_trp    ! called by traadv.F90
41   PUBLIC   ldf_eiv_dia    ! called by traldf_iso and traldf_iso_triad.F90
42   
43   !                                   !!* Namelist namtra_ldf : lateral mixing on tracers *
44   !                                    != Operator type =!
45   LOGICAL , PUBLIC ::   ln_traldf_OFF       !: no operator: No explicit diffusion
46   LOGICAL , PUBLIC ::   ln_traldf_lap       !: laplacian operator
47   LOGICAL , PUBLIC ::   ln_traldf_blp       !: bilaplacian operator
48   !                                    != Direction of action =!
49   LOGICAL , PUBLIC ::   ln_traldf_lev       !: iso-level direction
50   LOGICAL , PUBLIC ::   ln_traldf_hor       !: horizontal (geopotential) direction
51!  LOGICAL , PUBLIC ::   ln_traldf_iso       !: iso-neutral direction                    (see ldfslp)
52   !                                    != iso-neutral options =!
53!  LOGICAL , PUBLIC ::   ln_traldf_triad     !: griffies triad scheme                    (see ldfslp)
54   LOGICAL , PUBLIC ::   ln_traldf_msc       !: Method of Stabilizing Correction
55!  LOGICAL , PUBLIC ::   ln_triad_iso        !: pure horizontal mixing in ML             (see ldfslp)
56!  LOGICAL , PUBLIC ::   ln_botmix_triad     !: mixing on bottom                         (see ldfslp)
57!  REAL(wp), PUBLIC ::   rn_sw_triad         !: =1/0 switching triad / all 4 triads used (see ldfslp)
58!  REAL(wp), PUBLIC ::   rn_slpmax           !: slope limit                              (see ldfslp)
59   !                                    !=  Coefficients =!
60   INTEGER , PUBLIC ::   nn_aht_ijk_t        !: choice of time & space variations of the lateral eddy diffusivity coef.
61   !                                            !  time invariant coefficients:  aht_0 = 1/2  Ud*Ld   (lap case)
62   !                                            !                                bht_0 = 1/12 Ud*Ld^3 (blp case)
63   REAL(wp), PUBLIC ::      rn_Ud               !: lateral diffusive velocity  [m/s]
64   REAL(wp), PUBLIC ::      rn_Ld               !: lateral diffusive length    [m]
65
66   !                                   !!* Namelist namtra_eiv : eddy induced velocity param. *
67   !                                    != Use/diagnose eiv =!
68   LOGICAL , PUBLIC ::   ln_ldfeiv           !: eddy induced velocity flag
69   LOGICAL , PUBLIC ::   ln_ldfeiv_dia       !: diagnose & output eiv streamfunction and velocity (IOM)
70   !                                    != Coefficients =!
71   INTEGER , PUBLIC ::   nn_aei_ijk_t        !: choice of time/space variation of the eiv coeff.
72   REAL(wp), PUBLIC ::      rn_Ue               !: lateral diffusive velocity  [m/s]
73   REAL(wp), PUBLIC ::      rn_Le               !: lateral diffusive length    [m]
74   
75   !                                  ! Flag to control the type of lateral diffusive operator
76   INTEGER, PARAMETER, PUBLIC ::   np_ERROR  =-10   ! error in specification of lateral diffusion
77   INTEGER, PARAMETER, PUBLIC ::   np_no_ldf = 00   ! without operator (i.e. no lateral diffusive trend)
78   !                          !!      laplacian     !    bilaplacian    !
79   INTEGER, PARAMETER, PUBLIC ::   np_lap    = 10   ,   np_blp    = 20  ! iso-level operator
80   INTEGER, PARAMETER, PUBLIC ::   np_lap_i  = 11   ,   np_blp_i  = 21  ! standard iso-neutral or geopotential operator
81   INTEGER, PARAMETER, PUBLIC ::   np_lap_it = 12   ,   np_blp_it = 22  ! triad    iso-neutral or geopotential operator
82
83   INTEGER , PUBLIC ::   nldf_tra      = 0         !: type of lateral diffusion used defined from ln_traldf_... (namlist logicals)
84   LOGICAL , PUBLIC ::   l_ldftra_time = .FALSE.   !: flag for time variation of the lateral eddy diffusivity coef.
85   LOGICAL , PUBLIC ::   l_ldfeiv_time = .FALSE.   !: flag for time variation of the eiv coef.
86
87   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   ahtu, ahtv   !: eddy diffusivity coef. at U- and V-points   [m2/s]
88   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   aeiu, aeiv   !: eddy induced velocity coeff.                [m2/s]
89
90   REAL(wp) ::   aht0, aei0               ! constant eddy coefficients (deduced from namelist values)                     [m2/s]
91   REAL(wp) ::   r1_2  = 0.5_wp           ! =1/2
92   REAL(wp) ::   r1_4  = 0.25_wp          ! =1/4
93   REAL(wp) ::   r1_12 = 1._wp / 12._wp   ! =1/12
94
95   !! * Substitutions
96#  include "vectopt_loop_substitute.h90"
97   !!----------------------------------------------------------------------
98   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
99   !! $Id$
100   !! Software governed by the CeCILL license (see ./LICENSE)
101   !!----------------------------------------------------------------------
102CONTAINS
103
104   SUBROUTINE ldf_tra_init
105      !!----------------------------------------------------------------------
106      !!                  ***  ROUTINE ldf_tra_init  ***
107      !!
108      !! ** Purpose :   initializations of the tracer lateral mixing coeff.
109      !!
110      !! ** Method  : * the eddy diffusivity coef. specification depends on:
111      !!
112      !!    ln_traldf_lap = T     laplacian operator
113      !!    ln_traldf_blp = T   bilaplacian operator
114      !!
115      !!    nn_aht_ijk_t  =  0 => = constant
116      !!                  !
117      !!                  = 10 => = F(z) : constant with a reduction of 1/4 with depth
118      !!                  !
119      !!                  =-20 => = F(i,j)   = shape read in 'eddy_diffusivity.nc' file
120      !!                  = 20    = F(i,j)   = F(e1,e2) or F(e1^3,e2^3) (lap or bilap case)
121      !!                  = 21    = F(i,j,t) = F(growth rate of baroclinic instability)
122      !!                  !
123      !!                  =-30 => = F(i,j,k)   = shape read in 'eddy_diffusivity.nc' file
124      !!                  = 30    = F(i,j,k)   = 2D (case 20) + decrease with depth (case 10)
125      !!                  = 31    = F(i,j,k,t) = F(local velocity) (  1/2  |u|e     laplacian operator
126      !!                                                           or 1/12 |u|e^3 bilaplacian operator )
127      !!              * initialisation of the eddy induced velocity coefficient by a call to ldf_eiv_init
128      !!           
129      !! ** action  : ahtu, ahtv initialized one for all or l_ldftra_time set to true
130      !!              aeiu, aeiv initialized one for all or l_ldfeiv_time set to true
131      !!----------------------------------------------------------------------
132      INTEGER  ::   jk                             ! dummy loop indices
133      INTEGER  ::   ioptio, ierr, inum, ios, inn   ! local integer
134      REAL(wp) ::   zah_max, zUfac                 !   -      -
135      CHARACTER(len=5) ::   cl_Units               ! units (m2/s or m4/s)
136      !!
137      NAMELIST/namtra_ldf/ ln_traldf_OFF, ln_traldf_lap  , ln_traldf_blp  ,   &   ! type of operator
138         &                 ln_traldf_lev, ln_traldf_hor  , ln_traldf_triad,   &   ! acting direction of the operator
139         &                 ln_traldf_iso, ln_traldf_msc  ,  rn_slpmax     ,   &   ! option for iso-neutral operator
140         &                 ln_triad_iso , ln_botmix_triad, rn_sw_triad    ,   &   ! option for triad operator
141         &                 nn_aht_ijk_t , rn_Ud          , rn_Ld                  ! lateral eddy coefficient
142      !!----------------------------------------------------------------------
143      !
144      IF(lwp) THEN                      ! control print
145         WRITE(numout,*)
146         WRITE(numout,*) 'ldf_tra_init : lateral tracer diffusion'
147         WRITE(numout,*) '~~~~~~~~~~~~ '
148         IF(lflush) CALL FLUSH(numout)
149      ENDIF
150     
151      !
152      !  Choice of lateral tracer physics
153      ! =================================
154      !
155      REWIND( numnam_ref )              ! Namelist namtra_ldf in reference namelist : Lateral physics on tracers
156      READ  ( numnam_ref, namtra_ldf, IOSTAT = ios, ERR = 901)
157901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_ldf in reference namelist', lwp )
158      REWIND( numnam_cfg )              ! Namelist namtra_ldf in configuration namelist : Lateral physics on tracers
159      READ  ( numnam_cfg, namtra_ldf, IOSTAT = ios, ERR = 902 )
160902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_ldf in configuration namelist', lwp )
161      IF(lwm .AND. nprint > 2) WRITE( numond, namtra_ldf )
162      !
163      IF(lwp) THEN                      ! control print
164         WRITE(numout,*) '   Namelist : namtra_ldf --- lateral mixing parameters (type, direction, coefficients)'
165         WRITE(numout,*) '      type :'
166         WRITE(numout,*) '         no explicit diffusion                   ln_traldf_OFF   = ', ln_traldf_OFF
167         WRITE(numout,*) '         laplacian operator                      ln_traldf_lap   = ', ln_traldf_lap
168         WRITE(numout,*) '         bilaplacian operator                    ln_traldf_blp   = ', ln_traldf_blp
169         WRITE(numout,*) '      direction of action :'
170         WRITE(numout,*) '         iso-level                               ln_traldf_lev   = ', ln_traldf_lev
171         WRITE(numout,*) '         horizontal (geopotential)               ln_traldf_hor   = ', ln_traldf_hor
172         WRITE(numout,*) '         iso-neutral Madec operator              ln_traldf_iso   = ', ln_traldf_iso
173         WRITE(numout,*) '         iso-neutral triad operator              ln_traldf_triad = ', ln_traldf_triad
174         WRITE(numout,*) '            use the Method of Stab. Correction   ln_traldf_msc   = ', ln_traldf_msc
175         WRITE(numout,*) '            maximum isoppycnal slope             rn_slpmax       = ', rn_slpmax
176         WRITE(numout,*) '            pure lateral mixing in ML            ln_triad_iso    = ', ln_triad_iso
177         WRITE(numout,*) '            switching triad or not               rn_sw_triad     = ', rn_sw_triad
178         WRITE(numout,*) '            lateral mixing on bottom             ln_botmix_triad = ', ln_botmix_triad
179         WRITE(numout,*) '      coefficients :'
180         WRITE(numout,*) '         type of time-space variation            nn_aht_ijk_t    = ', nn_aht_ijk_t
181         WRITE(numout,*) '            lateral diffusive velocity (if cst)  rn_Ud           = ', rn_Ud, ' m/s'
182         WRITE(numout,*) '            lateral diffusive length   (if cst)  rn_Ld           = ', rn_Ld, ' m'
183         IF(lflush) CALL FLUSH(numout)
184      ENDIF
185      !
186      !
187      ! Operator and its acting direction   (set nldf_tra) 
188      ! =================================
189      !
190      nldf_tra = np_ERROR
191      ioptio   = 0
192      IF( ln_traldf_OFF ) THEN   ;   nldf_tra = np_no_ldf   ;   ioptio = ioptio + 1   ;   ENDIF
193      IF( ln_traldf_lap ) THEN   ;                              ioptio = ioptio + 1   ;   ENDIF
194      IF( ln_traldf_blp ) THEN   ;                              ioptio = ioptio + 1   ;   ENDIF
195      IF( ioptio /=  1  )   CALL ctl_stop( 'tra_ldf_init: use ONE of the 3 operator options (NONE/lap/blp)' )
196      !
197      IF( .NOT.ln_traldf_OFF ) THEN    !==  direction ==>> type of operator  ==!
198         ioptio = 0
199         IF( ln_traldf_lev   )   ioptio = ioptio + 1
200         IF( ln_traldf_hor   )   ioptio = ioptio + 1
201         IF( ln_traldf_iso   )   ioptio = ioptio + 1
202         IF( ln_traldf_triad )   ioptio = ioptio + 1
203         IF( ioptio /=  1  )   CALL ctl_stop( 'tra_ldf_init: use ONE direction (level/hor/iso/triad)' )
204         !
205         !                                ! defined the type of lateral diffusion from ln_traldf_... logicals
206         ierr = 0
207         IF ( ln_traldf_lap ) THEN        ! laplacian operator
208            IF ( ln_zco ) THEN                  ! z-coordinate
209               IF ( ln_traldf_lev   )   nldf_tra = np_lap     ! iso-level = horizontal (no rotation)
210               IF ( ln_traldf_hor   )   nldf_tra = np_lap     ! iso-level = horizontal (no rotation)
211               IF ( ln_traldf_iso   )   nldf_tra = np_lap_i   ! iso-neutral: standard  (   rotation)
212               IF ( ln_traldf_triad )   nldf_tra = np_lap_it  ! iso-neutral: triad     (   rotation)
213            ENDIF
214            IF ( ln_zps ) THEN                  ! z-coordinate with partial step
215               IF ( ln_traldf_lev   )   ierr     = 1          ! iso-level not allowed
216               IF ( ln_traldf_hor   )   nldf_tra = np_lap     ! horizontal             (no rotation)
217               IF ( ln_traldf_iso   )   nldf_tra = np_lap_i   ! iso-neutral: standard     (rotation)
218               IF ( ln_traldf_triad )   nldf_tra = np_lap_it  ! iso-neutral: triad        (rotation)
219            ENDIF
220            IF ( ln_sco ) THEN                  ! s-coordinate
221               IF ( ln_traldf_lev   )   nldf_tra = np_lap     ! iso-level              (no rotation)
222               IF ( ln_traldf_hor   )   nldf_tra = np_lap_i   ! horizontal             (   rotation)
223               IF ( ln_traldf_iso   )   nldf_tra = np_lap_i   ! iso-neutral: standard  (   rotation)
224               IF ( ln_traldf_triad )   nldf_tra = np_lap_it  ! iso-neutral: triad     (   rotation)
225            ENDIF
226         ENDIF
227         !
228         IF( ln_traldf_blp ) THEN         ! bilaplacian operator
229            IF ( ln_zco ) THEN                  ! z-coordinate
230               IF ( ln_traldf_lev   )   nldf_tra = np_blp     ! iso-level = horizontal (no rotation)
231               IF ( ln_traldf_hor   )   nldf_tra = np_blp     ! iso-level = horizontal (no rotation)
232               IF ( ln_traldf_iso   )   nldf_tra = np_blp_i   ! iso-neutral: standard  (   rotation)
233               IF ( ln_traldf_triad )   nldf_tra = np_blp_it  ! iso-neutral: triad     (   rotation)
234            ENDIF
235            IF ( ln_zps ) THEN                  ! z-coordinate with partial step
236               IF ( ln_traldf_lev   )   ierr     = 1          ! iso-level not allowed
237               IF ( ln_traldf_hor   )   nldf_tra = np_blp     ! horizontal             (no rotation)
238               IF ( ln_traldf_iso   )   nldf_tra = np_blp_i   ! iso-neutral: standard  (   rotation)
239               IF ( ln_traldf_triad )   nldf_tra = np_blp_it  ! iso-neutral: triad     (   rotation)
240            ENDIF
241            IF ( ln_sco ) THEN                  ! s-coordinate
242               IF ( ln_traldf_lev   )   nldf_tra = np_blp     ! iso-level              (no rotation)
243               IF ( ln_traldf_hor   )   nldf_tra = np_blp_it  ! horizontal             (   rotation)
244               IF ( ln_traldf_iso   )   nldf_tra = np_blp_i   ! iso-neutral: standard  (   rotation)
245               IF ( ln_traldf_triad )   nldf_tra = np_blp_it  ! iso-neutral: triad     (   rotation)
246            ENDIF
247         ENDIF
248         IF ( ierr == 1 )   CALL ctl_stop( 'iso-level in z-partial step, not allowed' )
249      ENDIF
250      !
251      IF( ln_ldfeiv .AND. .NOT.( ln_traldf_iso .OR. ln_traldf_triad ) )                &
252           &            CALL ctl_stop( 'ln_ldfeiv=T requires iso-neutral laplacian diffusion' )
253      IF( ln_isfcav .AND. ln_traldf_triad ) &
254           &            CALL ctl_stop( ' ice shelf cavity and traldf_triad not tested' )
255           !
256      IF(  nldf_tra == np_lap_i .OR. nldf_tra == np_lap_it .OR. &
257         & nldf_tra == np_blp_i .OR. nldf_tra == np_blp_it  )   l_ldfslp = .TRUE.    ! slope of neutral surfaces required
258      !
259      IF( ln_traldf_blp .AND. ( ln_traldf_iso .OR. ln_traldf_triad) ) THEN     ! iso-neutral bilaplacian need MSC
260         IF( .NOT.ln_traldf_msc )   CALL ctl_stop( 'tra_ldf_init: iso-neutral bilaplacian requires ln_traldf_msc=.true.' )
261      ENDIF
262      !
263      IF(lwp) THEN
264         WRITE(numout,*)
265         SELECT CASE( nldf_tra )
266         CASE( np_no_ldf )   ;   WRITE(numout,*) '   ==>>>   NO lateral diffusion'
267         CASE( np_lap    )   ;   WRITE(numout,*) '   ==>>>   laplacian iso-level operator'
268         CASE( np_lap_i  )   ;   WRITE(numout,*) '   ==>>>   Rotated laplacian operator (standard)'
269         CASE( np_lap_it )   ;   WRITE(numout,*) '   ==>>>   Rotated laplacian operator (triad)'
270         CASE( np_blp    )   ;   WRITE(numout,*) '   ==>>>   bilaplacian iso-level operator'
271         CASE( np_blp_i  )   ;   WRITE(numout,*) '   ==>>>   Rotated bilaplacian operator (standard)'
272         CASE( np_blp_it )   ;   WRITE(numout,*) '   ==>>>   Rotated bilaplacian operator (triad)'
273         END SELECT
274         WRITE(numout,*)
275         IF(lflush) CALL FLUSH(numout)
276      ENDIF
277
278      !
279      !  Space/time variation of eddy coefficients
280      ! ===========================================
281      !
282      l_ldftra_time = .FALSE.                ! no time variation except in case defined below
283      !
284      IF( ln_traldf_OFF ) THEN               !== no explicit diffusive operator  ==!
285         !
286         IF(lwp) THEN
287            WRITE(numout,*) '   ==>>>   No diffusive operator selected. ahtu and ahtv are not allocated'
288            IF(lflush) CALL FLUSH(numout)
289         ENDIF
290         RETURN
291         !
292      ELSE                                   !==  a lateral diffusion operator is used  ==!
293         !
294         !                                         ! allocate the aht arrays
295         ALLOCATE( ahtu(jpi,jpj,jpk) , ahtv(jpi,jpj,jpk) , STAT=ierr )
296         IF( ierr /= 0 )   CALL ctl_stop( 'STOP', 'ldf_tra_init: failed to allocate arrays')
297         !
298         ahtu(:,:,jpk) = 0._wp                     ! last level always 0 
299         ahtv(:,:,jpk) = 0._wp
300         !.
301         !                                         ! value of lap/blp eddy mixing coef.
302         IF(     ln_traldf_lap ) THEN   ;   zUfac = r1_2 *rn_Ud   ;   inn = 1   ;   cl_Units = ' m2/s'   !   laplacian
303         ELSEIF( ln_traldf_blp ) THEN   ;   zUfac = r1_12*rn_Ud   ;   inn = 3   ;   cl_Units = ' m4/s'   ! bilaplacian
304         ENDIF
305         aht0    = zUfac *    rn_Ld**inn              ! mixing coefficient
306         zah_max = zUfac * (ra*rad)**inn              ! maximum reachable coefficient (value at the Equator for e1=1 degree)
307         !
308         !
309         SELECT CASE(  nn_aht_ijk_t  )             !* Specification of space-time variations of ahtu, ahtv
310         !
311         CASE(   0  )      !==  constant  ==!
312            IF(lwp) THEN
313               WRITE(numout,*) '   ==>>>   eddy diffusivity = constant = ', aht0, cl_Units
314               IF(lflush) CALL FLUSH(numout)
315            ENDIF
316            ahtu(:,:,1:jpkm1) = aht0
317            ahtv(:,:,1:jpkm1) = aht0
318            !
319         CASE(  10  )      !==  fixed profile  ==!
320            IF(lwp) THEN
321               WRITE(numout,*) '   ==>>>   eddy diffusivity = F( depth )'
322               WRITE(numout,*) '           surface eddy diffusivity = constant = ', aht0, cl_Units
323               IF(lflush) CALL FLUSH(numout)
324            ENDIF
325            ahtu(:,:,1) = aht0                        ! constant surface value
326            ahtv(:,:,1) = aht0
327            CALL ldf_c1d( 'TRA', ahtu(:,:,1), ahtv(:,:,1), ahtu, ahtv )
328            !
329         CASE ( -20 )      !== fixed horizontal shape and magnitude read in file  ==!
330            IF(lwp) THEN
331               WRITE(numout,*) '   ==>>>   eddy diffusivity = F(i,j) read in eddy_diffusivity.nc file'
332               IF(lflush) CALL FLUSH(numout)
333            ENDIF
334            CALL iom_open( 'eddy_diffusivity_2D.nc', inum )
335            CALL iom_get ( inum, jpdom_data, 'ahtu_2D', ahtu(:,:,1) )
336            CALL iom_get ( inum, jpdom_data, 'ahtv_2D', ahtv(:,:,1) )
337            CALL iom_close( inum )
338            DO jk = 2, jpkm1
339               ahtu(:,:,jk) = ahtu(:,:,1)
340               ahtv(:,:,jk) = ahtv(:,:,1)
341            END DO
342            !
343         CASE(  20  )      !== fixed horizontal shape  ==!
344            IF(lwp) THEN
345               WRITE(numout,*) '   ==>>>   eddy diffusivity = F( e1, e2 ) or F( e1^3, e2^3 ) (lap or blp case)'
346               WRITE(numout,*) '           using a fixed diffusive velocity = ', rn_Ud,' m/s   and   Ld = Max(e1,e2)'
347               WRITE(numout,*) '           maximum reachable coefficient (at the Equator) = ', zah_max, cl_Units, '  for e1=1°)'
348               IF(lflush) CALL FLUSH(numout)
349            ENDIF
350            CALL ldf_c2d( 'TRA', zUfac      , inn        , ahtu, ahtv )    ! value proportional to scale factor^inn
351            !
352         CASE(  21  )      !==  time varying 2D field  ==!
353            IF(lwp) THEN
354               WRITE(numout,*) '   ==>>>   eddy diffusivity = F( latitude, longitude, time )'
355               WRITE(numout,*) '                            = F( growth rate of baroclinic instability )'
356               WRITE(numout,*) '            min value = 0.2 * aht0 (with aht0= 1/2 rn_Ud*rn_Ld)'
357               WRITE(numout,*) '            max value =       aei0 (with aei0=1/2 rn_Ue*Le  increased to aht0 within 20N-20S'
358               IF(lflush) CALL FLUSH(numout)
359            ENDIF
360            !
361            l_ldftra_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
362            !
363            IF( ln_traldf_blp )   CALL ctl_stop( 'ldf_tra_init: aht=F( growth rate of baroc. insta .)',   &
364               &                                 '              incompatible with bilaplacian operator' )
365            !
366         CASE( -30  )      !== fixed 3D shape read in file  ==!
367            IF(lwp) THEN
368               WRITE(numout,*) '   ==>>>   eddy diffusivity = F(i,j,k) read in eddy_diffusivity.nc file'
369               IF(lflush) CALL FLUSH(numout)
370            ENDIF
371            CALL iom_open( 'eddy_diffusivity_3D.nc', inum )
372            CALL iom_get ( inum, jpdom_data, 'ahtu_3D', ahtu )
373            CALL iom_get ( inum, jpdom_data, 'ahtv_3D', ahtv )
374            CALL iom_close( inum )
375            !
376         CASE(  30  )      !==  fixed 3D shape  ==!
377            IF(lwp) THEN
378               WRITE(numout,*) '   ==>>>   eddy diffusivity = F( latitude, longitude, depth )'
379               WRITE(numout,*) '           using a fixed diffusive velocity = ', rn_Ud,' m/s   and   Ld = Max(e1,e2)'
380               WRITE(numout,*) '           maximum reachable coefficient (at the Equator) = ', zah_max, cl_Units, '  for e1=1°)'
381               IF(lflush) CALL FLUSH(numout)
382            ENDIF
383            CALL ldf_c2d( 'TRA', zUfac      , inn        , ahtu, ahtv )    ! surface value proportional to scale factor^inn
384            CALL ldf_c1d( 'TRA', ahtu(:,:,1), ahtv(:,:,1), ahtu, ahtv )    ! reduction with depth
385            !
386         CASE(  31  )      !==  time varying 3D field  ==!
387            IF(lwp) THEN
388               WRITE(numout,*) '   ==>>>   eddy diffusivity = F( latitude, longitude, depth , time )'
389               WRITE(numout,*) '           proportional to the velocity : 1/2 |u|e or 1/12 |u|e^3'
390               IF(lflush) CALL FLUSH(numout)
391            ENDIF
392            !
393            l_ldftra_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
394            !
395         CASE DEFAULT
396            CALL ctl_stop('ldf_tra_init: wrong choice for nn_aht_ijk_t, the type of space-time variation of aht')
397         END SELECT
398         !
399         IF( .NOT.l_ldftra_time ) THEN             !* No time variation
400            IF(     ln_traldf_lap ) THEN                 !   laplacian operator (mask only)
401               ahtu(:,:,1:jpkm1) =       ahtu(:,:,1:jpkm1)   * umask(:,:,1:jpkm1)
402               ahtv(:,:,1:jpkm1) =       ahtv(:,:,1:jpkm1)   * vmask(:,:,1:jpkm1)
403            ELSEIF( ln_traldf_blp ) THEN                 ! bilaplacian operator (square root + mask)
404               ahtu(:,:,1:jpkm1) = SQRT( ahtu(:,:,1:jpkm1) ) * umask(:,:,1:jpkm1)
405               ahtv(:,:,1:jpkm1) = SQRT( ahtv(:,:,1:jpkm1) ) * vmask(:,:,1:jpkm1)
406            ENDIF
407         ENDIF
408         !
409      ENDIF
410      !
411   END SUBROUTINE ldf_tra_init
412
413
414   SUBROUTINE ldf_tra( kt )
415      !!----------------------------------------------------------------------
416      !!                  ***  ROUTINE ldf_tra  ***
417      !!
418      !! ** Purpose :   update at kt the tracer lateral mixing coeff. (aht and aeiv)
419      !!
420      !! ** Method  : * time varying eddy diffusivity coefficients:
421      !!
422      !!    nn_aei_ijk_t = 21    aeiu, aeiv = F(i,j,  t) = F(growth rate of baroclinic instability)
423      !!                                                   with a reduction to 0 in vicinity of the Equator
424      !!    nn_aht_ijk_t = 21    ahtu, ahtv = F(i,j,  t) = F(growth rate of baroclinic instability)
425      !!
426      !!                 = 31    ahtu, ahtv = F(i,j,k,t) = F(local velocity) (  |u|e  /12   laplacian operator
427      !!                                                                     or |u|e^3/12 bilaplacian operator )
428      !!
429      !!              * time varying EIV coefficients: call to ldf_eiv routine
430      !!
431      !! ** action  :   ahtu, ahtv   update at each time step   
432      !!                aeiu, aeiv      -       -     -    -   (if ln_ldfeiv=T)
433      !!----------------------------------------------------------------------
434      INTEGER, INTENT(in) ::   kt   ! time step
435      !
436      INTEGER  ::   ji, jj, jk   ! dummy loop indices
437      REAL(wp) ::   zaht, zahf, zaht_min, zDaht, z1_f20   ! local scalar
438      !!----------------------------------------------------------------------
439      !
440      IF( ln_ldfeiv .AND. nn_aei_ijk_t == 21 ) THEN       ! eddy induced velocity coefficients
441         !                                ! =F(growth rate of baroclinic instability)
442         !                                ! max value aeiv_0 ; decreased to 0 within 20N-20S
443         CALL ldf_eiv( kt, aei0, aeiu, aeiv )
444      ENDIF
445      !
446      SELECT CASE(  nn_aht_ijk_t  )       ! Eddy diffusivity coefficients
447      !
448      CASE(  21  )       !==  time varying 2D field  ==!   = F( growth rate of baroclinic instability )
449         !                                             !   min value 0.2*aht0
450         !                                             !   max value aht0 (aei0 if nn_aei_ijk_t=21)
451         !                                             !   increase to aht0 within 20N-20S
452         IF( ln_ldfeiv .AND. nn_aei_ijk_t == 21 ) THEN   ! use the already computed aei.
453            ahtu(:,:,1) = aeiu(:,:,1)
454            ahtv(:,:,1) = aeiv(:,:,1)
455         ELSE                                            ! compute aht.
456            CALL ldf_eiv( kt, aht0, ahtu, ahtv )
457         ENDIF
458         !
459         z1_f20   = 1._wp / (  2._wp * omega * SIN( rad * 20._wp )  )   ! 1 / ff(20 degrees)   
460         zaht_min = 0.2_wp * aht0                                       ! minimum value for aht
461         zDaht    = aht0 - zaht_min                                     
462         DO jj = 1, jpj
463            DO ji = 1, jpi
464               !!gm CAUTION : here we assume lat/lon grid in 20deg N/S band (like all ORCA cfg)
465               !!     ==>>>   The Coriolis value is identical for t- & u_points, and for v- and f-points
466               zaht = ( 1._wp -  MIN( 1._wp , ABS( ff_t(ji,jj) * z1_f20 ) ) ) * zDaht
467               zahf = ( 1._wp -  MIN( 1._wp , ABS( ff_f(ji,jj) * z1_f20 ) ) ) * zDaht
468               ahtu(ji,jj,1) = (  MAX( zaht_min, ahtu(ji,jj,1) ) + zaht  )     ! min value zaht_min
469               ahtv(ji,jj,1) = (  MAX( zaht_min, ahtv(ji,jj,1) ) + zahf  )     ! increase within 20S-20N
470            END DO
471         END DO
472         DO jk = 1, jpkm1                             ! deeper value = surface value + mask for all levels
473            ahtu(:,:,jk) = ahtu(:,:,1) * umask(:,:,jk)
474            ahtv(:,:,jk) = ahtv(:,:,1) * vmask(:,:,jk)
475         END DO
476         !
477      CASE(  31  )       !==  time varying 3D field  ==!   = F( local velocity )
478         IF( ln_traldf_lap     ) THEN          !   laplacian operator |u| e /12
479            DO jk = 1, jpkm1
480               ahtu(:,:,jk) = ABS( ub(:,:,jk) ) * e1u(:,:) * r1_12   ! n.b. ub,vb are masked
481               ahtv(:,:,jk) = ABS( vb(:,:,jk) ) * e2v(:,:) * r1_12
482            END DO
483         ELSEIF( ln_traldf_blp ) THEN      ! bilaplacian operator      sqrt( |u| e^3 /12 ) = sqrt( |u| e /12 ) * e
484            DO jk = 1, jpkm1
485               ahtu(:,:,jk) = SQRT(  ABS( ub(:,:,jk) ) * e1u(:,:) * r1_12  ) * e1u(:,:)
486               ahtv(:,:,jk) = SQRT(  ABS( vb(:,:,jk) ) * e2v(:,:) * r1_12  ) * e2v(:,:)
487            END DO
488         ENDIF
489         !
490      END SELECT
491      !
492      CALL iom_put( "ahtu_2d", ahtu(:,:,1) )   ! surface u-eddy diffusivity coeff.
493      CALL iom_put( "ahtv_2d", ahtv(:,:,1) )   ! surface v-eddy diffusivity coeff.
494      CALL iom_put( "ahtu_3d", ahtu(:,:,:) )   ! 3D      u-eddy diffusivity coeff.
495      CALL iom_put( "ahtv_3d", ahtv(:,:,:) )   ! 3D      v-eddy diffusivity coeff.
496      !
497      IF( ln_ldfeiv ) THEN
498        CALL iom_put( "aeiu_2d", aeiu(:,:,1) )   ! surface u-EIV coeff.
499        CALL iom_put( "aeiv_2d", aeiv(:,:,1) )   ! surface v-EIV coeff.
500        CALL iom_put( "aeiu_3d", aeiu(:,:,:) )   ! 3D      u-EIV coeff.
501        CALL iom_put( "aeiv_3d", aeiv(:,:,:) )   ! 3D      v-EIV coeff.
502      ENDIF
503      !
504   END SUBROUTINE ldf_tra
505
506
507   SUBROUTINE ldf_eiv_init
508      !!----------------------------------------------------------------------
509      !!                  ***  ROUTINE ldf_eiv_init  ***
510      !!
511      !! ** Purpose :   initialization of the eiv coeff. from namelist choices.
512      !!
513      !! ** Method  :   the eiv diffusivity coef. specification depends on:
514      !!    nn_aei_ijk_t  =  0 => = constant
515      !!                  !
516      !!                  = 10 => = F(z) : constant with a reduction of 1/4 with depth
517      !!                  !
518      !!                  =-20 => = F(i,j)   = shape read in 'eddy_diffusivity.nc' file
519      !!                  = 20    = F(i,j)   = F(e1,e2) or F(e1^3,e2^3) (lap or bilap case)
520      !!                  = 21    = F(i,j,t) = F(growth rate of baroclinic instability)
521      !!                  !
522      !!                  =-30 => = F(i,j,k)   = shape read in 'eddy_diffusivity.nc' file
523      !!                  = 30    = F(i,j,k)   = 2D (case 20) + decrease with depth (case 10)
524      !!
525      !! ** Action  :   aeiu , aeiv   :  initialized one for all or l_ldftra_time set to true
526      !!                l_ldfeiv_time : =T if EIV coefficients vary with time
527      !!----------------------------------------------------------------------
528      INTEGER  ::   jk                     ! dummy loop indices
529      INTEGER  ::   ierr, inum, ios, inn   ! local integer
530      REAL(wp) ::   zah_max, zUfac         !   -   scalar
531      !!
532      NAMELIST/namtra_eiv/ ln_ldfeiv   , ln_ldfeiv_dia,   &   ! eddy induced velocity (eiv)
533         &                 nn_aei_ijk_t, rn_Ue, rn_Le         ! eiv  coefficient
534      !!----------------------------------------------------------------------
535      !
536      IF(lwp) THEN                      ! control print
537         WRITE(numout,*)
538         WRITE(numout,*) 'ldf_eiv_init : eddy induced velocity parametrization'
539         WRITE(numout,*) '~~~~~~~~~~~~ '
540      ENDIF
541      !
542      REWIND( numnam_ref )              ! Namelist namtra_eiv in reference namelist : eddy induced velocity param.
543      READ  ( numnam_ref, namtra_eiv, IOSTAT = ios, ERR = 901)
544901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namtra_eiv in reference namelist', lwp )
545      !
546      REWIND( numnam_cfg )              ! Namelist namtra_eiv in configuration namelist : eddy induced velocity param.
547      READ  ( numnam_cfg, namtra_eiv, IOSTAT = ios, ERR = 902 )
548902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namtra_eiv in configuration namelist', lwp )
549      IF(lwm .AND. nprint > 2)  WRITE ( numond, namtra_eiv )
550
551      IF(lwp) THEN                      ! control print
552         WRITE(numout,*) '   Namelist namtra_eiv : '
553         WRITE(numout,*) '      Eddy Induced Velocity (eiv) param.         ln_ldfeiv     = ', ln_ldfeiv
554         WRITE(numout,*) '      eiv streamfunction & velocity diag.        ln_ldfeiv_dia = ', ln_ldfeiv_dia
555         WRITE(numout,*) '      coefficients :'
556         WRITE(numout,*) '         type of time-space variation            nn_aei_ijk_t  = ', nn_aht_ijk_t
557         WRITE(numout,*) '         lateral diffusive velocity (if cst)     rn_Ue         = ', rn_Ue, ' m/s'
558         WRITE(numout,*) '         lateral diffusive length   (if cst)     rn_Le         = ', rn_Le, ' m'
559         WRITE(numout,*)
560      ENDIF
561      !
562      l_ldfeiv_time = .FALSE.       ! no time variation except in case defined below
563      !
564      !
565      IF( .NOT.ln_ldfeiv ) THEN     !== Parametrization not used  ==!
566         !
567         IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity param is NOT used'
568         ln_ldfeiv_dia = .FALSE.
569         !
570      ELSE                          !== use the parametrization  ==!
571         !
572         IF(lwp) WRITE(numout,*) '   ==>>>   use eddy induced velocity parametrization'
573         IF(lwp) WRITE(numout,*)
574         !
575         IF( ln_traldf_blp )   CALL ctl_stop( 'ldf_eiv_init: eddy induced velocity ONLY with laplacian diffusivity' )
576         !
577         !                                != allocate the aei arrays
578         ALLOCATE( aeiu(jpi,jpj,jpk), aeiv(jpi,jpj,jpk), STAT=ierr )
579         IF( ierr /= 0 )   CALL ctl_stop('STOP', 'ldf_eiv: failed to allocate arrays')
580         !
581         !                                != Specification of space-time variations of eaiu, aeiv
582         !
583         aeiu(:,:,jpk) = 0._wp               ! last level always 0 
584         aeiv(:,:,jpk) = 0._wp
585         !                                   ! value of EIV coef. (laplacian operator)
586         zUfac = r1_2 *rn_Ue                    ! velocity factor
587         inn = 1                                ! L-exponent
588         aei0    = zUfac *    rn_Le**inn        ! mixing coefficient
589         zah_max = zUfac * (ra*rad)**inn        ! maximum reachable coefficient (value at the Equator)
590
591         SELECT CASE( nn_aei_ijk_t )         !* Specification of space-time variations
592         !
593         CASE(   0  )                        !--  constant  --!
594            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = constant = ', aei0, ' m2/s'
595            aeiu(:,:,1:jpkm1) = aei0
596            aeiv(:,:,1:jpkm1) = aei0
597            !
598         CASE(  10  )                        !--  fixed profile  --!
599            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F( depth )'
600            IF(lwp) WRITE(numout,*) '           surface eddy diffusivity = constant = ', aht0, ' m2/s'
601            aeiu(:,:,1) = aei0                  ! constant surface value
602            aeiv(:,:,1) = aei0
603            CALL ldf_c1d( 'TRA', aeiu(:,:,1), aeiv(:,:,1), aeiu, aeiv )
604            !
605         CASE ( -20 )                        !--  fixed horizontal shape read in file  --!
606            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F(i,j) read in eddy_diffusivity_2D.nc file'
607            CALL iom_open ( 'eddy_induced_velocity_2D.nc', inum )
608            CALL iom_get  ( inum, jpdom_data, 'aeiu', aeiu(:,:,1) )
609            CALL iom_get  ( inum, jpdom_data, 'aeiv', aeiv(:,:,1) )
610            CALL iom_close( inum )
611            DO jk = 2, jpkm1
612               aeiu(:,:,jk) = aeiu(:,:,1)
613               aeiv(:,:,jk) = aeiv(:,:,1)
614            END DO
615            !
616         CASE(  20  )                        !--  fixed horizontal shape  --!
617            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F( e1, e2 )'
618            IF(lwp) WRITE(numout,*) '           using a fixed diffusive velocity = ', rn_Ue, ' m/s   and   Le = Max(e1,e2)'
619            IF(lwp) WRITE(numout,*) '           maximum reachable coefficient (at the Equator) = ', zah_max, ' m2/s   for e1=1°)'
620            CALL ldf_c2d( 'TRA', zUfac      , inn        , aeiu, aeiv )    ! value proportional to scale factor^inn
621            !
622         CASE(  21  )                        !--  time varying 2D field  --!
623            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F( latitude, longitude, time )'
624            IF(lwp) WRITE(numout,*) '                                       = F( growth rate of baroclinic instability )'
625            IF(lwp) WRITE(numout,*) '           maximum allowed value: aei0 = ', aei0, ' m2/s'
626            !
627            l_ldfeiv_time = .TRUE.     ! will be calculated by call to ldf_tra routine in step.F90
628            !
629         CASE( -30  )                        !-- fixed 3D shape read in file  --!
630            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F(i,j,k) read in eddy_diffusivity_3D.nc file'
631            CALL iom_open ( 'eddy_induced_velocity_3D.nc', inum )
632            CALL iom_get  ( inum, jpdom_data, 'aeiu', aeiu )
633            CALL iom_get  ( inum, jpdom_data, 'aeiv', aeiv )
634            CALL iom_close( inum )
635            !
636         CASE(  30  )                        !--  fixed 3D shape  --!
637            IF(lwp) WRITE(numout,*) '   ==>>>   eddy induced velocity coef. = F( latitude, longitude, depth )'
638            CALL ldf_c2d( 'TRA', zUfac      , inn        , aeiu, aeiv )    ! surface value proportional to scale factor^inn
639            CALL ldf_c1d( 'TRA', aeiu(:,:,1), aeiv(:,:,1), aeiu, aeiv )    ! reduction with depth
640            !
641         CASE DEFAULT
642            CALL ctl_stop('ldf_tra_init: wrong choice for nn_aei_ijk_t, the type of space-time variation of aei')
643         END SELECT
644         !
645         IF( .NOT.l_ldfeiv_time ) THEN             !* mask if No time variation
646            DO jk = 1, jpkm1
647               aeiu(:,:,jk) = aeiu(:,:,jk) * umask(:,:,jk)
648               ahtv(:,:,jk) = ahtv(:,:,jk) * vmask(:,:,jk)
649            END DO
650         ENDIF
651         !
652      ENDIF
653      !                   
654   END SUBROUTINE ldf_eiv_init
655
656
657   SUBROUTINE ldf_eiv( kt, paei0, paeiu, paeiv )
658      !!----------------------------------------------------------------------
659      !!                  ***  ROUTINE ldf_eiv  ***
660      !!
661      !! ** Purpose :   Compute the eddy induced velocity coefficient from the
662      !!              growth rate of baroclinic instability.
663      !!
664      !! ** Method  :   coefficient function of the growth rate of baroclinic instability
665      !!
666      !! Reference : Treguier et al. JPO 1997   ; Held and Larichev JAS 1996
667      !!----------------------------------------------------------------------
668      INTEGER                         , INTENT(in   ) ::   kt             ! ocean time-step index
669      REAL(wp)                        , INTENT(inout) ::   paei0          ! max value            [m2/s]
670      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   paeiu, paeiv   ! eiv coefficient      [m2/s]
671      !
672      INTEGER  ::   ji, jj, jk    ! dummy loop indices
673      REAL(wp) ::   zfw, ze3w, zn2, z1_f20, zaht, zaht_min, zzaei    ! local scalars
674      REAL(wp), DIMENSION(jpi,jpj) ::   zn, zah, zhw, zRo, zaeiw   ! 2D workspace
675      !!----------------------------------------------------------------------
676      !
677      zn (:,:) = 0._wp        ! Local initialization
678      zhw(:,:) = 5._wp
679      zah(:,:) = 0._wp
680      zRo(:,:) = 0._wp
681      !                       ! Compute lateral diffusive coefficient at T-point
682      IF( ln_traldf_triad ) THEN
683         DO jk = 1, jpk
684            DO jj = 2, jpjm1
685               DO ji = 2, jpim1
686                  ! Take the max of N^2 and zero then take the vertical sum
687                  ! of the square root of the resulting N^2 ( required to compute
688                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
689                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
690                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * e3w_n(ji,jj,jk)
691                  ! Compute elements required for the inverse time scale of baroclinic
692                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
693                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
694                  ze3w = e3w_n(ji,jj,jk) * tmask(ji,jj,jk)
695                  zah(ji,jj) = zah(ji,jj) + zn2 * wslp2(ji,jj,jk) * ze3w
696                  zhw(ji,jj) = zhw(ji,jj) + ze3w
697               END DO
698            END DO
699         END DO
700      ELSE
701         DO jk = 1, jpk
702            DO jj = 2, jpjm1
703               DO ji = 2, jpim1
704                  ! Take the max of N^2 and zero then take the vertical sum
705                  ! of the square root of the resulting N^2 ( required to compute
706                  ! internal Rossby radius Ro = .5 * sum_jpk(N) / f
707                  zn2 = MAX( rn2b(ji,jj,jk), 0._wp )
708                  zn(ji,jj) = zn(ji,jj) + SQRT( zn2 ) * e3w_n(ji,jj,jk)
709                  ! Compute elements required for the inverse time scale of baroclinic
710                  ! eddies using the isopycnal slopes calculated in ldfslp.F :
711                  ! T^-1 = sqrt(m_jpk(N^2*(r1^2+r2^2)*e3w))
712                  ze3w = e3w_n(ji,jj,jk) * tmask(ji,jj,jk)
713                  zah(ji,jj) = zah(ji,jj) + zn2 * ( wslpi(ji,jj,jk) * wslpi(ji,jj,jk)   &
714                     &                            + wslpj(ji,jj,jk) * wslpj(ji,jj,jk) ) * ze3w
715                  zhw(ji,jj) = zhw(ji,jj) + ze3w
716               END DO
717            END DO
718         END DO
719      ENDIF
720
721      DO jj = 2, jpjm1
722         DO ji = fs_2, fs_jpim1   ! vector opt.
723            zfw = MAX( ABS( 2. * omega * SIN( rad * gphit(ji,jj) ) ) , 1.e-10 )
724            ! Rossby radius at w-point taken betwenn 2 km and  40km
725            zRo(ji,jj) = MAX(  2.e3 , MIN( .4 * zn(ji,jj) / zfw, 40.e3 )  )
726            ! Compute aeiw by multiplying Ro^2 and T^-1
727            zaeiw(ji,jj) = zRo(ji,jj) * zRo(ji,jj) * SQRT( zah(ji,jj) / zhw(ji,jj) ) * tmask(ji,jj,1)
728         END DO
729      END DO
730
731      !                                         !==  Bound on eiv coeff.  ==!
732      z1_f20 = 1._wp / (  2._wp * omega * sin( rad * 20._wp )  )
733      DO jj = 2, jpjm1
734         DO ji = fs_2, fs_jpim1   ! vector opt.
735            zzaei = MIN( 1._wp, ABS( ff_t(ji,jj) * z1_f20 ) ) * zaeiw(ji,jj)     ! tropical decrease
736            zaeiw(ji,jj) = MIN( zzaei , paei0 )                                  ! Max value = paei0
737         END DO
738      END DO
739      CALL lbc_lnk( 'ldftra', zaeiw(:,:), 'W', 1. )       ! lateral boundary condition
740      !               
741      DO jj = 2, jpjm1                          !== aei at u- and v-points  ==!
742         DO ji = fs_2, fs_jpim1   ! vector opt.
743            paeiu(ji,jj,1) = 0.5_wp * ( zaeiw(ji,jj) + zaeiw(ji+1,jj  ) ) * umask(ji,jj,1)
744            paeiv(ji,jj,1) = 0.5_wp * ( zaeiw(ji,jj) + zaeiw(ji  ,jj+1) ) * vmask(ji,jj,1)
745         END DO
746      END DO
747      CALL lbc_lnk_multi( 'ldftra', paeiu(:,:,1), 'U', 1. , paeiv(:,:,1), 'V', 1. )      ! lateral boundary condition
748
749      DO jk = 2, jpkm1                          !==  deeper values equal the surface one  ==!
750         paeiu(:,:,jk) = paeiu(:,:,1) * umask(:,:,jk)
751         paeiv(:,:,jk) = paeiv(:,:,1) * vmask(:,:,jk)
752      END DO
753      ! 
754   END SUBROUTINE ldf_eiv
755
756
757   SUBROUTINE ldf_eiv_trp( kt, kit000, pun, pvn, pwn, cdtype )
758      !!----------------------------------------------------------------------
759      !!                  ***  ROUTINE ldf_eiv_trp  ***
760      !!
761      !! ** Purpose :   add to the input ocean transport the contribution of
762      !!              the eddy induced velocity parametrization.
763      !!
764      !! ** Method  :   The eddy induced transport is computed from a flux stream-
765      !!              function which depends on the slope of iso-neutral surfaces
766      !!              (see ldf_slp). For example, in the i-k plan :
767      !!                   psi_uw = mk(aeiu) e2u mi(wslpi)   [in m3/s]
768      !!                   Utr_eiv = - dk[psi_uw]
769      !!                   Vtr_eiv = + di[psi_uw]
770      !!                ln_ldfeiv_dia = T : output the associated streamfunction,
771      !!                                    velocity and heat transport (call ldf_eiv_dia)
772      !!
773      !! ** Action  : pun, pvn increased by the eiv transport
774      !!----------------------------------------------------------------------
775      INTEGER                         , INTENT(in   ) ::   kt       ! ocean time-step index
776      INTEGER                         , INTENT(in   ) ::   kit000   ! first time step index
777      CHARACTER(len=3)                , INTENT(in   ) ::   cdtype   ! =TRA or TRC (tracer indicator)
778      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pun      ! in : 3 ocean transport components   [m3/s]
779      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pvn      ! out: 3 ocean transport components   [m3/s]
780      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   pwn      ! increased by the eiv                [m3/s]
781      !!
782      INTEGER  ::   ji, jj, jk                 ! dummy loop indices
783      REAL(wp) ::   zuwk, zuwk1, zuwi, zuwi1   ! local scalars
784      REAL(wp) ::   zvwk, zvwk1, zvwj, zvwj1   !   -      -
785      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zpsi_uw, zpsi_vw
786      !!----------------------------------------------------------------------
787      !
788      IF( kt == kit000 )  THEN
789         IF(lwp) WRITE(numout,*)
790         IF(lwp) WRITE(numout,*) 'ldf_eiv_trp : eddy induced advection on ', cdtype,' :'
791         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~   add to velocity fields the eiv component'
792      ENDIF
793
794     
795      zpsi_uw(:,:, 1 ) = 0._wp   ;   zpsi_vw(:,:, 1 ) = 0._wp
796      zpsi_uw(:,:,jpk) = 0._wp   ;   zpsi_vw(:,:,jpk) = 0._wp
797      !
798      DO jk = 2, jpkm1
799         DO jj = 1, jpjm1
800            DO ji = 1, fs_jpim1   ! vector opt.
801               zpsi_uw(ji,jj,jk) = - r1_4 * e2u(ji,jj) * ( wslpi(ji,jj,jk  ) + wslpi(ji+1,jj,jk) )   &
802                  &                                    * ( aeiu (ji,jj,jk-1) + aeiu (ji  ,jj,jk) ) * umask(ji,jj,jk)
803               zpsi_vw(ji,jj,jk) = - r1_4 * e1v(ji,jj) * ( wslpj(ji,jj,jk  ) + wslpj(ji,jj+1,jk) )   &
804                  &                                    * ( aeiv (ji,jj,jk-1) + aeiv (ji,jj  ,jk) ) * vmask(ji,jj,jk)
805            END DO
806         END DO
807      END DO
808      !
809      DO jk = 1, jpkm1
810         DO jj = 1, jpjm1
811            DO ji = 1, fs_jpim1   ! vector opt.               
812               pun(ji,jj,jk) = pun(ji,jj,jk) - ( zpsi_uw(ji,jj,jk) - zpsi_uw(ji,jj,jk+1) )
813               pvn(ji,jj,jk) = pvn(ji,jj,jk) - ( zpsi_vw(ji,jj,jk) - zpsi_vw(ji,jj,jk+1) )
814            END DO
815         END DO
816      END DO
817      DO jk = 1, jpkm1
818         DO jj = 2, jpjm1
819            DO ji = fs_2, fs_jpim1   ! vector opt.
820               pwn(ji,jj,jk) = pwn(ji,jj,jk) + (  zpsi_uw(ji,jj,jk) - zpsi_uw(ji-1,jj  ,jk)   &
821                  &                             + zpsi_vw(ji,jj,jk) - zpsi_vw(ji  ,jj-1,jk) )
822            END DO
823         END DO
824      END DO
825      !
826      !                              ! diagnose the eddy induced velocity and associated heat transport
827      IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' )   CALL ldf_eiv_dia( zpsi_uw, zpsi_vw )
828      !
829    END SUBROUTINE ldf_eiv_trp
830
831
832   SUBROUTINE ldf_eiv_dia( psi_uw, psi_vw )
833      !!----------------------------------------------------------------------
834      !!                  ***  ROUTINE ldf_eiv_dia  ***
835      !!
836      !! ** Purpose :   diagnose the eddy induced velocity and its associated
837      !!              vertically integrated heat transport.
838      !!
839      !! ** Method :
840      !!
841      !!----------------------------------------------------------------------
842      REAL(wp), DIMENSION(jpi,jpj,jpk), INTENT(inout) ::   psi_uw, psi_vw   ! streamfunction   [m3/s]
843      !
844      INTEGER  ::   ji, jj, jk    ! dummy loop indices
845      REAL(wp) ::   zztmp   ! local scalar
846      REAL(wp), DIMENSION(jpi,jpj)     ::   zw2d   ! 2D workspace
847      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zw3d   ! 3D workspace
848      !!----------------------------------------------------------------------
849      !
850!!gm I don't like this routine....   Crazy  way of doing things, not optimal at all...
851!!gm     to be redesigned....   
852      !                                                  !==  eiv stream function: output  ==!
853      CALL lbc_lnk_multi( 'ldftra', psi_uw, 'U', -1. , psi_vw, 'V', -1. )
854      !
855!!gm      CALL iom_put( "psi_eiv_uw", psi_uw )                 ! output
856!!gm      CALL iom_put( "psi_eiv_vw", psi_vw )
857      !
858      !                                                  !==  eiv velocities: calculate and output  ==!
859      !
860      zw3d(:,:,jpk) = 0._wp                                    ! bottom value always 0
861      !
862      DO jk = 1, jpkm1                                         ! e2u e3u u_eiv = -dk[psi_uw]
863         zw3d(:,:,jk) = ( psi_uw(:,:,jk+1) - psi_uw(:,:,jk) ) / ( e2u(:,:) * e3u_n(:,:,jk) )
864      END DO
865      CALL iom_put( "uoce_eiv", zw3d )
866      !
867      DO jk = 1, jpkm1                                         ! e1v e3v v_eiv = -dk[psi_vw]
868         zw3d(:,:,jk) = ( psi_vw(:,:,jk+1) - psi_vw(:,:,jk) ) / ( e1v(:,:) * e3v_n(:,:,jk) )
869      END DO
870      CALL iom_put( "voce_eiv", zw3d )
871      !
872      DO jk = 1, jpkm1                                         ! e1 e2 w_eiv = dk[psix] + dk[psix]
873         DO jj = 2, jpjm1
874            DO ji = fs_2, fs_jpim1  ! vector opt.
875               zw3d(ji,jj,jk) = (  psi_vw(ji,jj,jk) - psi_vw(ji  ,jj-1,jk)    &
876                  &              + psi_uw(ji,jj,jk) - psi_uw(ji-1,jj  ,jk)  ) / e1e2t(ji,jj)
877            END DO
878         END DO
879      END DO
880      CALL lbc_lnk( 'ldftra', zw3d, 'T', 1. )      ! lateral boundary condition
881      CALL iom_put( "woce_eiv", zw3d )
882      !
883      !
884      zztmp = 0.5_wp * rau0 * rcp 
885      IF( iom_use('ueiv_heattr') .OR. iom_use('ueiv_heattr3d') ) THEN
886        zw2d(:,:)   = 0._wp 
887        zw3d(:,:,:) = 0._wp 
888        DO jk = 1, jpkm1
889           DO jj = 2, jpjm1
890              DO ji = fs_2, fs_jpim1   ! vector opt.
891                 zw3d(ji,jj,jk) = zw3d(ji,jj,jk) + ( psi_uw(ji,jj,jk+1)      - psi_uw(ji,jj,jk)          )   &
892                    &                            * ( tsn   (ji,jj,jk,jp_tem) + tsn   (ji+1,jj,jk,jp_tem) ) 
893                 zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk)
894              END DO
895           END DO
896        END DO
897        CALL lbc_lnk( 'ldftra', zw2d, 'U', -1. )
898        CALL lbc_lnk( 'ldftra', zw3d, 'U', -1. )
899        CALL iom_put( "ueiv_heattr"  , zztmp * zw2d )                  ! heat transport in i-direction
900        CALL iom_put( "ueiv_heattr3d", zztmp * zw3d )                  ! heat transport in i-direction
901      ENDIF
902      zw2d(:,:)   = 0._wp 
903      zw3d(:,:,:) = 0._wp 
904      DO jk = 1, jpkm1
905         DO jj = 2, jpjm1
906            DO ji = fs_2, fs_jpim1   ! vector opt.
907               zw3d(ji,jj,jk) = zw3d(ji,jj,jk) + ( psi_vw(ji,jj,jk+1)      - psi_vw(ji,jj,jk)          )   &
908                  &                            * ( tsn   (ji,jj,jk,jp_tem) + tsn   (ji,jj+1,jk,jp_tem) ) 
909               zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk)
910            END DO
911         END DO
912      END DO
913      CALL lbc_lnk( 'ldftra', zw2d, 'V', -1. )
914      CALL iom_put( "veiv_heattr", zztmp * zw2d )                  !  heat transport in j-direction
915      CALL iom_put( "veiv_heattr", zztmp * zw3d )                  !  heat transport in j-direction
916      !
917      IF( ln_diaptr )  CALL dia_ptr_hst( jp_tem, 'eiv', 0.5 * zw3d )
918      !
919      zztmp = 0.5_wp * 0.5
920      IF( iom_use('ueiv_salttr') .OR. iom_use('ueiv_salttr3d')) THEN
921        zw2d(:,:) = 0._wp 
922        zw3d(:,:,:) = 0._wp 
923        DO jk = 1, jpkm1
924           DO jj = 2, jpjm1
925              DO ji = fs_2, fs_jpim1   ! vector opt.
926                 zw3d(ji,jj,jk) = zw3d(ji,jj,jk) * ( psi_uw(ji,jj,jk+1)      - psi_uw(ji,jj,jk)          )   &
927                    &                            * ( tsn   (ji,jj,jk,jp_sal) + tsn   (ji+1,jj,jk,jp_sal) ) 
928                 zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk)
929              END DO
930           END DO
931        END DO
932        CALL lbc_lnk( 'ldftra', zw2d, 'U', -1. )
933        CALL lbc_lnk( 'ldftra', zw3d, 'U', -1. )
934        CALL iom_put( "ueiv_salttr", zztmp * zw2d )                  ! salt transport in i-direction
935        CALL iom_put( "ueiv_salttr3d", zztmp * zw3d )                  ! salt transport in i-direction
936      ENDIF
937      zw2d(:,:) = 0._wp 
938      zw3d(:,:,:) = 0._wp 
939      DO jk = 1, jpkm1
940         DO jj = 2, jpjm1
941            DO ji = fs_2, fs_jpim1   ! vector opt.
942               zw3d(ji,jj,jk) = zw3d(ji,jj,jk) + ( psi_vw(ji,jj,jk+1)      - psi_vw(ji,jj,jk)          )   &
943                  &                            * ( tsn   (ji,jj,jk,jp_sal) + tsn   (ji,jj+1,jk,jp_sal) ) 
944               zw2d(ji,jj) = zw2d(ji,jj) + zw3d(ji,jj,jk)
945            END DO
946         END DO
947      END DO
948      CALL lbc_lnk( 'ldftra', zw2d, 'V', -1. )
949      CALL iom_put( "veiv_salttr", zztmp * zw2d )                  !  salt transport in j-direction
950      CALL iom_put( "veiv_salttr", zztmp * zw3d )                  !  salt transport in j-direction
951      !
952      IF( ln_diaptr ) CALL dia_ptr_hst( jp_sal, 'eiv', 0.5 * zw3d )
953      !
954      !
955   END SUBROUTINE ldf_eiv_dia
956
957   !!======================================================================
958END MODULE ldftra
Note: See TracBrowser for help on using the repository browser.