New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p4zsms.F90 in NEMO/branches/UKMO/dev_r10037_GPU/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/UKMO/dev_r10037_GPU/src/TOP/PISCES/P4Z/p4zsms.F90 @ 10843

Last change on this file since 10843 was 10843, checked in by andmirek, 5 years ago

ticket #2197 merge with dev_r9950_GO8_package at 10320

File size: 25.2 KB
Line 
1MODULE p4zsms
2   !!======================================================================
3   !!                         ***  MODULE p4zsms  ***
4   !! TOP :   PISCES Source Minus Sink manager
5   !!======================================================================
6   !! History :   1.0  !  2004-03 (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!----------------------------------------------------------------------
9   !!   p4z_sms        : Time loop of passive tracers sms
10   !!----------------------------------------------------------------------
11   USE oce_trc         ! shared variables between ocean and passive tracers
12   USE trc             ! passive tracers common variables
13   USE trcdta          !
14   USE sms_pisces      ! PISCES Source Minus Sink variables
15   USE p4zbio          ! Biological model
16   USE p4zche          ! Chemical model
17   USE p4zlys          ! Calcite saturation
18   USE p4zflx          ! Gas exchange
19   USE p4zsbc          ! External source of nutrients
20   USE p4zsed          ! Sedimentation
21   USE p4zint          ! time interpolation
22   USE p4zrem          ! remineralisation
23   USE iom             ! I/O manager
24   USE trd_oce         ! Ocean trends variables
25   USE trdtrc          ! TOP trends variables
26   USE sedmodel        ! Sediment model
27   USE prtctl_trc      ! print control for debugging
28
29   IMPLICIT NONE
30   PRIVATE
31
32   PUBLIC   p4z_sms_init   ! called in p4zsms.F90
33   PUBLIC   p4z_sms        ! called in p4zsms.F90
34
35   INTEGER ::    numco2, numnut, numnit      ! logical unit for co2 budget
36   REAL(wp) ::   alkbudget, no3budget, silbudget, ferbudget, po4budget
37   REAL(wp) ::   xfact1, xfact2, xfact3
38
39   REAL(wp), ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   xnegtr     ! Array used to indicate negative tracer values
40
41   !!----------------------------------------------------------------------
42   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
43   !! $Id$
44   !! Software governed by the CeCILL license (see ./LICENSE)
45   !!----------------------------------------------------------------------
46CONTAINS
47
48   SUBROUTINE p4z_sms( kt )
49      !!---------------------------------------------------------------------
50      !!                     ***  ROUTINE p4z_sms  ***
51      !!
52      !! ** Purpose :   Managment of the call to Biological sources and sinks
53      !!              routines of PISCES bio-model
54      !!
55      !! ** Method  : - at each new day ...
56      !!              - several calls of bio and sed ???
57      !!              - ...
58      !!---------------------------------------------------------------------
59      !
60      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index     
61      !!
62      INTEGER ::   ji, jj, jk, jnt, jn, jl
63      REAL(wp) ::  ztra
64      CHARACTER (len=25) :: charout
65      !!---------------------------------------------------------------------
66      !
67      IF( ln_timing )   CALL timing_start('p4z_sms')
68      !
69      IF( kt == nittrc000 ) THEN
70        !
71        ALLOCATE( xnegtr(jpi,jpj,jpk) )
72        !
73        IF( .NOT. ln_rsttr ) THEN
74            CALL p4z_che                              ! initialize the chemical constants
75            CALL ahini_for_at(hi)   !  set PH at kt=nit000
76        ELSE
77            CALL p4z_rst( nittrc000, 'READ' )  !* read or initialize all required fields
78        ENDIF
79        !
80      ENDIF
81      !
82      IF( ln_pisdmp .AND. MOD( kt - nn_dttrc, nn_pisdmp ) == 0 )   CALL p4z_dmp( kt )      ! Relaxation of some tracers
83      !
84      rfact = r2dttrc
85      !
86      IF( ( ln_top_euler .AND. kt == nittrc000 )  .OR. ( .NOT.ln_top_euler .AND. kt <= nittrc000 + nn_dttrc ) ) THEN
87         rfactr  = 1. / rfact
88         rfact2  = rfact / REAL( nrdttrc, wp )
89         rfact2r = 1. / rfact2
90         xstep = rfact2 / rday         ! Time step duration for biology
91         IF(lwp) WRITE(numout,*) 
92         IF(lwp) WRITE(numout,*) '    Passive Tracer  time step    rfact  = ', rfact, ' rdt = ', rdt
93         IF(lwp) write(numout,*) '    PISCES  Biology time step    rfact2 = ', rfact2
94         IF(lwp) WRITE(numout,*)
95      ENDIF
96
97      IF( ( neuler == 0 .AND. kt == nittrc000 ) .OR. ln_top_euler ) THEN
98         DO jn = jp_pcs0, jp_pcs1              !   SMS on tracer without Asselin time-filter
99            trb(:,:,:,jn) = trn(:,:,:,jn)
100         END DO
101      ENDIF
102      !
103      IF( ll_sbc ) CALL p4z_sbc( kt )   ! external sources of nutrients
104      !
105#if ! defined key_sed_off
106      CALL p4z_che              ! computation of chemical constants
107      CALL p4z_int( kt )        ! computation of various rates for biogeochemistry
108      !
109      DO jnt = 1, nrdttrc          ! Potential time splitting if requested
110         !
111         CALL p4z_bio( kt, jnt )   ! Biology
112         CALL p4z_lys( kt, jnt )   ! Compute CaCO3 saturation
113         CALL p4z_sed( kt, jnt )   ! Surface and Bottom boundary conditions
114         CALL p4z_flx( kt, jnt )   ! Compute surface fluxes
115         !
116         xnegtr(:,:,:) = 1.e0
117         DO jn = jp_pcs0, jp_pcs1
118            DO jk = 1, jpk
119               DO jj = 1, jpj
120                  DO ji = 1, jpi
121                     IF( ( trb(ji,jj,jk,jn) + tra(ji,jj,jk,jn) ) < 0.e0 ) THEN
122                        ztra             = ABS( trb(ji,jj,jk,jn) ) / ( ABS( tra(ji,jj,jk,jn) ) + rtrn )
123                        xnegtr(ji,jj,jk) = MIN( xnegtr(ji,jj,jk),  ztra )
124                     ENDIF
125                 END DO
126               END DO
127            END DO
128         END DO
129         !                                ! where at least 1 tracer concentration becomes negative
130         !                                !
131         DO jn = jp_pcs0, jp_pcs1
132           trb(:,:,:,jn) = trb(:,:,:,jn) + xnegtr(:,:,:) * tra(:,:,:,jn)
133         END DO
134        !
135         DO jn = jp_pcs0, jp_pcs1
136            tra(:,:,:,jn) = 0._wp
137         END DO
138         !
139         IF( ln_top_euler ) THEN
140            DO jn = jp_pcs0, jp_pcs1
141               trn(:,:,:,jn) = trb(:,:,:,jn)
142            END DO
143         ENDIF
144      END DO
145
146      !
147      IF( l_trdtrc ) THEN
148         DO jn = jp_pcs0, jp_pcs1
149           CALL trd_trc( tra(:,:,:,jn), jn, jptra_sms, kt )   ! save trends
150         END DO
151      END IF
152#endif
153      !
154      IF( ln_sediment ) THEN 
155         !
156         CALL sed_model( kt )     !  Main program of Sediment model
157         !
158         IF( ln_top_euler ) THEN
159            DO jn = jp_pcs0, jp_pcs1
160               trn(:,:,:,jn) = trb(:,:,:,jn)
161            END DO
162         ENDIF
163         !
164      ENDIF
165      !
166      IF( lrst_trc )  CALL p4z_rst( kt, 'WRITE' )  !* Write PISCES informations in restart file
167      !
168
169      IF( lk_iomput .OR. ln_check_mass )  CALL p4z_chk_mass( kt )    ! Mass conservation checking
170
171      IF( lwm .AND. kt == nittrc000    )  CALL FLUSH( numonp )       ! flush output namelist PISCES
172      !
173      IF( ln_timing )  CALL timing_stop('p4z_sms')
174      !
175   END SUBROUTINE p4z_sms
176
177
178   SUBROUTINE p4z_sms_init
179      !!----------------------------------------------------------------------
180      !!                     ***  p4z_sms_init  *** 
181      !!
182      !! ** Purpose :   read PISCES namelist
183      !!
184      !! ** input   :   file 'namelist.trc.s' containing the following
185      !!             namelist: natext, natbio, natsms
186      !!----------------------------------------------------------------------
187      INTEGER :: ios                 ! Local integer output status for namelist read
188      !!
189      NAMELIST/nampisbio/ nrdttrc, wsbio, xkmort, ferat3, wsbio2, wsbio2max, wsbio2scale,    &
190         &                   niter1max, niter2max, wfep, ldocp, ldocz, lthet,  &
191         &                   no3rat3, po4rat3
192         !
193      NAMELIST/nampisdmp/ ln_pisdmp, nn_pisdmp
194      NAMELIST/nampismass/ ln_check_mass
195      !!----------------------------------------------------------------------
196      !
197      IF(lwp) THEN
198         WRITE(numout,*)
199         WRITE(numout,*) 'p4z_sms_init : PISCES initialization'
200         WRITE(numout,*) '~~~~~~~~~~~~'
201      ENDIF
202
203      REWIND( numnatp_ref )              ! Namelist nampisbio in reference namelist : Pisces variables
204      READ  ( numnatp_ref, nampisbio, IOSTAT = ios, ERR = 901)
205901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisbio in reference namelist', lwp )
206      REWIND( numnatp_cfg )              ! Namelist nampisbio in configuration namelist : Pisces variables
207      READ  ( numnatp_cfg, nampisbio, IOSTAT = ios, ERR = 902 )
208902   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisbio in configuration namelist', lwp )
209      IF(lwm) WRITE( numonp, nampisbio )
210      !
211      IF(lwp) THEN                         ! control print
212         WRITE(numout,*) '   Namelist : nampisbio'
213         WRITE(numout,*) '      frequency for the biology                 nrdttrc     =', nrdttrc
214         WRITE(numout,*) '      POC sinking speed                         wsbio       =', wsbio
215         WRITE(numout,*) '      half saturation constant for mortality    xkmort      =', xkmort 
216         IF( ln_p5z ) THEN
217            WRITE(numout,*) '      N/C in zooplankton                        no3rat3     =', no3rat3
218            WRITE(numout,*) '      P/C in zooplankton                        po4rat3     =', po4rat3
219         ENDIF
220         WRITE(numout,*) '      Fe/C in zooplankton                       ferat3      =', ferat3
221         WRITE(numout,*) '      Big particles sinking speed               wsbio2      =', wsbio2
222         WRITE(numout,*) '      Big particles maximum sinking speed       wsbio2max   =', wsbio2max
223         WRITE(numout,*) '      Big particles sinking speed length scale  wsbio2scale =', wsbio2scale
224         WRITE(numout,*) '      Maximum number of iterations for POC      niter1max   =', niter1max
225         WRITE(numout,*) '      Maximum number of iterations for GOC      niter2max   =', niter2max
226         IF( ln_ligand ) THEN
227            WRITE(numout,*) '      FeP sinking speed                              wfep   =', wfep
228            IF( ln_p4z ) THEN
229               WRITE(numout,*) '      Phyto ligand production per unit doc           ldocp  =', ldocp
230               WRITE(numout,*) '      Zoo ligand production per unit doc             ldocz  =', ldocz
231               WRITE(numout,*) '      Proportional loss of ligands due to Fe uptake  lthet  =', lthet
232            ENDIF
233         ENDIF
234      ENDIF
235
236
237      REWIND( numnatp_ref )              ! Namelist nampisdmp in reference namelist : Pisces damping
238      READ  ( numnatp_ref, nampisdmp, IOSTAT = ios, ERR = 905)
239905   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampisdmp in reference namelist', lwp )
240      REWIND( numnatp_cfg )              ! Namelist nampisdmp in configuration namelist : Pisces damping
241      READ  ( numnatp_cfg, nampisdmp, IOSTAT = ios, ERR = 906 )
242906   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampisdmp in configuration namelist', lwp )
243      IF(lwm) WRITE( numonp, nampisdmp )
244      !
245      IF(lwp) THEN                         ! control print
246         WRITE(numout,*)
247         WRITE(numout,*) '   Namelist : nampisdmp --- relaxation to GLODAP'
248         WRITE(numout,*) '      Relaxation of tracer to glodap mean value   ln_pisdmp =', ln_pisdmp
249         WRITE(numout,*) '      Frequency of Relaxation                     nn_pisdmp =', nn_pisdmp
250      ENDIF
251
252      REWIND( numnatp_ref )              ! Namelist nampismass in reference namelist : Pisces mass conservation check
253      READ  ( numnatp_ref, nampismass, IOSTAT = ios, ERR = 907)
254907   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nampismass in reference namelist', lwp )
255      REWIND( numnatp_cfg )              ! Namelist nampismass in configuration namelist : Pisces mass conservation check
256      READ  ( numnatp_cfg, nampismass, IOSTAT = ios, ERR = 908 )
257908   IF( ios >  0 )   CALL ctl_nam ( ios , 'nampismass in configuration namelist', lwp )
258      IF(lwm) WRITE( numonp, nampismass )
259
260      IF(lwp) THEN                         ! control print
261         WRITE(numout,*)
262         WRITE(numout,*) '   Namelist : nampismass  --- mass conservation checking'
263         WRITE(numout,*) '      Flag to check mass conservation of NO3/Si/TALK   ln_check_mass = ', ln_check_mass
264      ENDIF
265      !
266   END SUBROUTINE p4z_sms_init
267
268
269   SUBROUTINE p4z_rst( kt, cdrw )
270      !!---------------------------------------------------------------------
271      !!                   ***  ROUTINE p4z_rst  ***
272      !!
273      !!  ** Purpose : Read or write variables in restart file:
274      !!
275      !!  WRITE(READ) mode:
276      !!       kt        : number of time step since the begining of the experiment at the
277      !!                   end of the current(previous) run
278      !!---------------------------------------------------------------------
279      INTEGER         , INTENT(in) ::   kt         ! ocean time-step
280      CHARACTER(len=*), INTENT(in) ::   cdrw       ! "READ"/"WRITE" flag
281      !!---------------------------------------------------------------------
282      !
283      IF( TRIM(cdrw) == 'READ' ) THEN
284         !
285         IF(lwp) WRITE(numout,*)
286         IF(lwp) WRITE(numout,*) ' p4z_rst : Read specific variables from pisces model '
287         IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
288         !
289         IF( iom_varid( numrtr, 'PH', ldstop = .FALSE. ) > 0 ) THEN
290            CALL iom_get( numrtr, jpdom_autoglo, 'PH' , hi(:,:,:)  )
291         ELSE
292            CALL p4z_che                              ! initialize the chemical constants
293            CALL ahini_for_at(hi)
294         ENDIF
295         CALL iom_get( numrtr, jpdom_autoglo, 'Silicalim', xksi(:,:) )
296         IF( iom_varid( numrtr, 'Silicamax', ldstop = .FALSE. ) > 0 ) THEN
297            CALL iom_get( numrtr, jpdom_autoglo, 'Silicamax' , xksimax(:,:)  )
298         ELSE
299            xksimax(:,:) = xksi(:,:)
300         ENDIF
301         !
302         IF( iom_varid( numrtr, 'tcflxcum', ldstop = .FALSE. ) > 0 ) THEN  ! cumulative total flux of carbon
303            CALL iom_get( numrtr, 'tcflxcum' , t_oce_co2_flx_cum  )
304         ELSE
305            t_oce_co2_flx_cum = 0._wp
306         ENDIF
307         !
308         IF( ln_p5z ) THEN
309            IF( iom_varid( numrtr, 'sized', ldstop = .FALSE. ) > 0 ) THEN
310               CALL iom_get( numrtr, jpdom_autoglo, 'sizep' , sizep(:,:,:)  )
311               CALL iom_get( numrtr, jpdom_autoglo, 'sizen' , sizen(:,:,:)  )
312               CALL iom_get( numrtr, jpdom_autoglo, 'sized' , sized(:,:,:)  )
313            ELSE
314               sizep(:,:,:) = 1.
315               sizen(:,:,:) = 1.
316               sized(:,:,:) = 1.
317            ENDIF
318        ENDIF
319        !
320      ELSEIF( TRIM(cdrw) == 'WRITE' ) THEN
321         IF( kt == nitrst ) THEN
322            IF(lwp) WRITE(numout,*)
323            IF(lwp) WRITE(numout,*) 'p4z_rst : write pisces restart file  kt =', kt
324            IF(lwp) WRITE(numout,*) '~~~~~~~'
325         ENDIF
326         CALL iom_rstput( kt, nitrst, numrtw, 'PH', hi(:,:,:) )
327         CALL iom_rstput( kt, nitrst, numrtw, 'Silicalim', xksi(:,:) )
328         CALL iom_rstput( kt, nitrst, numrtw, 'Silicamax', xksimax(:,:) )
329         CALL iom_rstput( kt, nitrst, numrtw, 'tcflxcum', t_oce_co2_flx_cum )
330         IF( ln_p5z ) THEN
331            CALL iom_rstput( kt, nitrst, numrtw, 'sizep', sizep(:,:,:) )
332            CALL iom_rstput( kt, nitrst, numrtw, 'sizen', sizen(:,:,:) )
333            CALL iom_rstput( kt, nitrst, numrtw, 'sized', sized(:,:,:) )
334         ENDIF
335      ENDIF
336      !
337   END SUBROUTINE p4z_rst
338
339
340   SUBROUTINE p4z_dmp( kt )
341      !!----------------------------------------------------------------------
342      !!                    ***  p4z_dmp  ***
343      !!
344      !! ** purpose  : Relaxation of some tracers
345      !!----------------------------------------------------------------------
346      !
347      INTEGER, INTENT( in )  ::     kt ! time step
348      !
349      REAL(wp) ::  alkmean = 2426.     ! mean value of alkalinity ( Glodap ; for Goyet 2391. )
350      REAL(wp) ::  po4mean = 2.165     ! mean value of phosphates
351      REAL(wp) ::  no3mean = 30.90     ! mean value of nitrate
352      REAL(wp) ::  silmean = 91.51     ! mean value of silicate
353      !
354      REAL(wp) :: zarea, zalksumn, zpo4sumn, zno3sumn, zsilsumn
355      REAL(wp) :: zalksumb, zpo4sumb, zno3sumb, zsilsumb
356      !!---------------------------------------------------------------------
357
358      IF(lwp)  WRITE(numout,*)
359      IF(lwp)  WRITE(numout,*) ' p4z_dmp : Restoring of nutrients at time-step kt = ', kt
360      IF(lwp)  WRITE(numout,*)
361
362      IF( cn_cfg == "ORCA" .OR. cn_cfg == "orca") THEN
363         IF( .NOT. lk_c1d ) THEN      ! ORCA configuration (not 1D) !
364            !                                                ! --------------------------- !
365            ! set total alkalinity, phosphate, nitrate & silicate
366            zarea          = 1._wp / glob_sum( cvol(:,:,:) ) * 1e6             
367
368            zalksumn = glob_sum( trn(:,:,:,jptal) * cvol(:,:,:)  ) * zarea
369            zpo4sumn = glob_sum( trn(:,:,:,jppo4) * cvol(:,:,:)  ) * zarea * po4r
370            zno3sumn = glob_sum( trn(:,:,:,jpno3) * cvol(:,:,:)  ) * zarea * rno3
371            zsilsumn = glob_sum( trn(:,:,:,jpsil) * cvol(:,:,:)  ) * zarea
372 
373            IF(lwp) WRITE(numout,*) '       TALKN mean : ', zalksumn
374            trn(:,:,:,jptal) = trn(:,:,:,jptal) * alkmean / zalksumn
375
376            IF(lwp) WRITE(numout,*) '       PO4N  mean : ', zpo4sumn
377            trn(:,:,:,jppo4) = trn(:,:,:,jppo4) * po4mean / zpo4sumn
378
379            IF(lwp) WRITE(numout,*) '       NO3N  mean : ', zno3sumn
380            trn(:,:,:,jpno3) = trn(:,:,:,jpno3) * no3mean / zno3sumn
381
382            IF(lwp) WRITE(numout,*) '       SiO3N mean : ', zsilsumn
383            trn(:,:,:,jpsil) = MIN( 400.e-6,trn(:,:,:,jpsil) * silmean / zsilsumn )
384            !
385            !
386            IF( .NOT. ln_top_euler ) THEN
387               zalksumb = glob_sum( trb(:,:,:,jptal) * cvol(:,:,:)  ) * zarea
388               zpo4sumb = glob_sum( trb(:,:,:,jppo4) * cvol(:,:,:)  ) * zarea * po4r
389               zno3sumb = glob_sum( trb(:,:,:,jpno3) * cvol(:,:,:)  ) * zarea * rno3
390               zsilsumb = glob_sum( trb(:,:,:,jpsil) * cvol(:,:,:)  ) * zarea
391 
392               IF(lwp) WRITE(numout,*) ' '
393               IF(lwp) WRITE(numout,*) '       TALKB mean : ', zalksumb
394               trb(:,:,:,jptal) = trb(:,:,:,jptal) * alkmean / zalksumb
395
396               IF(lwp) WRITE(numout,*) '       PO4B  mean : ', zpo4sumb
397               trb(:,:,:,jppo4) = trb(:,:,:,jppo4) * po4mean / zpo4sumb
398
399               IF(lwp) WRITE(numout,*) '       NO3B  mean : ', zno3sumb
400               trb(:,:,:,jpno3) = trb(:,:,:,jpno3) * no3mean / zno3sumb
401
402               IF(lwp) WRITE(numout,*) '       SiO3B mean : ', zsilsumb
403               trb(:,:,:,jpsil) = MIN( 400.e-6,trb(:,:,:,jpsil) * silmean / zsilsumb )
404           ENDIF
405        ENDIF
406        !
407      ENDIF
408        !
409   END SUBROUTINE p4z_dmp
410
411
412   SUBROUTINE p4z_chk_mass( kt )
413      !!----------------------------------------------------------------------
414      !!                  ***  ROUTINE p4z_chk_mass  ***
415      !!
416      !! ** Purpose :  Mass conservation check
417      !!
418      !!---------------------------------------------------------------------
419      INTEGER, INTENT( in ) ::   kt      ! ocean time-step index     
420      REAL(wp)             ::  zrdenittot, zsdenittot, znitrpottot
421      CHARACTER(LEN=100)   ::   cltxt
422      INTEGER :: jk
423      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zwork
424      !!----------------------------------------------------------------------
425      !
426      IF( kt == nittrc000 ) THEN
427         xfact1 = rfact2r * 12. / 1.e15 * ryyss    ! conversion molC/kt --> PgC/yr
428         xfact2 = 1.e+3 * rno3 * 14. / 1.e12 * ryyss   ! conversion molC/l/s ----> TgN/m3/yr
429         xfact3 = 1.e+3 * rfact2r * rno3   ! conversion molC/l/kt ----> molN/m3/s
430         IF( ln_check_mass .AND. lwp) THEN      !   Open budget file of NO3, ALK, Si, Fer
431            CALL ctl_opn( numco2, 'carbon.budget'  , 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
432            CALL ctl_opn( numnut, 'nutrient.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
433            CALL ctl_opn( numnit, 'nitrogen.budget', 'REPLACE', 'FORMATTED', 'SEQUENTIAL', -1, 6, .FALSE., narea )
434            cltxt='time-step   Alkalinity        Nitrate        Phosphorus         Silicate           Iron'
435            IF( lwp ) WRITE(numnut,*)  TRIM(cltxt)
436            IF( lwp ) WRITE(numnut,*) 
437         ENDIF
438      ENDIF
439
440      IF( iom_use( "pno3tot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
441         !   Compute the budget of NO3, ALK, Si, Fer
442         IF( ln_p4z ) THEN
443            zwork(:,:,:) =    trn(:,:,:,jpno3) + trn(:,:,:,jpnh4)                      &
444               &          +   trn(:,:,:,jpphy) + trn(:,:,:,jpdia)                      &
445               &          +   trn(:,:,:,jppoc) + trn(:,:,:,jpgoc)  + trn(:,:,:,jpdoc)  &       
446               &          +   trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) 
447        ELSE
448            zwork(:,:,:) =    trn(:,:,:,jpno3) + trn(:,:,:,jpnh4) + trn(:,:,:,jpnph)   &
449               &          +   trn(:,:,:,jpndi) + trn(:,:,:,jpnpi)                      & 
450               &          +   trn(:,:,:,jppon) + trn(:,:,:,jpgon) + trn(:,:,:,jpdon)   &
451               &          + ( trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) ) * no3rat3 
452        ENDIF
453        !
454        no3budget = glob_sum( zwork(:,:,:) * cvol(:,:,:)  ) 
455        no3budget = no3budget / areatot
456        CALL iom_put( "pno3tot", no3budget )
457      ENDIF
458      !
459      IF( iom_use( "ppo4tot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
460         IF( ln_p4z ) THEN
461            zwork(:,:,:) =    trn(:,:,:,jppo4)                                         &
462               &          +   trn(:,:,:,jpphy) + trn(:,:,:,jpdia)                      &
463               &          +   trn(:,:,:,jppoc) + trn(:,:,:,jpgoc)  + trn(:,:,:,jpdoc)  &       
464               &          +   trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) 
465        ELSE
466            zwork(:,:,:) =    trn(:,:,:,jppo4) + trn(:,:,:,jppph)                      &
467               &          +   trn(:,:,:,jppdi) + trn(:,:,:,jpppi)                      & 
468               &          +   trn(:,:,:,jppop) + trn(:,:,:,jpgop) + trn(:,:,:,jpdop)   &
469               &          + ( trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) ) * po4rat3 
470        ENDIF
471        !
472        po4budget = glob_sum( zwork(:,:,:) * cvol(:,:,:)  ) 
473        po4budget = po4budget / areatot
474        CALL iom_put( "ppo4tot", po4budget )
475      ENDIF
476      !
477      IF( iom_use( "psiltot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
478         zwork(:,:,:) =  trn(:,:,:,jpsil) + trn(:,:,:,jpgsi) + trn(:,:,:,jpdsi) 
479         !
480         silbudget = glob_sum( zwork(:,:,:) * cvol(:,:,:)  ) 
481         silbudget = silbudget / areatot
482         CALL iom_put( "psiltot", silbudget )
483      ENDIF
484      !
485      IF( iom_use( "palktot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
486         zwork(:,:,:) =  trn(:,:,:,jpno3) * rno3 + trn(:,:,:,jptal) + trn(:,:,:,jpcal) * 2.             
487         !
488         alkbudget = glob_sum( zwork(:,:,:) * cvol(:,:,:)  )         !
489         alkbudget = alkbudget / areatot
490         CALL iom_put( "palktot", alkbudget )
491      ENDIF
492      !
493      IF( iom_use( "pfertot" ) .OR. ( ln_check_mass .AND. kt == nitend )  ) THEN
494         zwork(:,:,:) =   trn(:,:,:,jpfer) + trn(:,:,:,jpnfe) + trn(:,:,:,jpdfe)   &
495            &         +   trn(:,:,:,jpbfe) + trn(:,:,:,jpsfe)                      &
496            &         + ( trn(:,:,:,jpzoo) + trn(:,:,:,jpmes) )  * ferat3   
497         IF( ln_ligand)  zwork(:,:,:) = zwork(:,:,:) + trn(:,:,:,jpfep)               
498         !
499         ferbudget = glob_sum( zwork(:,:,:) * cvol(:,:,:)  ) 
500         ferbudget = ferbudget / areatot
501         CALL iom_put( "pfertot", ferbudget )
502      ENDIF
503      !
504      ! Global budget of N SMS : denitrification in the water column and in the sediment
505      !                          nitrogen fixation by the diazotrophs
506      ! --------------------------------------------------------------------------------
507      IF( iom_use( "tnfix" ) .OR.  ( ln_check_mass .AND. kt == nitend )  ) THEN
508         znitrpottot  = glob_sum ( nitrpot(:,:,:) * nitrfix * cvol(:,:,:) )
509         CALL iom_put( "tnfix"  , znitrpottot * xfact3 )  ! Global  nitrogen fixation molC/l  to molN/m3
510      ENDIF
511      !
512      IF( iom_use( "tdenit" ) .OR.  ( ln_check_mass .AND. kt == nitend )  ) THEN
513         zrdenittot = glob_sum ( denitr(:,:,:) * rdenit * xnegtr(:,:,:) * cvol(:,:,:) )
514         zsdenittot = glob_sum ( sdenit(:,:) * e1e2t(:,:) * tmask(:,:,1) )
515         CALL iom_put( "tdenit" , ( zrdenittot + zsdenittot ) * xfact3 )  ! Total denitrification molC/l to molN/m3
516      ENDIF
517      !
518      IF( ln_check_mass .AND. kt == nitend ) THEN   ! Compute the budget of NO3, ALK, Si, Fer
519         t_atm_co2_flx  = t_atm_co2_flx / glob_sum( e1e2t(:,:) )
520         t_oce_co2_flx  = t_oce_co2_flx         * xfact1 * (-1 )
521         tpp            = tpp           * 1000. * xfact1
522         t_oce_co2_exp  = t_oce_co2_exp * 1000. * xfact1
523         IF( lwp ) WRITE(numco2,9000) ndastp, t_atm_co2_flx, t_oce_co2_flx, tpp, t_oce_co2_exp
524         IF( lwp ) WRITE(numnut,9100) ndastp, alkbudget        * 1.e+06, &
525             &                                no3budget * rno3 * 1.e+06, &
526             &                                po4budget * po4r * 1.e+06, &
527             &                                silbudget        * 1.e+06, &
528             &                                ferbudget        * 1.e+09
529         !
530         IF( lwp ) WRITE(numnit,9200) ndastp, znitrpottot * xfact2  , &
531            &                             zrdenittot  * xfact2  , &
532            &                             zsdenittot  * xfact2
533      ENDIF
534      !
535 9000  FORMAT(i8,f10.5,e18.10,f10.5,f10.5)
536 9100  FORMAT(i8,5e18.10)
537 9200  FORMAT(i8,3f10.5)
538       !
539   END SUBROUTINE p4z_chk_mass
540
541   !!======================================================================
542END MODULE p4zsms 
Note: See TracBrowser for help on using the repository browser.