| 1 | MODULE trasbc |
|---|
| 2 | !!============================================================================== |
|---|
| 3 | !! *** MODULE trasbc *** |
|---|
| 4 | !! Ocean active tracers: surface boundary condition |
|---|
| 5 | !!============================================================================== |
|---|
| 6 | !! History : OPA ! 1998-10 (G. Madec, G. Roullet, M. Imbard) Original code |
|---|
| 7 | !! 8.2 ! 2001-02 (D. Ludicone) sea ice and free surface |
|---|
| 8 | !! NEMO 1.0 ! 2002-06 (G. Madec) F90: Free form and module |
|---|
| 9 | !! 3.3 ! 2010-04 (M. Leclair, G. Madec) Forcing averaged over 2 time steps |
|---|
| 10 | !! - ! 2010-09 (C. Ethe, G. Madec) Merge TRA-TRC |
|---|
| 11 | !! 3.6 ! 2014-11 (P. Mathiot) isf melting forcing |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | |
|---|
| 14 | !!---------------------------------------------------------------------- |
|---|
| 15 | !! tra_sbc : update the tracer trend at ocean surface |
|---|
| 16 | !!---------------------------------------------------------------------- |
|---|
| 17 | USE oce ! ocean dynamics and active tracers |
|---|
| 18 | USE sbc_oce ! surface boundary condition: ocean |
|---|
| 19 | USE dom_oce ! ocean space domain variables |
|---|
| 20 | USE phycst ! physical constant |
|---|
| 21 | USE eosbn2 ! Equation Of State |
|---|
| 22 | USE sbcmod ! ln_rnf |
|---|
| 23 | USE sbcrnf ! River runoff |
|---|
| 24 | USE sbcisf ! Ice shelf |
|---|
| 25 | USE iscplini ! Ice sheet coupling |
|---|
| 26 | USE traqsr ! solar radiation penetration |
|---|
| 27 | USE trd_oce ! trends: ocean variables |
|---|
| 28 | USE trdtra ! trends manager: tracers |
|---|
| 29 | #if defined key_asminc |
|---|
| 30 | USE asminc ! Assimilation increment |
|---|
| 31 | #endif |
|---|
| 32 | ! |
|---|
| 33 | USE in_out_manager ! I/O manager |
|---|
| 34 | USE prtctl ! Print control |
|---|
| 35 | USE iom ! xIOS server |
|---|
| 36 | USE lbclnk ! ocean lateral boundary conditions (or mpp link) |
|---|
| 37 | USE timing ! Timing |
|---|
| 38 | |
|---|
| 39 | IMPLICIT NONE |
|---|
| 40 | PRIVATE |
|---|
| 41 | |
|---|
| 42 | PUBLIC tra_sbc ! routine called by step.F90 |
|---|
| 43 | |
|---|
| 44 | !! * Substitutions |
|---|
| 45 | # include "vectopt_loop_substitute.h90" |
|---|
| 46 | !!---------------------------------------------------------------------- |
|---|
| 47 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 48 | !! $Id$ |
|---|
| 49 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 50 | !!---------------------------------------------------------------------- |
|---|
| 51 | CONTAINS |
|---|
| 52 | |
|---|
| 53 | SUBROUTINE tra_sbc ( kt ) |
|---|
| 54 | !!---------------------------------------------------------------------- |
|---|
| 55 | !! *** ROUTINE tra_sbc *** |
|---|
| 56 | !! |
|---|
| 57 | !! ** Purpose : Compute the tracer surface boundary condition trend of |
|---|
| 58 | !! (flux through the interface, concentration/dilution effect) |
|---|
| 59 | !! and add it to the general trend of tracer equations. |
|---|
| 60 | !! |
|---|
| 61 | !! ** Method : The (air+ice)-sea flux has two components: |
|---|
| 62 | !! (1) Fext, external forcing (i.e. flux through the (air+ice)-sea interface); |
|---|
| 63 | !! (2) Fwe , tracer carried with the water that is exchanged with air+ice. |
|---|
| 64 | !! The input forcing fields (emp, rnf, sfx, isf) contain Fext+Fwe, |
|---|
| 65 | !! they are simply added to the tracer trend (tsa). |
|---|
| 66 | !! In linear free surface case (ln_linssh=T), the volume of the |
|---|
| 67 | !! ocean does not change with the water exchanges at the (air+ice)-sea |
|---|
| 68 | !! interface. Therefore another term has to be added, to mimic the |
|---|
| 69 | !! concentration/dilution effect associated with water exchanges. |
|---|
| 70 | !! |
|---|
| 71 | !! ** Action : - Update tsa with the surface boundary condition trend |
|---|
| 72 | !! - send trends to trdtra module for further diagnostics(l_trdtra=T) |
|---|
| 73 | !!---------------------------------------------------------------------- |
|---|
| 74 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 75 | ! |
|---|
| 76 | INTEGER :: ji, jj, jk, jn ! dummy loop indices |
|---|
| 77 | INTEGER :: ikt, ikb ! local integers |
|---|
| 78 | REAL(wp) :: zfact, z1_e3t, zdep, ztim ! local scalar |
|---|
| 79 | REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrdt, ztrds |
|---|
| 80 | !!---------------------------------------------------------------------- |
|---|
| 81 | ! |
|---|
| 82 | IF( ln_timing ) CALL timing_start('tra_sbc') |
|---|
| 83 | ! |
|---|
| 84 | IF( kt == nit000 .AND. lwp) THEN |
|---|
| 85 | WRITE(numout,*) |
|---|
| 86 | WRITE(numout,*) 'tra_sbc : TRAcer Surface Boundary Condition' |
|---|
| 87 | WRITE(numout,*) '~~~~~~~ ' |
|---|
| 88 | IF(lflush) CALL FLUSH(numout) |
|---|
| 89 | ENDIF |
|---|
| 90 | ! |
|---|
| 91 | IF( l_trdtra ) THEN !* Save ta and sa trends |
|---|
| 92 | ALLOCATE( ztrdt(jpi,jpj,jpk) , ztrds(jpi,jpj,jpk) ) |
|---|
| 93 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) |
|---|
| 94 | ztrds(:,:,:) = tsa(:,:,:,jp_sal) |
|---|
| 95 | ENDIF |
|---|
| 96 | ! |
|---|
| 97 | !!gm This should be moved into sbcmod.F90 module ? (especially now that ln_traqsr is read in namsbc namelist) |
|---|
| 98 | IF( .NOT.ln_traqsr ) THEN ! no solar radiation penetration |
|---|
| 99 | qns(:,:) = qns(:,:) + qsr(:,:) ! total heat flux in qns |
|---|
| 100 | qsr(:,:) = 0._wp ! qsr set to zero |
|---|
| 101 | ENDIF |
|---|
| 102 | |
|---|
| 103 | !---------------------------------------- |
|---|
| 104 | ! EMP, SFX and QNS effects |
|---|
| 105 | !---------------------------------------- |
|---|
| 106 | ! !== Set before sbc tracer content fields ==! |
|---|
| 107 | IF( kt == nit000 ) THEN !* 1st time-step |
|---|
| 108 | IF( ln_rstart .AND. & ! Restart: read in restart file |
|---|
| 109 | & iom_varid( numror, 'sbc_hc_b', ldstop = .FALSE. ) > 0 ) THEN |
|---|
| 110 | IF(lwp .AND. nprint > 0) THEN |
|---|
| 111 | WRITE(numout,*) ' nit000-1 sbc tracer content field read in the restart file' |
|---|
| 112 | IF(lflush) CALL FLUSH(numout) |
|---|
| 113 | ENDIF |
|---|
| 114 | zfact = 0.5_wp |
|---|
| 115 | sbc_tsc(:,:,:) = 0._wp |
|---|
| 116 | CALL iom_get( numror, jpdom_autoglo, 'sbc_hc_b', sbc_tsc_b(:,:,jp_tem), ldxios = lrxios ) ! before heat content sbc trend |
|---|
| 117 | CALL iom_get( numror, jpdom_autoglo, 'sbc_sc_b', sbc_tsc_b(:,:,jp_sal), ldxios = lrxios ) ! before salt content sbc trend |
|---|
| 118 | ELSE ! No restart or restart not found: Euler forward time stepping |
|---|
| 119 | zfact = 1._wp |
|---|
| 120 | sbc_tsc(:,:,:) = 0._wp |
|---|
| 121 | sbc_tsc_b(:,:,:) = 0._wp |
|---|
| 122 | ENDIF |
|---|
| 123 | ELSE !* other time-steps: swap of forcing fields |
|---|
| 124 | zfact = 0.5_wp |
|---|
| 125 | sbc_tsc_b(:,:,:) = sbc_tsc(:,:,:) |
|---|
| 126 | ENDIF |
|---|
| 127 | ! !== Now sbc tracer content fields ==! |
|---|
| 128 | DO jj = 2, jpj |
|---|
| 129 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 130 | sbc_tsc(ji,jj,jp_tem) = r1_rau0_rcp * qns(ji,jj) ! non solar heat flux |
|---|
| 131 | sbc_tsc(ji,jj,jp_sal) = r1_rau0 * sfx(ji,jj) ! salt flux due to freezing/melting |
|---|
| 132 | END DO |
|---|
| 133 | END DO |
|---|
| 134 | IF( ln_linssh ) THEN !* linear free surface |
|---|
| 135 | DO jj = 2, jpj !==>> add concentration/dilution effect due to constant volume cell |
|---|
| 136 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 137 | sbc_tsc(ji,jj,jp_tem) = sbc_tsc(ji,jj,jp_tem) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_tem) |
|---|
| 138 | sbc_tsc(ji,jj,jp_sal) = sbc_tsc(ji,jj,jp_sal) + r1_rau0 * emp(ji,jj) * tsn(ji,jj,1,jp_sal) |
|---|
| 139 | END DO |
|---|
| 140 | END DO !==>> output c./d. term |
|---|
| 141 | IF( iom_use('emp_x_sst') ) CALL iom_put( "emp_x_sst", emp (:,:) * tsn(:,:,1,jp_tem) ) |
|---|
| 142 | IF( iom_use('emp_x_sss') ) CALL iom_put( "emp_x_sss", emp (:,:) * tsn(:,:,1,jp_sal) ) |
|---|
| 143 | ENDIF |
|---|
| 144 | ! |
|---|
| 145 | DO jn = 1, jpts !== update tracer trend ==! |
|---|
| 146 | DO jj = 2, jpj |
|---|
| 147 | DO ji = fs_2, fs_jpim1 ! vector opt. |
|---|
| 148 | tsa(ji,jj,1,jn) = tsa(ji,jj,1,jn) + zfact * ( sbc_tsc_b(ji,jj,jn) + sbc_tsc(ji,jj,jn) ) / e3t_n(ji,jj,1) |
|---|
| 149 | END DO |
|---|
| 150 | END DO |
|---|
| 151 | END DO |
|---|
| 152 | ! |
|---|
| 153 | IF( lrst_oce ) THEN !== write sbc_tsc in the ocean restart file ==! |
|---|
| 154 | IF( lwxios ) CALL iom_swap( cwxios_context ) |
|---|
| 155 | CALL iom_rstput( kt, nitrst, numrow, 'sbc_hc_b', sbc_tsc(:,:,jp_tem), ldxios = lwxios ) |
|---|
| 156 | CALL iom_rstput( kt, nitrst, numrow, 'sbc_sc_b', sbc_tsc(:,:,jp_sal), ldxios = lwxios ) |
|---|
| 157 | IF( lwxios ) CALL iom_swap( cxios_context ) |
|---|
| 158 | ENDIF |
|---|
| 159 | ! |
|---|
| 160 | !---------------------------------------- |
|---|
| 161 | ! Ice Shelf effects (ISF) |
|---|
| 162 | ! tbl treated as in Losh (2008) JGR |
|---|
| 163 | !---------------------------------------- |
|---|
| 164 | ! |
|---|
| 165 | !!gm BUG ? Why no differences between non-linear and linear free surface ? |
|---|
| 166 | !!gm probably taken into account in r1_hisf_tbl : to be verified |
|---|
| 167 | IF( ln_isf ) THEN |
|---|
| 168 | zfact = 0.5_wp |
|---|
| 169 | DO jj = 2, jpj |
|---|
| 170 | DO ji = fs_2, fs_jpim1 |
|---|
| 171 | ! |
|---|
| 172 | ikt = misfkt(ji,jj) |
|---|
| 173 | ikb = misfkb(ji,jj) |
|---|
| 174 | ! |
|---|
| 175 | ! level fully include in the ice shelf boundary layer |
|---|
| 176 | ! sign - because fwf sign of evapo (rnf sign of precip) |
|---|
| 177 | DO jk = ikt, ikb - 1 |
|---|
| 178 | ! compute trend |
|---|
| 179 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) & |
|---|
| 180 | & + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) ) & |
|---|
| 181 | & * r1_hisf_tbl(ji,jj) |
|---|
| 182 | END DO |
|---|
| 183 | |
|---|
| 184 | ! level partially include in ice shelf boundary layer |
|---|
| 185 | ! compute trend |
|---|
| 186 | tsa(ji,jj,ikb,jp_tem) = tsa(ji,jj,ikb,jp_tem) & |
|---|
| 187 | & + zfact * ( risf_tsc_b(ji,jj,jp_tem) + risf_tsc(ji,jj,jp_tem) ) & |
|---|
| 188 | & * r1_hisf_tbl(ji,jj) * ralpha(ji,jj) |
|---|
| 189 | |
|---|
| 190 | END DO |
|---|
| 191 | END DO |
|---|
| 192 | END IF |
|---|
| 193 | ! |
|---|
| 194 | !---------------------------------------- |
|---|
| 195 | ! River Runoff effects |
|---|
| 196 | !---------------------------------------- |
|---|
| 197 | ! |
|---|
| 198 | IF( ln_rnf ) THEN ! input of heat and salt due to river runoff |
|---|
| 199 | zfact = 0.5_wp |
|---|
| 200 | DO jj = 2, jpj |
|---|
| 201 | DO ji = fs_2, fs_jpim1 |
|---|
| 202 | IF( rnf(ji,jj) /= 0._wp ) THEN |
|---|
| 203 | zdep = zfact / h_rnf(ji,jj) |
|---|
| 204 | DO jk = 1, nk_rnf(ji,jj) |
|---|
| 205 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) & |
|---|
| 206 | & + ( rnf_tsc_b(ji,jj,jp_tem) + rnf_tsc(ji,jj,jp_tem) ) * zdep |
|---|
| 207 | IF( ln_rnf_sal ) tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) & |
|---|
| 208 | & + ( rnf_tsc_b(ji,jj,jp_sal) + rnf_tsc(ji,jj,jp_sal) ) * zdep |
|---|
| 209 | END DO |
|---|
| 210 | ENDIF |
|---|
| 211 | END DO |
|---|
| 212 | END DO |
|---|
| 213 | ENDIF |
|---|
| 214 | |
|---|
| 215 | IF( iom_use('rnf_x_sst') ) CALL iom_put( "rnf_x_sst", rnf*tsn(:,:,1,jp_tem) ) ! runoff term on sst |
|---|
| 216 | IF( iom_use('rnf_x_sss') ) CALL iom_put( "rnf_x_sss", rnf*tsn(:,:,1,jp_sal) ) ! runoff term on sss |
|---|
| 217 | |
|---|
| 218 | #if defined key_asminc |
|---|
| 219 | ! |
|---|
| 220 | !---------------------------------------- |
|---|
| 221 | ! Assmilation effects |
|---|
| 222 | !---------------------------------------- |
|---|
| 223 | ! |
|---|
| 224 | IF( ln_sshinc ) THEN ! input of heat and salt due to assimilation |
|---|
| 225 | ! |
|---|
| 226 | IF( ln_linssh ) THEN |
|---|
| 227 | DO jj = 2, jpj |
|---|
| 228 | DO ji = fs_2, fs_jpim1 |
|---|
| 229 | ztim = ssh_iau(ji,jj) / e3t_n(ji,jj,1) |
|---|
| 230 | tsa(ji,jj,1,jp_tem) = tsa(ji,jj,1,jp_tem) + tsn(ji,jj,1,jp_tem) * ztim |
|---|
| 231 | tsa(ji,jj,1,jp_sal) = tsa(ji,jj,1,jp_sal) + tsn(ji,jj,1,jp_sal) * ztim |
|---|
| 232 | END DO |
|---|
| 233 | END DO |
|---|
| 234 | ELSE |
|---|
| 235 | DO jj = 2, jpj |
|---|
| 236 | DO ji = fs_2, fs_jpim1 |
|---|
| 237 | ztim = ssh_iau(ji,jj) / ( ht_n(ji,jj) + 1. - ssmask(ji, jj) ) |
|---|
| 238 | tsa(ji,jj,:,jp_tem) = tsa(ji,jj,:,jp_tem) + tsn(ji,jj,:,jp_tem) * ztim |
|---|
| 239 | tsa(ji,jj,:,jp_sal) = tsa(ji,jj,:,jp_sal) + tsn(ji,jj,:,jp_sal) * ztim |
|---|
| 240 | END DO |
|---|
| 241 | END DO |
|---|
| 242 | ENDIF |
|---|
| 243 | ! |
|---|
| 244 | ENDIF |
|---|
| 245 | ! |
|---|
| 246 | #endif |
|---|
| 247 | ! |
|---|
| 248 | !---------------------------------------- |
|---|
| 249 | ! Ice Sheet coupling imbalance correction to have conservation |
|---|
| 250 | !---------------------------------------- |
|---|
| 251 | ! |
|---|
| 252 | IF( ln_iscpl .AND. ln_hsb) THEN ! input of heat and salt due to river runoff |
|---|
| 253 | DO jk = 1,jpk |
|---|
| 254 | DO jj = 2, jpj |
|---|
| 255 | DO ji = fs_2, fs_jpim1 |
|---|
| 256 | zdep = 1._wp / e3t_n(ji,jj,jk) |
|---|
| 257 | tsa(ji,jj,jk,jp_tem) = tsa(ji,jj,jk,jp_tem) - htsc_iscpl(ji,jj,jk,jp_tem) * zdep |
|---|
| 258 | tsa(ji,jj,jk,jp_sal) = tsa(ji,jj,jk,jp_sal) - htsc_iscpl(ji,jj,jk,jp_sal) * zdep |
|---|
| 259 | END DO |
|---|
| 260 | END DO |
|---|
| 261 | END DO |
|---|
| 262 | ENDIF |
|---|
| 263 | |
|---|
| 264 | IF( l_trdtra ) THEN ! save the horizontal diffusive trends for further diagnostics |
|---|
| 265 | ztrdt(:,:,:) = tsa(:,:,:,jp_tem) - ztrdt(:,:,:) |
|---|
| 266 | ztrds(:,:,:) = tsa(:,:,:,jp_sal) - ztrds(:,:,:) |
|---|
| 267 | CALL trd_tra( kt, 'TRA', jp_tem, jptra_nsr, ztrdt ) |
|---|
| 268 | CALL trd_tra( kt, 'TRA', jp_sal, jptra_nsr, ztrds ) |
|---|
| 269 | DEALLOCATE( ztrdt , ztrds ) |
|---|
| 270 | ENDIF |
|---|
| 271 | ! |
|---|
| 272 | IF(ln_ctl) CALL prt_ctl( tab3d_1=tsa(:,:,:,jp_tem), clinfo1=' sbc - Ta: ', mask1=tmask, & |
|---|
| 273 | & tab3d_2=tsa(:,:,:,jp_sal), clinfo2= ' Sa: ', mask2=tmask, clinfo3='tra' ) |
|---|
| 274 | ! |
|---|
| 275 | IF( ln_timing ) CALL timing_stop('tra_sbc') |
|---|
| 276 | ! |
|---|
| 277 | END SUBROUTINE tra_sbc |
|---|
| 278 | |
|---|
| 279 | !!====================================================================== |
|---|
| 280 | END MODULE trasbc |
|---|
