Context Navigation

dynhpg.F90 @ 11467

Last change on this file since 11467 was 11467, checked in by andmirek, 5 years ago
Ticket #2197 allocate arrays at the beggining of the run
File size: 72.1 KB

Line
1	MODULE dynhpg
2	!!======================================================================
3	!! * MODULE dynhpg *
4	!! Ocean dynamics: hydrostatic pressure gradient trend
5	!!======================================================================
6	!! History : OPA ! 1987-09 (P. Andrich, M.-A. Foujols) hpg_zco: Original code
7	!! 5.0 ! 1991-11 (G. Madec)
8	!! 7.0 ! 1996-01 (G. Madec) hpg_sco: Original code for s-coordinates
9	!! 8.0 ! 1997-05 (G. Madec) split dynber into dynkeg and dynhpg
10	!! 8.5 ! 2002-07 (G. Madec) F90: Free form and module
11	!! 8.5 ! 2002-08 (A. Bozec) hpg_zps: Original code
12	!! NEMO 1.0 ! 2005-10 (A. Beckmann, B.W. An) various s-coordinate options
13	!! ! Original code for hpg_ctl, hpg_hel hpg_wdj, hpg_djc, hpg_rot
14	!! - ! 2005-11 (G. Madec) style & small optimisation
15	!! 3.3 ! 2010-10 (C. Ethe, G. Madec) reorganisation of initialisation phase
16	!! 3.4 ! 2011-11 (H. Liu) hpg_prj: Original code for s-coordinates
17	!! ! (A. Coward) suppression of hel, wdj and rot options
18	!! 3.6 ! 2014-11 (P. Mathiot) hpg_isf: original code for ice shelf cavity
19	!!----------------------------------------------------------------------
20
21	!!----------------------------------------------------------------------
22	!! dyn_hpg : update the momentum trend with the now horizontal
23	!! gradient of the hydrostatic pressure
24	!! dyn_hpg_init : initialisation and control of options
25	!! hpg_zco : z-coordinate scheme
26	!! hpg_zps : z-coordinate plus partial steps (interpolation)
27	!! hpg_sco : s-coordinate (standard jacobian formulation)
28	!! hpg_isf : s-coordinate (sco formulation) adapted to ice shelf
29	!! hpg_djc : s-coordinate (Density Jacobian with Cubic polynomial)
30	!! hpg_prj : s-coordinate (Pressure Jacobian with Cubic polynomial)
31	!!----------------------------------------------------------------------
32	USE oce ! ocean dynamics and tracers
33	USE sbc_oce ! surface variable (only for the flag with ice shelf)
34	USE dom_oce ! ocean space and time domain
35	USE wet_dry ! wetting and drying
36	USE phycst ! physical constants
37	USE trd_oce ! trends: ocean variables
38	USE trddyn ! trend manager: dynamics
39	!jc USE zpshde ! partial step: hor. derivative (zps_hde routine)
40	!
41	USE in_out_manager ! I/O manager
42	USE prtctl ! Print control
43	USE lbclnk ! lateral boundary condition
44	USE lib_mpp ! MPP library
45	USE eosbn2 ! compute density
46	USE timing ! Timing
47	USE iom
48
49	IMPLICIT NONE
50	PRIVATE
51
52	PUBLIC dyn_hpg ! routine called by step module
53	PUBLIC dyn_hpg_init ! routine called by opa module
54
55	! !!* Namelist namdyn_hpg : hydrostatic pressure gradient
56	LOGICAL, PUBLIC :: ln_hpg_zco !: z-coordinate - full steps
57	LOGICAL, PUBLIC :: ln_hpg_zps !: z-coordinate - partial steps (interpolation)
58	LOGICAL, PUBLIC :: ln_hpg_sco !: s-coordinate (standard jacobian formulation)
59	LOGICAL, PUBLIC :: ln_hpg_djc !: s-coordinate (Density Jacobian with Cubic polynomial)
60	LOGICAL, PUBLIC :: ln_hpg_prj !: s-coordinate (Pressure Jacobian scheme)
61	LOGICAL, PUBLIC :: ln_hpg_isf !: s-coordinate similar to sco modify for isf
62
63	! !! Flag to control the type of hydrostatic pressure gradient
64	INTEGER, PARAMETER :: np_ERROR =-10 ! error in specification of lateral diffusion
65	INTEGER, PARAMETER :: np_zco = 0 ! z-coordinate - full steps
66	INTEGER, PARAMETER :: np_zps = 1 ! z-coordinate - partial steps (interpolation)
67	INTEGER, PARAMETER :: np_sco = 2 ! s-coordinate (standard jacobian formulation)
68	INTEGER, PARAMETER :: np_djc = 3 ! s-coordinate (Density Jacobian with Cubic polynomial)
69	INTEGER, PARAMETER :: np_prj = 4 ! s-coordinate (Pressure Jacobian scheme)
70	INTEGER, PARAMETER :: np_isf = 5 ! s-coordinate similar to sco modify for isf
71	!
72	INTEGER, PUBLIC :: nhpg !: type of pressure gradient scheme used ! (deduced from ln_hpg_... flags) (PUBLIC for TAM)
73
74	!! * Substitutions
75	# include "vectopt_loop_substitute.h90"
76	!!----------------------------------------------------------------------
77	!! NEMO/OCE 4.0 , NEMO Consortium (2018)
78	!! $Id$
79	!! Software governed by the CeCILL license (see ./LICENSE)
80	!!----------------------------------------------------------------------
81	CONTAINS
82
83	SUBROUTINE dyn_hpg( kt )
84	!!---------------------------------------------------------------------
85	!! * ROUTINE dyn_hpg *
86	!!
87	!! ** Method : Call the hydrostatic pressure gradient routine
88	!! using the scheme defined in the namelist
89	!!
90	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
91	!! - send trends to trd_dyn for futher diagnostics (l_trddyn=T)
92	!!----------------------------------------------------------------------
93	INTEGER, INTENT(in) :: kt ! ocean time-step index
94	REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: ztrdu, ztrdv
95	!!----------------------------------------------------------------------
96	!
97	IF( ln_timing ) CALL timing_start('dyn_hpg')
98	!
99	IF( l_trddyn ) THEN ! Temporary saving of ua and va trends (l_trddyn)
100	ALLOCATE( ztrdu(jpi,jpj,jpk) , ztrdv(jpi,jpj,jpk) )
101	ztrdu(:,:,:) = ua(:,:,:)
102	ztrdv(:,:,:) = va(:,:,:)
103	ENDIF
104	!
105	SELECT CASE ( nhpg ) ! Hydrostatic pressure gradient computation
106	CASE ( np_zco ) ; CALL hpg_zco ( kt ) ! z-coordinate
107	CASE ( np_zps ) ; CALL hpg_zps ( kt ) ! z-coordinate plus partial steps (interpolation)
108	CASE ( np_sco ) ; CALL hpg_sco ( kt ) ! s-coordinate (standard jacobian formulation)
109	CASE ( np_djc ) ; CALL hpg_djc ( kt ) ! s-coordinate (Density Jacobian with Cubic polynomial)
110	CASE ( np_prj ) ; CALL hpg_prj ( kt ) ! s-coordinate (Pressure Jacobian scheme)
111	CASE ( np_isf ) ; CALL hpg_isf ( kt ) ! s-coordinate similar to sco modify for ice shelf
112	END SELECT
113	!
114	IF( l_trddyn ) THEN ! save the hydrostatic pressure gradient trends for momentum trend diagnostics
115	ztrdu(:,:,:) = ua(:,:,:) - ztrdu(:,:,:)
116	ztrdv(:,:,:) = va(:,:,:) - ztrdv(:,:,:)
117	CALL trd_dyn( ztrdu, ztrdv, jpdyn_hpg, kt )
118	DEALLOCATE( ztrdu , ztrdv )
119	ENDIF
120	!
121	IF(ln_ctl) CALL prt_ctl( tab3d_1=ua, clinfo1=' hpg - Ua: ', mask1=umask, &
122	& tab3d_2=va, clinfo2= ' Va: ', mask2=vmask, clinfo3='dyn' )
123	!
124	IF( ln_timing ) CALL timing_stop('dyn_hpg')
125	!
126	END SUBROUTINE dyn_hpg
127
128
129	SUBROUTINE dyn_hpg_init
130	!!----------------------------------------------------------------------
131	!! * ROUTINE dyn_hpg_init *
132	!!
133	!! ** Purpose : initializations for the hydrostatic pressure gradient
134	!! computation and consistency control
135	!!
136	!! ** Action : Read the namelist namdyn_hpg and check the consistency
137	!! with the type of vertical coordinate used (zco, zps, sco)
138	!!----------------------------------------------------------------------
139	INTEGER :: ioptio = 0 ! temporary integer
140	INTEGER :: ios ! Local integer output status for namelist read
141	!!
142	INTEGER :: ji, jj, jk, ikt ! dummy loop indices ISF
143	REAL(wp) :: znad
144	REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zts_top, zrhd ! hypothesys on isf density
145	REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zrhdtop_isf ! density at bottom of ISF
146	REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: ziceload ! density at bottom of ISF
147	!!
148	NAMELIST/namdyn_hpg/ ln_hpg_zco, ln_hpg_zps, ln_hpg_sco, &
149	& ln_hpg_djc, ln_hpg_prj, ln_hpg_isf
150	!!----------------------------------------------------------------------
151	!
152	REWIND( numnam_ref ) ! Namelist namdyn_hpg in reference namelist : Hydrostatic pressure gradient
153	READ ( numnam_ref, namdyn_hpg, IOSTAT = ios, ERR = 901)
154	901 IF( ios /= 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in reference namelist', lwp )
155	!
156	REWIND( numnam_cfg ) ! Namelist namdyn_hpg in configuration namelist : Hydrostatic pressure gradient
157	READ ( numnam_cfg, namdyn_hpg, IOSTAT = ios, ERR = 902 )
158	902 IF( ios > 0 ) CALL ctl_nam ( ios , 'namdyn_hpg in configuration namelist', lwp )
159	IF(lwm) WRITE ( numond, namdyn_hpg )
160	!
161	IF(lwp) THEN ! Control print
162	WRITE(numout,*)
163	WRITE(numout,*) 'dyn_hpg_init : hydrostatic pressure gradient initialisation'
164	WRITE(numout,*) '~~~~~~~~~~~~'
165	WRITE(numout,*) ' Namelist namdyn_hpg : choice of hpg scheme'
166	WRITE(numout,*) ' z-coord. - full steps ln_hpg_zco = ', ln_hpg_zco
167	WRITE(numout,*) ' z-coord. - partial steps (interpolation) ln_hpg_zps = ', ln_hpg_zps
168	WRITE(numout,*) ' s-coord. (standard jacobian formulation) ln_hpg_sco = ', ln_hpg_sco
169	WRITE(numout,*) ' s-coord. (standard jacobian formulation) for isf ln_hpg_isf = ', ln_hpg_isf
170	WRITE(numout,*) ' s-coord. (Density Jacobian: Cubic polynomial) ln_hpg_djc = ', ln_hpg_djc
171	WRITE(numout,*) ' s-coord. (Pressure Jacobian: Cubic polynomial) ln_hpg_prj = ', ln_hpg_prj
172	ENDIF
173	!
174	IF( ln_hpg_djc ) &
175	& CALL ctl_stop('dyn_hpg_init : Density Jacobian: Cubic polynominal method', &
176	& ' currently disabled (bugs under investigation).' , &
177	& ' Please select either ln_hpg_sco or ln_hpg_prj instead' )
178	!
179	IF( .NOT.ln_linssh .AND. .NOT.(ln_hpg_sco.OR.ln_hpg_prj.OR.ln_hpg_isf) ) &
180	& CALL ctl_stop('dyn_hpg_init : non-linear free surface requires either ', &
181	& ' the standard jacobian formulation hpg_sco or ' , &
182	& ' the pressure jacobian formulation hpg_prj' )
183	!
184	IF( ln_hpg_isf ) THEN
185	IF( .NOT. ln_isfcav ) CALL ctl_stop( ' hpg_isf not available if ln_isfcav = false ' )
186	ELSE
187	IF( ln_isfcav ) CALL ctl_stop( 'Only hpg_isf has been corrected to work with ice shelf cavity.' )
188	ENDIF
189	!
190	! ! Set nhpg from ln_hpg_... flags & consistency check
191	nhpg = np_ERROR
192	ioptio = 0
193	IF( ln_hpg_zco ) THEN ; nhpg = np_zco ; ioptio = ioptio +1 ; ENDIF
194	IF( ln_hpg_zps ) THEN ; nhpg = np_zps ; ioptio = ioptio +1 ; ENDIF
195	IF( ln_hpg_sco ) THEN ; nhpg = np_sco ; ioptio = ioptio +1 ; ENDIF
196	IF( ln_hpg_djc ) THEN ; nhpg = np_djc ; ioptio = ioptio +1 ; ENDIF
197	IF( ln_hpg_prj ) THEN ; nhpg = np_prj ; ioptio = ioptio +1 ; ENDIF
198	IF( ln_hpg_isf ) THEN ; nhpg = np_isf ; ioptio = ioptio +1 ; ENDIF
199	!
200	IF( ioptio /= 1 ) CALL ctl_stop( 'NO or several hydrostatic pressure gradient options used' )
201	!
202	IF(lwp) THEN
203	WRITE(numout,*)
204	SELECT CASE( nhpg )
205	CASE( np_zco ) ; WRITE(numout,*) ' ==>>> z-coord. - full steps '
206	CASE( np_zps ) ; WRITE(numout,*) ' ==>>> z-coord. - partial steps (interpolation)'
207	CASE( np_sco ) ; WRITE(numout,*) ' ==>>> s-coord. (standard jacobian formulation)'
208	CASE( np_djc ) ; WRITE(numout,*) ' ==>>> s-coord. (Density Jacobian: Cubic polynomial)'
209	CASE( np_prj ) ; WRITE(numout,*) ' ==>>> s-coord. (Pressure Jacobian: Cubic polynomial)'
210	CASE( np_isf ) ; WRITE(numout,*) ' ==>>> s-coord. (standard jacobian formulation) for isf'
211	END SELECT
212	WRITE(numout,*)
213	ENDIF
214	!
215	IF ( .NOT. ln_isfcav ) THEN !--- no ice shelf load
216	riceload(:,:) = 0._wp
217	!
218	ELSE !--- set an ice shelf load
219	!
220	IF(lwp) WRITE(numout,*)
221	IF(lwp) WRITE(numout,*) ' ice shelf case: set the ice-shelf load'
222	ALLOCATE( zts_top(jpi,jpj,jpts) , zrhd(jpi,jpj,jpk) , zrhdtop_isf(jpi,jpj) , ziceload(jpi,jpj) )
223	!
224	znad = 1._wp !- To use density and not density anomaly
225	!
226	! !- assume water displaced by the ice shelf is at T=-1.9 and S=34.4 (rude)
227	zts_top(:,:,jp_tem) = -1.9_wp ; zts_top(:,:,jp_sal) = 34.4_wp
228	!
229	DO jk = 1, jpk !- compute density of the water displaced by the ice shelf
230	CALL eos( zts_top(:,:,:), gdept_n(:,:,jk), zrhd(:,:,jk) )
231	END DO
232	!
233	! !- compute rhd at the ice/oce interface (ice shelf side)
234	CALL eos( zts_top , risfdep, zrhdtop_isf )
235	!
236	! !- Surface value + ice shelf gradient
237	ziceload = 0._wp ! compute pressure due to ice shelf load
238	DO jj = 1, jpj ! (used to compute hpgi/j for all the level from 1 to miku/v)
239	DO ji = 1, jpi ! divided by 2 later
240	ikt = mikt(ji,jj)
241	ziceload(ji,jj) = ziceload(ji,jj) + (znad + zrhd(ji,jj,1) ) * e3w_n(ji,jj,1) * (1._wp - tmask(ji,jj,1))
242	DO jk = 2, ikt-1
243	ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhd(ji,jj,jk-1) + zrhd(ji,jj,jk)) * e3w_n(ji,jj,jk) &
244	& * (1._wp - tmask(ji,jj,jk))
245	END DO
246	IF (ikt >= 2) ziceload(ji,jj) = ziceload(ji,jj) + (2._wp * znad + zrhdtop_isf(ji,jj) + zrhd(ji,jj,ikt-1)) &
247	& * ( risfdep(ji,jj) - gdept_1d(ikt-1) )
248	END DO
249	END DO
250	riceload(:,:) = ziceload(:,:) ! need to be saved for diaar5
251	!
252	DEALLOCATE( zts_top , zrhd , zrhdtop_isf , ziceload )
253	ENDIF
254	!
255	END SUBROUTINE dyn_hpg_init
256
257
258	SUBROUTINE hpg_zco( kt )
259	!!---------------------------------------------------------------------
260	!! * ROUTINE hpg_zco *
261	!!
262	!! ** Method : z-coordinate case, levels are horizontal surfaces.
263	!! The now hydrostatic pressure gradient at a given level, jk,
264	!! is computed by taking the vertical integral of the in-situ
265	!! density gradient along the model level from the suface to that
266	!! level: zhpi = grav .....
267	!! zhpj = grav .....
268	!! add it to the general momentum trend (ua,va).
269	!! ua = ua - 1/e1u * zhpi
270	!! va = va - 1/e2v * zhpj
271	!!
272	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
273	!!----------------------------------------------------------------------
274	USE scoce, ONLY : zhpi => scr1, zhpj => scr2
275	INTEGER, INTENT(in) :: kt ! ocean time-step index
276	!
277	INTEGER :: ji, jj, jk ! dummy loop indices
278	REAL(wp) :: zcoef0, zcoef1 ! temporary scalars
279	!!----------------------------------------------------------------------
280	!
281	IF( kt == nit000 ) THEN
282	IF(lwp) WRITE(numout,*)
283	IF(lwp) WRITE(numout,*) 'dyn:hpg_zco : hydrostatic pressure gradient trend'
284	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate case '
285	ENDIF
286
287	zcoef0 = - grav * 0.5_wp ! Local constant initialization
288
289	! Surface value
290	DO jj = 2, jpjm1
291	DO ji = fs_2, fs_jpim1 ! vector opt.
292	zcoef1 = zcoef0 * e3w_n(ji,jj,1)
293	! hydrostatic pressure gradient
294	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
295	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
296	! add to the general momentum trend
297	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
298	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
299	END DO
300	END DO
301
302	!
303	! interior value (2=<jk=<jpkm1)
304	DO jk = 2, jpkm1
305	DO jj = 2, jpjm1
306	DO ji = fs_2, fs_jpim1 ! vector opt.
307	zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
308	! hydrostatic pressure gradient
309	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
310	& + zcoef1 * ( ( rhd(ji+1,jj,jk)+rhd(ji+1,jj,jk-1) ) &
311	& - ( rhd(ji ,jj,jk)+rhd(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
312
313	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
314	& + zcoef1 * ( ( rhd(ji,jj+1,jk)+rhd(ji,jj+1,jk-1) ) &
315	& - ( rhd(ji,jj, jk)+rhd(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
316	! add to the general momentum trend
317	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
318	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
319	END DO
320	END DO
321	END DO
322	!
323	END SUBROUTINE hpg_zco
324
325
326	SUBROUTINE hpg_zps( kt )
327	!!---------------------------------------------------------------------
328	!! * ROUTINE hpg_zps *
329	!!
330	!! ** Method : z-coordinate plus partial steps case. blahblah...
331	!!
332	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
333	!!----------------------------------------------------------------------
334	USE scoce, ONLY : zhpi => scr1, zhpj => scr2
335	INTEGER, INTENT(in) :: kt ! ocean time-step index
336	!!
337	INTEGER :: ji, jj, jk ! dummy loop indices
338	INTEGER :: iku, ikv ! temporary integers
339	REAL(wp) :: zcoef0, zcoef1, zcoef2, zcoef3 ! temporary scalars
340	!!----------------------------------------------------------------------
341	!
342	IF( kt == nit000 ) THEN
343	IF(lwp) WRITE(numout,*)
344	IF(lwp) WRITE(numout,*) 'dyn:hpg_zps : hydrostatic pressure gradient trend'
345	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ z-coordinate with partial steps - vector optimization'
346	ENDIF
347
348	! Partial steps: bottom before horizontal gradient of t, s, rd at the last ocean level
349	!jc CALL zps_hde ( kt, jpts, tsn, gtsu, gtsv, rhd, gru , grv )
350
351	! Local constant initialization
352	zcoef0 = - grav * 0.5_wp
353
354	! Surface value (also valid in partial step case)
355	DO jj = 2, jpjm1
356	DO ji = fs_2, fs_jpim1 ! vector opt.
357	zcoef1 = zcoef0 * e3w_n(ji,jj,1)
358	! hydrostatic pressure gradient
359	zhpi(ji,jj,1) = zcoef1 * ( rhd(ji+1,jj ,1) - rhd(ji,jj,1) ) * r1_e1u(ji,jj)
360	zhpj(ji,jj,1) = zcoef1 * ( rhd(ji ,jj+1,1) - rhd(ji,jj,1) ) * r1_e2v(ji,jj)
361	! add to the general momentum trend
362	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
363	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
364	END DO
365	END DO
366
367	! interior value (2=<jk=<jpkm1)
368	DO jk = 2, jpkm1
369	DO jj = 2, jpjm1
370	DO ji = fs_2, fs_jpim1 ! vector opt.
371	zcoef1 = zcoef0 * e3w_n(ji,jj,jk)
372	! hydrostatic pressure gradient
373	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
374	& + zcoef1 * ( ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) ) &
375	& - ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) ) ) * r1_e1u(ji,jj)
376
377	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
378	& + zcoef1 * ( ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) ) &
379	& - ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) ) ) * r1_e2v(ji,jj)
380	! add to the general momentum trend
381	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
382	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
383	END DO
384	END DO
385	END DO
386
387	! partial steps correction at the last level (use gru & grv computed in zpshde.F90)
388	DO jj = 2, jpjm1
389	DO ji = 2, jpim1
390	iku = mbku(ji,jj)
391	ikv = mbkv(ji,jj)
392	zcoef2 = zcoef0 * MIN( e3w_n(ji,jj,iku), e3w_n(ji+1,jj ,iku) )
393	zcoef3 = zcoef0 * MIN( e3w_n(ji,jj,ikv), e3w_n(ji ,jj+1,ikv) )
394	IF( iku > 1 ) THEN ! on i-direction (level 2 or more)
395	ua (ji,jj,iku) = ua(ji,jj,iku) - zhpi(ji,jj,iku) ! subtract old value
396	zhpi(ji,jj,iku) = zhpi(ji,jj,iku-1) & ! compute the new one
397	& + zcoef2 * ( rhd(ji+1,jj,iku-1) - rhd(ji,jj,iku-1) + gru(ji,jj) ) * r1_e1u(ji,jj)
398	ua (ji,jj,iku) = ua(ji,jj,iku) + zhpi(ji,jj,iku) ! add the new one to the general momentum trend
399	ENDIF
400	IF( ikv > 1 ) THEN ! on j-direction (level 2 or more)
401	va (ji,jj,ikv) = va(ji,jj,ikv) - zhpj(ji,jj,ikv) ! subtract old value
402	zhpj(ji,jj,ikv) = zhpj(ji,jj,ikv-1) & ! compute the new one
403	& + zcoef3 * ( rhd(ji,jj+1,ikv-1) - rhd(ji,jj,ikv-1) + grv(ji,jj) ) * r1_e2v(ji,jj)
404	va (ji,jj,ikv) = va(ji,jj,ikv) + zhpj(ji,jj,ikv) ! add the new one to the general momentum trend
405	ENDIF
406	END DO
407	END DO
408	!
409	END SUBROUTINE hpg_zps
410
411
412	SUBROUTINE hpg_sco( kt )
413	!!---------------------------------------------------------------------
414	!! * ROUTINE hpg_sco *
415	!!
416	!! ** Method : s-coordinate case. Jacobian scheme.
417	!! The now hydrostatic pressure gradient at a given level, jk,
418	!! is computed by taking the vertical integral of the in-situ
419	!! density gradient along the model level from the suface to that
420	!! level. s-coordinates (ln_sco): a corrective term is added
421	!! to the horizontal pressure gradient :
422	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
423	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
424	!! add it to the general momentum trend (ua,va).
425	!! ua = ua - 1/e1u * zhpi
426	!! va = va - 1/e2v * zhpj
427	!!
428	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
429	!!----------------------------------------------------------------------
430	USE scoce, ONLY : zhpi => scr1, zhpj => scr2, &
431	zcpx => scr2D1, zcpy => scr2D2 ! W/D pressure filter
432	INTEGER, INTENT(in) :: kt ! ocean time-step index
433	!!
434	INTEGER :: ji, jj, jk, jii, jjj ! dummy loop indices
435	REAL(wp) :: zcoef0, zuap, zvap, znad, ztmp ! temporary scalars
436	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
437	!!----------------------------------------------------------------------
438	!
439	IF( kt == nit000 ) THEN
440	IF(lwp) WRITE(numout,*)
441	IF(lwp) WRITE(numout,*) 'dyn:hpg_sco : hydrostatic pressure gradient trend'
442	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, OPA original scheme used'
443	ENDIF
444	!
445	zcoef0 = - grav * 0.5_wp
446	IF ( ln_linssh ) THEN ; znad = 0._wp ! Fixed volume: density anomaly
447	ELSE ; znad = 1._wp ! Variable volume: density
448	ENDIF
449	!
450	IF( ln_wd_il ) THEN
451	DO jj = 2, jpjm1
452	DO ji = 2, jpim1
453	ll_tmp1 = MIN( sshn(ji,jj) , sshn(ji+1,jj) ) > &
454	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
455	& MAX( sshn(ji,jj) + ht_0(ji,jj), sshn(ji+1,jj) + ht_0(ji+1,jj) ) &
456	& > rn_wdmin1 + rn_wdmin2
457	ll_tmp2 = ( ABS( sshn(ji,jj) - sshn(ji+1,jj) ) > 1.E-12 ) .AND. ( &
458	& MAX( sshn(ji,jj) , sshn(ji+1,jj) ) > &
459	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
460
461	IF(ll_tmp1) THEN
462	zcpx(ji,jj) = 1.0_wp
463	ELSE IF(ll_tmp2) THEN
464	! no worries about sshn(ji+1,jj) - sshn(ji ,jj) = 0, it won't happen ! here
465	zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
466	& / (sshn(ji+1,jj) - sshn(ji ,jj)) )
467	ELSE
468	zcpx(ji,jj) = 0._wp
469	END IF
470
471	ll_tmp1 = MIN( sshn(ji,jj) , sshn(ji,jj+1) ) > &
472	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
473	& MAX( sshn(ji,jj) + ht_0(ji,jj), sshn(ji,jj+1) + ht_0(ji,jj+1) ) &
474	& > rn_wdmin1 + rn_wdmin2
475	ll_tmp2 = ( ABS( sshn(ji,jj) - sshn(ji,jj+1) ) > 1.E-12 ) .AND. ( &
476	& MAX( sshn(ji,jj) , sshn(ji,jj+1) ) > &
477	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
478
479	IF(ll_tmp1) THEN
480	zcpy(ji,jj) = 1.0_wp
481	ELSE IF(ll_tmp2) THEN
482	! no worries about sshn(ji,jj+1) - sshn(ji,jj ) = 0, it won't happen ! here
483	zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
484	& / (sshn(ji,jj+1) - sshn(ji,jj )) )
485	ELSE
486	zcpy(ji,jj) = 0._wp
487	END IF
488	END DO
489	END DO
490	CALL lbc_lnk_multi( zcpx, 'U', 1., zcpy, 'V', 1. )
491	END IF
492
493	! Surface value
494	DO jj = 2, jpjm1
495	DO ji = fs_2, fs_jpim1 ! vector opt.
496	! hydrostatic pressure gradient along s-surfaces
497	zhpi(ji,jj,1) = zcoef0 * ( e3w_n(ji+1,jj ,1) * ( znad + rhd(ji+1,jj ,1) ) &
498	& - e3w_n(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) ) * r1_e1u(ji,jj)
499	zhpj(ji,jj,1) = zcoef0 * ( e3w_n(ji ,jj+1,1) * ( znad + rhd(ji ,jj+1,1) ) &
500	& - e3w_n(ji ,jj ,1) * ( znad + rhd(ji ,jj ,1) ) ) * r1_e2v(ji,jj)
501	! s-coordinate pressure gradient correction
502	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
503	& * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
504	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
505	& * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
506	!
507	IF( ln_wd_il ) THEN
508	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
509	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
510	zuap = zuap * zcpx(ji,jj)
511	zvap = zvap * zcpy(ji,jj)
512	ENDIF
513	!
514	! add to the general momentum trend
515	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1) + zuap
516	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1) + zvap
517	END DO
518	END DO
519
520	! interior value (2=<jk=<jpkm1)
521	DO jk = 2, jpkm1
522	DO jj = 2, jpjm1
523	DO ji = fs_2, fs_jpim1 ! vector opt.
524	! hydrostatic pressure gradient along s-surfaces
525	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 * r1_e1u(ji,jj) &
526	& * ( e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2*znad ) &
527	& - e3w_n(ji ,jj,jk) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) + 2*znad ) )
528	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 * r1_e2v(ji,jj) &
529	& * ( e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2*znad ) &
530	& - e3w_n(ji,jj ,jk) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) + 2*znad ) )
531	! s-coordinate pressure gradient correction
532	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
533	& * ( gde3w_n(ji+1,jj ,jk) - gde3w_n(ji,jj,jk) ) * r1_e1u(ji,jj)
534	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
535	& * ( gde3w_n(ji ,jj+1,jk) - gde3w_n(ji,jj,jk) ) * r1_e2v(ji,jj)
536	!
537	IF( ln_wd_il ) THEN
538	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
539	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
540	zuap = zuap * zcpx(ji,jj)
541	zvap = zvap * zcpy(ji,jj)
542	ENDIF
543	!
544	! add to the general momentum trend
545	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk) + zuap
546	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk) + zvap
547	END DO
548	END DO
549	END DO
550	!
551	END SUBROUTINE hpg_sco
552
553
554	SUBROUTINE hpg_isf( kt )
555	!!---------------------------------------------------------------------
556	!! * ROUTINE hpg_isf *
557	!!
558	!! ** Method : s-coordinate case. Jacobian scheme.
559	!! The now hydrostatic pressure gradient at a given level, jk,
560	!! is computed by taking the vertical integral of the in-situ
561	!! density gradient along the model level from the suface to that
562	!! level. s-coordinates (ln_sco): a corrective term is added
563	!! to the horizontal pressure gradient :
564	!! zhpi = grav ..... + 1/e1u mi(rhd) di[ grav dep3w ]
565	!! zhpj = grav ..... + 1/e2v mj(rhd) dj[ grav dep3w ]
566	!! add it to the general momentum trend (ua,va).
567	!! ua = ua - 1/e1u * zhpi
568	!! va = va - 1/e2v * zhpj
569	!! iceload is added and partial cell case are added to the top and bottom
570	!!
571	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
572	!!----------------------------------------------------------------------
573	USE scoce, ONLY : zhpi => scr1, zhpj => scr2, &
574	zrhdtop_oce => scr2D1, &
575	zts_top => scr3D1
576	INTEGER, INTENT(in) :: kt ! ocean time-step index
577	!!
578	INTEGER :: ji, jj, jk, ikt, iktp1i, iktp1j ! dummy loop indices
579	REAL(wp) :: zcoef0, zuap, zvap, znad ! temporary scalars
580	! REAL(wp), DIMENSION(jpi,jpj,jpts) :: zts_top
581	!!----------------------------------------------------------------------
582	!
583	zcoef0 = - grav * 0.5_wp ! Local constant initialization
584	!
585	znad=1._wp ! To use density and not density anomaly
586	!
587	! ! iniitialised to 0. zhpi zhpi
588	zhpi(:,:,:) = 0._wp ; zhpj(:,:,:) = 0._wp
589
590	! compute rhd at the ice/oce interface (ocean side)
591	! usefull to reduce residual current in the test case ISOMIP with no melting
592	DO ji = 1, jpi
593	DO jj = 1, jpj
594	ikt = mikt(ji,jj)
595	zts_top(ji,jj,1) = tsn(ji,jj,ikt,1)
596	zts_top(ji,jj,2) = tsn(ji,jj,ikt,2)
597	END DO
598	END DO
599	CALL eos( zts_top, risfdep, zrhdtop_oce )
600
601	!==================================================================================
602	!===== Compute surface value =====================================================
603	!==================================================================================
604	DO jj = 2, jpjm1
605	DO ji = fs_2, fs_jpim1 ! vector opt.
606	ikt = mikt(ji,jj)
607	iktp1i = mikt(ji+1,jj)
608	iktp1j = mikt(ji,jj+1)
609	! hydrostatic pressure gradient along s-surfaces and ice shelf pressure
610	! we assume ISF is in isostatic equilibrium
611	zhpi(ji,jj,1) = zcoef0 / e1u(ji,jj) * ( 0.5_wp * e3w_n(ji+1,jj,iktp1i) &
612	& * ( 2._wp * znad + rhd(ji+1,jj,iktp1i) + zrhdtop_oce(ji+1,jj) ) &
613	& - 0.5_wp * e3w_n(ji,jj,ikt) &
614	& * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) ) &
615	& + ( riceload(ji+1,jj) - riceload(ji,jj)) )
616	zhpj(ji,jj,1) = zcoef0 / e2v(ji,jj) * ( 0.5_wp * e3w_n(ji,jj+1,iktp1j) &
617	& * ( 2._wp * znad + rhd(ji,jj+1,iktp1j) + zrhdtop_oce(ji,jj+1) ) &
618	& - 0.5_wp * e3w_n(ji,jj,ikt) &
619	& * ( 2._wp * znad + rhd(ji,jj,ikt) + zrhdtop_oce(ji,jj) ) &
620	& + ( riceload(ji,jj+1) - riceload(ji,jj)) )
621	! s-coordinate pressure gradient correction (=0 if z coordinate)
622	zuap = -zcoef0 * ( rhd (ji+1,jj,1) + rhd (ji,jj,1) + 2._wp * znad ) &
623	& * ( gde3w_n(ji+1,jj,1) - gde3w_n(ji,jj,1) ) * r1_e1u(ji,jj)
624	zvap = -zcoef0 * ( rhd (ji,jj+1,1) + rhd (ji,jj,1) + 2._wp * znad ) &
625	& * ( gde3w_n(ji,jj+1,1) - gde3w_n(ji,jj,1) ) * r1_e2v(ji,jj)
626	! add to the general momentum trend
627	ua(ji,jj,1) = ua(ji,jj,1) + (zhpi(ji,jj,1) + zuap) * umask(ji,jj,1)
628	va(ji,jj,1) = va(ji,jj,1) + (zhpj(ji,jj,1) + zvap) * vmask(ji,jj,1)
629	END DO
630	END DO
631	!==================================================================================
632	!===== Compute interior value =====================================================
633	!==================================================================================
634	! interior value (2=<jk=<jpkm1)
635	DO jk = 2, jpkm1
636	DO jj = 2, jpjm1
637	DO ji = fs_2, fs_jpim1 ! vector opt.
638	! hydrostatic pressure gradient along s-surfaces
639	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + zcoef0 / e1u(ji,jj) &
640	& * ( e3w_n(ji+1,jj,jk) * ( rhd(ji+1,jj,jk) + rhd(ji+1,jj,jk-1) + 2znad ) wmask(ji+1,jj,jk) &
641	& - e3w_n(ji ,jj,jk) * ( rhd(ji ,jj,jk) + rhd(ji ,jj,jk-1) + 2znad ) wmask(ji ,jj,jk) )
642	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) + zcoef0 / e2v(ji,jj) &
643	& * ( e3w_n(ji,jj+1,jk) * ( rhd(ji,jj+1,jk) + rhd(ji,jj+1,jk-1) + 2znad ) wmask(ji,jj+1,jk) &
644	& - e3w_n(ji,jj ,jk) * ( rhd(ji,jj, jk) + rhd(ji,jj ,jk-1) + 2znad ) wmask(ji,jj ,jk) )
645	! s-coordinate pressure gradient correction
646	zuap = -zcoef0 * ( rhd (ji+1,jj ,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
647	& * ( gde3w_n(ji+1,jj ,jk) - gde3w_n(ji,jj,jk) ) / e1u(ji,jj)
648	zvap = -zcoef0 * ( rhd (ji ,jj+1,jk) + rhd (ji,jj,jk) + 2._wp * znad ) &
649	& * ( gde3w_n(ji ,jj+1,jk) - gde3w_n(ji,jj,jk) ) / e2v(ji,jj)
650	! add to the general momentum trend
651	ua(ji,jj,jk) = ua(ji,jj,jk) + (zhpi(ji,jj,jk) + zuap) * umask(ji,jj,jk)
652	va(ji,jj,jk) = va(ji,jj,jk) + (zhpj(ji,jj,jk) + zvap) * vmask(ji,jj,jk)
653	END DO
654	END DO
655	END DO
656	!
657	END SUBROUTINE hpg_isf
658
659
660	SUBROUTINE hpg_djc( kt )
661	!!---------------------------------------------------------------------
662	!! * ROUTINE hpg_djc *
663	!!
664	!! ** Method : Density Jacobian with Cubic polynomial scheme
665	!!
666	!! Reference: Shchepetkin and McWilliams, J. Geophys. Res., 108(C3), 3090, 2003
667	!!----------------------------------------------------------------------
668	USE scoce, ONLY : zcpx => scr2D1, zcpy => scr2D2
669	INTEGER, INTENT(in) :: kt ! ocean time-step index
670	!!
671	INTEGER :: ji, jj, jk ! dummy loop indices
672	REAL(wp) :: zcoef0, zep, cffw ! temporary scalars
673	REAL(wp) :: z1_10, cffu, cffx ! " "
674	REAL(wp) :: z1_12, cffv, cffy ! " "
675	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
676	REAL(wp), DIMENSION(jpi,jpj,jpk) :: zhpi, zhpj
677	REAL(wp), DIMENSION(jpi,jpj,jpk) :: dzx, dzy, dzz, dzu, dzv, dzw
678	REAL(wp), DIMENSION(jpi,jpj,jpk) :: drhox, drhoy, drhoz, drhou, drhov, drhow
679	REAL(wp), DIMENSION(jpi,jpj,jpk) :: rho_i, rho_j, rho_k
680	!!----------------------------------------------------------------------
681	!
682	IF( ln_wd_il ) THEN
683	DO jj = 2, jpjm1
684	DO ji = 2, jpim1
685	ll_tmp1 = MIN( sshn(ji,jj) , sshn(ji+1,jj) ) > &
686	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
687	& MAX( sshn(ji,jj) + ht_0(ji,jj), sshn(ji+1,jj) + ht_0(ji+1,jj) ) &
688	& > rn_wdmin1 + rn_wdmin2
689	ll_tmp2 = ( ABS( sshn(ji,jj) - sshn(ji+1,jj) ) > 1.E-12 ) .AND. ( &
690	& MAX( sshn(ji,jj) , sshn(ji+1,jj) ) > &
691	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
692	IF(ll_tmp1) THEN
693	zcpx(ji,jj) = 1.0_wp
694	ELSE IF(ll_tmp2) THEN
695	! no worries about sshn(ji+1,jj) - sshn(ji ,jj) = 0, it won't happen ! here
696	zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
697	& / (sshn(ji+1,jj) - sshn(ji ,jj)) )
698	ELSE
699	zcpx(ji,jj) = 0._wp
700	END IF
701
702	ll_tmp1 = MIN( sshn(ji,jj) , sshn(ji,jj+1) ) > &
703	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
704	& MAX( sshn(ji,jj) + ht_0(ji,jj), sshn(ji,jj+1) + ht_0(ji,jj+1) ) &
705	& > rn_wdmin1 + rn_wdmin2
706	ll_tmp2 = ( ABS( sshn(ji,jj) - sshn(ji,jj+1) ) > 1.E-12 ) .AND. ( &
707	& MAX( sshn(ji,jj) , sshn(ji,jj+1) ) > &
708	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
709
710	IF(ll_tmp1) THEN
711	zcpy(ji,jj) = 1.0_wp
712	ELSE IF(ll_tmp2) THEN
713	! no worries about sshn(ji,jj+1) - sshn(ji,jj ) = 0, it won't happen ! here
714	zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
715	& / (sshn(ji,jj+1) - sshn(ji,jj )) )
716	ELSE
717	zcpy(ji,jj) = 0._wp
718	END IF
719	END DO
720	END DO
721	CALL lbc_lnk_multi( zcpx, 'U', 1., zcpy, 'V', 1. )
722	END IF
723
724	IF( kt == nit000 ) THEN
725	IF(lwp) WRITE(numout,*)
726	IF(lwp) WRITE(numout,*) 'dyn:hpg_djc : hydrostatic pressure gradient trend'
727	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, density Jacobian with cubic polynomial scheme'
728	ENDIF
729
730	! Local constant initialization
731	zcoef0 = - grav * 0.5_wp
732	z1_10 = 1._wp / 10._wp
733	z1_12 = 1._wp / 12._wp
734
735	!----------------------------------------------------------------------------------------
736	! compute and store in provisional arrays elementary vertical and horizontal differences
737	!----------------------------------------------------------------------------------------
738
739	!!bug gm Not a true bug, but... dzz=e3w for dzx, dzy verify what it is really
740
741	DO jk = 2, jpkm1
742	DO jj = 2, jpjm1
743	DO ji = fs_2, fs_jpim1 ! vector opt.
744	drhoz(ji,jj,jk) = rhd (ji ,jj ,jk) - rhd (ji,jj,jk-1)
745	dzz (ji,jj,jk) = gde3w_n(ji ,jj ,jk) - gde3w_n(ji,jj,jk-1)
746	drhox(ji,jj,jk) = rhd (ji+1,jj ,jk) - rhd (ji,jj,jk )
747	dzx (ji,jj,jk) = gde3w_n(ji+1,jj ,jk) - gde3w_n(ji,jj,jk )
748	drhoy(ji,jj,jk) = rhd (ji ,jj+1,jk) - rhd (ji,jj,jk )
749	dzy (ji,jj,jk) = gde3w_n(ji ,jj+1,jk) - gde3w_n(ji,jj,jk )
750	END DO
751	END DO
752	END DO
753
754	!-------------------------------------------------------------------------
755	! compute harmonic averages using eq. 5.18
756	!-------------------------------------------------------------------------
757	zep = 1.e-15
758
759	!!bug gm drhoz not defined at level 1 and used (jk-1 with jk=2)
760	!!bug gm idem for drhox, drhoy et ji=jpi and jj=jpj
761
762	DO jk = 2, jpkm1
763	DO jj = 2, jpjm1
764	DO ji = fs_2, fs_jpim1 ! vector opt.
765	cffw = 2._wp * drhoz(ji ,jj ,jk) * drhoz(ji,jj,jk-1)
766
767	cffu = 2._wp * drhox(ji+1,jj ,jk) * drhox(ji,jj,jk )
768	cffx = 2._wp * dzx (ji+1,jj ,jk) * dzx (ji,jj,jk )
769
770	cffv = 2._wp * drhoy(ji ,jj+1,jk) * drhoy(ji,jj,jk )
771	cffy = 2._wp * dzy (ji ,jj+1,jk) * dzy (ji,jj,jk )
772
773	IF( cffw > zep) THEN
774	drhow(ji,jj,jk) = 2._wp * drhoz(ji,jj,jk) * drhoz(ji,jj,jk-1) &
775	& / ( drhoz(ji,jj,jk) + drhoz(ji,jj,jk-1) )
776	ELSE
777	drhow(ji,jj,jk) = 0._wp
778	ENDIF
779
780	dzw(ji,jj,jk) = 2._wp * dzz(ji,jj,jk) * dzz(ji,jj,jk-1) &
781	& / ( dzz(ji,jj,jk) + dzz(ji,jj,jk-1) )
782
783	IF( cffu > zep ) THEN
784	drhou(ji,jj,jk) = 2._wp * drhox(ji+1,jj,jk) * drhox(ji,jj,jk) &
785	& / ( drhox(ji+1,jj,jk) + drhox(ji,jj,jk) )
786	ELSE
787	drhou(ji,jj,jk ) = 0._wp
788	ENDIF
789
790	IF( cffx > zep ) THEN
791	dzu(ji,jj,jk) = 2._wp * dzx(ji+1,jj,jk) * dzx(ji,jj,jk) &
792	& / ( dzx(ji+1,jj,jk) + dzx(ji,jj,jk) )
793	ELSE
794	dzu(ji,jj,jk) = 0._wp
795	ENDIF
796
797	IF( cffv > zep ) THEN
798	drhov(ji,jj,jk) = 2._wp * drhoy(ji,jj+1,jk) * drhoy(ji,jj,jk) &
799	& / ( drhoy(ji,jj+1,jk) + drhoy(ji,jj,jk) )
800	ELSE
801	drhov(ji,jj,jk) = 0._wp
802	ENDIF
803
804	IF( cffy > zep ) THEN
805	dzv(ji,jj,jk) = 2._wp * dzy(ji,jj+1,jk) * dzy(ji,jj,jk) &
806	& / ( dzy(ji,jj+1,jk) + dzy(ji,jj,jk) )
807	ELSE
808	dzv(ji,jj,jk) = 0._wp
809	ENDIF
810
811	END DO
812	END DO
813	END DO
814
815	!----------------------------------------------------------------------------------
816	! apply boundary conditions at top and bottom using 5.36-5.37
817	!----------------------------------------------------------------------------------
818	drhow(:,:, 1 ) = 1.5_wp * ( drhoz(:,:, 2 ) - drhoz(:,:, 1 ) ) - 0.5_wp * drhow(:,:, 2 )
819	drhou(:,:, 1 ) = 1.5_wp * ( drhox(:,:, 2 ) - drhox(:,:, 1 ) ) - 0.5_wp * drhou(:,:, 2 )
820	drhov(:,:, 1 ) = 1.5_wp * ( drhoy(:,:, 2 ) - drhoy(:,:, 1 ) ) - 0.5_wp * drhov(:,:, 2 )
821
822	drhow(:,:,jpk) = 1.5_wp * ( drhoz(:,:,jpk) - drhoz(:,:,jpkm1) ) - 0.5_wp * drhow(:,:,jpkm1)
823	drhou(:,:,jpk) = 1.5_wp * ( drhox(:,:,jpk) - drhox(:,:,jpkm1) ) - 0.5_wp * drhou(:,:,jpkm1)
824	drhov(:,:,jpk) = 1.5_wp * ( drhoy(:,:,jpk) - drhoy(:,:,jpkm1) ) - 0.5_wp * drhov(:,:,jpkm1)
825
826
827	!--------------------------------------------------------------
828	! Upper half of top-most grid box, compute and store
829	!-------------------------------------------------------------
830
831	!!bug gm : e3w-gde3w = 0.5*e3w .... and gde3w(2)-gde3w(1)=e3w(2) .... to be verified
832	! true if gde3w is really defined as the sum of the e3w scale factors as, it seems to me, it should be
833
834	DO jj = 2, jpjm1
835	DO ji = fs_2, fs_jpim1 ! vector opt.
836	rho_k(ji,jj,1) = -grav * ( e3w_n(ji,jj,1) - gde3w_n(ji,jj,1) ) &
837	& * ( rhd(ji,jj,1) &
838	& + 0.5_wp * ( rhd (ji,jj,2) - rhd (ji,jj,1) ) &
839	& * ( e3w_n (ji,jj,1) - gde3w_n(ji,jj,1) ) &
840	& / ( gde3w_n(ji,jj,2) - gde3w_n(ji,jj,1) ) )
841	END DO
842	END DO
843
844	!!bug gm : here also, simplification is possible
845	!!bug gm : optimisation: 1/10 and 1/12 the division should be done before the loop
846
847	DO jk = 2, jpkm1
848	DO jj = 2, jpjm1
849	DO ji = fs_2, fs_jpim1 ! vector opt.
850
851	rho_k(ji,jj,jk) = zcoef0 * ( rhd (ji,jj,jk) + rhd (ji,jj,jk-1) ) &
852	& * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) ) &
853	& - grav * z1_10 * ( &
854	& ( drhow (ji,jj,jk) - drhow (ji,jj,jk-1) ) &
855	& * ( gde3w_n(ji,jj,jk) - gde3w_n(ji,jj,jk-1) - z1_12 * ( dzw (ji,jj,jk) + dzw (ji,jj,jk-1) ) ) &
856	& - ( dzw (ji,jj,jk) - dzw (ji,jj,jk-1) ) &
857	& * ( rhd (ji,jj,jk) - rhd (ji,jj,jk-1) - z1_12 * ( drhow(ji,jj,jk) + drhow(ji,jj,jk-1) ) ) &
858	& )
859
860	rho_i(ji,jj,jk) = zcoef0 * ( rhd (ji+1,jj,jk) + rhd (ji,jj,jk) ) &
861	& * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) ) &
862	& - grav* z1_10 * ( &
863	& ( drhou (ji+1,jj,jk) - drhou (ji,jj,jk) ) &
864	& * ( gde3w_n(ji+1,jj,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzu (ji+1,jj,jk) + dzu (ji,jj,jk) ) ) &
865	& - ( dzu (ji+1,jj,jk) - dzu (ji,jj,jk) ) &
866	& * ( rhd (ji+1,jj,jk) - rhd (ji,jj,jk) - z1_12 * ( drhou(ji+1,jj,jk) + drhou(ji,jj,jk) ) ) &
867	& )
868
869	rho_j(ji,jj,jk) = zcoef0 * ( rhd (ji,jj+1,jk) + rhd (ji,jj,jk) ) &
870	& * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) ) &
871	& - grav* z1_10 * ( &
872	& ( drhov (ji,jj+1,jk) - drhov (ji,jj,jk) ) &
873	& * ( gde3w_n(ji,jj+1,jk) - gde3w_n(ji,jj,jk) - z1_12 * ( dzv (ji,jj+1,jk) + dzv (ji,jj,jk) ) ) &
874	& - ( dzv (ji,jj+1,jk) - dzv (ji,jj,jk) ) &
875	& * ( rhd (ji,jj+1,jk) - rhd (ji,jj,jk) - z1_12 * ( drhov(ji,jj+1,jk) + drhov(ji,jj,jk) ) ) &
876	& )
877
878	END DO
879	END DO
880	END DO
881	CALL lbc_lnk_multi( rho_k, 'W', 1., rho_i, 'U', 1., rho_j, 'V', 1. )
882
883	! ---------------
884	! Surface value
885	! ---------------
886	DO jj = 2, jpjm1
887	DO ji = fs_2, fs_jpim1 ! vector opt.
888	zhpi(ji,jj,1) = ( rho_k(ji+1,jj ,1) - rho_k(ji,jj,1) - rho_i(ji,jj,1) ) * r1_e1u(ji,jj)
889	zhpj(ji,jj,1) = ( rho_k(ji ,jj+1,1) - rho_k(ji,jj,1) - rho_j(ji,jj,1) ) * r1_e2v(ji,jj)
890	IF( ln_wd_il ) THEN
891	zhpi(ji,jj,1) = zhpi(ji,jj,1) * zcpx(ji,jj)
892	zhpj(ji,jj,1) = zhpj(ji,jj,1) * zcpy(ji,jj)
893	ENDIF
894	! add to the general momentum trend
895	ua(ji,jj,1) = ua(ji,jj,1) + zhpi(ji,jj,1)
896	va(ji,jj,1) = va(ji,jj,1) + zhpj(ji,jj,1)
897	END DO
898	END DO
899
900	! ----------------
901	! interior value (2=<jk=<jpkm1)
902	! ----------------
903	DO jk = 2, jpkm1
904	DO jj = 2, jpjm1
905	DO ji = fs_2, fs_jpim1 ! vector opt.
906	! hydrostatic pressure gradient along s-surfaces
907	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) &
908	& + ( ( rho_k(ji+1,jj,jk) - rho_k(ji,jj,jk ) ) &
909	& - ( rho_i(ji ,jj,jk) - rho_i(ji,jj,jk-1) ) ) * r1_e1u(ji,jj)
910	zhpj(ji,jj,jk) = zhpj(ji,jj,jk-1) &
911	& + ( ( rho_k(ji,jj+1,jk) - rho_k(ji,jj,jk ) ) &
912	& -( rho_j(ji,jj ,jk) - rho_j(ji,jj,jk-1) ) ) * r1_e2v(ji,jj)
913	IF( ln_wd_il ) THEN
914	zhpi(ji,jj,jk) = zhpi(ji,jj,jk) * zcpx(ji,jj)
915	zhpj(ji,jj,jk) = zhpj(ji,jj,jk) * zcpy(ji,jj)
916	ENDIF
917	! add to the general momentum trend
918	ua(ji,jj,jk) = ua(ji,jj,jk) + zhpi(ji,jj,jk)
919	va(ji,jj,jk) = va(ji,jj,jk) + zhpj(ji,jj,jk)
920	END DO
921	END DO
922	END DO
923	!
924	END SUBROUTINE hpg_djc
925
926
927	SUBROUTINE hpg_prj( kt )
928	!!---------------------------------------------------------------------
929	!! * ROUTINE hpg_prj *
930	!!
931	!! ** Method : s-coordinate case.
932	!! A Pressure-Jacobian horizontal pressure gradient method
933	!! based on the constrained cubic-spline interpolation for
934	!! all vertical coordinate systems
935	!!
936	!! ** Action : - Update (ua,va) with the now hydrastatic pressure trend
937	!!----------------------------------------------------------------------
938	USE scoce, ONLY : zdept => scr1, zrhh => scr2, &
939	zhpi => scr3, zu => scr4, zv => scr5, fsp => scr6, &
940	xsp => scr7, asp => scr8, bsp => scr9, &
941	csp => scr10, dsp => scr11, &
942	zsshu_n => scr2D1, zsshv_n => scr2D2, &
943	zcpx => scr2D3, zcpy => scr2D4
944	INTEGER, PARAMETER :: polynomial_type = 1 ! 1: cubic spline, 2: linear
945	INTEGER, INTENT(in) :: kt ! ocean time-step index
946	!!
947	INTEGER :: ji, jj, jk, jkk ! dummy loop indices
948	REAL(wp) :: zcoef0, znad ! local scalars
949	!
950	!! The local variables for the correction term
951	INTEGER :: jk1, jis, jid, jjs, jjd
952	LOGICAL :: ll_tmp1, ll_tmp2 ! local logical variables
953	REAL(wp) :: zuijk, zvijk, zpwes, zpwed, zpnss, zpnsd, zdeps
954	REAL(wp) :: zrhdt1
955	REAL(wp) :: zdpdx1, zdpdx2, zdpdy1, zdpdy2
956	!!----------------------------------------------------------------------
957	!
958	IF( kt == nit000 ) THEN
959	IF(lwp) WRITE(numout,*)
960	IF(lwp) WRITE(numout,*) 'dyn:hpg_prj : hydrostatic pressure gradient trend'
961	IF(lwp) WRITE(numout,*) '~~~~~~~~~~~ s-coordinate case, cubic spline pressure Jacobian'
962	ENDIF
963
964	! Local constant initialization
965	zcoef0 = - grav
966	znad = 1._wp
967	IF( ln_linssh ) znad = 0._wp
968
969	IF( ln_wd_il ) THEN
970	DO jj = 2, jpjm1
971	DO ji = 2, jpim1
972	ll_tmp1 = MIN( sshn(ji,jj) , sshn(ji+1,jj) ) > &
973	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) .AND. &
974	& MAX( sshn(ji,jj) + ht_0(ji,jj), sshn(ji+1,jj) + ht_0(ji+1,jj) ) &
975	& > rn_wdmin1 + rn_wdmin2
976	ll_tmp2 = ( ABS( sshn(ji,jj) - sshn(ji+1,jj) ) > 1.E-12 ) .AND. ( &
977	& MAX( sshn(ji,jj) , sshn(ji+1,jj) ) > &
978	& MAX( -ht_0(ji,jj) , -ht_0(ji+1,jj) ) + rn_wdmin1 + rn_wdmin2 )
979
980	IF(ll_tmp1) THEN
981	zcpx(ji,jj) = 1.0_wp
982	ELSE IF(ll_tmp2) THEN
983	! no worries about sshn(ji+1,jj) - sshn(ji ,jj) = 0, it won't happen ! here
984	zcpx(ji,jj) = ABS( (sshn(ji+1,jj) + ht_0(ji+1,jj) - sshn(ji,jj) - ht_0(ji,jj)) &
985	& / (sshn(ji+1,jj) - sshn(ji ,jj)) )
986
987	zcpx(ji,jj) = max(min( zcpx(ji,jj) , 1.0_wp),0.0_wp)
988	ELSE
989	zcpx(ji,jj) = 0._wp
990	END IF
991
992	ll_tmp1 = MIN( sshn(ji,jj) , sshn(ji,jj+1) ) > &
993	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) .AND. &
994	& MAX( sshn(ji,jj) + ht_0(ji,jj), sshn(ji,jj+1) + ht_0(ji,jj+1) ) &
995	& > rn_wdmin1 + rn_wdmin2
996	ll_tmp2 = ( ABS( sshn(ji,jj) - sshn(ji,jj+1) ) > 1.E-12 ) .AND. ( &
997	& MAX( sshn(ji,jj) , sshn(ji,jj+1) ) > &
998	& MAX( -ht_0(ji,jj) , -ht_0(ji,jj+1) ) + rn_wdmin1 + rn_wdmin2 )
999
1000	IF(ll_tmp1) THEN
1001	zcpy(ji,jj) = 1.0_wp
1002	ELSE IF(ll_tmp2) THEN
1003	! no worries about sshn(ji,jj+1) - sshn(ji,jj ) = 0, it won't happen ! here
1004	zcpy(ji,jj) = ABS( (sshn(ji,jj+1) + ht_0(ji,jj+1) - sshn(ji,jj) - ht_0(ji,jj)) &
1005	& / (sshn(ji,jj+1) - sshn(ji,jj )) )
1006	zcpy(ji,jj) = max(min( zcpy(ji,jj) , 1.0_wp),0.0_wp)
1007
1008	ELSE
1009	zcpy(ji,jj) = 0._wp
1010	ENDIF
1011	END DO
1012	END DO
1013	CALL lbc_lnk_multi( zcpx, 'U', 1., zcpy, 'V', 1. )
1014	ENDIF
1015
1016	! Clean 3-D work arrays
1017	zhpi(:,:,:) = 0._wp
1018	zrhh(:,:,:) = rhd(:,:,:)
1019
1020	! Preparing vertical density profile "zrhh(:,:,:)" for hybrid-sco coordinate
1021	DO jj = 1, jpj
1022	DO ji = 1, jpi
1023	jk = mbkt(ji,jj)+1
1024	IF( jk <= 0 ) THEN ; zrhh(ji,jj, : ) = 0._wp
1025	ELSEIF( jk == 1 ) THEN ; zrhh(ji,jj,jk+1:jpk) = rhd(ji,jj,jk)
1026	ELSEIF( jk < jpkm1 ) THEN
1027	DO jkk = jk+1, jpk
1028	zrhh(ji,jj,jkk) = interp1(gde3w_n(ji,jj,jkk ), gde3w_n(ji,jj,jkk-1), &
1029	& gde3w_n(ji,jj,jkk-2), rhd (ji,jj,jkk-1), rhd(ji,jj,jkk-2))
1030	END DO
1031	ENDIF
1032	END DO
1033	END DO
1034
1035	! Transfer the depth of "T(:,:,:)" to vertical coordinate "zdept(:,:,:)"
1036	DO jj = 1, jpj
1037	DO ji = 1, jpi
1038	zdept(ji,jj,1) = 0.5_wp * e3w_n(ji,jj,1) - sshn(ji,jj) * znad
1039	END DO
1040	END DO
1041
1042	DO jk = 2, jpk
1043	DO jj = 1, jpj
1044	DO ji = 1, jpi
1045	zdept(ji,jj,jk) = zdept(ji,jj,jk-1) + e3w_n(ji,jj,jk)
1046	END DO
1047	END DO
1048	END DO
1049
1050	fsp(:,:,:) = zrhh (:,:,:)
1051	xsp(:,:,:) = zdept(:,:,:)
1052
1053	! Construct the vertical density profile with the
1054	! constrained cubic spline interpolation
1055	! rho(z) = asp + bspz + cspz^2 + dsp*z^3
1056	CALL cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1057
1058	! Integrate the hydrostatic pressure "zhpi(:,:,:)" at "T(ji,jj,1)"
1059	DO jj = 2, jpj
1060	DO ji = 2, jpi
1061	zrhdt1 = zrhh(ji,jj,1) - interp3( zdept(ji,jj,1), asp(ji,jj,1), bsp(ji,jj,1), &
1062	& csp(ji,jj,1), dsp(ji,jj,1) ) * 0.25_wp * e3w_n(ji,jj,1)
1063
1064	! assuming linear profile across the top half surface layer
1065	zhpi(ji,jj,1) = 0.5_wp * e3w_n(ji,jj,1) * zrhdt1
1066	END DO
1067	END DO
1068
1069	! Calculate the pressure "zhpi(:,:,:)" at "T(ji,jj,2:jpkm1)"
1070	DO jk = 2, jpkm1
1071	DO jj = 2, jpj
1072	DO ji = 2, jpi
1073	zhpi(ji,jj,jk) = zhpi(ji,jj,jk-1) + &
1074	& integ_spline( zdept(ji,jj,jk-1), zdept(ji,jj,jk), &
1075	& asp (ji,jj,jk-1), bsp (ji,jj,jk-1), &
1076	& csp (ji,jj,jk-1), dsp (ji,jj,jk-1) )
1077	END DO
1078	END DO
1079	END DO
1080
1081	! Z coordinate of U(ji,jj,1:jpkm1) and V(ji,jj,1:jpkm1)
1082
1083	! Prepare zsshu_n and zsshv_n
1084	DO jj = 2, jpjm1
1085	DO ji = 2, jpim1
1086	!!gm BUG ? if it is ssh at u- & v-point then it should be:
1087	! zsshu_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji+1,jj) * sshn(ji+1,jj)) * &
1088	! & r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1089	! zsshv_n(ji,jj) = (e1e2t(ji,jj) * sshn(ji,jj) + e1e2t(ji,jj+1) * sshn(ji,jj+1)) * &
1090	! & r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1091	!!gm not this:
1092	zsshu_n(ji,jj) = (e1e2u(ji,jj) * sshn(ji,jj) + e1e2u(ji+1, jj) * sshn(ji+1,jj)) * &
1093	& r1_e1e2u(ji,jj) * umask(ji,jj,1) * 0.5_wp
1094	zsshv_n(ji,jj) = (e1e2v(ji,jj) * sshn(ji,jj) + e1e2v(ji+1, jj) * sshn(ji,jj+1)) * &
1095	& r1_e1e2v(ji,jj) * vmask(ji,jj,1) * 0.5_wp
1096	END DO
1097	END DO
1098
1099	CALL lbc_lnk_multi (zsshu_n, 'U', 1., zsshv_n, 'V', 1. )
1100
1101	DO jj = 2, jpjm1
1102	DO ji = 2, jpim1
1103	zu(ji,jj,1) = - ( e3u_n(ji,jj,1) - zsshu_n(ji,jj) * znad)
1104	zv(ji,jj,1) = - ( e3v_n(ji,jj,1) - zsshv_n(ji,jj) * znad)
1105	END DO
1106	END DO
1107
1108	DO jk = 2, jpkm1
1109	DO jj = 2, jpjm1
1110	DO ji = 2, jpim1
1111	zu(ji,jj,jk) = zu(ji,jj,jk-1) - e3u_n(ji,jj,jk)
1112	zv(ji,jj,jk) = zv(ji,jj,jk-1) - e3v_n(ji,jj,jk)
1113	END DO
1114	END DO
1115	END DO
1116
1117	DO jk = 1, jpkm1
1118	DO jj = 2, jpjm1
1119	DO ji = 2, jpim1
1120	zu(ji,jj,jk) = zu(ji,jj,jk) + 0.5_wp * e3u_n(ji,jj,jk)
1121	zv(ji,jj,jk) = zv(ji,jj,jk) + 0.5_wp * e3v_n(ji,jj,jk)
1122	END DO
1123	END DO
1124	END DO
1125
1126	DO jk = 1, jpkm1
1127	DO jj = 2, jpjm1
1128	DO ji = 2, jpim1
1129	zu(ji,jj,jk) = MIN( zu(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) ) )
1130	zu(ji,jj,jk) = MAX( zu(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji+1,jj,jk) ) )
1131	zv(ji,jj,jk) = MIN( zv(ji,jj,jk) , MAX( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) ) )
1132	zv(ji,jj,jk) = MAX( zv(ji,jj,jk) , MIN( -zdept(ji,jj,jk) , -zdept(ji,jj+1,jk) ) )
1133	END DO
1134	END DO
1135	END DO
1136
1137
1138	DO jk = 1, jpkm1
1139	DO jj = 2, jpjm1
1140	DO ji = 2, jpim1
1141	zpwes = 0._wp; zpwed = 0._wp
1142	zpnss = 0._wp; zpnsd = 0._wp
1143	zuijk = zu(ji,jj,jk)
1144	zvijk = zv(ji,jj,jk)
1145
1146	!!!!! for u equation
1147	IF( jk <= mbku(ji,jj) ) THEN
1148	IF( -zdept(ji+1,jj,jk) >= -zdept(ji,jj,jk) ) THEN
1149	jis = ji + 1; jid = ji
1150	ELSE
1151	jis = ji; jid = ji +1
1152	ENDIF
1153
1154	! integrate the pressure on the shallow side
1155	jk1 = jk
1156	DO WHILE ( -zdept(jis,jj,jk1) > zuijk )
1157	IF( jk1 == mbku(ji,jj) ) THEN
1158	zuijk = -zdept(jis,jj,jk1)
1159	EXIT
1160	ENDIF
1161	zdeps = MIN(zdept(jis,jj,jk1+1), -zuijk)
1162	zpwes = zpwes + &
1163	integ_spline(zdept(jis,jj,jk1), zdeps, &
1164	asp(jis,jj,jk1), bsp(jis,jj,jk1), &
1165	csp(jis,jj,jk1), dsp(jis,jj,jk1))
1166	jk1 = jk1 + 1
1167	END DO
1168
1169	! integrate the pressure on the deep side
1170	jk1 = jk
1171	DO WHILE ( -zdept(jid,jj,jk1) < zuijk )
1172	IF( jk1 == 1 ) THEN
1173	zdeps = zdept(jid,jj,1) + MIN(zuijk, sshn(jid,jj)*znad)
1174	zrhdt1 = zrhh(jid,jj,1) - interp3(zdept(jid,jj,1), asp(jid,jj,1), &
1175	bsp(jid,jj,1), csp(jid,jj,1), &
1176	dsp(jid,jj,1)) * zdeps
1177	zpwed = zpwed + 0.5_wp * (zrhh(jid,jj,1) + zrhdt1) * zdeps
1178	EXIT
1179	ENDIF
1180	zdeps = MAX(zdept(jid,jj,jk1-1), -zuijk)
1181	zpwed = zpwed + &
1182	integ_spline(zdeps, zdept(jid,jj,jk1), &
1183	asp(jid,jj,jk1-1), bsp(jid,jj,jk1-1), &
1184	csp(jid,jj,jk1-1), dsp(jid,jj,jk1-1) )
1185	jk1 = jk1 - 1
1186	END DO
1187
1188	! update the momentum trends in u direction
1189
1190	zdpdx1 = zcoef0 * r1_e1u(ji,jj) * ( zhpi(ji+1,jj,jk) - zhpi(ji,jj,jk) )
1191	IF( .NOT.ln_linssh ) THEN
1192	zdpdx2 = zcoef0 * r1_e1u(ji,jj) * &
1193	& ( REAL(jis-jid, wp) * (zpwes + zpwed) + (sshn(ji+1,jj)-sshn(ji,jj)) )
1194	ELSE
1195	zdpdx2 = zcoef0 * r1_e1u(ji,jj) * REAL(jis-jid, wp) * (zpwes + zpwed)
1196	ENDIF
1197	IF( ln_wd_il ) THEN
1198	zdpdx1 = zdpdx1 * zcpx(ji,jj) * wdrampu(ji,jj)
1199	zdpdx2 = zdpdx2 * zcpx(ji,jj) * wdrampu(ji,jj)
1200	ENDIF
1201	ua(ji,jj,jk) = ua(ji,jj,jk) + (zdpdx1 + zdpdx2) * umask(ji,jj,jk)
1202	ENDIF
1203
1204	!!!!! for v equation
1205	IF( jk <= mbkv(ji,jj) ) THEN
1206	IF( -zdept(ji,jj+1,jk) >= -zdept(ji,jj,jk) ) THEN
1207	jjs = jj + 1; jjd = jj
1208	ELSE
1209	jjs = jj ; jjd = jj + 1
1210	ENDIF
1211
1212	! integrate the pressure on the shallow side
1213	jk1 = jk
1214	DO WHILE ( -zdept(ji,jjs,jk1) > zvijk )
1215	IF( jk1 == mbkv(ji,jj) ) THEN
1216	zvijk = -zdept(ji,jjs,jk1)
1217	EXIT
1218	ENDIF
1219	zdeps = MIN(zdept(ji,jjs,jk1+1), -zvijk)
1220	zpnss = zpnss + &
1221	integ_spline(zdept(ji,jjs,jk1), zdeps, &
1222	asp(ji,jjs,jk1), bsp(ji,jjs,jk1), &
1223	csp(ji,jjs,jk1), dsp(ji,jjs,jk1) )
1224	jk1 = jk1 + 1
1225	END DO
1226
1227	! integrate the pressure on the deep side
1228	jk1 = jk
1229	DO WHILE ( -zdept(ji,jjd,jk1) < zvijk )
1230	IF( jk1 == 1 ) THEN
1231	zdeps = zdept(ji,jjd,1) + MIN(zvijk, sshn(ji,jjd)*znad)
1232	zrhdt1 = zrhh(ji,jjd,1) - interp3(zdept(ji,jjd,1), asp(ji,jjd,1), &
1233	bsp(ji,jjd,1), csp(ji,jjd,1), &
1234	dsp(ji,jjd,1) ) * zdeps
1235	zpnsd = zpnsd + 0.5_wp * (zrhh(ji,jjd,1) + zrhdt1) * zdeps
1236	EXIT
1237	ENDIF
1238	zdeps = MAX(zdept(ji,jjd,jk1-1), -zvijk)
1239	zpnsd = zpnsd + &
1240	integ_spline(zdeps, zdept(ji,jjd,jk1), &
1241	asp(ji,jjd,jk1-1), bsp(ji,jjd,jk1-1), &
1242	csp(ji,jjd,jk1-1), dsp(ji,jjd,jk1-1) )
1243	jk1 = jk1 - 1
1244	END DO
1245
1246
1247	! update the momentum trends in v direction
1248
1249	zdpdy1 = zcoef0 * r1_e2v(ji,jj) * ( zhpi(ji,jj+1,jk) - zhpi(ji,jj,jk) )
1250	IF( .NOT.ln_linssh ) THEN
1251	zdpdy2 = zcoef0 * r1_e2v(ji,jj) * &
1252	( REAL(jjs-jjd, wp) * (zpnss + zpnsd) + (sshn(ji,jj+1)-sshn(ji,jj)) )
1253	ELSE
1254	zdpdy2 = zcoef0 * r1_e2v(ji,jj) * REAL(jjs-jjd, wp) * (zpnss + zpnsd )
1255	ENDIF
1256	IF( ln_wd_il ) THEN
1257	zdpdy1 = zdpdy1 * zcpy(ji,jj) * wdrampv(ji,jj)
1258	zdpdy2 = zdpdy2 * zcpy(ji,jj) * wdrampv(ji,jj)
1259	ENDIF
1260
1261	va(ji,jj,jk) = va(ji,jj,jk) + (zdpdy1 + zdpdy2) * vmask(ji,jj,jk)
1262	ENDIF
1263	!
1264	END DO
1265	END DO
1266	END DO
1267	!
1268	END SUBROUTINE hpg_prj
1269
1270
1271	SUBROUTINE cspline( fsp, xsp, asp, bsp, csp, dsp, polynomial_type )
1272	!!----------------------------------------------------------------------
1273	!! * ROUTINE cspline *
1274	!!
1275	!! ** Purpose : constrained cubic spline interpolation
1276	!!
1277	!! ** Method : f(x) = asp + bspx + cspx^2 + dsp*x^3
1278	!!
1279	!! Reference: CJC Kruger, Constrained Cubic Spline Interpoltation
1280	!!----------------------------------------------------------------------
1281	REAL(wp), DIMENSION(:,:,:), INTENT(in ) :: fsp, xsp ! value and coordinate
1282	REAL(wp), DIMENSION(:,:,:), INTENT( out) :: asp, bsp, csp, dsp ! coefficients of the interpoated function
1283	INTEGER , INTENT(in ) :: polynomial_type ! 1: cubic spline ; 2: Linear
1284	!
1285	INTEGER :: ji, jj, jk ! dummy loop indices
1286	INTEGER :: jpi, jpj, jpkm1
1287	REAL(wp) :: zdf1, zdf2, zddf1, zddf2, ztmp1, ztmp2, zdxtmp
1288	REAL(wp) :: zdxtmp1, zdxtmp2, zalpha
1289	REAL(wp) :: zdf(size(fsp,3))
1290	!!----------------------------------------------------------------------
1291	!
1292	!!gm WHAT !!!!! THIS IS VERY DANGEROUS !!!!!
1293	jpi = size(fsp,1)
1294	jpj = size(fsp,2)
1295	jpkm1 = MAX( 1, size(fsp,3) - 1 )
1296	!
1297	IF (polynomial_type == 1) THEN ! Constrained Cubic Spline
1298	DO ji = 1, jpi
1299	DO jj = 1, jpj
1300	!!Fritsch&Butland's method, 1984 (preferred, but more computation)
1301	! DO jk = 2, jpkm1-1
1302	! zdxtmp1 = xsp(ji,jj,jk) - xsp(ji,jj,jk-1)
1303	! zdxtmp2 = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1304	! zdf1 = ( fsp(ji,jj,jk) - fsp(ji,jj,jk-1) ) / zdxtmp1
1305	! zdf2 = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp2
1306	!
1307	! zalpha = ( zdxtmp1 + 2._wp * zdxtmp2 ) / ( zdxtmp1 + zdxtmp2 ) / 3._wp
1308	!
1309	! IF(zdf1 * zdf2 <= 0._wp) THEN
1310	! zdf(jk) = 0._wp
1311	! ELSE
1312	! zdf(jk) = zdf1 * zdf2 / ( ( 1._wp - zalpha ) * zdf1 + zalpha * zdf2 )
1313	! ENDIF
1314	! END DO
1315
1316	!!Simply geometric average
1317	DO jk = 2, jpkm1-1
1318	zdf1 = (fsp(ji,jj,jk ) - fsp(ji,jj,jk-1)) / (xsp(ji,jj,jk ) - xsp(ji,jj,jk-1))
1319	zdf2 = (fsp(ji,jj,jk+1) - fsp(ji,jj,jk )) / (xsp(ji,jj,jk+1) - xsp(ji,jj,jk ))
1320
1321	IF(zdf1 * zdf2 <= 0._wp) THEN
1322	zdf(jk) = 0._wp
1323	ELSE
1324	zdf(jk) = 2._wp * zdf1 * zdf2 / (zdf1 + zdf2)
1325	ENDIF
1326	END DO
1327
1328	zdf(1) = 1.5_wp * ( fsp(ji,jj,2) - fsp(ji,jj,1) ) / &
1329	& ( xsp(ji,jj,2) - xsp(ji,jj,1) ) - 0.5_wp * zdf(2)
1330	zdf(jpkm1) = 1.5_wp * ( fsp(ji,jj,jpkm1) - fsp(ji,jj,jpkm1-1) ) / &
1331	& ( xsp(ji,jj,jpkm1) - xsp(ji,jj,jpkm1-1) ) - 0.5_wp * zdf(jpkm1 - 1)
1332
1333	DO jk = 1, jpkm1 - 1
1334	zdxtmp = xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1335	ztmp1 = (zdf(jk+1) + 2._wp * zdf(jk)) / zdxtmp
1336	ztmp2 = 6._wp * (fsp(ji,jj,jk+1) - fsp(ji,jj,jk)) / zdxtmp / zdxtmp
1337	zddf1 = -2._wp * ztmp1 + ztmp2
1338	ztmp1 = (2._wp * zdf(jk+1) + zdf(jk)) / zdxtmp
1339	zddf2 = 2._wp * ztmp1 - ztmp2
1340
1341	dsp(ji,jj,jk) = (zddf2 - zddf1) / 6._wp / zdxtmp
1342	csp(ji,jj,jk) = ( xsp(ji,jj,jk+1) * zddf1 - xsp(ji,jj,jk)*zddf2 ) / 2._wp / zdxtmp
1343	bsp(ji,jj,jk) = ( fsp(ji,jj,jk+1) - fsp(ji,jj,jk) ) / zdxtmp - &
1344	& csp(ji,jj,jk) * ( xsp(ji,jj,jk+1) + xsp(ji,jj,jk) ) - &
1345	& dsp(ji,jj,jk) * ((xsp(ji,jj,jk+1) + xsp(ji,jj,jk))**2 - &
1346	& xsp(ji,jj,jk+1) * xsp(ji,jj,jk))
1347	asp(ji,jj,jk) = fsp(ji,jj,jk) - xsp(ji,jj,jk) * (bsp(ji,jj,jk) + &
1348	& (xsp(ji,jj,jk) * (csp(ji,jj,jk) + &
1349	& dsp(ji,jj,jk) * xsp(ji,jj,jk))))
1350	END DO
1351	END DO
1352	END DO
1353
1354	ELSEIF ( polynomial_type == 2 ) THEN ! Linear
1355	DO ji = 1, jpi
1356	DO jj = 1, jpj
1357	DO jk = 1, jpkm1-1
1358	zdxtmp =xsp(ji,jj,jk+1) - xsp(ji,jj,jk)
1359	ztmp1 = fsp(ji,jj,jk+1) - fsp(ji,jj,jk)
1360
1361	dsp(ji,jj,jk) = 0._wp
1362	csp(ji,jj,jk) = 0._wp
1363	bsp(ji,jj,jk) = ztmp1 / zdxtmp
1364	asp(ji,jj,jk) = fsp(ji,jj,jk) - bsp(ji,jj,jk) * xsp(ji,jj,jk)
1365	END DO
1366	END DO
1367	END DO
1368	!
1369	ELSE
1370	CALL ctl_stop( 'invalid polynomial type in cspline' )
1371	ENDIF
1372	!
1373	END SUBROUTINE cspline
1374
1375
1376	FUNCTION interp1(x, xl, xr, fl, fr) RESULT(f)
1377	!!----------------------------------------------------------------------
1378	!! * ROUTINE interp1 *
1379	!!
1380	!! ** Purpose : 1-d linear interpolation
1381	!!
1382	!! ** Method : interpolation is straight forward
1383	!! extrapolation is also permitted (no value limit)
1384	!!----------------------------------------------------------------------
1385	REAL(wp), INTENT(in) :: x, xl, xr, fl, fr
1386	REAL(wp) :: f ! result of the interpolation (extrapolation)
1387	REAL(wp) :: zdeltx
1388	!!----------------------------------------------------------------------
1389	!
1390	zdeltx = xr - xl
1391	IF( abs(zdeltx) <= 10._wp * EPSILON(x) ) THEN
1392	f = 0.5_wp * (fl + fr)
1393	ELSE
1394	f = ( (x - xl ) * fr - ( x - xr ) * fl ) / zdeltx
1395	ENDIF
1396	!
1397	END FUNCTION interp1
1398
1399
1400	FUNCTION interp2( x, a, b, c, d ) RESULT(f)
1401	!!----------------------------------------------------------------------
1402	!! * ROUTINE interp1 *
1403	!!
1404	!! ** Purpose : 1-d constrained cubic spline interpolation
1405	!!
1406	!! ** Method : cubic spline interpolation
1407	!!
1408	!!----------------------------------------------------------------------
1409	REAL(wp), INTENT(in) :: x, a, b, c, d
1410	REAL(wp) :: f ! value from the interpolation
1411	!!----------------------------------------------------------------------
1412	!
1413	f = a + x* ( b + x * ( c + d * x ) )
1414	!
1415	END FUNCTION interp2
1416
1417
1418	FUNCTION interp3( x, a, b, c, d ) RESULT(f)
1419	!!----------------------------------------------------------------------
1420	!! * ROUTINE interp1 *
1421	!!
1422	!! ** Purpose : Calculate the first order of derivative of
1423	!! a cubic spline function y=a+bx+cx^2+d*x^3
1424	!!
1425	!! ** Method : f=dy/dx=b+2cx+3dx^2
1426	!!
1427	!!----------------------------------------------------------------------
1428	REAL(wp), INTENT(in) :: x, a, b, c, d
1429	REAL(wp) :: f ! value from the interpolation
1430	!!----------------------------------------------------------------------
1431	!
1432	f = b + x * ( 2._wp * c + 3._wp * d * x)
1433	!
1434	END FUNCTION interp3
1435
1436
1437	FUNCTION integ_spline( xl, xr, a, b, c, d ) RESULT(f)
1438	!!----------------------------------------------------------------------
1439	!! * ROUTINE interp1 *
1440	!!
1441	!! ** Purpose : 1-d constrained cubic spline integration
1442	!!
1443	!! ** Method : integrate polynomial a+bx+cx^2+dx^3 from xl to xr
1444	!!
1445	!!----------------------------------------------------------------------
1446	REAL(wp), INTENT(in) :: xl, xr, a, b, c, d
1447	REAL(wp) :: za1, za2, za3
1448	REAL(wp) :: f ! integration result
1449	!!----------------------------------------------------------------------
1450	!
1451	za1 = 0.5_wp * b
1452	za2 = c / 3.0_wp
1453	za3 = 0.25_wp * d
1454	!
1455	f = xr * ( a + xr * ( za1 + xr * ( za2 + za3 * xr ) ) ) - &
1456	& xl * ( a + xl * ( za1 + xl * ( za2 + za3 * xl ) ) )
1457	!
1458	END FUNCTION integ_spline
1459
1460	!!======================================================================
1461	END MODULE dynhpg
1462

Note: See TracBrowser for help on using the repository browser.

New URL for NEMO forge! http://forge.nemo-ocean.eu

Context Navigation

source: NEMO/branches/UKMO/dev_r10037_GPU/src/OCE/DYN/dynhpg.F90 @ 11467

Download in other formats: