New URL for NEMO forge! http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.

nemogcm.F90 in NEMO/branches/UKMO/NEMO_4.0_mirror_text_diagnostics/src/OCE – NEMO

Context Navigation

source: NEMO/branches/UKMO/NEMO_4.0_mirror_text_diagnostics/src/OCE/nemogcm.F90 @ 10968

Last change on this file since 10968 was 10968, checked in by andmirek, 5 years ago
GMED 462 print levels implementation
File size: 35.7 KB

Line
1	MODULE nemogcm
2	!!======================================================================
3	!! * MODULE nemogcm *
4	!! Ocean system : NEMO GCM (ocean dynamics, on-line tracers, biochemistry and sea-ice)
5	!!======================================================================
6	!! History : OPA ! 1990-10 (C. Levy, G. Madec) Original code
7	!! 7.0 ! 1991-11 (M. Imbard, C. Levy, G. Madec)
8	!! 7.1 ! 1993-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
9	!! P. Delecluse, C. Perigaud, G. Caniaux, B. Colot, C. Maes) release 7.1
10	!! - ! 1992-06 (L.Terray) coupling implementation
11	!! - ! 1993-11 (M.A. Filiberti) IGLOO sea-ice
12	!! 8.0 ! 1996-03 (M. Imbard, C. Levy, G. Madec, O. Marti, M. Guyon, A. Lazar,
13	!! P. Delecluse, L.Terray, M.A. Filiberti, J. Vialar, A.M. Treguier, M. Levy) release 8.0
14	!! 8.1 ! 1997-06 (M. Imbard, G. Madec)
15	!! 8.2 ! 1999-11 (M. Imbard, H. Goosse) sea-ice model
16	!! ! 1999-12 (V. Thierry, A-M. Treguier, M. Imbard, M-A. Foujols) OPEN-MP
17	!! ! 2000-07 (J-M Molines, M. Imbard) Open Boundary Conditions (CLIPPER)
18	!! NEMO 1.0 ! 2002-08 (G. Madec) F90: Free form and modules
19	!! - ! 2004-06 (R. Redler, NEC CCRLE, Germany) add OASIS[3/4] coupled interfaces
20	!! - ! 2004-08 (C. Talandier) New trends organization
21	!! - ! 2005-06 (C. Ethe) Add the 1D configuration possibility
22	!! - ! 2005-11 (V. Garnier) Surface pressure gradient organization
23	!! - ! 2006-03 (L. Debreu, C. Mazauric) Agrif implementation
24	!! - ! 2006-04 (G. Madec, R. Benshila) Step reorganization
25	!! - ! 2007-07 (J. Chanut, A. Sellar) Unstructured open boundaries (BDY)
26	!! 3.2 ! 2009-08 (S. Masson) open/write in the listing file in mpp
27	!! 3.3 ! 2010-05 (K. Mogensen, A. Weaver, M. Martin, D. Lea) Assimilation interface
28	!! - ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
29	!! 3.3.1! 2011-01 (A. R. Porter, STFC Daresbury) dynamical allocation
30	!! - ! 2011-11 (C. Harris) decomposition changes for running with CICE
31	!! 3.6 ! 2012-05 (C. Calone, J. Simeon, G. Madec, C. Ethe) Add grid coarsening
32	!! - ! 2014-12 (G. Madec) remove KPP scheme and cross-land advection (cla)
33	!! 4.0 ! 2016-10 (G. Madec, S. Flavoni) domain configuration / user defined interface
34	!!----------------------------------------------------------------------
35
36	!!----------------------------------------------------------------------
37	!! nemo_gcm : solve ocean dynamics, tracer, biogeochemistry and/or sea-ice
38	!! nemo_init : initialization of the NEMO system
39	!! nemo_ctl : initialisation of the contol print
40	!! nemo_closefile: close remaining open files
41	!! nemo_alloc : dynamical allocation
42	!!----------------------------------------------------------------------
43	USE step_oce ! module used in the ocean time stepping module (step.F90)
44	USE phycst ! physical constant (par_cst routine)
45	USE domain ! domain initialization (dom_init & dom_cfg routines)
46	USE closea ! treatment of closed seas (for ln_closea)
47	USE usrdef_nam ! user defined configuration
48	USE tideini ! tidal components initialization (tide_ini routine)
49	USE bdy_oce, ONLY : ln_bdy
50	USE bdyini ! open boundary cond. setting (bdy_init routine)
51	USE istate ! initial state setting (istate_init routine)
52	USE ldfdyn ! lateral viscosity setting (ldfdyn_init routine)
53	USE ldftra ! lateral diffusivity setting (ldftra_init routine)
54	USE trdini ! dyn/tra trends initialization (trd_init routine)
55	USE asminc ! assimilation increments
56	USE asmbkg ! writing out state trajectory
57	USE diaptr ! poleward transports (dia_ptr_init routine)
58	USE diadct ! sections transports (dia_dct_init routine)
59	USE diaobs ! Observation diagnostics (dia_obs_init routine)
60	USE diacfl ! CFL diagnostics (dia_cfl_init routine)
61	USE step ! NEMO time-stepping (stp routine)
62	USE icbini ! handle bergs, initialisation
63	USE icbstp ! handle bergs, calving, themodynamics and transport
64	USE cpl_oasis3 ! OASIS3 coupling
65	USE c1d ! 1D configuration
66	USE step_c1d ! Time stepping loop for the 1D configuration
67	USE dyndmp ! Momentum damping
68	USE stopar ! Stochastic param.: ???
69	USE stopts ! Stochastic param.: ???
70	USE diurnal_bulk ! diurnal bulk SST
71	USE step_diu ! diurnal bulk SST timestepping (called from here if run offline)
72	USE crsini ! initialise grid coarsening utility
73	USE diatmb ! Top,middle,bottom output
74	USE dia25h ! 25h mean output
75	USE sbc_oce , ONLY : lk_oasis
76	USE wet_dry ! Wetting and drying setting (wad_init routine)
77	#if defined key_top
78	USE trcini ! passive tracer initialisation
79	#endif
80	#if defined key_nemocice_decomp
81	USE ice_domain_size, only: nx_global, ny_global
82	#endif
83	!
84	USE lib_mpp ! distributed memory computing
85	USE mppini ! shared/distributed memory setting (mpp_init routine)
86	USE lbcnfd , ONLY : isendto, nsndto, nfsloop, nfeloop ! Setup of north fold exchanges
87	USE lib_fortran ! Fortran utilities (allows no signed zero when 'key_nosignedzero' defined)
88	#if defined key_iomput
89	USE xios ! xIOserver
90	#endif
91	#if defined key_agrif
92	USE agrif_all_update ! Master Agrif update
93	#endif
94
95	IMPLICIT NONE
96	PRIVATE
97
98	PUBLIC nemo_gcm ! called by model.F90
99	PUBLIC nemo_init ! needed by AGRIF
100	PUBLIC nemo_alloc ! needed by TAM
101
102	CHARACTER(lc) :: cform_start="( /, 'Start run', / ) " ! flag for output listing
103	CHARACTER(lc) :: cform_end="( /, 'End run', / ) " ! flag for output listing
104	CHARACTER(lc) :: cform_aaa="( /, 'AAAAAAAA', / ) " ! flag for output listing
105
106	#if defined key_mpp_mpi
107	INCLUDE 'mpif.h'
108	#endif
109
110	!!----------------------------------------------------------------------
111	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
112	!! $Id$
113	!! Software governed by the CeCILL license (see ./LICENSE)
114	!!----------------------------------------------------------------------
115	CONTAINS
116
117	SUBROUTINE nemo_gcm
118	!!----------------------------------------------------------------------
119	!! * ROUTINE nemo_gcm *
120	!!
121	!! ** Purpose : NEMO solves the primitive equations on an orthogonal
122	!! curvilinear mesh on the sphere.
123	!!
124	!! ** Method : - model general initialization
125	!! - launch the time-stepping (stp routine)
126	!! - finalize the run by closing files and communications
127	!!
128	!! References : Madec, Delecluse, Imbard, and Levy, 1997: internal report, IPSL.
129	!! Madec, 2008, internal report, IPSL.
130	!!----------------------------------------------------------------------
131	INTEGER :: istp ! time step index
132	!!----------------------------------------------------------------------
133	!
134	#if defined key_agrif
135	CALL Agrif_Init_Grids() ! AGRIF: set the meshes
136	#endif
137	! !-----------------------!
138	CALL nemo_init !== Initialisations ==!
139	! !-----------------------!
140	#if defined key_agrif
141	CALL Agrif_Declare_Var_dom ! AGRIF: set the meshes for DOM
142	CALL Agrif_Declare_Var ! " " " " " DYN/TRA
143	# if defined key_top
144	CALL Agrif_Declare_Var_top ! " " " " " TOP
145	# endif
146	# if defined key_si3
147	CALL Agrif_Declare_Var_ice ! " " " " " Sea ice
148	# endif
149	#endif
150	! check that all process are still there... If some process have an error,
151	! they will never enter in step and other processes will wait until the end of the cpu time!
152	CALL mpp_max( 'nemogcm', nstop )
153
154	IF(lwp) WRITE(numout, cform_start) ! Flag AAAAAAA
155
156	! !-----------------------!
157	! !== time stepping ==!
158	! !-----------------------!
159	istp = nit000
160	!
161	#if defined key_c1d
162	DO WHILE ( istp <= nitend .AND. nstop == 0 ) !== C1D time-stepping ==!
163	CALL stp_c1d( istp )
164	istp = istp + 1
165	END DO
166	#else
167	!
168	# if defined key_agrif
169	! !== AGRIF time-stepping ==!
170	CALL Agrif_Regrid()
171	!
172	! Recursive update from highest nested level to lowest:
173	CALL Agrif_step_child_adj(Agrif_Update_All)
174	!
175	DO WHILE( istp <= nitend .AND. nstop == 0 )
176	CALL stp
177	istp = istp + 1
178	END DO
179	!
180	IF( .NOT. Agrif_Root() ) THEN
181	CALL Agrif_ParentGrid_To_ChildGrid()
182	IF( ln_diaobs ) CALL dia_obs_wri
183	IF( ln_timing ) CALL timing_finalize
184	CALL Agrif_ChildGrid_To_ParentGrid()
185	ENDIF
186	!
187	# else
188	!
189	IF( .NOT.ln_diurnal_only ) THEN !== Standard time-stepping ==!
190	!
191	DO WHILE( istp <= nitend .AND. nstop == 0 )
192	#if defined key_mpp_mpi
193	ncom_stp = istp
194	IF ( istp == ( nit000 + 1 ) ) elapsed_time = MPI_Wtime()
195	IF ( istp == nitend ) elapsed_time = MPI_Wtime() - elapsed_time
196	#endif
197	CALL stp ( istp )
198	istp = istp + 1
199	END DO
200	!
201	ELSE !== diurnal SST time-steeping only ==!
202	!
203	DO WHILE( istp <= nitend .AND. nstop == 0 )
204	CALL stp_diurnal( istp ) ! time step only the diurnal SST
205	istp = istp + 1
206	END DO
207	!
208	ENDIF
209	!
210	# endif
211	!
212	#endif
213	!
214	IF( ln_diaobs ) CALL dia_obs_wri
215	!
216	IF( ln_icebergs ) CALL icb_end( nitend )
217
218	! !------------------------!
219	! !== finalize the run ==!
220	! !------------------------!
221	IF(lwp) WRITE(numout, cform_end) ! Flag AAAAAAA
222	!
223	IF( nstop /= 0 .AND. lwp ) THEN ! error print
224	WRITE(numout,cform_err)
225	WRITE(numout,*) ' ==>>> nemo_gcm: a total of ', nstop, ' errors have been found'
226	WRITE(numout,*)
227	ENDIF
228	!
229	IF( ln_timing ) CALL timing_finalize
230	!
231	CALL nemo_closefile
232	!
233	#if defined key_iomput
234	CALL xios_finalize ! end mpp communications with xios
235	IF( lk_oasis ) CALL cpl_finalize ! end coupling and mpp communications with OASIS
236	#else
237	IF ( lk_oasis ) THEN ; CALL cpl_finalize ! end coupling and mpp communications with OASIS
238	ELSEIF( lk_mpp ) THEN ; CALL mppstop( ldfinal = .TRUE. ) ! end mpp communications
239	ENDIF
240	#endif
241	!
242	IF(lwm) THEN
243	IF( nstop == 0 ) THEN ; STOP 0
244	ELSE ; STOP 999
245	ENDIF
246	ENDIF
247	!
248	END SUBROUTINE nemo_gcm
249
250
251	SUBROUTINE nemo_init
252	!!----------------------------------------------------------------------
253	!! * ROUTINE nemo_init *
254	!!
255	!! ** Purpose : initialization of the NEMO GCM
256	!!----------------------------------------------------------------------
257	INTEGER :: ji ! dummy loop indices
258	INTEGER :: ios, ilocal_comm ! local integers
259	CHARACTER(len=120), DIMENSION(60) :: cltxt, cltxt2, clnam
260	!!
261	NAMELIST/namctl/ ln_ctl , sn_cfctl, nn_print, nn_ictls, nn_ictle, &
262	& nn_isplt , nn_jsplt, nn_jctls, nn_jctle, &
263	& ln_timing, ln_diacfl
264	NAMELIST/namcfg/ ln_read_cfg, cn_domcfg, ln_closea, ln_write_cfg, cn_domcfg_out, ln_use_jattr
265	!!----------------------------------------------------------------------
266	!
267	cltxt = ''
268	cltxt2 = ''
269	clnam = ''
270	cxios_context = 'nemo'
271	!
272	! ! Open reference namelist and configuration namelist files
273	CALL ctl_opn( numnam_ref, 'namelist_ref', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
274	CALL ctl_opn( numnam_cfg, 'namelist_cfg', 'OLD', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
275	!
276	REWIND( numnam_ref ) ! Namelist namctl in reference namelist
277	READ ( numnam_ref, namctl, IOSTAT = ios, ERR = 901 )
278	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namctl in reference namelist', .TRUE. )
279	REWIND( numnam_cfg ) ! Namelist namctl in confguration namelist
280	READ ( numnam_cfg, namctl, IOSTAT = ios, ERR = 902 )
281	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namctl in configuration namelist', .TRUE. )
282	!
283	REWIND( numnam_ref ) ! Namelist namcfg in reference namelist
284	READ ( numnam_ref, namcfg, IOSTAT = ios, ERR = 903 )
285	903 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namcfg in reference namelist', .TRUE. )
286	REWIND( numnam_cfg ) ! Namelist namcfg in confguration namelist
287	READ ( numnam_cfg, namcfg, IOSTAT = ios, ERR = 904 )
288	904 IF( ios > 0 ) CALL ctl_nam ( ios , 'namcfg in configuration namelist', .TRUE. )
289
290	! !--------------------------!
291	! ! Set global domain size ! (control print return in cltxt2)
292	! !--------------------------!
293	IF( ln_read_cfg ) THEN ! Read sizes in domain configuration file
294	CALL domain_cfg ( cltxt2, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
295	!
296	ELSE ! user-defined namelist
297	CALL usr_def_nam( cltxt2, clnam, cn_cfg, nn_cfg, jpiglo, jpjglo, jpkglo, jperio )
298	ENDIF
299	nprint = nn_print ! convert DOCTOR namelist names into OLD names
300	!
301	!
302	! !--------------------------------------------!
303	! ! set communicator & select the local node !
304	! ! NB: mynode also opens output.namelist.dyn !
305	! ! on unit number numond on first proc !
306	! !--------------------------------------------!
307	#if defined key_iomput
308	IF( Agrif_Root() ) THEN
309	IF( lk_oasis ) THEN
310	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
311	CALL xios_initialize( "not used" ,local_comm= ilocal_comm ) ! send nemo communicator to xios
312	ELSE
313	CALL xios_initialize( "for_xios_mpi_id",return_comm=ilocal_comm ) ! nemo local communicator given by xios
314	ENDIF
315	ENDIF
316	! Nodes selection (control print return in cltxt)
317	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
318	#else
319	IF( lk_oasis ) THEN
320	IF( Agrif_Root() ) THEN
321	CALL cpl_init( "oceanx", ilocal_comm ) ! nemo local communicator given by oasis
322	ENDIF
323	! Nodes selection (control print return in cltxt)
324	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop, ilocal_comm )
325	ELSE
326	ilocal_comm = 0 ! Nodes selection (control print return in cltxt)
327	narea = mynode( cltxt, 'output.namelist.dyn', numnam_ref, numnam_cfg, numond , nstop )
328	ENDIF
329	#endif
330
331	narea = narea + 1 ! mynode return the rank of proc (0 --> jpnij -1 )
332
333	IF( sn_cfctl%l_config ) THEN
334	! Activate finer control of report outputs
335	! optionally switch off output from selected areas (note this only
336	! applies to output which does not involve global communications)
337	IF( ( narea < sn_cfctl%procmin .OR. narea > sn_cfctl%procmax ) .OR. &
338	& ( MOD( narea - sn_cfctl%procmin, sn_cfctl%procincr ) /= 0 ) ) &
339	& CALL nemo_set_cfctl( sn_cfctl, .FALSE., .FALSE. )
340	ELSE
341	! Use ln_ctl to turn on or off all options.
342	CALL nemo_set_cfctl( sn_cfctl, ln_ctl, .TRUE. )
343	ENDIF
344
345	lwm = (narea == 1) ! control of output namelists
346	lwp = (narea == 1) .OR. ln_ctl ! control of all listing output print
347
348	IF(lwm .AND. nprint > 2) THEN ! write merged namelists from earlier to output namelist
349	! ! now that the file has been opened in call to mynode.
350	! ! NB: nammpp has already been written in mynode (if lk_mpp_mpi)
351	WRITE( numond, namctl )
352	WRITE( numond, namcfg )
353	IF( .NOT.ln_read_cfg ) THEN
354	DO ji = 1, SIZE(clnam)
355	IF( TRIM(clnam(ji)) /= '' ) WRITE(numond, * ) clnam(ji) ! namusr_def print
356	END DO
357	ENDIF
358	ENDIF
359
360	IF(lwp) THEN ! open listing units
361	!
362	CALL ctl_opn( numout, 'ocean.output', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
363	!
364	WRITE(numout,*)
365	WRITE(numout,*) ' CNRS - NERC - Met OFFICE - MERCATOR-ocean - INGV - CMCC'
366	WRITE(numout,*) ' NEMO team'
367	WRITE(numout,*) ' Ocean General Circulation Model'
368	WRITE(numout,*) ' NEMO version 4.0 (2019) '
369	WRITE(numout,*)
370	WRITE(numout,*) " ._ ._ ._ ._ ._ "
371	WRITE(numout,*) " _.-._)`\_.-._)`\_.-._)`\_.-._)`\_.-._)`\_ "
372	WRITE(numout,*)
373	WRITE(numout,*) " o _, _, "
374	WRITE(numout,*) " o .' ( .-' / "
375	WRITE(numout,*) " o _/..._'. .' / "
376	WRITE(numout,*) " ( o .-'` ` '-./ _.' "
377	WRITE(numout,*) " ) ( o) ;= <_ ( "
378	WRITE(numout,*) " ( '-.,\\__ __.-;`\ '. ) "
379	WRITE(numout,*) " ) ) \) \|`\ \) '. \ ( ( "
380	WRITE(numout,*) " ( ( \_/ '-._\ ) ) "
381	WRITE(numout,*) " ) ) jgs ` ( ( "
382	WRITE(numout,*) " ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ "
383	WRITE(numout,*)
384
385	DO ji = 1, SIZE(cltxt)
386	IF( TRIM(cltxt (ji)) /= '' ) WRITE(numout,*) TRIM(cltxt(ji)) ! control print of mynode
387	END DO
388	WRITE(numout,*)
389	WRITE(numout,*)
390	DO ji = 1, SIZE(cltxt2)
391	IF( TRIM(cltxt2(ji)) /= '' ) WRITE(numout,*) TRIM(cltxt2(ji)) ! control print of domain size
392	END DO
393	!
394	IF(nprint > 1) WRITE(numout,cform_aaa) ! Flag AAAAAAA
395	!
396	ENDIF
397	! open /dev/null file to be able to supress output write easily
398	CALL ctl_opn( numnul, '/dev/null', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE. )
399	!
400	! ! Domain decomposition
401	CALL mpp_init ! MPP
402
403	! Now we know the dimensions of the grid and numout has been set: we can allocate arrays
404	CALL nemo_alloc()
405
406	! !-------------------------------!
407	! ! NEMO general initialization !
408	! !-------------------------------!
409
410	CALL nemo_ctl ! Control prints
411	!
412	! ! General initialization
413	IF( ln_timing ) CALL timing_init ! timing
414	IF( ln_timing ) CALL timing_start( 'nemo_init')
415	!
416	CALL phy_cst ! Physical constants
417	CALL eos_init ! Equation of state
418	IF( lk_c1d ) CALL c1d_init ! 1D column configuration
419	CALL wad_init ! Wetting and drying options
420	CALL dom_init("OPA") ! Domain
421	IF( ln_crs ) CALL crs_init ! coarsened grid: domain initialization
422	IF( ln_ctl ) CALL prt_ctl_init ! Print control
423
424	CALL diurnal_sst_bulk_init ! diurnal sst
425	IF( ln_diurnal ) CALL diurnal_sst_coolskin_init ! cool skin
426	!
427	IF( ln_diurnal_only ) THEN ! diurnal only: a subset of the initialisation routines
428	CALL istate_init ! ocean initial state (Dynamics and tracers)
429	CALL sbc_init ! Forcings : surface module
430	CALL tra_qsr_init ! penetrative solar radiation qsr
431	IF( ln_diaobs ) THEN ! Observation & model comparison
432	CALL dia_obs_init ! Initialize observational data
433	CALL dia_obs( nit000 - 1 ) ! Observation operator for restart
434	ENDIF
435	IF( lk_asminc ) CALL asm_inc_init ! Assimilation increments
436	!
437	RETURN ! end of initialization
438	ENDIF
439
440	CALL istate_init ! ocean initial state (Dynamics and tracers)
441
442	! ! external forcing
443	CALL tide_init ! tidal harmonics
444	CALL sbc_init ! surface boundary conditions (including sea-ice)
445	CALL bdy_init ! Open boundaries initialisation
446
447	! ! Ocean physics
448	CALL zdf_phy_init ! Vertical physics
449
450	! ! Lateral physics
451	CALL ldf_tra_init ! Lateral ocean tracer physics
452	CALL ldf_eiv_init ! eddy induced velocity param.
453	CALL ldf_dyn_init ! Lateral ocean momentum physics
454
455	! ! Active tracers
456	IF( ln_traqsr ) CALL tra_qsr_init ! penetrative solar radiation qsr
457	CALL tra_bbc_init ! bottom heat flux
458	CALL tra_bbl_init ! advective (and/or diffusive) bottom boundary layer scheme
459	CALL tra_dmp_init ! internal tracer damping
460	CALL tra_adv_init ! horizontal & vertical advection
461	CALL tra_ldf_init ! lateral mixing
462
463	! ! Dynamics
464	IF( lk_c1d ) CALL dyn_dmp_init ! internal momentum damping
465	CALL dyn_adv_init ! advection (vector or flux form)
466	CALL dyn_vor_init ! vorticity term including Coriolis
467	CALL dyn_ldf_init ! lateral mixing
468	CALL dyn_hpg_init ! horizontal gradient of Hydrostatic pressure
469	CALL dyn_spg_init ! surface pressure gradient
470
471	#if defined key_top
472	! ! Passive tracers
473	CALL trc_init
474	#endif
475	IF( l_ldfslp ) CALL ldf_slp_init ! slope of lateral mixing
476
477	! ! Icebergs
478	CALL icb_init( rdt, nit000) ! initialise icebergs instance
479
480	! ! Misc. options
481	CALL sto_par_init ! Stochastic parametrization
482	IF( ln_sto_eos ) CALL sto_pts_init ! RRandom T/S fluctuations
483
484	! ! Diagnostics
485	IF( lk_floats ) CALL flo_init ! drifting Floats
486	IF( ln_diacfl ) CALL dia_cfl_init ! Initialise CFL diagnostics
487	CALL dia_ptr_init ! Poleward TRansports initialization
488	IF( lk_diadct ) CALL dia_dct_init ! Sections tranports
489	CALL dia_hsb_init ! heat content, salt content and volume budgets
490	CALL trd_init ! Mixed-layer/Vorticity/Integral constraints trends
491	CALL dia_obs_init ! Initialize observational data
492	CALL dia_tmb_init ! TMB outputs
493	CALL dia_25h_init ! 25h mean outputs
494	IF( ln_diaobs ) CALL dia_obs( nit000-1 ) ! Observation operator for restart
495
496	! ! Assimilation increments
497	IF( lk_asminc ) CALL asm_inc_init ! Initialize assimilation increments
498	!
499	IF(lwp .AND. nprint > 1) WRITE(numout,cform_aaa) ! Flag AAAAAAA
500	!
501	IF( ln_timing ) CALL timing_stop( 'nemo_init')
502	!
503	END SUBROUTINE nemo_init
504
505
506	SUBROUTINE nemo_ctl
507	!!----------------------------------------------------------------------
508	!! * ROUTINE nemo_ctl *
509	!!
510	!! ** Purpose : control print setting
511	!!
512	!! ** Method : - print namctl information and check some consistencies
513	!!----------------------------------------------------------------------
514	!
515	IF(lwp) THEN ! control print
516	WRITE(numout,*)
517	WRITE(numout,*) 'nemo_ctl: Control prints'
518	WRITE(numout,*) '~~~~~~~~'
519	WRITE(numout,*) ' Namelist namctl'
520	WRITE(numout,*) ' run control (for debugging) ln_ctl = ', ln_ctl
521	WRITE(numout,*) ' finer control over o/p sn_cfctl%l_config = ', sn_cfctl%l_config
522	WRITE(numout,*) ' sn_cfctl%l_runstat = ', sn_cfctl%l_runstat
523	WRITE(numout,*) ' sn_cfctl%l_trcstat = ', sn_cfctl%l_trcstat
524	WRITE(numout,*) ' sn_cfctl%l_oceout = ', sn_cfctl%l_oceout
525	WRITE(numout,*) ' sn_cfctl%l_layout = ', sn_cfctl%l_layout
526	WRITE(numout,*) ' sn_cfctl%l_mppout = ', sn_cfctl%l_mppout
527	WRITE(numout,*) ' sn_cfctl%l_mpptop = ', sn_cfctl%l_mpptop
528	WRITE(numout,*) ' sn_cfctl%procmin = ', sn_cfctl%procmin
529	WRITE(numout,*) ' sn_cfctl%procmax = ', sn_cfctl%procmax
530	WRITE(numout,*) ' sn_cfctl%procincr = ', sn_cfctl%procincr
531	WRITE(numout,*) ' sn_cfctl%ptimincr = ', sn_cfctl%ptimincr
532	WRITE(numout,*) ' level of print nn_print = ', nn_print
533	WRITE(numout,*) ' Start i indice for SUM control nn_ictls = ', nn_ictls
534	WRITE(numout,*) ' End i indice for SUM control nn_ictle = ', nn_ictle
535	WRITE(numout,*) ' Start j indice for SUM control nn_jctls = ', nn_jctls
536	WRITE(numout,*) ' End j indice for SUM control nn_jctle = ', nn_jctle
537	WRITE(numout,*) ' number of proc. following i nn_isplt = ', nn_isplt
538	WRITE(numout,*) ' number of proc. following j nn_jsplt = ', nn_jsplt
539	WRITE(numout,*) ' timing by routine ln_timing = ', ln_timing
540	WRITE(numout,*) ' CFL diagnostics ln_diacfl = ', ln_diacfl
541	ENDIF
542	!
543	nictls = nn_ictls
544	nictle = nn_ictle
545	njctls = nn_jctls
546	njctle = nn_jctle
547	isplt = nn_isplt
548	jsplt = nn_jsplt
549
550	IF(lwp) THEN ! control print
551	WRITE(numout,*)
552	WRITE(numout,*) ' Namelist namcfg'
553	WRITE(numout,*) ' read domain configuration file ln_read_cfg = ', ln_read_cfg
554	WRITE(numout,*) ' filename to be read cn_domcfg = ', TRIM(cn_domcfg)
555	WRITE(numout,*) ' keep closed seas in the domain (if exist) ln_closea = ', ln_closea
556	WRITE(numout,*) ' create a configuration definition file ln_write_cfg = ', ln_write_cfg
557	WRITE(numout,*) ' filename to be written cn_domcfg_out = ', TRIM(cn_domcfg_out)
558	WRITE(numout,*) ' use file attribute if exists as i/p j-start ln_use_jattr = ', ln_use_jattr
559	ENDIF
560	IF( .NOT.ln_read_cfg ) ln_closea = .false. ! dealing possible only with a domcfg file
561	!
562	! ! Parameter control
563	!
564	IF( ln_ctl ) THEN ! sub-domain area indices for the control prints
565	IF( lk_mpp .AND. jpnij > 1 ) THEN
566	isplt = jpni ; jsplt = jpnj ; ijsplt = jpni*jpnj ! the domain is forced to the real split domain
567	ELSE
568	IF( isplt == 1 .AND. jsplt == 1 ) THEN
569	CALL ctl_warn( ' - isplt & jsplt are equal to 1', &
570	& ' - the print control will be done over the whole domain' )
571	ENDIF
572	ijsplt = isplt * jsplt ! total number of processors ijsplt
573	ENDIF
574	IF(lwp) WRITE(numout,*)' - The total number of processors over which the'
575	IF(lwp) WRITE(numout,*)' print control will be done is ijsplt : ', ijsplt
576	!
577	! ! indices used for the SUM control
578	IF( nictls+nictle+njctls+njctle == 0 ) THEN ! print control done over the default area
579	lsp_area = .FALSE.
580	ELSE ! print control done over a specific area
581	lsp_area = .TRUE.
582	IF( nictls < 1 .OR. nictls > jpiglo ) THEN
583	CALL ctl_warn( ' - nictls must be 1<=nictls>=jpiglo, it is forced to 1' )
584	nictls = 1
585	ENDIF
586	IF( nictle < 1 .OR. nictle > jpiglo ) THEN
587	CALL ctl_warn( ' - nictle must be 1<=nictle>=jpiglo, it is forced to jpiglo' )
588	nictle = jpiglo
589	ENDIF
590	IF( njctls < 1 .OR. njctls > jpjglo ) THEN
591	CALL ctl_warn( ' - njctls must be 1<=njctls>=jpjglo, it is forced to 1' )
592	njctls = 1
593	ENDIF
594	IF( njctle < 1 .OR. njctle > jpjglo ) THEN
595	CALL ctl_warn( ' - njctle must be 1<=njctle>=jpjglo, it is forced to jpjglo' )
596	njctle = jpjglo
597	ENDIF
598	ENDIF
599	ENDIF
600	!
601	IF( 1._wp /= SIGN(1._wp,-0._wp) ) CALL ctl_stop( 'nemo_ctl: The intrinsec SIGN function follows f2003 standard.', &
602	& 'Compile with key_nosignedzero enabled:', &
603	& '--> add -Dkey_nosignedzero to the definition of %CPP in your arch file' )
604	!
605	#if defined key_agrif
606	IF( ln_timing ) CALL ctl_stop( 'AGRIF not implemented with ln_timing = true')
607	#endif
608	!
609	END SUBROUTINE nemo_ctl
610
611
612	SUBROUTINE nemo_closefile
613	!!----------------------------------------------------------------------
614	!! * ROUTINE nemo_closefile *
615	!!
616	!! ** Purpose : Close the files
617	!!----------------------------------------------------------------------
618	!
619	IF( lk_mpp ) CALL mppsync
620	!
621	CALL iom_close ! close all input/output files managed by iom_*
622	!
623	IF( numstp /= -1 ) CLOSE( numstp ) ! time-step file
624	IF( numrun /= -1 ) CLOSE( numrun ) ! run statistics file
625	IF( numnam_ref /= -1 ) CLOSE( numnam_ref ) ! oce reference namelist
626	IF( numnam_cfg /= -1 ) CLOSE( numnam_cfg ) ! oce configuration namelist
627	IF( lwm.AND.numond /= -1 ) CLOSE( numond ) ! oce output namelist
628	IF( numnam_ice_ref /= -1 ) CLOSE( numnam_ice_ref ) ! ice reference namelist
629	IF( numnam_ice_cfg /= -1 ) CLOSE( numnam_ice_cfg ) ! ice configuration namelist
630	IF( lwm.AND.numoni /= -1 ) CLOSE( numoni ) ! ice output namelist
631	IF( numevo_ice /= -1 ) CLOSE( numevo_ice ) ! ice variables (temp. evolution)
632	IF( numout /= 6 ) CLOSE( numout ) ! standard model output file
633	IF( numdct_vol /= -1 ) CLOSE( numdct_vol ) ! volume transports
634	IF( numdct_heat /= -1 ) CLOSE( numdct_heat ) ! heat transports
635	IF( numdct_salt /= -1 ) CLOSE( numdct_salt ) ! salt transports
636	!
637	numout = 6 ! redefine numout in case it is used after this point...
638	!
639	END SUBROUTINE nemo_closefile
640
641
642	SUBROUTINE nemo_alloc
643	!!----------------------------------------------------------------------
644	!! * ROUTINE nemo_alloc *
645	!!
646	!! ** Purpose : Allocate all the dynamic arrays of the OPA modules
647	!!
648	!! ** Method :
649	!!----------------------------------------------------------------------
650	USE diawri , ONLY : dia_wri_alloc
651	USE dom_oce , ONLY : dom_oce_alloc
652	USE trc_oce , ONLY : trc_oce_alloc
653	USE bdy_oce , ONLY : bdy_oce_alloc
654	#if defined key_diadct
655	USE diadct , ONLY : diadct_alloc
656	#endif
657	!
658	INTEGER :: ierr
659	!!----------------------------------------------------------------------
660	!
661	ierr = oce_alloc () ! ocean
662	ierr = ierr + dia_wri_alloc()
663	ierr = ierr + dom_oce_alloc() ! ocean domain
664	ierr = ierr + zdf_oce_alloc() ! ocean vertical physics
665	ierr = ierr + trc_oce_alloc() ! shared TRC / TRA arrays
666	ierr = ierr + bdy_oce_alloc() ! bdy masks (incl. initialization)
667	!
668	#if defined key_diadct
669	ierr = ierr + diadct_alloc () !
670	#endif
671	!
672	CALL mpp_sum( 'nemogcm', ierr )
673	IF( ierr /= 0 ) CALL ctl_stop( 'STOP', 'nemo_alloc: unable to allocate standard ocean arrays' )
674	!
675	END SUBROUTINE nemo_alloc
676
677	SUBROUTINE nemo_set_cfctl(sn_cfctl, setto, for_all )
678	!!----------------------------------------------------------------------
679	!! * ROUTINE nemo_set_cfctl *
680	!!
681	!! ** Purpose : Set elements of the output control structure to setto.
682	!! for_all should be .false. unless all areas are to be
683	!! treated identically.
684	!!
685	!! ** Method : Note this routine can be used to switch on/off some
686	!! types of output for selected areas but any output types
687	!! that involve global communications (e.g. mpp_max, glob_sum)
688	!! should be protected from selective switching by the
689	!! for_all argument
690	!!----------------------------------------------------------------------
691	LOGICAL :: setto, for_all
692	TYPE(sn_ctl) :: sn_cfctl
693	!!----------------------------------------------------------------------
694	IF( for_all ) THEN
695	sn_cfctl%l_runstat = setto
696	sn_cfctl%l_trcstat = setto
697	ENDIF
698	sn_cfctl%l_oceout = setto
699	sn_cfctl%l_layout = setto
700	sn_cfctl%l_mppout = setto
701	sn_cfctl%l_mpptop = setto
702	END SUBROUTINE nemo_set_cfctl
703
704	!!======================================================================
705	END MODULE nemogcm
706

Note: See TracBrowser for help on using the repository browser.

Download in other formats: