New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
icethd_do.F90 in NEMO/branches/UKMO/NEMO_4.0_old_tidal_mixing/src/ICE – NEMO

source: NEMO/branches/UKMO/NEMO_4.0_old_tidal_mixing/src/ICE/icethd_do.F90 @ 11084

Last change on this file since 11084 was 11084, checked in by davestorkey, 5 years ago

UKMO/NEMO_4.0_old_tidal_mixing : Update to be relative to rev 11081 of NEMO_4.0_mirror.

File size: 23.4 KB
Line 
1MODULE icethd_do
2   !!======================================================================
3   !!                       ***  MODULE icethd_do   ***
4   !!   sea-ice: sea ice growth in the leads (open water) 
5   !!======================================================================
6   !! History :       !  2005-12  (M. Vancoppenolle) Original code
7   !!            4.0  !  2018     (many people)      SI3 [aka Sea Ice cube]
8   !!----------------------------------------------------------------------
9#if defined key_si3
10   !!----------------------------------------------------------------------
11   !!   'key_si3'                                       SI3 sea-ice model
12   !!----------------------------------------------------------------------
13   !!   ice_thd_do        : ice growth in open water (=lateral accretion of ice)
14   !!   ice_thd_do_init   : initialization
15   !!----------------------------------------------------------------------
16   USE dom_oce        ! ocean space and time domain
17   USE phycst         ! physical constants
18   USE sbc_oce , ONLY : sss_m
19   USE sbc_ice , ONLY : utau_ice, vtau_ice
20   USE ice1D          ! sea-ice: thermodynamics variables
21   USE ice            ! sea-ice: variables
22   USE icetab         ! sea-ice: 2D <==> 1D
23   USE icectl         ! sea-ice: conservation
24   USE icethd_ent     ! sea-ice: thermodynamics, enthalpy
25   USE icevar         ! sea-ice: operations
26   USE icethd_sal     ! sea-ice: salinity profiles
27   !
28   USE in_out_manager ! I/O manager
29   USE lib_mpp        ! MPP library
30   USE lib_fortran    ! fortran utilities (glob_sum + no signed zero)
31   USE lbclnk         ! lateral boundary conditions (or mpp links)
32
33   IMPLICIT NONE
34   PRIVATE
35
36   PUBLIC   ice_thd_do        ! called by ice_thd
37   PUBLIC   ice_thd_do_init   ! called by ice_stp
38
39   !                          !!** namelist (namthd_do) **
40   REAL(wp) ::   rn_hinew      ! thickness for new ice formation (m)
41   LOGICAL  ::   ln_frazil     ! use of frazil ice collection as function of wind (T) or not (F)
42   REAL(wp) ::   rn_maxfraz    ! maximum portion of frazil ice collecting at the ice bottom
43   REAL(wp) ::   rn_vfraz      ! threshold drift speed for collection of bottom frazil ice
44   REAL(wp) ::   rn_Cfraz      ! squeezing coefficient for collection of bottom frazil ice
45
46   !!----------------------------------------------------------------------
47   !! NEMO/ICE 4.0 , NEMO Consortium (2018)
48   !! $Id$
49   !! Software governed by the CeCILL license (see ./LICENSE)
50   !!----------------------------------------------------------------------
51CONTAINS
52
53   SUBROUTINE ice_thd_do
54      !!-------------------------------------------------------------------
55      !!               ***   ROUTINE ice_thd_do  ***
56      !! 
57      !! ** Purpose : Computation of the evolution of the ice thickness and
58      !!              concentration as a function of the heat balance in the leads
59      !!       
60      !! ** Method  : Ice is formed in the open water when ocean looses heat
61      !!              (heat budget of open water is negative) following
62      !!
63      !!       (dA/dt)acc = F[ (1-A)/(1-a) ] * [ Bl / (Li*h0) ]
64      !!          where - h0 is the thickness of ice created in the lead
65      !!                - a is a minimum fraction for leads
66      !!                - F is a monotonic non-increasing function defined as:
67      !!                  F(X)=( 1 - X**exld )**(1.0/exld)
68      !!                - exld is the exponent closure rate (=2 default val.)
69      !!
70      !! ** Action : - Adjustment of snow and ice thicknesses and heat
71      !!                content in brine pockets
72      !!             - Updating ice internal temperature
73      !!             - Computation of variation of ice volume and mass
74      !!             - Computation of a_i after lateral accretion and
75      !!               update h_s_1d, h_i_1d     
76      !!------------------------------------------------------------------------
77      INTEGER  ::   ji, jj, jk, jl   ! dummy loop indices
78      INTEGER  ::   iter             !   -       -
79      REAL(wp) ::   ztmelts, zfrazb, zweight, zde                               ! local scalars
80      REAL(wp) ::   zgamafr, zvfrx, zvgx, ztaux, ztwogp, zf                     !   -      -
81      REAL(wp) ::   ztenagm, zvfry, zvgy, ztauy, zvrel2, zfp, zsqcd , zhicrit   !   -      -
82      !
83      REAL(wp) ::   zQm          ! enthalpy exchanged with the ocean (J/m2, >0 towards ocean)
84      REAL(wp) ::   zEi          ! sea ice specific enthalpy (J/kg)
85      REAL(wp) ::   zEw          ! seawater specific enthalpy (J/kg)
86      REAL(wp) ::   zfmdt        ! mass flux x time step (kg/m2, >0 towards ocean)
87      !
88      REAL(wp) ::   zv_newfra
89      !
90      INTEGER , DIMENSION(jpij) ::   jcat        ! indexes of categories where new ice grows
91      REAL(wp), DIMENSION(jpij) ::   zswinew     ! switch for new ice or not
92      !
93      REAL(wp), DIMENSION(jpij) ::   zv_newice   ! volume of accreted ice
94      REAL(wp), DIMENSION(jpij) ::   za_newice   ! fractional area of accreted ice
95      REAL(wp), DIMENSION(jpij) ::   zh_newice   ! thickness of accreted ice
96      REAL(wp), DIMENSION(jpij) ::   ze_newice   ! heat content of accreted ice
97      REAL(wp), DIMENSION(jpij) ::   zs_newice   ! salinity of accreted ice
98      REAL(wp), DIMENSION(jpij) ::   zo_newice   ! age of accreted ice
99      REAL(wp), DIMENSION(jpij) ::   zdv_res     ! residual volume in case of excessive heat budget
100      REAL(wp), DIMENSION(jpij) ::   zda_res     ! residual area in case of excessive heat budget
101      REAL(wp), DIMENSION(jpij) ::   zv_frazb    ! accretion of frazil ice at the ice bottom
102      REAL(wp), DIMENSION(jpij) ::   zvrel_1d    ! relative ice / frazil velocity (1D vector)
103      !
104      REAL(wp), DIMENSION(jpij,jpl) ::   zv_b    ! old volume of ice in category jl
105      REAL(wp), DIMENSION(jpij,jpl) ::   za_b    ! old area of ice in category jl
106      !
107      REAL(wp), DIMENSION(jpij,nlay_i,jpl) ::   ze_i_2d !: 1-D version of e_i
108      !
109      REAL(wp), DIMENSION(jpi,jpj) ::   zvrel    ! relative ice / frazil velocity
110      !
111      REAL(wp) :: zcai = 1.4e-3_wp               ! ice-air drag (clem: should be dependent on coupling/forcing used)
112      !!-----------------------------------------------------------------------!
113
114      IF( ln_icediachk )   CALL ice_cons_hsm( 0, 'icethd_do', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft )
115
116      at_i(:,:) = SUM( a_i, dim=3 )
117      !------------------------------------------------------------------------------!
118      ! 1) Collection thickness of ice formed in leads and polynyas
119      !------------------------------------------------------------------------------!   
120      ! ht_i_new is the thickness of new ice formed in open water
121      ! ht_i_new can be either prescribed (ln_frazil=F) or computed (ln_frazil=T)
122      ! Frazil ice forms in open water, is transported by wind
123      ! accumulates at the edge of the consolidated ice edge
124      ! where it forms aggregates of a specific thickness called
125      ! collection thickness.
126
127      zvrel(:,:) = 0._wp
128
129      ! Default new ice thickness
130      WHERE( qlead(:,:) < 0._wp )   ;   ht_i_new(:,:) = rn_hinew
131      ELSEWHERE                     ;   ht_i_new(:,:) = 0._wp
132      END WHERE
133
134      IF( ln_frazil ) THEN
135         !
136         ht_i_new(:,:) = 0._wp
137         !
138         ! Physical constants
139         zhicrit = 0.04                                          ! frazil ice thickness
140         ztwogp  = 2. * rau0 / ( grav * 0.3 * ( rau0 - rhoi ) )  ! reduced grav
141         zsqcd   = 1.0 / SQRT( 1.3 * zcai )                      ! 1/SQRT(airdensity*drag)
142         zgamafr = 0.03
143         !
144         DO jj = 2, jpjm1
145            DO ji = 2, jpim1
146               IF ( qlead(ji,jj) < 0._wp .AND. tau_icebfr(ji,jj) == 0._wp ) THEN ! activated if cooling and no landfast
147                  ! -- Wind stress -- !
148                  ztaux         = ( utau_ice(ji-1,jj  ) * umask(ji-1,jj  ,1)   &
149                     &          +   utau_ice(ji  ,jj  ) * umask(ji  ,jj  ,1) ) * 0.5_wp
150                  ztauy         = ( vtau_ice(ji  ,jj-1) * vmask(ji  ,jj-1,1)   &
151                     &          +   vtau_ice(ji  ,jj  ) * vmask(ji  ,jj  ,1) ) * 0.5_wp
152                  ! Square root of wind stress
153                  ztenagm       =  SQRT( SQRT( ztaux * ztaux + ztauy * ztauy ) )
154
155                  ! -- Frazil ice velocity -- !
156                  rswitch = MAX( 0._wp, SIGN( 1._wp , ztenagm - epsi10 ) )
157                  zvfrx   = rswitch * zgamafr * zsqcd * ztaux / MAX( ztenagm, epsi10 )
158                  zvfry   = rswitch * zgamafr * zsqcd * ztauy / MAX( ztenagm, epsi10 )
159
160                  ! -- Pack ice velocity -- !
161                  zvgx    = ( u_ice(ji-1,jj  ) * umask(ji-1,jj  ,1)  + u_ice(ji,jj) * umask(ji,jj,1) ) * 0.5_wp
162                  zvgy    = ( v_ice(ji  ,jj-1) * vmask(ji  ,jj-1,1)  + v_ice(ji,jj) * vmask(ji,jj,1) ) * 0.5_wp
163
164                  ! -- Relative frazil/pack ice velocity -- !
165                  rswitch      = MAX( 0._wp, SIGN( 1._wp , at_i(ji,jj) - epsi10 ) )
166                  zvrel2       = MAX(  ( zvfrx - zvgx ) * ( zvfrx - zvgx )   &
167                     &               + ( zvfry - zvgy ) * ( zvfry - zvgy ) , 0.15 * 0.15 ) * rswitch
168                  zvrel(ji,jj) = SQRT( zvrel2 )
169
170                  ! -- new ice thickness (iterative loop) -- !
171                  ht_i_new(ji,jj) = zhicrit +   ( zhicrit + 0.1 )    &
172                     &                   / ( ( zhicrit + 0.1 ) * ( zhicrit + 0.1 ) -  zhicrit * zhicrit ) * ztwogp * zvrel2
173
174                  iter = 1
175                  DO WHILE ( iter < 20 ) 
176                     zf  = ( ht_i_new(ji,jj) - zhicrit ) * ( ht_i_new(ji,jj) * ht_i_new(ji,jj) - zhicrit * zhicrit ) -   &
177                        &    ht_i_new(ji,jj) * zhicrit * ztwogp * zvrel2
178                     zfp = ( ht_i_new(ji,jj) - zhicrit ) * ( 3.0 * ht_i_new(ji,jj) + zhicrit ) - zhicrit * ztwogp * zvrel2
179
180                     ht_i_new(ji,jj) = ht_i_new(ji,jj) - zf / MAX( zfp, epsi20 )
181                     iter = iter + 1
182                  END DO
183                  !
184               ENDIF
185               !
186            END DO
187         END DO 
188         !
189         CALL lbc_lnk_multi( 'icethd_do', zvrel, 'T', 1., ht_i_new, 'T', 1.  )
190
191      ENDIF
192
193      !------------------------------------------------------------------------------!
194      ! 2) Compute thickness, salinity, enthalpy, age, area and volume of new ice
195      !------------------------------------------------------------------------------!
196      ! This occurs if open water energy budget is negative (cooling) and there is no landfast ice
197
198      ! Identify grid points where new ice forms
199      npti = 0   ;   nptidx(:) = 0
200      DO jj = 1, jpj
201         DO ji = 1, jpi
202            IF ( qlead(ji,jj)  <  0._wp .AND. tau_icebfr(ji,jj) == 0._wp ) THEN
203               npti = npti + 1
204               nptidx( npti ) = (jj - 1) * jpi + ji
205            ENDIF
206         END DO
207      END DO
208
209      ! Move from 2-D to 1-D vectors
210      IF ( npti > 0 ) THEN
211
212         CALL tab_2d_1d( npti, nptidx(1:npti), at_i_1d(1:npti)      , at_i        )
213         CALL tab_3d_2d( npti, nptidx(1:npti), a_i_2d (1:npti,1:jpl), a_i (:,:,:) )
214         CALL tab_3d_2d( npti, nptidx(1:npti), v_i_2d (1:npti,1:jpl), v_i (:,:,:) )
215         CALL tab_3d_2d( npti, nptidx(1:npti), sv_i_2d(1:npti,1:jpl), sv_i(:,:,:) )
216         DO jl = 1, jpl
217            DO jk = 1, nlay_i
218               CALL tab_2d_1d( npti, nptidx(1:npti), ze_i_2d(1:npti,jk,jl), e_i(:,:,jk,jl) )
219            END DO
220         END DO
221         CALL tab_2d_1d( npti, nptidx(1:npti), qlead_1d  (1:npti) , qlead      )
222         CALL tab_2d_1d( npti, nptidx(1:npti), t_bo_1d   (1:npti) , t_bo       )
223         CALL tab_2d_1d( npti, nptidx(1:npti), sfx_opw_1d(1:npti) , sfx_opw    )
224         CALL tab_2d_1d( npti, nptidx(1:npti), wfx_opw_1d(1:npti) , wfx_opw    )
225         CALL tab_2d_1d( npti, nptidx(1:npti), zh_newice (1:npti) , ht_i_new   )
226         CALL tab_2d_1d( npti, nptidx(1:npti), zvrel_1d  (1:npti) , zvrel      )
227
228         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_thd_1d(1:npti) , hfx_thd    )
229         CALL tab_2d_1d( npti, nptidx(1:npti), hfx_opw_1d(1:npti) , hfx_opw    )
230         CALL tab_2d_1d( npti, nptidx(1:npti), rn_amax_1d(1:npti) , rn_amax_2d )
231         CALL tab_2d_1d( npti, nptidx(1:npti), sss_1d    (1:npti) , sss_m      )
232
233         ! Convert units for ice internal energy
234         DO jl = 1, jpl
235            DO jk = 1, nlay_i               
236               WHERE( v_i_2d(1:npti,jl) > 0._wp )
237                  ze_i_2d(1:npti,jk,jl) = ze_i_2d(1:npti,jk,jl) / v_i_2d(1:npti,jl) * REAL( nlay_i )
238               ELSEWHERE
239                  ze_i_2d(1:npti,jk,jl) = 0._wp
240               END WHERE
241            END DO
242         END DO
243
244         ! Keep old ice areas and volume in memory
245         zv_b(1:npti,:) = v_i_2d(1:npti,:) 
246         za_b(1:npti,:) = a_i_2d(1:npti,:)
247
248         ! --- Salinity of new ice --- !
249         SELECT CASE ( nn_icesal )
250         CASE ( 1 )                    ! Sice = constant
251            zs_newice(1:npti) = rn_icesal
252         CASE ( 2 )                    ! Sice = F(z,t) [Vancoppenolle et al (2005)]
253            DO ji = 1, npti
254               zs_newice(ji) = MIN(  4.606 + 0.91 / zh_newice(ji) , rn_simax , 0.5 * sss_1d(ji) )
255            END DO
256         CASE ( 3 )                    ! Sice = F(z) [multiyear ice]
257            zs_newice(1:npti) =   2.3
258         END SELECT
259
260         ! --- Heat content of new ice --- !
261         ! We assume that new ice is formed at the seawater freezing point
262         DO ji = 1, npti
263            ztmelts       = - rTmlt * zs_newice(ji)                  ! Melting point (C)
264            ze_newice(ji) =   rhoi * (  rcpi  * ( ztmelts - ( t_bo_1d(ji) - rt0 ) )                     &
265               &                      + rLfus * ( 1.0 - ztmelts / MIN( t_bo_1d(ji) - rt0, -epsi10 ) )   &
266               &                      - rcp   *         ztmelts )
267         END DO
268
269         ! --- Age of new ice --- !
270         zo_newice(1:npti) = 0._wp
271
272         ! --- Volume of new ice --- !
273         DO ji = 1, npti
274
275            zEi           = - ze_newice(ji) * r1_rhoi              ! specific enthalpy of forming ice [J/kg]
276
277            zEw           = rcp * ( t_bo_1d(ji) - rt0 )            ! specific enthalpy of seawater at t_bo_1d [J/kg]
278                                                                   ! clem: we suppose we are already at the freezing point (condition qlead<0 is satisfyied)
279                                                                   
280            zdE           = zEi - zEw                              ! specific enthalpy difference [J/kg]
281                                             
282            zfmdt         = - qlead_1d(ji) / zdE                   ! Fm.dt [kg/m2] (<0)
283                                                                   ! clem: we use qlead instead of zqld (icethd) because we suppose we are at the freezing point   
284            zv_newice(ji) = - zfmdt * r1_rhoi
285
286            zQm           = zfmdt * zEw                            ! heat to the ocean >0 associated with mass flux 
287
288            ! Contribution to heat flux to the ocean [W.m-2], >0 
289            hfx_thd_1d(ji) = hfx_thd_1d(ji) + zfmdt * zEw * r1_rdtice
290            ! Total heat flux used in this process [W.m-2] 
291            hfx_opw_1d(ji) = hfx_opw_1d(ji) - zfmdt * zdE * r1_rdtice
292            ! mass flux
293            wfx_opw_1d(ji) = wfx_opw_1d(ji) - zv_newice(ji) * rhoi * r1_rdtice
294            ! salt flux
295            sfx_opw_1d(ji) = sfx_opw_1d(ji) - zv_newice(ji) * rhoi * zs_newice(ji) * r1_rdtice
296         END DO
297         
298         zv_frazb(1:npti) = 0._wp
299         IF( ln_frazil ) THEN
300            ! A fraction zfrazb of frazil ice is accreted at the ice bottom
301            DO ji = 1, npti
302               rswitch       = 1._wp - MAX( 0._wp, SIGN( 1._wp , - at_i_1d(ji) ) )
303               zfrazb        = rswitch * ( TANH( rn_Cfraz * ( zvrel_1d(ji) - rn_vfraz ) ) + 1.0 ) * 0.5 * rn_maxfraz
304               zv_frazb(ji)  =         zfrazb   * zv_newice(ji)
305               zv_newice(ji) = ( 1.0 - zfrazb ) * zv_newice(ji)
306            END DO
307         END IF
308         
309         ! --- Area of new ice --- !
310         DO ji = 1, npti
311            za_newice(ji) = zv_newice(ji) / zh_newice(ji)
312         END DO
313
314         !------------------------------------------------------------------------------!
315         ! 3) Redistribute new ice area and volume into ice categories                  !
316         !------------------------------------------------------------------------------!
317
318         ! --- lateral ice growth --- !
319         ! If lateral ice growth gives an ice concentration > amax, then
320         ! we keep the excessive volume in memory and attribute it later to bottom accretion
321         DO ji = 1, npti
322            IF ( za_newice(ji) >  MAX( 0._wp, rn_amax_1d(ji) - at_i_1d(ji) ) ) THEN ! max is for roundoff error
323               zda_res(ji)   = za_newice(ji) - MAX( 0._wp, rn_amax_1d(ji) - at_i_1d(ji) )
324               zdv_res(ji)   = zda_res  (ji) * zh_newice(ji) 
325               za_newice(ji) = MAX( 0._wp, za_newice(ji) - zda_res  (ji) )
326               zv_newice(ji) = MAX( 0._wp, zv_newice(ji) - zdv_res  (ji) )
327            ELSE
328               zda_res(ji) = 0._wp
329               zdv_res(ji) = 0._wp
330            ENDIF
331         END DO
332
333         ! find which category to fill
334         DO jl = 1, jpl
335            DO ji = 1, npti
336               IF( zh_newice(ji) > hi_max(jl-1) .AND. zh_newice(ji) <= hi_max(jl) ) THEN
337                  a_i_2d(ji,jl) = a_i_2d(ji,jl) + za_newice(ji)
338                  v_i_2d(ji,jl) = v_i_2d(ji,jl) + zv_newice(ji)
339                  jcat(ji) = jl
340               ENDIF
341            END DO
342         END DO
343         at_i_1d(1:npti) = SUM( a_i_2d(1:npti,:), dim=2 )
344
345         ! Heat content
346         DO ji = 1, npti
347            jl = jcat(ji)                                                    ! categroy in which new ice is put
348            zswinew  (ji) = MAX( 0._wp , SIGN( 1._wp , - za_b(ji,jl) ) )   ! 0 if old ice
349         END DO
350
351         DO jk = 1, nlay_i
352            DO ji = 1, npti
353               jl = jcat(ji)
354               rswitch = MAX( 0._wp, SIGN( 1._wp , v_i_2d(ji,jl) - epsi20 ) )
355               ze_i_2d(ji,jk,jl) = zswinew(ji)   *   ze_newice(ji) +                                                    &
356                  &        ( 1.0 - zswinew(ji) ) * ( ze_newice(ji) * zv_newice(ji) + ze_i_2d(ji,jk,jl) * zv_b(ji,jl) )  &
357                  &        * rswitch / MAX( v_i_2d(ji,jl), epsi20 )
358            END DO
359         END DO
360
361         ! --- bottom ice growth + ice enthalpy remapping --- !
362         DO jl = 1, jpl
363
364            ! for remapping
365            h_i_old (1:npti,0:nlay_i+1) = 0._wp
366            eh_i_old(1:npti,0:nlay_i+1) = 0._wp
367            DO jk = 1, nlay_i
368               DO ji = 1, npti
369                  h_i_old (ji,jk) = v_i_2d(ji,jl) * r1_nlay_i
370                  eh_i_old(ji,jk) = ze_i_2d(ji,jk,jl) * h_i_old(ji,jk)
371               END DO
372            END DO
373
374            ! new volumes including lateral/bottom accretion + residual
375            DO ji = 1, npti
376               rswitch        = MAX( 0._wp, SIGN( 1._wp , at_i_1d(ji) - epsi20 ) )
377               zv_newfra     = rswitch * ( zdv_res(ji) + zv_frazb(ji) ) * a_i_2d(ji,jl) / MAX( at_i_1d(ji) , epsi20 )
378               a_i_2d(ji,jl) = rswitch * a_i_2d(ji,jl)               
379               v_i_2d(ji,jl) = v_i_2d(ji,jl) + zv_newfra
380               ! for remapping
381               h_i_old (ji,nlay_i+1) = zv_newfra
382               eh_i_old(ji,nlay_i+1) = ze_newice(ji) * zv_newfra
383            END DO
384            ! --- Ice enthalpy remapping --- !
385            CALL ice_thd_ent( ze_i_2d(1:npti,:,jl) ) 
386         END DO
387
388         ! --- Update salinity --- !
389         DO jl = 1, jpl
390            DO ji = 1, npti
391               sv_i_2d(ji,jl) = sv_i_2d(ji,jl) + zs_newice(ji) * ( v_i_2d(ji,jl) - zv_b(ji,jl) )
392            END DO
393         END DO
394
395         ! Change units for e_i
396         DO jl = 1, jpl
397            DO jk = 1, nlay_i
398               ze_i_2d(1:npti,jk,jl) = ze_i_2d(1:npti,jk,jl) * v_i_2d(1:npti,jl) * r1_nlay_i 
399            END DO
400         END DO
401
402         ! Move 2D vectors to 1D vectors
403         CALL tab_2d_3d( npti, nptidx(1:npti), a_i_2d (1:npti,1:jpl), a_i (:,:,:) )
404         CALL tab_2d_3d( npti, nptidx(1:npti), v_i_2d (1:npti,1:jpl), v_i (:,:,:) )
405         CALL tab_2d_3d( npti, nptidx(1:npti), sv_i_2d(1:npti,1:jpl), sv_i(:,:,:) )
406          DO jl = 1, jpl
407            DO jk = 1, nlay_i
408               CALL tab_1d_2d( npti, nptidx(1:npti), ze_i_2d(1:npti,jk,jl), e_i(:,:,jk,jl) )
409            END DO
410         END DO
411         CALL tab_1d_2d( npti, nptidx(1:npti), sfx_opw_1d(1:npti), sfx_opw )
412         CALL tab_1d_2d( npti, nptidx(1:npti), wfx_opw_1d(1:npti), wfx_opw )
413         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_thd_1d(1:npti), hfx_thd )
414         CALL tab_1d_2d( npti, nptidx(1:npti), hfx_opw_1d(1:npti), hfx_opw )
415         !
416      ENDIF ! npti > 0
417      !
418      IF( ln_icediachk )   CALL ice_cons_hsm(1, 'icethd_do', rdiag_v, rdiag_s, rdiag_t, rdiag_fv, rdiag_fs, rdiag_ft)
419      !
420   END SUBROUTINE ice_thd_do
421
422
423   SUBROUTINE ice_thd_do_init
424      !!-----------------------------------------------------------------------
425      !!                   ***  ROUTINE ice_thd_do_init ***
426      !!                 
427      !! ** Purpose :   Physical constants and parameters associated with
428      !!                ice growth in the leads
429      !!
430      !! ** Method  :   Read the namthd_do namelist and check the parameters
431      !!                called at the first timestep (nit000)
432      !!
433      !! ** input   :   Namelist namthd_do
434      !!-------------------------------------------------------------------
435      INTEGER  ::   ios   ! Local integer
436      !!
437      NAMELIST/namthd_do/ rn_hinew, ln_frazil, rn_maxfraz, rn_vfraz, rn_Cfraz
438      !!-------------------------------------------------------------------
439      !
440      REWIND( numnam_ice_ref )              ! Namelist namthd_do in reference namelist : Ice thermodynamics
441      READ  ( numnam_ice_ref, namthd_do, IOSTAT = ios, ERR = 901)
442901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namthd_do in reference namelist', lwp )
443      REWIND( numnam_ice_cfg )              ! Namelist namthd_do in configuration namelist : Ice thermodynamics
444      READ  ( numnam_ice_cfg, namthd_do, IOSTAT = ios, ERR = 902 )
445902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namthd_do in configuration namelist', lwp )
446      IF(lwm) WRITE( numoni, namthd_do )
447      !
448      IF(lwp) THEN                          ! control print
449         WRITE(numout,*)
450         WRITE(numout,*) 'ice_thd_do_init: Ice growth in open water'
451         WRITE(numout,*) '~~~~~~~~~~~~~~~'
452         WRITE(numout,*) '   Namelist namthd_do:'
453         WRITE(numout,*) '      ice thickness for lateral accretion                       rn_hinew   = ', rn_hinew
454         WRITE(numout,*) '      Frazil ice thickness as a function of wind or not         ln_frazil  = ', ln_frazil
455         WRITE(numout,*) '      Maximum proportion of frazil ice collecting at bottom     rn_maxfraz = ', rn_maxfraz
456         WRITE(numout,*) '      Threshold relative drift speed for collection of frazil   rn_vfraz   = ', rn_vfraz
457         WRITE(numout,*) '      Squeezing coefficient for collection of frazil            rn_Cfraz   = ', rn_Cfraz
458      ENDIF
459      !
460      IF ( rn_hinew < rn_himin )   CALL ctl_stop( 'ice_thd_do_init : rn_hinew should be >= rn_himin' )
461      !
462   END SUBROUTINE ice_thd_do_init
463   
464#else
465   !!----------------------------------------------------------------------
466   !!   Default option                                NO SI3 sea-ice model
467   !!----------------------------------------------------------------------
468#endif
469
470   !!======================================================================
471END MODULE icethd_do
Note: See TracBrowser for help on using the repository browser.