New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
sbcrnf.F90 in NEMO/branches/UKMO/NEMO_4.0_mirror_text_diagnostics/src/OCE/SBC – NEMO

source: NEMO/branches/UKMO/NEMO_4.0_mirror_text_diagnostics/src/OCE/SBC/sbcrnf.F90 @ 10986

Last change on this file since 10986 was 10986, checked in by andmirek, 5 years ago

GMED 462 add flush

File size: 30.2 KB
Line 
1MODULE sbcrnf
2   !!======================================================================
3   !!                       ***  MODULE  sbcrnf  ***
4   !! Ocean forcing:  river runoff
5   !!=====================================================================
6   !! History :  OPA  ! 2000-11  (R. Hordoir, E. Durand)  NetCDF FORMAT
7   !!   NEMO     1.0  ! 2002-09  (G. Madec)  F90: Free form and module
8   !!            3.0  ! 2006-07  (G. Madec)  Surface module
9   !!            3.2  ! 2009-04  (B. Lemaire)  Introduce iom_put
10   !!            3.3  ! 2010-10  (R. Furner, G. Madec) runoff distributed over ocean levels
11   !!----------------------------------------------------------------------
12
13   !!----------------------------------------------------------------------
14   !!   sbc_rnf       : monthly runoffs read in a NetCDF file
15   !!   sbc_rnf_init  : runoffs initialisation
16   !!   rnf_mouth     : set river mouth mask
17   !!----------------------------------------------------------------------
18   USE dom_oce        ! ocean space and time domain
19   USE phycst         ! physical constants
20   USE sbc_oce        ! surface boundary condition variables
21   USE sbcisf         ! PM we could remove it I think
22   USE eosbn2         ! Equation Of State
23   USE closea         ! closed seas
24   !
25   USE in_out_manager ! I/O manager
26   USE fldread        ! read input field at current time step
27   USE iom            ! I/O module
28   USE lib_mpp        ! MPP library
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   sbc_rnf       ! called in sbcmod module
34   PUBLIC   sbc_rnf_div   ! called in divhor module
35   PUBLIC   sbc_rnf_alloc ! called in sbcmod module
36   PUBLIC   sbc_rnf_init  ! called in sbcmod module
37   
38   !                                                !!* namsbc_rnf namelist *
39   CHARACTER(len=100)         ::   cn_dir            !: Root directory for location of rnf files
40   LOGICAL           , PUBLIC ::   ln_rnf_depth      !: depth       river runoffs attribute specified in a file
41   LOGICAL                    ::      ln_rnf_depth_ini  !: depth       river runoffs  computed at the initialisation
42   REAL(wp)                   ::      rn_rnf_max        !: maximum value of the runoff climatologie (ln_rnf_depth_ini =T)
43   REAL(wp)                   ::      rn_dep_max        !: depth over which runoffs is spread       (ln_rnf_depth_ini =T)
44   INTEGER                    ::      nn_rnf_depth_file !: create (=1) a runoff depth file or not (=0)
45   LOGICAL                    ::   ln_rnf_tem        !: temperature river runoffs attribute specified in a file
46   LOGICAL           , PUBLIC ::   ln_rnf_sal        !: salinity    river runoffs attribute specified in a file
47   TYPE(FLD_N)       , PUBLIC ::   sn_rnf            !: information about the runoff file to be read
48   TYPE(FLD_N)                ::   sn_cnf            !: information about the runoff mouth file to be read
49   TYPE(FLD_N)                ::   sn_s_rnf          !: information about the salinities of runoff file to be read
50   TYPE(FLD_N)                ::   sn_t_rnf          !: information about the temperatures of runoff file to be read
51   TYPE(FLD_N)                ::   sn_dep_rnf        !: information about the depth which river inflow affects
52   LOGICAL           , PUBLIC ::   ln_rnf_mouth      !: specific treatment in mouths vicinity
53   REAL(wp)                   ::   rn_hrnf           !: runoffs, depth over which enhanced vertical mixing is used
54   REAL(wp)          , PUBLIC ::   rn_avt_rnf        !: runoffs, value of the additional vertical mixing coef. [m2/s]
55   REAL(wp)          , PUBLIC ::   rn_rfact          !: multiplicative factor for runoff
56
57   LOGICAL , PUBLIC ::   l_rnfcpl = .false.   !: runoffs recieved from oasis
58   INTEGER , PUBLIC ::   nkrnf = 0            !: nb of levels over which Kz is increased at river mouths
59   
60   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   rnfmsk              !: river mouth mask (hori.)
61   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:)     ::   rnfmsk_z            !: river mouth mask (vert.)
62   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   h_rnf               !: depth of runoff in m
63   INTEGER,  PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   nk_rnf              !: depth of runoff in model levels
64   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   rnf_tsc_b, rnf_tsc  !: before and now T & S runoff contents   [K.m/s & PSU.m/s]   
65
66   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_rnf       ! structure: river runoff (file information, fields read)
67   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_s_rnf     ! structure: river runoff salinity (file information, fields read) 
68   TYPE(FLD),        ALLOCATABLE, DIMENSION(:) ::   sf_t_rnf     ! structure: river runoff temperature (file information, fields read) 
69 
70   !!----------------------------------------------------------------------
71   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
72   !! $Id$
73   !! Software governed by the CeCILL license (see ./LICENSE)
74   !!----------------------------------------------------------------------
75CONTAINS
76
77   INTEGER FUNCTION sbc_rnf_alloc()
78      !!----------------------------------------------------------------------
79      !!                ***  ROUTINE sbc_rnf_alloc  ***
80      !!----------------------------------------------------------------------
81      ALLOCATE( rnfmsk(jpi,jpj)         , rnfmsk_z(jpk)          ,     &
82         &      h_rnf (jpi,jpj)         , nk_rnf  (jpi,jpj)      ,     &
83         &      rnf_tsc_b(jpi,jpj,jpts) , rnf_tsc (jpi,jpj,jpts) , STAT=sbc_rnf_alloc )
84         !
85      CALL mpp_sum ( 'sbcrnf', sbc_rnf_alloc )
86      IF( sbc_rnf_alloc > 0 )   CALL ctl_warn('sbc_rnf_alloc: allocation of arrays failed')
87   END FUNCTION sbc_rnf_alloc
88
89
90   SUBROUTINE sbc_rnf( kt )
91      !!----------------------------------------------------------------------
92      !!                  ***  ROUTINE sbc_rnf  ***
93      !!
94      !! ** Purpose :   Introduce a climatological run off forcing
95      !!
96      !! ** Method  :   Set each river mouth with a monthly climatology
97      !!                provided from different data.
98      !!                CAUTION : upward water flux, runoff forced to be < 0
99      !!
100      !! ** Action  :   runoff updated runoff field at time-step kt
101      !!----------------------------------------------------------------------
102      INTEGER, INTENT(in) ::   kt          ! ocean time step
103      !
104      INTEGER  ::   ji, jj    ! dummy loop indices
105      INTEGER  ::   z_err = 0 ! dummy integer for error handling
106      !!----------------------------------------------------------------------
107      REAL(wp), DIMENSION(jpi,jpj) ::   ztfrz   ! freezing point used for temperature correction
108      !
109      !
110      !                                            !-------------------!
111      !                                            !   Update runoff   !
112      !                                            !-------------------!
113      !
114      IF( .NOT. l_rnfcpl )   CALL fld_read ( kt, nn_fsbc, sf_rnf   )    ! Read Runoffs data and provide it at kt
115      IF(   ln_rnf_tem   )   CALL fld_read ( kt, nn_fsbc, sf_t_rnf )    ! idem for runoffs temperature if required
116      IF(   ln_rnf_sal   )   CALL fld_read ( kt, nn_fsbc, sf_s_rnf )    ! idem for runoffs salinity    if required
117      !
118      IF( MOD( kt - 1, nn_fsbc ) == 0 ) THEN
119         !
120         IF( .NOT. l_rnfcpl )   rnf(:,:) = rn_rfact * ( sf_rnf(1)%fnow(:,:,1) ) * tmask(:,:,1)       ! updated runoff value at time step kt
121         !
122         !                                                           ! set temperature & salinity content of runoffs
123         IF( ln_rnf_tem ) THEN                                       ! use runoffs temperature data
124            rnf_tsc(:,:,jp_tem) = ( sf_t_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
125            CALL eos_fzp( sss_m(:,:), ztfrz(:,:) )
126            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -999._wp )             ! if missing data value use SST as runoffs temperature
127               rnf_tsc(:,:,jp_tem) = sst_m(:,:) * rnf(:,:) * r1_rau0
128            END WHERE
129            WHERE( sf_t_rnf(1)%fnow(:,:,1) == -222._wp )             ! where fwf comes from melting of ice shelves or iceberg
130               rnf_tsc(:,:,jp_tem) = ztfrz(:,:) * rnf(:,:) * r1_rau0 - rnf(:,:) * rLfusisf * r1_rau0_rcp
131            END WHERE
132         ELSE                                                        ! use SST as runoffs temperature
133            !CEOD River is fresh water so must at least be 0 unless we consider ice
134            rnf_tsc(:,:,jp_tem) = MAX(sst_m(:,:),0.0_wp) * rnf(:,:) * r1_rau0
135         ENDIF
136         !                                                           ! use runoffs salinity data
137         IF( ln_rnf_sal )   rnf_tsc(:,:,jp_sal) = ( sf_s_rnf(1)%fnow(:,:,1) ) * rnf(:,:) * r1_rau0
138         !                                                           ! else use S=0 for runoffs (done one for all in the init)
139         IF( iom_use('runoffs') )        CALL iom_put( 'runoffs'     , rnf(:,:)                         )   ! output runoff mass flux
140         IF( iom_use('hflx_rnf_cea') )   CALL iom_put( 'hflx_rnf_cea', rnf_tsc(:,:,jp_tem) * rau0 * rcp )   ! output runoff sensible heat (W/m2)
141      ENDIF
142      !
143      !                                                ! ---------------------------------------- !
144      IF( kt == nit000 ) THEN                          !   set the forcing field at nit000 - 1    !
145         !                                             ! ---------------------------------------- !
146         IF( ln_rstart .AND.    &                               !* Restart: read in restart file
147            & iom_varid( numror, 'rnf_b', ldstop = .FALSE. ) > 0 ) THEN
148            IF(lwp .AND. nprint > 0) THEN
149               WRITE(numout,*) '          nit000-1 runoff forcing fields red in the restart file', lrxios
150               IF(lflush) CALL FLUSH(numout)
151            ENDIF
152            CALL iom_get( numror, jpdom_autoglo, 'rnf_b', rnf_b, ldxios = lrxios )     ! before runoff
153            CALL iom_get( numror, jpdom_autoglo, 'rnf_hc_b', rnf_tsc_b(:,:,jp_tem), ldxios = lrxios )   ! before heat content of runoff
154            CALL iom_get( numror, jpdom_autoglo, 'rnf_sc_b', rnf_tsc_b(:,:,jp_sal), ldxios = lrxios )   ! before salinity content of runoff
155         ELSE                                                   !* no restart: set from nit000 values
156            IF(lwp .AND. nprint > 0) THEN
157               WRITE(numout,*) '          nit000-1 runoff forcing fields set to nit000'
158               IF(lflush) CALL FLUSH(numout)
159            ENDIF
160            rnf_b    (:,:  ) = rnf    (:,:  )
161            rnf_tsc_b(:,:,:) = rnf_tsc(:,:,:)
162         ENDIF
163      ENDIF
164      !                                                ! ---------------------------------------- !
165      IF( lrst_oce ) THEN                              !      Write in the ocean restart file     !
166         !                                             ! ---------------------------------------- !
167         IF(lwp .AND. nprint > 0) THEN
168            WRITE(numout,*)
169            WRITE(numout,*) 'sbcrnf : runoff forcing fields written in ocean restart file ',   &
170            &                    'at it= ', kt,' date= ', ndastp
171            WRITE(numout,*) '~~~~'
172            IF(lflush) CALL FLUSH(numout)
173         ENDIF
174         IF( lwxios ) CALL iom_swap(      cwxios_context          )
175         CALL iom_rstput( kt, nitrst, numrow, 'rnf_b' , rnf, ldxios = lwxios )
176         CALL iom_rstput( kt, nitrst, numrow, 'rnf_hc_b', rnf_tsc(:,:,jp_tem), ldxios = lwxios )
177         CALL iom_rstput( kt, nitrst, numrow, 'rnf_sc_b', rnf_tsc(:,:,jp_sal), ldxios = lwxios )
178         IF( lwxios ) CALL iom_swap(      cxios_context          )
179      ENDIF
180      !
181   END SUBROUTINE sbc_rnf
182
183
184   SUBROUTINE sbc_rnf_div( phdivn )
185      !!----------------------------------------------------------------------
186      !!                  ***  ROUTINE sbc_rnf  ***
187      !!
188      !! ** Purpose :   update the horizontal divergence with the runoff inflow
189      !!
190      !! ** Method  :
191      !!                CAUTION : rnf is positive (inflow) decreasing the
192      !!                          divergence and expressed in m/s
193      !!
194      !! ** Action  :   phdivn   decreased by the runoff inflow
195      !!----------------------------------------------------------------------
196      REAL(wp), DIMENSION(:,:,:), INTENT(inout) ::   phdivn   ! horizontal divergence
197      !!
198      INTEGER  ::   ji, jj, jk   ! dummy loop indices
199      REAL(wp) ::   zfact     ! local scalar
200      !!----------------------------------------------------------------------
201      !
202      zfact = 0.5_wp
203      !
204      IF( ln_rnf_depth .OR. ln_rnf_depth_ini ) THEN      !==   runoff distributed over several levels   ==!
205         IF( ln_linssh ) THEN    !* constant volume case : just apply the runoff input flow
206            DO jj = 1, jpj
207               DO ji = 1, jpi
208                  DO jk = 1, nk_rnf(ji,jj)
209                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
210                  END DO
211               END DO
212            END DO
213         ELSE                    !* variable volume case
214            DO jj = 1, jpj                   ! update the depth over which runoffs are distributed
215               DO ji = 1, jpi
216                  h_rnf(ji,jj) = 0._wp
217                  DO jk = 1, nk_rnf(ji,jj)                           ! recalculates h_rnf to be the depth in metres
218                     h_rnf(ji,jj) = h_rnf(ji,jj) + e3t_n(ji,jj,jk)   ! to the bottom of the relevant grid box
219                  END DO
220                  !                          ! apply the runoff input flow
221                  DO jk = 1, nk_rnf(ji,jj)
222                     phdivn(ji,jj,jk) = phdivn(ji,jj,jk) - ( rnf(ji,jj) + rnf_b(ji,jj) ) * zfact * r1_rau0 / h_rnf(ji,jj)
223                  END DO
224               END DO
225            END DO
226         ENDIF
227      ELSE                       !==   runoff put only at the surface   ==!
228         h_rnf (:,:)   = e3t_n (:,:,1)        ! update h_rnf to be depth of top box
229         phdivn(:,:,1) = phdivn(:,:,1) - ( rnf(:,:) + rnf_b(:,:) ) * zfact * r1_rau0 / e3t_n(:,:,1)
230      ENDIF
231      !
232   END SUBROUTINE sbc_rnf_div
233
234
235   SUBROUTINE sbc_rnf_init
236      !!----------------------------------------------------------------------
237      !!                  ***  ROUTINE sbc_rnf_init  ***
238      !!
239      !! ** Purpose :   Initialisation of the runoffs if (ln_rnf=T)
240      !!
241      !! ** Method  : - read the runoff namsbc_rnf namelist
242      !!
243      !! ** Action  : - read parameters
244      !!----------------------------------------------------------------------
245      CHARACTER(len=32) ::   rn_dep_file   ! runoff file name
246      INTEGER           ::   ji, jj, jk, jm    ! dummy loop indices
247      INTEGER           ::   ierror, inum  ! temporary integer
248      INTEGER           ::   ios           ! Local integer output status for namelist read
249      INTEGER           ::   nbrec         ! temporary integer
250      REAL(wp)          ::   zacoef 
251      REAL(wp), DIMENSION(jpi,jpj,2) :: zrnfcl   
252      !!
253      NAMELIST/namsbc_rnf/ cn_dir            , ln_rnf_depth, ln_rnf_tem, ln_rnf_sal,   &
254         &                 sn_rnf, sn_cnf    , sn_s_rnf    , sn_t_rnf  , sn_dep_rnf,   &
255         &                 ln_rnf_mouth      , rn_hrnf     , rn_avt_rnf, rn_rfact,     &
256         &                 ln_rnf_depth_ini  , rn_dep_max  , rn_rnf_max, nn_rnf_depth_file
257      !!----------------------------------------------------------------------
258      !
259      !                                         !==  allocate runoff arrays
260      IF( sbc_rnf_alloc() /= 0 )   CALL ctl_stop( 'STOP', 'sbc_rnf_alloc : unable to allocate arrays' )
261      !
262      IF( .NOT. ln_rnf ) THEN                      ! no specific treatment in vicinity of river mouths
263         ln_rnf_mouth  = .FALSE.                   ! default definition needed for example by sbc_ssr or by tra_adv_muscl
264         nkrnf         = 0
265         rnf     (:,:) = 0.0_wp
266         rnf_b   (:,:) = 0.0_wp
267         rnfmsk  (:,:) = 0.0_wp
268         rnfmsk_z(:)   = 0.0_wp
269         RETURN
270      ENDIF
271      !
272      !                                   ! ============
273      !                                   !   Namelist
274      !                                   ! ============
275      !
276      REWIND( numnam_ref )              ! Namelist namsbc_rnf in reference namelist : Runoffs
277      READ  ( numnam_ref, namsbc_rnf, IOSTAT = ios, ERR = 901)
278901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namsbc_rnf in reference namelist', lwp )
279
280      REWIND( numnam_cfg )              ! Namelist namsbc_rnf in configuration namelist : Runoffs
281      READ  ( numnam_cfg, namsbc_rnf, IOSTAT = ios, ERR = 902 )
282902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namsbc_rnf in configuration namelist', lwp )
283      IF(lwm .AND. nprint > 2) WRITE ( numond, namsbc_rnf )
284      !
285      !                                         ! Control print
286      IF(lwp) THEN
287         WRITE(numout,*)
288         WRITE(numout,*) 'sbc_rnf_init : runoff '
289         WRITE(numout,*) '~~~~~~~~~~~~ '
290         WRITE(numout,*) '   Namelist namsbc_rnf'
291         WRITE(numout,*) '      specific river mouths treatment            ln_rnf_mouth = ', ln_rnf_mouth
292         WRITE(numout,*) '      river mouth additional Kz                  rn_avt_rnf   = ', rn_avt_rnf
293         WRITE(numout,*) '      depth of river mouth additional mixing     rn_hrnf      = ', rn_hrnf
294         WRITE(numout,*) '      multiplicative factor for runoff           rn_rfact     = ', rn_rfact
295         IF(lflush) CALL FLUSH(numout)
296      ENDIF
297      !                                   ! ==================
298      !                                   !   Type of runoff
299      !                                   ! ==================
300      !
301      IF( .NOT. l_rnfcpl ) THEN                   
302         ALLOCATE( sf_rnf(1), STAT=ierror )         ! Create sf_rnf structure (runoff inflow)
303         IF(lwp) THEN
304            WRITE(numout,*)
305            WRITE(numout,*) '   ==>>>   runoffs inflow read in a file'
306            IF(lflush) CALL FLUSH(numout)
307         ENDIF
308         IF( ierror > 0 ) THEN
309            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_rnf structure' )   ;   RETURN
310         ENDIF
311         ALLOCATE( sf_rnf(1)%fnow(jpi,jpj,1)   )
312         IF( sn_rnf%ln_tint ) ALLOCATE( sf_rnf(1)%fdta(jpi,jpj,1,2) )
313         CALL fld_fill( sf_rnf, (/ sn_rnf /), cn_dir, 'sbc_rnf_init', 'read runoffs data', 'namsbc_rnf', no_print )
314      ENDIF
315      !
316      IF( ln_rnf_tem ) THEN                      ! Create (if required) sf_t_rnf structure
317         IF(lwp) THEN
318            WRITE(numout,*)
319            WRITE(numout,*) '   ==>>>   runoffs temperatures read in a file'
320            IF(lflush) CALL FLUSH(numout)
321         ENDIF
322         ALLOCATE( sf_t_rnf(1), STAT=ierror  )
323         IF( ierror > 0 ) THEN
324            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_t_rnf structure' )   ;   RETURN
325         ENDIF
326         ALLOCATE( sf_t_rnf(1)%fnow(jpi,jpj,1)   )
327         IF( sn_t_rnf%ln_tint ) ALLOCATE( sf_t_rnf(1)%fdta(jpi,jpj,1,2) )
328         CALL fld_fill (sf_t_rnf, (/ sn_t_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff temperature data', 'namsbc_rnf', no_print )
329      ENDIF
330      !
331      IF( ln_rnf_sal  ) THEN                     ! Create (if required) sf_s_rnf and sf_t_rnf structures
332         IF(lwp) THEN
333            WRITE(numout,*)
334            WRITE(numout,*) '   ==>>>   runoffs salinities read in a file'
335            IF(lflush) CALL FLUSH(numout)
336         ENDIF
337         ALLOCATE( sf_s_rnf(1), STAT=ierror  )
338         IF( ierror > 0 ) THEN
339            CALL ctl_stop( 'sbc_rnf_init: unable to allocate sf_s_rnf structure' )   ;   RETURN
340         ENDIF
341         ALLOCATE( sf_s_rnf(1)%fnow(jpi,jpj,1)   )
342         IF( sn_s_rnf%ln_tint ) ALLOCATE( sf_s_rnf(1)%fdta(jpi,jpj,1,2) )
343         CALL fld_fill (sf_s_rnf, (/ sn_s_rnf /), cn_dir, 'sbc_rnf_init', 'read runoff salinity data', 'namsbc_rnf', no_print )
344      ENDIF
345      !
346      IF( ln_rnf_depth ) THEN                    ! depth of runoffs set from a file
347         IF(lwp) THEN
348            WRITE(numout,*)
349            WRITE(numout,*) '   ==>>>   runoffs depth read in a file'
350            IF(lflush) CALL FLUSH(numout)
351         ENDIF
352         rn_dep_file = TRIM( cn_dir )//TRIM( sn_dep_rnf%clname )
353         IF( .NOT. sn_dep_rnf%ln_clim ) THEN   ;   WRITE(rn_dep_file, '(a,"_y",i4)' ) TRIM( rn_dep_file ), nyear    ! add year
354            IF( sn_dep_rnf%cltype == 'monthly' )   WRITE(rn_dep_file, '(a,"m",i2)'  ) TRIM( rn_dep_file ), nmonth   ! add month
355         ENDIF
356         CALL iom_open ( rn_dep_file, inum )                           ! open file
357         CALL iom_get  ( inum, jpdom_data, sn_dep_rnf%clvar, h_rnf )   ! read the river mouth array
358         CALL iom_close( inum )                                        ! close file
359         !
360         nk_rnf(:,:) = 0                               ! set the number of level over which river runoffs are applied
361         DO jj = 1, jpj
362            DO ji = 1, jpi
363               IF( h_rnf(ji,jj) > 0._wp ) THEN
364                  jk = 2
365                  DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
366                  END DO
367                  nk_rnf(ji,jj) = jk
368               ELSEIF( h_rnf(ji,jj) == -1._wp   ) THEN   ;  nk_rnf(ji,jj) = 1
369               ELSEIF( h_rnf(ji,jj) == -999._wp ) THEN   ;  nk_rnf(ji,jj) = mbkt(ji,jj)
370               ELSE
371                  CALL ctl_stop( 'sbc_rnf_init: runoff depth not positive, and not -999 or -1, rnf value in file fort.999'  )
372                  WRITE(999,*) 'ji, jj, h_rnf(ji,jj) :', ji, jj, h_rnf(ji,jj)
373               ENDIF
374            END DO
375         END DO
376         DO jj = 1, jpj                                ! set the associated depth
377            DO ji = 1, jpi
378               h_rnf(ji,jj) = 0._wp
379               DO jk = 1, nk_rnf(ji,jj)
380                  h_rnf(ji,jj) = h_rnf(ji,jj) + e3t_n(ji,jj,jk)
381               END DO
382            END DO
383         END DO
384         !
385      ELSE IF( ln_rnf_depth_ini ) THEN           ! runoffs applied at the surface
386         !
387         IF(lwp) THEN
388            WRITE(numout,*)
389            WRITE(numout,*) '   ==>>>   depth of runoff computed once from max value of runoff'
390            WRITE(numout,*) '        max value of the runoff climatologie (over global domain) rn_rnf_max = ', rn_rnf_max
391            WRITE(numout,*) '        depth over which runoffs is spread                        rn_dep_max = ', rn_dep_max
392            WRITE(numout,*) '        create (=1) a runoff depth file or not (=0)      nn_rnf_depth_file  = ', nn_rnf_depth_file
393            IF(lflush) CALL FLUSH(numout)
394         ENDIF
395
396         CALL iom_open( TRIM( sn_rnf%clname ), inum )    !  open runoff file
397         nbrec = iom_getszuld( inum )
398         zrnfcl(:,:,1) = 0._wp                                                          ! init the max to 0. in 1
399         DO jm = 1, nbrec
400            CALL iom_get( inum, jpdom_data, TRIM( sn_rnf%clvar ), zrnfcl(:,:,2), jm )   ! read the value in 2
401            zrnfcl(:,:,1) = MAXVAL( zrnfcl(:,:,:), DIM=3 )                              ! store the maximum value in time in 1
402         END DO
403         CALL iom_close( inum )
404         !
405         h_rnf(:,:) = 1.
406         !
407         zacoef = rn_dep_max / rn_rnf_max            ! coef of linear relation between runoff and its depth (150m for max of runoff)
408         !
409         WHERE( zrnfcl(:,:,1) > 0._wp )  h_rnf(:,:) = zacoef * zrnfcl(:,:,1)   ! compute depth for all runoffs
410         !
411         DO jj = 1, jpj                     ! take in account min depth of ocean rn_hmin
412            DO ji = 1, jpi
413               IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
414                  jk = mbkt(ji,jj)
415                  h_rnf(ji,jj) = MIN( h_rnf(ji,jj), gdept_0(ji,jj,jk ) )
416               ENDIF
417            END DO
418         END DO
419         !
420         nk_rnf(:,:) = 0                       ! number of levels on which runoffs are distributed
421         DO jj = 1, jpj
422            DO ji = 1, jpi
423               IF( zrnfcl(ji,jj,1) > 0._wp ) THEN
424                  jk = 2
425                  DO WHILE ( jk /= mbkt(ji,jj) .AND. gdept_0(ji,jj,jk) < h_rnf(ji,jj) ) ;  jk = jk + 1
426                  END DO
427                  nk_rnf(ji,jj) = jk
428               ELSE
429                  nk_rnf(ji,jj) = 1
430               ENDIF
431            END DO
432         END DO
433         !
434         DO jj = 1, jpj                                ! set the associated depth
435            DO ji = 1, jpi
436               h_rnf(ji,jj) = 0._wp
437               DO jk = 1, nk_rnf(ji,jj)
438                  h_rnf(ji,jj) = h_rnf(ji,jj) + e3t_n(ji,jj,jk)
439               END DO
440            END DO
441         END DO
442         !
443         IF( nn_rnf_depth_file == 1 ) THEN      !  save  output nb levels for runoff
444            IF(lwp) THEN
445               WRITE(numout,*) '   ==>>>   create runoff depht file'
446               IF(lflush) CALL FLUSH(numout)
447            ENDIF
448            CALL iom_open  ( TRIM( sn_dep_rnf%clname ), inum, ldwrt = .TRUE. )
449            CALL iom_rstput( 0, 0, inum, 'rodepth', h_rnf )
450            CALL iom_close ( inum )
451         ENDIF
452      ELSE                                       ! runoffs applied at the surface
453         nk_rnf(:,:) = 1
454         h_rnf (:,:) = e3t_n(:,:,1)
455      ENDIF
456      !
457      rnf(:,:) =  0._wp                         ! runoff initialisation
458      rnf_tsc(:,:,:) = 0._wp                    ! runoffs temperature & salinty contents initilisation
459      !
460      !                                   ! ========================
461      !                                   !   River mouth vicinity
462      !                                   ! ========================
463      !
464      IF( ln_rnf_mouth ) THEN                   ! Specific treatment in vicinity of river mouths :
465         !                                      !    - Increase Kz in surface layers ( rn_hrnf > 0 )
466         !                                      !    - set to zero SSS damping (ln_ssr=T)
467         !                                      !    - mixed upstream-centered (ln_traadv_cen2=T)
468         !
469         IF ( ln_rnf_depth )   CALL ctl_warn( 'sbc_rnf_init: increased mixing turned on but effects may already',   &
470            &                                              'be spread through depth by ln_rnf_depth'               )
471         !
472         nkrnf = 0                                  ! Number of level over which Kz increase
473         IF( rn_hrnf > 0._wp ) THEN
474            nkrnf = 2
475            DO WHILE( nkrnf /= jpkm1 .AND. gdepw_1d(nkrnf+1) < rn_hrnf )   ;   nkrnf = nkrnf + 1
476            END DO
477            IF( ln_sco )   CALL ctl_warn( 'sbc_rnf_init: number of levels over which Kz is increased is computed for zco...' )
478         ENDIF
479         IF(lwp) THEN
480            WRITE(numout,*)
481            WRITE(numout,*) '   ==>>>   Specific treatment used in vicinity of river mouths :'
482            WRITE(numout,*) '             - Increase Kz in surface layers (if rn_hrnf > 0 )'
483            WRITE(numout,*) '               by ', rn_avt_rnf,' m2/s  over ', nkrnf, ' w-levels'
484            WRITE(numout,*) '             - set to zero SSS damping       (if ln_ssr=T)'
485            WRITE(numout,*) '             - mixed upstream-centered       (if ln_traadv_cen2=T)'
486            IF(lflush) CALL FLUSH(numout)
487         ENDIF
488         !
489         CALL rnf_mouth                             ! set river mouth mask
490         !
491      ELSE                                      ! No treatment at river mouths
492         IF(lwp) THEN
493            WRITE(numout,*)
494            WRITE(numout,*) '   ==>>>   No specific treatment at river mouths'
495            IF(lflush) CALL FLUSH(numout)
496         ENDIF
497         rnfmsk  (:,:) = 0._wp
498         rnfmsk_z(:)   = 0._wp
499         nkrnf = 0
500      ENDIF
501      !
502      IF( lwxios ) THEN
503         CALL iom_set_rstw_var_active('rnf_b')
504         CALL iom_set_rstw_var_active('rnf_hc_b')
505         CALL iom_set_rstw_var_active('rnf_sc_b')
506      ENDIF
507
508   END SUBROUTINE sbc_rnf_init
509
510
511   SUBROUTINE rnf_mouth
512      !!----------------------------------------------------------------------
513      !!                  ***  ROUTINE rnf_mouth  ***
514      !!
515      !! ** Purpose :   define the river mouths mask
516      !!
517      !! ** Method  :   read the river mouth mask (=0/1) in the river runoff
518      !!                climatological file. Defined a given vertical structure.
519      !!                CAUTION, the vertical structure is hard coded on the
520      !!                first 5 levels.
521      !!                This fields can be used to:
522      !!                 - set an upstream advection scheme
523      !!                   (ln_rnf_mouth=T and ln_traadv_cen2=T)
524      !!                 - increase vertical on the top nn_krnf vertical levels
525      !!                   at river runoff input grid point (nn_krnf>=2, see step.F90)
526      !!                 - set to zero SSS restoring flux at river mouth grid points
527      !!
528      !! ** Action  :   rnfmsk   set to 1 at river runoff input, 0 elsewhere
529      !!                rnfmsk_z vertical structure
530      !!----------------------------------------------------------------------
531      INTEGER            ::   inum        ! temporary integers
532      CHARACTER(len=140) ::   cl_rnfile   ! runoff file name
533      !!----------------------------------------------------------------------
534      !
535      IF(lwp) THEN
536         WRITE(numout,*)
537         WRITE(numout,*) '   rnf_mouth : river mouth mask'
538         WRITE(numout,*) '   ~~~~~~~~~ '
539         IF(lflush) CALL FLUSH(numout)
540      ENDIF
541      !
542      cl_rnfile = TRIM( cn_dir )//TRIM( sn_cnf%clname )
543      IF( .NOT. sn_cnf%ln_clim ) THEN   ;   WRITE(cl_rnfile, '(a,"_y",i4)' ) TRIM( cl_rnfile ), nyear    ! add year
544         IF( sn_cnf%cltype == 'monthly' )   WRITE(cl_rnfile, '(a,"m",i2)'  ) TRIM( cl_rnfile ), nmonth   ! add month
545      ENDIF
546      !
547      ! horizontal mask (read in NetCDF file)
548      CALL iom_open ( cl_rnfile, inum )                           ! open file
549      CALL iom_get  ( inum, jpdom_data, sn_cnf%clvar, rnfmsk )    ! read the river mouth array
550      CALL iom_close( inum )                                      ! close file
551      !
552      IF( l_clo_rnf )   CALL clo_rnf( rnfmsk )   ! closed sea inflow set as river mouth
553      !
554      rnfmsk_z(:)   = 0._wp                                       ! vertical structure
555      rnfmsk_z(1)   = 1.0
556      rnfmsk_z(2)   = 1.0                                         ! **********
557      rnfmsk_z(3)   = 0.5                                         ! HARD CODED on the 5 first levels
558      rnfmsk_z(4)   = 0.25                                        ! **********
559      rnfmsk_z(5)   = 0.125
560      !
561   END SUBROUTINE rnf_mouth
562
563   !!======================================================================
564END MODULE sbcrnf
Note: See TracBrowser for help on using the repository browser.