New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
dommsk.F90 in NEMO/branches/UKMO/dev_r10037_shlat2d/src/OCE/DOM – NEMO

source: NEMO/branches/UKMO/dev_r10037_shlat2d/src/OCE/DOM/dommsk.F90 @ 10642

Last change on this file since 10642 was 10642, checked in by davestorkey, 5 years ago

UKMO dev_r10037_shlat2d branch: commit code changes.

File size: 16.0 KB
Line 
1MODULE dommsk
2   !!======================================================================
3   !!                       ***  MODULE dommsk   ***
4   !! Ocean initialization : domain land/sea mask
5   !!======================================================================
6   !! History :  OPA  ! 1987-07  (G. Madec)  Original code
7   !!            6.0  ! 1993-03  (M. Guyon)  symetrical conditions (M. Guyon)
8   !!            7.0  ! 1996-01  (G. Madec)  suppression of common work arrays
9   !!             -   ! 1996-05  (G. Madec)  mask computed from tmask
10   !!            8.0  ! 1997-02  (G. Madec)  mesh information put in domhgr.F
11   !!            8.1  ! 1997-07  (G. Madec)  modification of kbat and fmask
12   !!             -   ! 1998-05  (G. Roullet)  free surface
13   !!            8.2  ! 2000-03  (G. Madec)  no slip accurate
14   !!             -   ! 2001-09  (J.-M. Molines)  Open boundaries
15   !!   NEMO     1.0  ! 2002-08  (G. Madec)  F90: Free form and module
16   !!             -   ! 2005-11  (V. Garnier) Surface pressure gradient organization
17   !!            3.2  ! 2009-07  (R. Benshila) Suppression of rigid-lid option
18   !!            3.6  ! 2015-05  (P. Mathiot) ISF: add wmask,wumask and wvmask
19   !!            4.0  ! 2016-06  (G. Madec, S. Flavoni)  domain configuration / user defined interface
20   !!----------------------------------------------------------------------
21
22   !!----------------------------------------------------------------------
23   !!   dom_msk       : compute land/ocean mask
24   !!----------------------------------------------------------------------
25   USE oce            ! ocean dynamics and tracers
26   USE dom_oce        ! ocean space and time domain
27   USE usrdef_fmask   ! user defined fmask
28   USE bdy_oce        ! open boundary
29   !
30   USE in_out_manager ! I/O manager
31   USE iom            ! IOM library
32   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
33   USE lib_mpp        ! Massively Parallel Processing library
34   USE iom             ! For shlat2d
35   USE fldread         ! for sn_shlat2d
36
37   IMPLICIT NONE
38   PRIVATE
39
40   PUBLIC   dom_msk    ! routine called by inidom.F90
41
42   !                            !!* Namelist namlbc : lateral boundary condition *
43   REAL(wp)        :: rn_shlat   ! type of lateral boundary condition on velocity
44   LOGICAL, PUBLIC :: ln_vorlat  !  consistency of vorticity boundary condition
45   !                                            with analytical eqs.
46
47   !! * Substitutions
48#  include "vectopt_loop_substitute.h90"
49   !!----------------------------------------------------------------------
50   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL licence     (./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE dom_msk( k_top, k_bot )
57      !!---------------------------------------------------------------------
58      !!                 ***  ROUTINE dom_msk  ***
59      !!
60      !! ** Purpose :   Compute land/ocean mask arrays at tracer points, hori-
61      !!      zontal velocity points (u & v), vorticity points (f) points.
62      !!
63      !! ** Method  :   The ocean/land mask  at t-point is deduced from ko_top
64      !!      and ko_bot, the indices of the fist and last ocean t-levels which
65      !!      are either defined in usrdef_zgr or read in zgr_read.
66      !!                The velocity masks (umask, vmask, wmask, wumask, wvmask)
67      !!      are deduced from a product of the two neighboring tmask.
68      !!                The vorticity mask (fmask) is deduced from tmask taking
69      !!      into account the choice of lateral boundary condition (rn_shlat) :
70      !!         rn_shlat = 0, free slip  (no shear along the coast)
71      !!         rn_shlat = 2, no slip  (specified zero velocity at the coast)
72      !!         0 < rn_shlat < 2, partial slip   | non-linear velocity profile
73      !!         2 < rn_shlat, strong slip        | in the lateral boundary layer
74      !!
75      !!      tmask_i : interior ocean mask at t-point, i.e. excluding duplicated
76      !!                rows/lines due to cyclic or North Fold boundaries as well
77      !!                as MPP halos.
78      !!      tmask_h : halo mask at t-point, i.e. excluding duplicated rows/lines
79      !!                due to cyclic or North Fold boundaries as well as MPP halos.
80      !!
81      !! ** Action :   tmask, umask, vmask, wmask, wumask, wvmask : land/ocean mask
82      !!                         at t-, u-, v- w, wu-, and wv-points (=0. or 1.)
83      !!               fmask   : land/ocean mask at f-point (=0., or =1., or
84      !!                         =rn_shlat along lateral boundaries)
85      !!               tmask_i : interior ocean mask
86      !!               tmask_h : halo mask
87      !!               ssmask , ssumask, ssvmask, ssfmask : 2D ocean mask
88      !!----------------------------------------------------------------------
89      INTEGER, DIMENSION(:,:), INTENT(in) ::   k_top, k_bot   ! first and last ocean level
90      !
91      INTEGER  ::   ji, jj, jk     ! dummy loop indices
92      INTEGER  ::   iif, iil       ! local integers
93      INTEGER  ::   ijf, ijl       !   -       -
94      INTEGER  ::   iktop, ikbot   !   -       -
95      INTEGER  ::   ios, inum
96      REAL(wp), ALLOCATABLE, DIMENSION(:,:) ::   zwf   ! 2D workspace
97      !!
98      INTEGER  :: inum             !  logical unit for shlat2d
99      REAL(wp) :: zshlat           !: locally modified shlat for some strait
100      REAL(wp), ALLOCATABLE, DIMENSION(:,:) :: zshlat2d
101      LOGICAL                         :: ln_shlat2d
102      CHARACTER(len = 256)            :: cn_shlat2d_file, cn_shlat2d_var 
103      !!
104      NAMELIST/namlbc/ rn_shlat, ln_vorlat, ln_shlat2d, cn_shlat2d_file, cn_shlat2d_var
105      NAMELIST/nambdy/ ln_bdy ,nb_bdy, ln_coords_file, cn_coords_file,         &
106         &             ln_mask_file, cn_mask_file, cn_dyn2d, nn_dyn2d_dta,     &
107         &             cn_dyn3d, nn_dyn3d_dta, cn_tra, nn_tra_dta,             &
108         &             ln_tra_dmp, ln_dyn3d_dmp, rn_time_dmp, rn_time_dmp_out, &
109         &             cn_ice, nn_ice_dta,                                     &
110         &             rn_ice_tem, rn_ice_sal, rn_ice_age,                     &
111         &             ln_vol, nn_volctl, nn_rimwidth, nb_jpk_bdy
112      !!---------------------------------------------------------------------
113      !
114      REWIND( numnam_ref )              ! Namelist namlbc in reference namelist : Lateral momentum boundary condition
115      READ  ( numnam_ref, namlbc, IOSTAT = ios, ERR = 901 )
116901   IF( ios /= 0 )   CALL ctl_nam ( ios , 'namlbc in reference namelist', lwp )
117      REWIND( numnam_cfg )              ! Namelist namlbc in configuration namelist : Lateral momentum boundary condition
118      READ  ( numnam_cfg, namlbc, IOSTAT = ios, ERR = 902 )
119902   IF( ios >  0 )   CALL ctl_nam ( ios , 'namlbc in configuration namelist', lwp )
120      IF(lwm) WRITE ( numond, namlbc )
121     
122      IF(lwp) THEN                  ! control print
123         WRITE(numout,*)
124         WRITE(numout,*) 'dommsk : ocean mask '
125         WRITE(numout,*) '~~~~~~'
126         WRITE(numout,*) '   Namelist namlbc'
127         WRITE(numout,*) '      lateral momentum boundary cond.    rn_shlat  = ',rn_shlat
128         WRITE(numout,*) '      consistency with analytical form   ln_vorlat = ',ln_vorlat 
129      ENDIF
130      !
131      IF(lwp) WRITE(numout,*)
132      IF     (      rn_shlat == 0.               ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  free-slip'
133      ELSEIF (      rn_shlat == 2.               ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  no-slip'
134      ELSEIF ( 0. < rn_shlat .AND. rn_shlat < 2. ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  partial-slip'
135      ELSEIF ( 2. < rn_shlat                     ) THEN   ;   IF(lwp) WRITE(numout,*) '   ==>>>   ocean lateral  strong-slip'
136      ELSE
137         CALL ctl_stop( 'dom_msk: wrong value for rn_shlat (i.e. a negalive value). We stop.' )
138      ENDIF
139
140      IF ( ln_shlat2d ) THEN
141         IF(lwp) WRITE(numout,*) '         READ shlat as a 2D coefficient in a file '
142         ALLOCATE( zshlat2d(jpi,jpj) )
143         CALL iom_open(TRIM(cn_shlat2d_file), inum)
144         CALL iom_get (inum, jpdom_data, TRIM(cn_shlat2d_var), zshlat2d, 1) !
145         CALL iom_close(inum)
146      ENDIF
147
148      !  Ocean/land mask at t-point  (computed from ko_top and ko_bot)
149      ! ----------------------------
150      !
151      tmask(:,:,:) = 0._wp
152      DO jj = 1, jpj
153         DO ji = 1, jpi
154            iktop = k_top(ji,jj)
155            ikbot = k_bot(ji,jj)
156            IF( iktop /= 0 ) THEN       ! water in the column
157               tmask(ji,jj,iktop:ikbot  ) = 1._wp
158            ENDIF
159         END DO 
160      END DO 
161!SF  add here lbc_lnk: bug not still understood : cause now domain configuration is read !
162!!gm I don't understand why... 
163      CALL lbc_lnk( tmask  , 'T', 1._wp )      ! Lateral boundary conditions
164
165     ! Mask corrections for bdy (read in mppini2)
166      REWIND( numnam_ref )              ! Namelist nambdy in reference namelist :Unstructured open boundaries
167      READ  ( numnam_ref, nambdy, IOSTAT = ios, ERR = 903)
168903   IF( ios /= 0 )   CALL ctl_nam ( ios , 'nambdy in reference namelist', lwp )
169      REWIND( numnam_cfg )              ! Namelist nambdy in configuration namelist :Unstructured open boundaries
170      READ  ( numnam_cfg, nambdy, IOSTAT = ios, ERR = 904 )
171904   IF( ios >  0 )   CALL ctl_nam ( ios , 'nambdy in configuration namelist', lwp )
172      ! ------------------------
173      IF ( ln_bdy .AND. ln_mask_file ) THEN
174         CALL iom_open( cn_mask_file, inum )
175         CALL iom_get ( inum, jpdom_data, 'bdy_msk', bdytmask(:,:) )
176         CALL iom_close( inum )
177         DO jk = 1, jpkm1
178            DO jj = 1, jpj
179               DO ji = 1, jpi
180                  tmask(ji,jj,jk) = tmask(ji,jj,jk) * bdytmask(ji,jj)
181               END DO
182            END DO
183         END DO
184      ENDIF
185         
186      !  Ocean/land mask at u-, v-, and f-points   (computed from tmask)
187      ! ----------------------------------------
188      ! NB: at this point, fmask is designed for free slip lateral boundary condition
189      DO jk = 1, jpk
190         DO jj = 1, jpjm1
191            DO ji = 1, fs_jpim1   ! vector loop
192               umask(ji,jj,jk) = tmask(ji,jj  ,jk) * tmask(ji+1,jj  ,jk)
193               vmask(ji,jj,jk) = tmask(ji,jj  ,jk) * tmask(ji  ,jj+1,jk)
194            END DO
195            DO ji = 1, jpim1      ! NO vector opt.
196               fmask(ji,jj,jk) = tmask(ji,jj  ,jk) * tmask(ji+1,jj  ,jk)   &
197                  &            * tmask(ji,jj+1,jk) * tmask(ji+1,jj+1,jk)
198            END DO
199         END DO
200      END DO
201      CALL lbc_lnk_multi( umask, 'U', 1., vmask, 'V', 1., fmask, 'F', 1. )      ! Lateral boundary conditions
202 
203      ! Ocean/land mask at wu-, wv- and w points    (computed from tmask)
204      !-----------------------------------------
205      wmask (:,:,1) = tmask(:,:,1)     ! surface
206      wumask(:,:,1) = umask(:,:,1)
207      wvmask(:,:,1) = vmask(:,:,1)
208      DO jk = 2, jpk                   ! interior values
209         wmask (:,:,jk) = tmask(:,:,jk) * tmask(:,:,jk-1)
210         wumask(:,:,jk) = umask(:,:,jk) * umask(:,:,jk-1)   
211         wvmask(:,:,jk) = vmask(:,:,jk) * vmask(:,:,jk-1)
212      END DO
213
214
215      ! Ocean/land column mask at t-, u-, and v-points   (i.e. at least 1 wet cell in the vertical)
216      ! ----------------------------------------------
217      ssmask (:,:) = MAXVAL( tmask(:,:,:), DIM=3 )
218      ssumask(:,:) = MAXVAL( umask(:,:,:), DIM=3 )
219      ssvmask(:,:) = MAXVAL( vmask(:,:,:), DIM=3 )
220
221
222      ! Interior domain mask  (used for global sum)
223      ! --------------------
224      !
225      iif = nn_hls   ;   iil = nlci - nn_hls + 1
226      ijf = nn_hls   ;   ijl = nlcj - nn_hls + 1
227      !
228      !                          ! halo mask : 0 on the halo and 1 elsewhere
229      tmask_h(:,:) = 1._wp                 
230      tmask_h( 1 :iif,   :   ) = 0._wp      ! first columns
231      tmask_h(iil:jpi,   :   ) = 0._wp      ! last  columns (including mpp extra columns)
232      tmask_h(   :   , 1 :ijf) = 0._wp      ! first rows
233      tmask_h(   :   ,ijl:jpj) = 0._wp      ! last  rows (including mpp extra rows)
234      !
235      !                          ! north fold mask
236      tpol(1:jpiglo) = 1._wp 
237      fpol(1:jpiglo) = 1._wp
238      IF( jperio == 3 .OR. jperio == 4 ) THEN      ! T-point pivot
239         tpol(jpiglo/2+1:jpiglo) = 0._wp
240         fpol(     1    :jpiglo) = 0._wp
241         IF( mjg(nlej) == jpjglo ) THEN                  ! only half of the nlcj-1 row for tmask_h
242            DO ji = iif+1, iil-1
243               tmask_h(ji,nlej-1) = tmask_h(ji,nlej-1) * tpol(mig(ji))
244            END DO
245         ENDIF
246      ENDIF
247      !
248      IF( jperio == 5 .OR. jperio == 6 ) THEN      ! F-point pivot
249         tpol(     1    :jpiglo) = 0._wp
250         fpol(jpiglo/2+1:jpiglo) = 0._wp
251      ENDIF
252      !
253      !                          ! interior mask : 2D ocean mask x halo mask
254      tmask_i(:,:) = ssmask(:,:) * tmask_h(:,:)
255
256
257      ! Lateral boundary conditions on velocity (modify fmask)
258      ! --------------------------------------- 
259      IF( rn_shlat /= 0 .or. ln_shlat2d ) THEN      ! Not free-slip lateral boundary condition everywhere
260         !
261         ALLOCATE( zwf(jpi,jpj) )
262         !
263         DO jk = 1, jpk
264            zwf(:,:) = fmask(:,:,jk)         
265            IF (  ln_shlat2d ) THEN
266               DO jj = 2, jpjm1
267                  DO ji = fs_2, fs_jpim1   ! vector opt.
268                     IF( fmask(ji,jj,jk) == 0._wp ) THEN
269                        fmask(ji,jj,jk) = zshlat2d(ji,jj) * MIN( 1._wp , MAX( zwf(ji+1,jj), zwf(ji,jj+1),   &
270                           &                                           zwf(ji-1,jj), zwf(ji,jj-1)  )  )
271                     ENDIF
272                  END DO
273               END DO
274            ELSE
275               DO jj = 2, jpjm1
276                  DO ji = fs_2, fs_jpim1   ! vector opt.
277                     IF( fmask(ji,jj,jk) == 0._wp ) THEN
278                        fmask(ji,jj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(ji+1,jj), zwf(ji,jj+1),   &
279                           &                                           zwf(ji-1,jj), zwf(ji,jj-1)  )  )
280                     ENDIF
281                  END DO
282               END DO
283            ENDIF
284            DO jj = 2, jpjm1
285               IF( fmask(1,jj,jk) == 0._wp ) THEN
286                  fmask(1  ,jj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(2,jj), zwf(1,jj+1), zwf(1,jj-1) ) )
287               ENDIF
288               IF( fmask(jpi,jj,jk) == 0._wp ) THEN
289                  fmask(jpi,jj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(jpi,jj+1), zwf(jpim1,jj), zwf(jpi,jj-1) ) )
290               ENDIF
291            END DO         
292            DO ji = 2, jpim1
293               IF( fmask(ji,1,jk) == 0._wp ) THEN
294                  fmask(ji, 1 ,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(ji+1,1), zwf(ji,2), zwf(ji-1,1) ) )
295               ENDIF
296               IF( fmask(ji,jpj,jk) == 0._wp ) THEN
297                  fmask(ji,jpj,jk) = rn_shlat * MIN( 1._wp , MAX( zwf(ji+1,jpj), zwf(ji-1,jpj), zwf(ji,jpjm1) ) )
298               ENDIF
299            END DO
300#if defined key_agrif 
301            IF( .NOT. AGRIF_Root() ) THEN
302               IF ((nbondi ==  1).OR.(nbondi == 2)) fmask(nlci-1 , :     ,jk) = 0.e0      ! east
303               IF ((nbondi == -1).OR.(nbondi == 2)) fmask(1      , :     ,jk) = 0.e0      ! west
304               IF ((nbondj ==  1).OR.(nbondj == 2)) fmask(:      ,nlcj-1 ,jk) = 0.e0      ! north
305               IF ((nbondj == -1).OR.(nbondj == 2)) fmask(:      ,1      ,jk) = 0.e0      ! south
306            ENDIF 
307#endif
308         END DO
309         !
310         DEALLOCATE( zwf )
311         IF( ln_shlat2d ) DEALLOCATE( zshlat2d )
312         !
313         CALL lbc_lnk( fmask, 'F', 1._wp )      ! Lateral boundary conditions on fmask
314         !
315         ! CAUTION : The fmask may be further modified in dyn_vor_init ( dynvor.F90 ) depending on ln_vorlat
316         !
317      ENDIF
318     
319      ! User defined alteration of fmask (use to reduce ocean transport in specified straits)
320      ! --------------------------------
321      !
322      CALL usr_def_fmask( cn_cfg, nn_cfg, fmask )
323      !
324   END SUBROUTINE dom_msk
325   
326   !!======================================================================
327END MODULE dommsk
Note: See TracBrowser for help on using the repository browser.