| 1 | MODULE zdfphy |
|---|
| 2 | !!====================================================================== |
|---|
| 3 | !! *** MODULE zdfphy *** |
|---|
| 4 | !! Vertical ocean physics : manager of all vertical physics packages |
|---|
| 5 | !!====================================================================== |
|---|
| 6 | !! History : 4.0 ! 2017-04 (G. Madec) original code |
|---|
| 7 | !!---------------------------------------------------------------------- |
|---|
| 8 | |
|---|
| 9 | !!---------------------------------------------------------------------- |
|---|
| 10 | !! zdf_phy_init : initialization of all vertical physics packages |
|---|
| 11 | !! zdf_phy : upadate at each time-step the vertical mixing coeff. |
|---|
| 12 | !!---------------------------------------------------------------------- |
|---|
| 13 | USE oce ! ocean dynamics and tracers variables |
|---|
| 14 | USE zdf_oce ! vertical physics: shared variables |
|---|
| 15 | USE zdfdrg ! vertical physics: top/bottom drag coef. |
|---|
| 16 | USE zdfsh2 ! vertical physics: shear production term of TKE |
|---|
| 17 | USE zdfric ! vertical physics: RIChardson dependent vertical mixing |
|---|
| 18 | USE zdftke ! vertical physics: TKE vertical mixing |
|---|
| 19 | USE zdfgls ! vertical physics: GLS vertical mixing |
|---|
| 20 | USE zdfosm ! vertical physics: OSMOSIS vertical mixing |
|---|
| 21 | USE zdfddm ! vertical physics: double diffusion mixing |
|---|
| 22 | USE zdfevd ! vertical physics: convection via enhanced vertical diffusion |
|---|
| 23 | USE zdfiwm ! vertical physics: internal wave-induced mixing |
|---|
| 24 | USE zdfswm ! vertical physics: surface wave-induced mixing |
|---|
| 25 | USE zdfmxl ! vertical physics: mixed layer |
|---|
| 26 | USE tranpc ! convection: non penetrative adjustment |
|---|
| 27 | USE trc_oce ! variables shared between passive tracer & ocean |
|---|
| 28 | USE sbc_oce ! surface module (only for nn_isf in the option compatibility test) |
|---|
| 29 | USE sbcrnf ! surface boundary condition: runoff variables |
|---|
| 30 | #if defined key_agrif |
|---|
| 31 | USE agrif_oce_interp ! interpavm |
|---|
| 32 | #endif |
|---|
| 33 | ! |
|---|
| 34 | USE in_out_manager ! I/O manager |
|---|
| 35 | USE iom ! IOM library |
|---|
| 36 | USE lbclnk ! lateral boundary conditions |
|---|
| 37 | USE lib_mpp ! distribued memory computing |
|---|
| 38 | USE timing ! Timing |
|---|
| 39 | |
|---|
| 40 | IMPLICIT NONE |
|---|
| 41 | PRIVATE |
|---|
| 42 | |
|---|
| 43 | PUBLIC zdf_phy_init ! called by nemogcm.F90 |
|---|
| 44 | PUBLIC zdf_phy ! called by step.F90 |
|---|
| 45 | |
|---|
| 46 | INTEGER :: nzdf_phy ! type of vertical closure used |
|---|
| 47 | ! ! associated indicators |
|---|
| 48 | INTEGER, PARAMETER :: np_CST = 1 ! Constant Kz |
|---|
| 49 | INTEGER, PARAMETER :: np_RIC = 2 ! Richardson number dependent Kz |
|---|
| 50 | INTEGER, PARAMETER :: np_TKE = 3 ! Turbulente Kinetic Eenergy closure scheme for Kz |
|---|
| 51 | INTEGER, PARAMETER :: np_GLS = 4 ! Generic Length Scale closure scheme for Kz |
|---|
| 52 | INTEGER, PARAMETER :: np_OSM = 5 ! OSMOSIS-OBL closure scheme for Kz |
|---|
| 53 | |
|---|
| 54 | LOGICAL :: l_zdfsh2 ! shear production term flag (=F for CST, =T otherwise (i.e. TKE, GLS, RIC)) |
|---|
| 55 | |
|---|
| 56 | !!---------------------------------------------------------------------- |
|---|
| 57 | !! NEMO/OCE 4.0 , NEMO Consortium (2018) |
|---|
| 58 | !! $Id$ |
|---|
| 59 | !! Software governed by the CeCILL license (see ./LICENSE) |
|---|
| 60 | !!---------------------------------------------------------------------- |
|---|
| 61 | CONTAINS |
|---|
| 62 | |
|---|
| 63 | SUBROUTINE zdf_phy_init |
|---|
| 64 | !!---------------------------------------------------------------------- |
|---|
| 65 | !! *** ROUTINE zdf_phy_init *** |
|---|
| 66 | !! |
|---|
| 67 | !! ** Purpose : initializations of the vertical ocean physics |
|---|
| 68 | !! |
|---|
| 69 | !! ** Method : Read namelist namzdf, control logicals |
|---|
| 70 | !! set horizontal shape and vertical profile of background mixing coef. |
|---|
| 71 | !!---------------------------------------------------------------------- |
|---|
| 72 | INTEGER :: jk ! dummy loop indices |
|---|
| 73 | INTEGER :: ioptio, ios ! local integers |
|---|
| 74 | !! |
|---|
| 75 | NAMELIST/namzdf/ ln_zdfcst, ln_zdfric, ln_zdftke, ln_zdfgls, & ! type of closure scheme |
|---|
| 76 | & ln_zdfosm, & ! type of closure scheme |
|---|
| 77 | & ln_zdfevd, nn_evdm, rn_evd , & ! convection : evd |
|---|
| 78 | & ln_zdfnpc, nn_npc , nn_npcp, & ! convection : npc |
|---|
| 79 | & ln_zdfddm, rn_avts, rn_hsbfr, & ! double diffusion |
|---|
| 80 | & ln_zdfswm, & ! surface wave-induced mixing |
|---|
| 81 | & ln_zdfiwm, & ! internal - - - |
|---|
| 82 | & ln_zad_Aimp, & ! apdative-implicit vertical advection |
|---|
| 83 | & rn_avm0, rn_avt0, nn_avb, nn_havtb ! coefficients |
|---|
| 84 | !!---------------------------------------------------------------------- |
|---|
| 85 | ! |
|---|
| 86 | IF(lwp) THEN |
|---|
| 87 | WRITE(numout,*) |
|---|
| 88 | WRITE(numout,*) 'zdf_phy_init: ocean vertical physics' |
|---|
| 89 | WRITE(numout,*) '~~~~~~~~~~~~' |
|---|
| 90 | IF(lflush) CALL FLUSH(numout) |
|---|
| 91 | ENDIF |
|---|
| 92 | ! |
|---|
| 93 | ! !== Namelist ==! |
|---|
| 94 | REWIND( numnam_ref ) ! Namelist namzdf in reference namelist : Vertical mixing parameters |
|---|
| 95 | READ ( numnam_ref, namzdf, IOSTAT = ios, ERR = 901) |
|---|
| 96 | 901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namzdf in reference namelist', lwp ) |
|---|
| 97 | ! |
|---|
| 98 | REWIND( numnam_cfg ) ! Namelist namzdf in reference namelist : Vertical mixing parameters |
|---|
| 99 | READ ( numnam_cfg, namzdf, IOSTAT = ios, ERR = 902 ) |
|---|
| 100 | 902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namzdf in configuration namelist', lwp ) |
|---|
| 101 | IF(lwm .AND. nprint > 2) WRITE ( numond, namzdf ) |
|---|
| 102 | ! |
|---|
| 103 | IF(lwp) THEN ! Parameter print |
|---|
| 104 | WRITE(numout,*) ' Namelist namzdf : set vertical mixing mixing parameters' |
|---|
| 105 | WRITE(numout,*) ' adaptive-implicit vertical advection' |
|---|
| 106 | WRITE(numout,*) ' Courant number targeted application ln_zad_Aimp = ', ln_zad_Aimp |
|---|
| 107 | WRITE(numout,*) ' vertical closure scheme' |
|---|
| 108 | WRITE(numout,*) ' constant vertical mixing coefficient ln_zdfcst = ', ln_zdfcst |
|---|
| 109 | WRITE(numout,*) ' Richardson number dependent closure ln_zdfric = ', ln_zdfric |
|---|
| 110 | WRITE(numout,*) ' Turbulent Kinetic Energy closure (TKE) ln_zdftke = ', ln_zdftke |
|---|
| 111 | WRITE(numout,*) ' Generic Length Scale closure (GLS) ln_zdfgls = ', ln_zdfgls |
|---|
| 112 | WRITE(numout,*) ' OSMOSIS-OBL closure (OSM) ln_zdfosm = ', ln_zdfosm |
|---|
| 113 | WRITE(numout,*) ' convection: ' |
|---|
| 114 | WRITE(numout,*) ' enhanced vertical diffusion ln_zdfevd = ', ln_zdfevd |
|---|
| 115 | WRITE(numout,*) ' applied on momentum (=1/0) nn_evdm = ', nn_evdm |
|---|
| 116 | WRITE(numout,*) ' vertical coefficient for evd rn_evd = ', rn_evd |
|---|
| 117 | WRITE(numout,*) ' non-penetrative convection (npc) ln_zdfnpc = ', ln_zdfnpc |
|---|
| 118 | WRITE(numout,*) ' npc call frequency nn_npc = ', nn_npc |
|---|
| 119 | WRITE(numout,*) ' npc print frequency nn_npcp = ', nn_npcp |
|---|
| 120 | WRITE(numout,*) ' double diffusive mixing ln_zdfddm = ', ln_zdfddm |
|---|
| 121 | WRITE(numout,*) ' maximum avs for dd mixing rn_avts = ', rn_avts |
|---|
| 122 | WRITE(numout,*) ' heat/salt buoyancy flux ratio rn_hsbfr= ', rn_hsbfr |
|---|
| 123 | WRITE(numout,*) ' gravity wave-induced mixing' |
|---|
| 124 | WRITE(numout,*) ' surface wave (Qiao et al 2010) ln_zdfswm = ', ln_zdfswm ! surface wave induced mixing |
|---|
| 125 | WRITE(numout,*) ' internal wave (de Lavergne et al 2017) ln_zdfiwm = ', ln_zdfiwm |
|---|
| 126 | WRITE(numout,*) ' coefficients : ' |
|---|
| 127 | WRITE(numout,*) ' vertical eddy viscosity rn_avm0 = ', rn_avm0 |
|---|
| 128 | WRITE(numout,*) ' vertical eddy diffusivity rn_avt0 = ', rn_avt0 |
|---|
| 129 | WRITE(numout,*) ' constant background or profile nn_avb = ', nn_avb |
|---|
| 130 | WRITE(numout,*) ' horizontal variation for avtb nn_havtb = ', nn_havtb |
|---|
| 131 | IF(lflush) CALL FLUSH(numout) |
|---|
| 132 | ENDIF |
|---|
| 133 | |
|---|
| 134 | IF( ln_zad_Aimp ) THEN |
|---|
| 135 | IF( zdf_phy_alloc() /= 0 ) & |
|---|
| 136 | & CALL ctl_stop( 'STOP', 'zdf_phy_init : unable to allocate adaptive-implicit z-advection arrays' ) |
|---|
| 137 | wi(:,:,:) = 0._wp |
|---|
| 138 | ENDIF |
|---|
| 139 | ! !== Background eddy viscosity and diffusivity ==! |
|---|
| 140 | IF( nn_avb == 0 ) THEN ! Define avmb, avtb from namelist parameter |
|---|
| 141 | avmb(:) = rn_avm0 |
|---|
| 142 | avtb(:) = rn_avt0 |
|---|
| 143 | ELSE ! Background profile of avt (fit a theoretical/observational profile (Krauss 1990) |
|---|
| 144 | avmb(:) = rn_avm0 |
|---|
| 145 | avtb(:) = rn_avt0 + ( 3.e-4_wp - 2._wp * rn_avt0 ) * 1.e-4_wp * gdepw_1d(:) ! m2/s |
|---|
| 146 | IF(ln_sco .AND. lwp) CALL ctl_warn( 'avtb profile not valid in sco' ) |
|---|
| 147 | ENDIF |
|---|
| 148 | ! ! 2D shape of the avtb |
|---|
| 149 | avtb_2d(:,:) = 1._wp ! uniform |
|---|
| 150 | ! |
|---|
| 151 | IF( nn_havtb == 1 ) THEN ! decrease avtb by a factor of ten in the equatorial band |
|---|
| 152 | ! ! -15S -5S : linear decrease from avt0 to avt0/10. |
|---|
| 153 | ! ! -5S +5N : cst value avt0/10. |
|---|
| 154 | ! ! 5N 15N : linear increase from avt0/10, to avt0 |
|---|
| 155 | WHERE(-15. <= gphit .AND. gphit < -5 ) avtb_2d = (1. - 0.09 * (gphit + 15.)) |
|---|
| 156 | WHERE( -5. <= gphit .AND. gphit < 5 ) avtb_2d = 0.1 |
|---|
| 157 | WHERE( 5. <= gphit .AND. gphit < 15 ) avtb_2d = (0.1 + 0.09 * (gphit - 5.)) |
|---|
| 158 | ENDIF |
|---|
| 159 | ! |
|---|
| 160 | DO jk = 1, jpk ! set turbulent closure Kz to the background value (avt_k, avm_k) |
|---|
| 161 | avt_k(:,:,jk) = avtb_2d(:,:) * avtb(jk) * wmask (:,:,jk) |
|---|
| 162 | avm_k(:,:,jk) = avmb(jk) * wmask (:,:,jk) |
|---|
| 163 | END DO |
|---|
| 164 | !!gm to be tested only the 1st & last levels |
|---|
| 165 | ! avt (:,:, 1 ) = 0._wp ; avs(:,:, 1 ) = 0._wp ; avm (:,:, 1 ) = 0._wp |
|---|
| 166 | ! avt (:,:,jpk) = 0._wp ; avs(:,:,jpk) = 0._wp ; avm (:,:,jpk) = 0._wp |
|---|
| 167 | !!gm |
|---|
| 168 | avt (:,:,:) = 0._wp ; avs(:,:,:) = 0._wp ; avm (:,:,:) = 0._wp |
|---|
| 169 | |
|---|
| 170 | ! !== Convection ==! |
|---|
| 171 | ! |
|---|
| 172 | IF( ln_zdfnpc .AND. ln_zdfevd ) CALL ctl_stop( 'zdf_phy_init: chose between ln_zdfnpc and ln_zdfevd' ) |
|---|
| 173 | IF( ln_zdfosm .AND. ln_zdfevd ) CALL ctl_stop( 'zdf_phy_init: chose between ln_zdfosm and ln_zdfevd' ) |
|---|
| 174 | IF( lk_top .AND. ln_zdfnpc ) CALL ctl_stop( 'zdf_phy_init: npc scheme is not working with key_top' ) |
|---|
| 175 | IF( lk_top .AND. ln_zdfosm ) CALL ctl_stop( 'zdf_phy_init: osmosis scheme is not working with key_top' ) |
|---|
| 176 | IF(lwp) THEN |
|---|
| 177 | WRITE(numout,*) |
|---|
| 178 | IF ( ln_zdfnpc ) THEN ; WRITE(numout,*) ' ==>>> convection: use non penetrative convective scheme' |
|---|
| 179 | ELSEIF( ln_zdfevd ) THEN ; WRITE(numout,*) ' ==>>> convection: use enhanced vertical diffusion scheme' |
|---|
| 180 | ELSE ; WRITE(numout,*) ' ==>>> convection: no specific scheme used' |
|---|
| 181 | ENDIF |
|---|
| 182 | IF(lflush) CALL FLUSH(numout) |
|---|
| 183 | ENDIF |
|---|
| 184 | |
|---|
| 185 | IF(lwp) THEN !== Double Diffusion Mixing parameterization ==! (ddm) |
|---|
| 186 | WRITE(numout,*) |
|---|
| 187 | IF( ln_zdfddm ) THEN ; WRITE(numout,*) ' ==>>> use double diffusive mixing: avs /= avt' |
|---|
| 188 | ELSE ; WRITE(numout,*) ' ==>>> No double diffusive mixing: avs = avt' |
|---|
| 189 | ENDIF |
|---|
| 190 | IF(lflush) CALL FLUSH(numout) |
|---|
| 191 | ENDIF |
|---|
| 192 | |
|---|
| 193 | ! !== type of vertical turbulent closure ==! (set nzdf_phy) |
|---|
| 194 | ioptio = 0 |
|---|
| 195 | IF( ln_zdfcst ) THEN ; ioptio = ioptio + 1 ; nzdf_phy = np_CST ; ENDIF |
|---|
| 196 | IF( ln_zdfric ) THEN ; ioptio = ioptio + 1 ; nzdf_phy = np_RIC ; CALL zdf_ric_init ; ENDIF |
|---|
| 197 | IF( ln_zdftke ) THEN ; ioptio = ioptio + 1 ; nzdf_phy = np_TKE ; CALL zdf_tke_init ; ENDIF |
|---|
| 198 | IF( ln_zdfgls ) THEN ; ioptio = ioptio + 1 ; nzdf_phy = np_GLS ; CALL zdf_gls_init ; ENDIF |
|---|
| 199 | IF( ln_zdfosm ) THEN ; ioptio = ioptio + 1 ; nzdf_phy = np_OSM ; CALL zdf_osm_init ; ENDIF |
|---|
| 200 | ! |
|---|
| 201 | IF( ioptio /= 1 ) CALL ctl_stop( 'zdf_phy_init: one and only one vertical diffusion option has to be defined ' ) |
|---|
| 202 | IF( ln_isfcav ) THEN |
|---|
| 203 | IF( ln_zdfric .OR. ln_zdfgls ) CALL ctl_stop( 'zdf_phy_init: zdfric and zdfgls never tested with ice shelves cavities ' ) |
|---|
| 204 | ENDIF |
|---|
| 205 | ! ! shear production term flag |
|---|
| 206 | IF( ln_zdfcst ) THEN ; l_zdfsh2 = .FALSE. |
|---|
| 207 | ELSE ; l_zdfsh2 = .TRUE. |
|---|
| 208 | ENDIF |
|---|
| 209 | |
|---|
| 210 | ! !== gravity wave-driven mixing ==! |
|---|
| 211 | IF( ln_zdfiwm ) CALL zdf_iwm_init ! internal wave-driven mixing |
|---|
| 212 | IF( ln_zdfswm ) CALL zdf_swm_init ! surface wave-driven mixing |
|---|
| 213 | |
|---|
| 214 | ! !== top/bottom friction ==! |
|---|
| 215 | CALL zdf_drg_init |
|---|
| 216 | ! |
|---|
| 217 | ! !== time-stepping ==! |
|---|
| 218 | ! Check/update of time stepping done in dynzdf_init/trazdf_init |
|---|
| 219 | !!gm move it here ? |
|---|
| 220 | ! |
|---|
| 221 | END SUBROUTINE zdf_phy_init |
|---|
| 222 | |
|---|
| 223 | |
|---|
| 224 | SUBROUTINE zdf_phy( kt ) |
|---|
| 225 | !!---------------------------------------------------------------------- |
|---|
| 226 | !! *** ROUTINE zdf_phy *** |
|---|
| 227 | !! |
|---|
| 228 | !! ** Purpose : Update ocean physics at each time-step |
|---|
| 229 | !! |
|---|
| 230 | !! ** Method : |
|---|
| 231 | !! |
|---|
| 232 | !! ** Action : avm, avt vertical eddy viscosity and diffusivity at w-points |
|---|
| 233 | !! nmld ??? mixed layer depth in level and meters <<<<====verifier ! |
|---|
| 234 | !! bottom stress..... <<<<====verifier ! |
|---|
| 235 | !!---------------------------------------------------------------------- |
|---|
| 236 | INTEGER, INTENT(in) :: kt ! ocean time-step index |
|---|
| 237 | ! |
|---|
| 238 | INTEGER :: ji, jj, jk ! dummy loop indice |
|---|
| 239 | REAL(wp), DIMENSION(jpi,jpj,jpk) :: zsh2 ! shear production |
|---|
| 240 | !! --------------------------------------------------------------------- |
|---|
| 241 | ! |
|---|
| 242 | IF( ln_timing ) CALL timing_start('zdf_phy') |
|---|
| 243 | ! |
|---|
| 244 | IF( l_zdfdrg ) THEN !== update top/bottom drag ==! (non-linear cases) |
|---|
| 245 | ! |
|---|
| 246 | ! !* bottom drag |
|---|
| 247 | CALL zdf_drg( kt, mbkt , r_Cdmin_bot, r_Cdmax_bot, & ! <<== in |
|---|
| 248 | & r_z0_bot, r_ke0_bot, rCd0_bot, & |
|---|
| 249 | & rCdU_bot ) ! ==>> out : bottom drag [m/s] |
|---|
| 250 | IF( ln_isfcav ) THEN !* top drag (ocean cavities) |
|---|
| 251 | CALL zdf_drg( kt, mikt , r_Cdmin_top, r_Cdmax_top, & ! <<== in |
|---|
| 252 | & r_z0_top, r_ke0_top, rCd0_top, & |
|---|
| 253 | & rCdU_top ) ! ==>> out : bottom drag [m/s] |
|---|
| 254 | ENDIF |
|---|
| 255 | ENDIF |
|---|
| 256 | ! |
|---|
| 257 | ! !== Kz from chosen turbulent closure ==! (avm_k, avt_k) |
|---|
| 258 | ! |
|---|
| 259 | IF( l_zdfsh2 ) & !* shear production at w-points (energy conserving form) |
|---|
| 260 | CALL zdf_sh2( ub, vb, un, vn, avm_k, & ! <<== in |
|---|
| 261 | & zsh2 ) ! ==>> out : shear production |
|---|
| 262 | ! |
|---|
| 263 | SELECT CASE ( nzdf_phy ) !* Vertical eddy viscosity and diffusivity coefficients at w-points |
|---|
| 264 | CASE( np_RIC ) ; CALL zdf_ric( kt, gdept_n, zsh2, avm_k, avt_k ) ! Richardson number dependent Kz |
|---|
| 265 | CASE( np_TKE ) ; CALL zdf_tke( kt , zsh2, avm_k, avt_k ) ! TKE closure scheme for Kz |
|---|
| 266 | CASE( np_GLS ) ; CALL zdf_gls( kt , zsh2, avm_k, avt_k ) ! GLS closure scheme for Kz |
|---|
| 267 | CASE( np_OSM ) ; CALL zdf_osm( kt , avm_k, avt_k ) ! OSMOSIS closure scheme for Kz |
|---|
| 268 | ! CASE( np_CST ) ! Constant Kz (reset avt, avm to the background value) |
|---|
| 269 | ! ! avt_k and avm_k set one for all at initialisation phase |
|---|
| 270 | !!gm avt(2:jpim1,2:jpjm1,1:jpkm1) = rn_avt0 * wmask(2:jpim1,2:jpjm1,1:jpkm1) |
|---|
| 271 | !!gm avm(2:jpim1,2:jpjm1,1:jpkm1) = rn_avm0 * wmask(2:jpim1,2:jpjm1,1:jpkm1) |
|---|
| 272 | END SELECT |
|---|
| 273 | ! |
|---|
| 274 | ! !== ocean Kz ==! (avt, avs, avm) |
|---|
| 275 | ! |
|---|
| 276 | ! !* start from turbulent closure values |
|---|
| 277 | avt(:,:,2:jpkm1) = avt_k(:,:,2:jpkm1) |
|---|
| 278 | avm(:,:,2:jpkm1) = avm_k(:,:,2:jpkm1) |
|---|
| 279 | ! |
|---|
| 280 | IF( ln_rnf_mouth ) THEN !* increase diffusivity at rivers mouths |
|---|
| 281 | DO jk = 2, nkrnf |
|---|
| 282 | avt(:,:,jk) = avt(:,:,jk) + 2._wp * rn_avt_rnf * rnfmsk(:,:) * wmask(:,:,jk) |
|---|
| 283 | END DO |
|---|
| 284 | ENDIF |
|---|
| 285 | ! |
|---|
| 286 | IF( ln_zdfevd ) CALL zdf_evd( kt, avm, avt ) !* convection: enhanced vertical eddy diffusivity |
|---|
| 287 | ! |
|---|
| 288 | ! !* double diffusive mixing |
|---|
| 289 | IF( ln_zdfddm ) THEN ! update avt and compute avs |
|---|
| 290 | CALL zdf_ddm( kt, avm, avt, avs ) |
|---|
| 291 | ELSE ! same mixing on all tracers |
|---|
| 292 | avs(2:jpim1,2:jpjm1,1:jpkm1) = avt(2:jpim1,2:jpjm1,1:jpkm1) |
|---|
| 293 | ENDIF |
|---|
| 294 | ! |
|---|
| 295 | ! !* wave-induced mixing |
|---|
| 296 | IF( ln_zdfswm ) CALL zdf_swm( kt, avm, avt, avs ) ! surface wave (Qiao et al. 2004) |
|---|
| 297 | IF( ln_zdfiwm ) CALL zdf_iwm( kt, avm, avt, avs ) ! internal wave (de Lavergne et al 2017) |
|---|
| 298 | |
|---|
| 299 | #if defined key_agrif |
|---|
| 300 | ! interpolation parent grid => child grid for avm_k ( ex : at west border: update column 1 and 2) |
|---|
| 301 | IF( l_zdfsh2 ) CALL Agrif_avm |
|---|
| 302 | #endif |
|---|
| 303 | |
|---|
| 304 | ! !* Lateral boundary conditions (sign unchanged) |
|---|
| 305 | IF( l_zdfsh2 ) THEN |
|---|
| 306 | CALL lbc_lnk_multi( 'zdfphy', avm_k, 'W', 1. , avt_k, 'W', 1., & |
|---|
| 307 | & avm , 'W', 1. , avt , 'W', 1. , avs , 'W', 1. ) |
|---|
| 308 | ELSE |
|---|
| 309 | CALL lbc_lnk_multi( 'zdfphy', avm , 'W', 1. , avt , 'W', 1. , avs , 'W', 1. ) |
|---|
| 310 | ENDIF |
|---|
| 311 | ! |
|---|
| 312 | IF( l_zdfdrg ) THEN ! drag have been updated (non-linear cases) |
|---|
| 313 | IF( ln_isfcav ) THEN ; CALL lbc_lnk_multi( 'zdfphy', rCdU_top, 'T', 1. , rCdU_bot, 'T', 1. ) ! top & bot drag |
|---|
| 314 | ELSE ; CALL lbc_lnk ( 'zdfphy', rCdU_bot, 'T', 1. ) ! bottom drag only |
|---|
| 315 | ENDIF |
|---|
| 316 | ENDIF |
|---|
| 317 | ! |
|---|
| 318 | CALL zdf_mxl( kt ) !* mixed layer depth, and level |
|---|
| 319 | ! |
|---|
| 320 | IF( lrst_oce ) THEN !* write TKE, GLS or RIC fields in the restart file |
|---|
| 321 | IF( ln_zdftke ) CALL tke_rst( kt, 'WRITE' ) |
|---|
| 322 | IF( ln_zdfgls ) CALL gls_rst( kt, 'WRITE' ) |
|---|
| 323 | IF( ln_zdfric ) CALL ric_rst( kt, 'WRITE' ) |
|---|
| 324 | ! NB. OSMOSIS restart (osm_rst) will be called in step.F90 after wn has been updated |
|---|
| 325 | ENDIF |
|---|
| 326 | ! |
|---|
| 327 | IF( ln_timing ) CALL timing_stop('zdf_phy') |
|---|
| 328 | ! |
|---|
| 329 | END SUBROUTINE zdf_phy |
|---|
| 330 | INTEGER FUNCTION zdf_phy_alloc() |
|---|
| 331 | !!---------------------------------------------------------------------- |
|---|
| 332 | !! *** FUNCTION zdf_phy_alloc *** |
|---|
| 333 | !!---------------------------------------------------------------------- |
|---|
| 334 | ! Allocate wi array (declared in oce.F90) for use with the adaptive-implicit vertical velocity option |
|---|
| 335 | ALLOCATE( wi(jpi,jpj,jpk), Cu_adv(jpi,jpj,jpk), STAT= zdf_phy_alloc ) |
|---|
| 336 | IF( zdf_phy_alloc /= 0 ) CALL ctl_warn('zdf_phy_alloc: failed to allocate ln_zad_Aimp=T required arrays') |
|---|
| 337 | CALL mpp_sum ( 'zdfphy', zdf_phy_alloc ) |
|---|
| 338 | END FUNCTION zdf_phy_alloc |
|---|
| 339 | |
|---|
| 340 | !!====================================================================== |
|---|
| 341 | END MODULE zdfphy |
|---|
