New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
zpshde.F90 in NEMO/branches/UKMO/dev_r10448_bdyvol/src/OCE/TRA – NEMO

source: NEMO/branches/UKMO/dev_r10448_bdyvol/src/OCE/TRA/zpshde.F90 @ 10455

Last change on this file since 10455 was 10425, checked in by smasson, 5 years ago

trunk: merge back dev_r10164_HPC09_ESIWACE_PREP_MERGE@10424 into the trunk

  • Property svn:keywords set to Id
File size: 24.6 KB
Line 
1MODULE zpshde
2   !!======================================================================
3   !!                       ***  MODULE zpshde   ***
4   !! z-coordinate + partial step : Horizontal Derivative at ocean bottom level
5   !!======================================================================
6   !! History :  OPA  !  2002-04  (A. Bozec)  Original code
7   !!   NEMO     1.0  !  2002-08  (G. Madec E. Durand)  Optimization and Free form
8   !!             -   !  2004-03  (C. Ethe)  adapted for passive tracers
9   !!            3.3  !  2010-05  (C. Ethe, G. Madec)  merge TRC-TRA
10   !!            3.6  !  2014-11  (P. Mathiot) Add zps_hde_isf (needed to open a cavity)
11   !!======================================================================
12   
13   !!----------------------------------------------------------------------
14   !!   zps_hde      :  Horizontal DErivative of T, S and rd at the last
15   !!                   ocean level (Z-coord. with Partial Steps)
16   !!----------------------------------------------------------------------
17   USE oce             ! ocean: dynamics and tracers variables
18   USE dom_oce         ! domain: ocean variables
19   USE phycst          ! physical constants
20   USE eosbn2          ! ocean equation of state
21   USE in_out_manager  ! I/O manager
22   USE lbclnk          ! lateral boundary conditions (or mpp link)
23   USE lib_mpp         ! MPP library
24   USE timing          ! Timing
25
26   IMPLICIT NONE
27   PRIVATE
28
29   PUBLIC   zps_hde     ! routine called by step.F90
30   PUBLIC   zps_hde_isf ! routine called by step.F90
31
32   !! * Substitutions
33#  include "vectopt_loop_substitute.h90"
34   !!----------------------------------------------------------------------
35   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
36   !! $Id$
37   !! Software governed by the CeCILL license (see ./LICENSE)
38   !!----------------------------------------------------------------------
39CONTAINS
40
41   SUBROUTINE zps_hde( kt, kjpt, pta, pgtu, pgtv,   &
42      &                          prd, pgru, pgrv    )
43      !!----------------------------------------------------------------------
44      !!                     ***  ROUTINE zps_hde  ***
45      !!                   
46      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
47      !!      at u- and v-points with a linear interpolation for z-coordinate
48      !!      with partial steps.
49      !!
50      !! ** Method  :   In z-coord with partial steps, scale factors on last
51      !!      levels are different for each grid point, so that T, S and rd
52      !!      points are not at the same depth as in z-coord. To have horizontal
53      !!      gradients again, we interpolate T and S at the good depth :
54      !!      Linear interpolation of T, S   
55      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
56      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
57      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
58      !!         This formulation computes the two cases:
59      !!                 CASE 1                   CASE 2 
60      !!         k-1  ___ ___________   k-1   ___ ___________
61      !!                    Ti  T~                  T~  Ti+1
62      !!                  _____                        _____
63      !!         k        |   |Ti+1     k           Ti |   |
64      !!                  |   |____                ____|   |
65      !!              ___ |   |   |           ___  |   |   |
66      !!                 
67      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
68      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
69      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
70      !!          or
71      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
72      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
73      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
74      !!          Idem for di(s) and dj(s)         
75      !!
76      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
77      !!      depth zh from interpolated T and S for the different formulations
78      !!      of the equation of state (eos).
79      !!      Gradient formulation for rho :
80      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
81      !!
82      !! ** Action  : compute for top interfaces
83      !!              - pgtu, pgtv: horizontal gradient of tracer at u- & v-points
84      !!              - pgru, pgrv: horizontal gradient of rho (if present) at u- & v-points
85      !!----------------------------------------------------------------------
86      INTEGER                              , INTENT(in   )           ::  kt          ! ocean time-step index
87      INTEGER                              , INTENT(in   )           ::  kjpt        ! number of tracers
88      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta         ! 4D tracers fields
89      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv  ! hor. grad. of ptra at u- & v-pts
90      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd         ! 3D density anomaly fields
91      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv  ! hor. grad of prd at u- & v-pts (bottom)
92      !
93      INTEGER  ::   ji, jj, jn                  ! Dummy loop indices
94      INTEGER  ::   iku, ikv, ikum1, ikvm1      ! partial step level (ocean bottom level) at u- and v-points
95      REAL(wp) ::   ze3wu, ze3wv, zmaxu, zmaxv  ! local scalars
96      REAL(wp), DIMENSION(jpi,jpj)      ::   zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
97      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::   zti, ztj             !
98      !!----------------------------------------------------------------------
99      !
100      IF( ln_timing )   CALL timing_start( 'zps_hde')
101      !
102      pgtu(:,:,:) = 0._wp   ;   zti (:,:,:) = 0._wp   ;   zhi (:,:) = 0._wp
103      pgtv(:,:,:) = 0._wp   ;   ztj (:,:,:) = 0._wp   ;   zhj (:,:) = 0._wp
104      !
105      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
106         !
107         DO jj = 1, jpjm1
108            DO ji = 1, jpim1
109               iku = mbku(ji,jj)   ;   ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
110               ikv = mbkv(ji,jj)   ;   ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
111!!gm BUG ? when applied to before fields, e3w_b should be used....
112               ze3wu = e3w_n(ji+1,jj  ,iku) - e3w_n(ji,jj,iku)
113               ze3wv = e3w_n(ji  ,jj+1,ikv) - e3w_n(ji,jj,ikv)
114               !
115               ! i- direction
116               IF( ze3wu >= 0._wp ) THEN      ! case 1
117                  zmaxu =  ze3wu / e3w_n(ji+1,jj,iku)
118                  ! interpolated values of tracers
119                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
120                  ! gradient of  tracers
121                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
122               ELSE                           ! case 2
123                  zmaxu = -ze3wu / e3w_n(ji,jj,iku)
124                  ! interpolated values of tracers
125                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
126                  ! gradient of tracers
127                  pgtu(ji,jj,jn) = umask(ji,jj,1) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
128               ENDIF
129               !
130               ! j- direction
131               IF( ze3wv >= 0._wp ) THEN      ! case 1
132                  zmaxv =  ze3wv / e3w_n(ji,jj+1,ikv)
133                  ! interpolated values of tracers
134                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
135                  ! gradient of tracers
136                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
137               ELSE                           ! case 2
138                  zmaxv =  -ze3wv / e3w_n(ji,jj,ikv)
139                  ! interpolated values of tracers
140                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
141                  ! gradient of tracers
142                  pgtv(ji,jj,jn) = vmask(ji,jj,1) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
143               ENDIF
144            END DO
145         END DO
146      END DO
147      !
148      CALL lbc_lnk_multi( 'zpshde', pgtu(:,:,:), 'U', -1. , pgtv(:,:,:), 'V', -1. )   ! Lateral boundary cond.
149      !               
150      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
151         pgru(:,:) = 0._wp
152         pgrv(:,:) = 0._wp                ! depth of the partial step level
153         DO jj = 1, jpjm1
154            DO ji = 1, jpim1
155               iku = mbku(ji,jj)
156               ikv = mbkv(ji,jj)
157               ze3wu  = e3w_n(ji+1,jj  ,iku) - e3w_n(ji,jj,iku)
158               ze3wv  = e3w_n(ji  ,jj+1,ikv) - e3w_n(ji,jj,ikv)
159               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept_n(ji  ,jj,iku)     ! i-direction: case 1
160               ELSE                        ;   zhi(ji,jj) = gdept_n(ji+1,jj,iku)     ! -     -      case 2
161               ENDIF
162               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept_n(ji,jj  ,ikv)     ! j-direction: case 1
163               ELSE                        ;   zhj(ji,jj) = gdept_n(ji,jj+1,ikv)     ! -     -      case 2
164               ENDIF
165            END DO
166         END DO
167         !
168         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
169         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
170         !
171         DO jj = 1, jpjm1                 ! Gradient of density at the last level
172            DO ji = 1, jpim1
173               iku = mbku(ji,jj)
174               ikv = mbkv(ji,jj)
175               ze3wu  = e3w_n(ji+1,jj  ,iku) - e3w_n(ji,jj,iku)
176               ze3wv  = e3w_n(ji  ,jj+1,ikv) - e3w_n(ji,jj,ikv)
177               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = umask(ji,jj,1) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
178               ELSE                        ;   pgru(ji,jj) = umask(ji,jj,1) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
179               ENDIF
180               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
181               ELSE                        ;   pgrv(ji,jj) = vmask(ji,jj,1) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
182               ENDIF
183            END DO
184         END DO
185         CALL lbc_lnk_multi( 'zpshde', pgru , 'U', -1. , pgrv , 'V', -1. )   ! Lateral boundary conditions
186         !
187      END IF
188      !
189      IF( ln_timing )   CALL timing_stop( 'zps_hde')
190      !
191   END SUBROUTINE zps_hde
192
193
194   SUBROUTINE zps_hde_isf( kt, kjpt, pta, pgtu, pgtv, pgtui, pgtvi,  &
195      &                          prd, pgru, pgrv, pgrui, pgrvi )
196      !!----------------------------------------------------------------------
197      !!                     ***  ROUTINE zps_hde_isf  ***
198      !!                   
199      !! ** Purpose :   Compute the horizontal derivative of T, S and rho
200      !!      at u- and v-points with a linear interpolation for z-coordinate
201      !!      with partial steps for top (ice shelf) and bottom.
202      !!
203      !! ** Method  :   In z-coord with partial steps, scale factors on last
204      !!      levels are different for each grid point, so that T, S and rd
205      !!      points are not at the same depth as in z-coord. To have horizontal
206      !!      gradients again, we interpolate T and S at the good depth :
207      !!      For the bottom case:
208      !!      Linear interpolation of T, S   
209      !!         Computation of di(tb) and dj(tb) by vertical interpolation:
210      !!          di(t) = t~ - t(i,j,k) or t(i+1,j,k) - t~
211      !!          dj(t) = t~ - t(i,j,k) or t(i,j+1,k) - t~
212      !!         This formulation computes the two cases:
213      !!                 CASE 1                   CASE 2 
214      !!         k-1  ___ ___________   k-1   ___ ___________
215      !!                    Ti  T~                  T~  Ti+1
216      !!                  _____                        _____
217      !!         k        |   |Ti+1     k           Ti |   |
218      !!                  |   |____                ____|   |
219      !!              ___ |   |   |           ___  |   |   |
220      !!                 
221      !!      case 1->   e3w(i+1) >= e3w(i) ( and e3w(j+1) >= e3w(j) ) then
222      !!          t~ = t(i+1,j  ,k) + (e3w(i+1) - e3w(i)) * dk(Ti+1)/e3w(i+1)
223      !!        ( t~ = t(i  ,j+1,k) + (e3w(j+1) - e3w(j)) * dk(Tj+1)/e3w(j+1)  )
224      !!          or
225      !!      case 2->   e3w(i+1) <= e3w(i) ( and e3w(j+1) <= e3w(j) ) then
226      !!          t~ = t(i,j,k) + (e3w(i) - e3w(i+1)) * dk(Ti)/e3w(i )
227      !!        ( t~ = t(i,j,k) + (e3w(j) - e3w(j+1)) * dk(Tj)/e3w(j ) )
228      !!          Idem for di(s) and dj(s)         
229      !!
230      !!      For rho, we call eos which will compute rd~(t~,s~) at the right
231      !!      depth zh from interpolated T and S for the different formulations
232      !!      of the equation of state (eos).
233      !!      Gradient formulation for rho :
234      !!          di(rho) = rd~ - rd(i,j,k)   or   rd(i+1,j,k) - rd~
235      !!
236      !!      For the top case (ice shelf): As for the bottom case but upside down
237      !!
238      !! ** Action  : compute for top and bottom interfaces
239      !!              - pgtu, pgtv, pgtui, pgtvi: horizontal gradient of tracer at u- & v-points
240      !!              - pgru, pgrv, pgrui, pgtvi: horizontal gradient of rho (if present) at u- & v-points
241      !!----------------------------------------------------------------------
242      INTEGER                              , INTENT(in   )           ::  kt           ! ocean time-step index
243      INTEGER                              , INTENT(in   )           ::  kjpt         ! number of tracers
244      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   )           ::  pta          ! 4D tracers fields
245      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtu, pgtv   ! hor. grad. of ptra at u- & v-pts
246      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(  out)           ::  pgtui, pgtvi ! hor. grad. of stra at u- & v-pts (ISF)
247      REAL(wp), DIMENSION(jpi,jpj,jpk     ), INTENT(in   ), OPTIONAL ::  prd          ! 3D density anomaly fields
248      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgru, pgrv   ! hor. grad of prd at u- & v-pts (bottom)
249      REAL(wp), DIMENSION(jpi,jpj         ), INTENT(  out), OPTIONAL ::  pgrui, pgrvi ! hor. grad of prd at u- & v-pts (top)
250      !
251      INTEGER  ::   ji, jj, jn      ! Dummy loop indices
252      INTEGER  ::   iku, ikv, ikum1, ikvm1,ikup1, ikvp1   ! partial step level (ocean bottom level) at u- and v-points
253      REAL(wp) ::  ze3wu, ze3wv, zmaxu, zmaxv             ! temporary scalars
254      REAL(wp), DIMENSION(jpi,jpj)      ::  zri, zrj, zhi, zhj   ! NB: 3rd dim=1 to use eos
255      REAL(wp), DIMENSION(jpi,jpj,kjpt) ::  zti, ztj             !
256      !!----------------------------------------------------------------------
257      !
258      IF( ln_timing )   CALL timing_start( 'zps_hde_isf')
259      !
260      pgtu (:,:,:) = 0._wp   ;   pgtv (:,:,:) =0._wp
261      pgtui(:,:,:) = 0._wp   ;   pgtvi(:,:,:) =0._wp
262      zti  (:,:,:) = 0._wp   ;   ztj  (:,:,:) =0._wp
263      zhi  (:,:  ) = 0._wp   ;   zhj  (:,:  ) =0._wp
264      !
265      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!
266         !
267         DO jj = 1, jpjm1
268            DO ji = 1, jpim1
269
270               iku = mbku(ji,jj); ikum1 = MAX( iku - 1 , 1 )    ! last and before last ocean level at u- & v-points
271               ikv = mbkv(ji,jj); ikvm1 = MAX( ikv - 1 , 1 )    ! if level first is a p-step, ik.m1=1
272               ze3wu = gdept_n(ji+1,jj,iku) - gdept_n(ji,jj,iku)
273               ze3wv = gdept_n(ji,jj+1,ikv) - gdept_n(ji,jj,ikv)
274               !
275               ! i- direction
276               IF( ze3wu >= 0._wp ) THEN      ! case 1
277                  zmaxu =  ze3wu / e3w_n(ji+1,jj,iku)
278                  ! interpolated values of tracers
279                  zti (ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikum1,jn) - pta(ji+1,jj,iku,jn) )
280                  ! gradient of  tracers
281                  pgtu(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
282               ELSE                           ! case 2
283                  zmaxu = -ze3wu / e3w_n(ji,jj,iku)
284                  ! interpolated values of tracers
285                  zti (ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikum1,jn) - pta(ji,jj,iku,jn) )
286                  ! gradient of tracers
287                  pgtu(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
288               ENDIF
289               !
290               ! j- direction
291               IF( ze3wv >= 0._wp ) THEN      ! case 1
292                  zmaxv =  ze3wv / e3w_n(ji,jj+1,ikv)
293                  ! interpolated values of tracers
294                  ztj (ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvm1,jn) - pta(ji,jj+1,ikv,jn) )
295                  ! gradient of tracers
296                  pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
297               ELSE                           ! case 2
298                  zmaxv =  -ze3wv / e3w_n(ji,jj,ikv)
299                  ! interpolated values of tracers
300                  ztj (ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvm1,jn) - pta(ji,jj,ikv,jn) )
301                  ! gradient of tracers
302                  pgtv(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
303               ENDIF
304
305            END DO
306         END DO
307      END DO
308      !
309      CALL lbc_lnk_multi( 'zpshde', pgtu(:,:,:), 'U', -1. , pgtv(:,:,:), 'V', -1. )   ! Lateral boundary cond.
310
311      ! horizontal derivative of density anomalies (rd)
312      IF( PRESENT( prd ) ) THEN         ! depth of the partial step level
313         pgru(:,:)=0.0_wp   ; pgrv(:,:)=0.0_wp ; 
314         !
315         DO jj = 1, jpjm1
316            DO ji = 1, jpim1
317
318               iku = mbku(ji,jj)
319               ikv = mbkv(ji,jj)
320               ze3wu = gdept_n(ji+1,jj,iku) - gdept_n(ji,jj,iku)
321               ze3wv = gdept_n(ji,jj+1,ikv) - gdept_n(ji,jj,ikv)
322               !
323               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept_n(ji  ,jj,iku)    ! i-direction: case 1
324               ELSE                        ;   zhi(ji,jj) = gdept_n(ji+1,jj,iku)    ! -     -      case 2
325               ENDIF
326               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept_n(ji,jj  ,ikv)    ! j-direction: case 1
327               ELSE                        ;   zhj(ji,jj) = gdept_n(ji,jj+1,ikv)    ! -     -      case 2
328               ENDIF
329
330            END DO
331         END DO
332
333         ! Compute interpolated rd from zti, ztj for the 2 cases at the depth of the partial
334         ! step and store it in  zri, zrj for each  case
335         CALL eos( zti, zhi, zri )
336         CALL eos( ztj, zhj, zrj )
337
338         DO jj = 1, jpjm1                 ! Gradient of density at the last level
339            DO ji = 1, jpim1
340               iku = mbku(ji,jj)
341               ikv = mbkv(ji,jj)
342               ze3wu = gdept_n(ji+1,jj,iku) - gdept_n(ji,jj,iku)
343               ze3wv = gdept_n(ji,jj+1,ikv) - gdept_n(ji,jj,ikv)
344
345               IF( ze3wu >= 0._wp ) THEN   ;   pgru(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj    ) - prd(ji,jj,iku) )   ! i: 1
346               ELSE                        ;   pgru(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj,iku) - zri(ji,jj    ) )   ! i: 2
347               ENDIF
348               IF( ze3wv >= 0._wp ) THEN   ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( zrj(ji,jj      ) - prd(ji,jj,ikv) )   ! j: 1
349               ELSE                        ;   pgrv(ji,jj) = ssvmask(ji,jj) * ( prd(ji,jj+1,ikv) - zrj(ji,jj    ) )   ! j: 2
350               ENDIF
351
352            END DO
353         END DO
354
355         CALL lbc_lnk_multi( 'zpshde', pgru , 'U', -1. , pgrv , 'V', -1. )   ! Lateral boundary conditions
356         !
357      END IF
358      !
359      !     !==  (ISH)  compute grui and gruvi  ==!
360      !
361      DO jn = 1, kjpt      !==   Interpolation of tracers at the last ocean level   ==!            !
362         DO jj = 1, jpjm1
363            DO ji = 1, jpim1
364               iku = miku(ji,jj); ikup1 = miku(ji,jj) + 1
365               ikv = mikv(ji,jj); ikvp1 = mikv(ji,jj) + 1
366               !
367               ! (ISF) case partial step top and bottom in adjacent cell in vertical
368               ! cannot used e3w because if 2 cell water column, we have ps at top and bottom
369               ! in this case e3w(i,j) - e3w(i,j+1) is not the distance between Tj~ and Tj
370               ! the only common depth between cells (i,j) and (i,j+1) is gdepw_0
371               ze3wu  =  gdept_n(ji,jj,iku) - gdept_n(ji+1,jj,iku)
372               ze3wv  =  gdept_n(ji,jj,ikv) - gdept_n(ji,jj+1,ikv) 
373
374               ! i- direction
375               IF( ze3wu >= 0._wp ) THEN      ! case 1
376                  zmaxu = ze3wu / e3w_n(ji+1,jj,ikup1)
377                  ! interpolated values of tracers
378                  zti(ji,jj,jn) = pta(ji+1,jj,iku,jn) + zmaxu * ( pta(ji+1,jj,ikup1,jn) - pta(ji+1,jj,iku,jn) )
379                  ! gradient of tracers
380                  pgtui(ji,jj,jn) = ssumask(ji,jj) * ( zti(ji,jj,jn) - pta(ji,jj,iku,jn) )
381               ELSE                           ! case 2
382                  zmaxu = - ze3wu / e3w_n(ji,jj,ikup1)
383                  ! interpolated values of tracers
384                  zti(ji,jj,jn) = pta(ji,jj,iku,jn) + zmaxu * ( pta(ji,jj,ikup1,jn) - pta(ji,jj,iku,jn) )
385                  ! gradient of  tracers
386                  pgtui(ji,jj,jn) = ssumask(ji,jj) * ( pta(ji+1,jj,iku,jn) - zti(ji,jj,jn) )
387               ENDIF
388               !
389               ! j- direction
390               IF( ze3wv >= 0._wp ) THEN      ! case 1
391                  zmaxv =  ze3wv / e3w_n(ji,jj+1,ikvp1)
392                  ! interpolated values of tracers
393                  ztj(ji,jj,jn) = pta(ji,jj+1,ikv,jn) + zmaxv * ( pta(ji,jj+1,ikvp1,jn) - pta(ji,jj+1,ikv,jn) )
394                  ! gradient of tracers
395                  pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( ztj(ji,jj,jn) - pta(ji,jj,ikv,jn) )
396               ELSE                           ! case 2
397                  zmaxv =  - ze3wv / e3w_n(ji,jj,ikvp1)
398                  ! interpolated values of tracers
399                  ztj(ji,jj,jn) = pta(ji,jj,ikv,jn) + zmaxv * ( pta(ji,jj,ikvp1,jn) - pta(ji,jj,ikv,jn) )
400                  ! gradient of tracers
401                  pgtvi(ji,jj,jn) = ssvmask(ji,jj) * ( pta(ji,jj+1,ikv,jn) - ztj(ji,jj,jn) )
402               ENDIF
403
404            END DO
405         END DO
406         !
407      END DO
408      CALL lbc_lnk_multi( 'zpshde', pgtui(:,:,:), 'U', -1. , pgtvi(:,:,:), 'V', -1. )   ! Lateral boundary cond.
409
410      IF( PRESENT( prd ) ) THEN    !==  horizontal derivative of density anomalies (rd)  ==!    (optional part)
411         !
412         pgrui(:,:)  =0.0_wp; pgrvi(:,:)  =0.0_wp;
413         DO jj = 1, jpjm1
414            DO ji = 1, jpim1
415
416               iku = miku(ji,jj)
417               ikv = mikv(ji,jj)
418               ze3wu  =  gdept_n(ji,jj,iku) - gdept_n(ji+1,jj,iku)
419               ze3wv  =  gdept_n(ji,jj,ikv) - gdept_n(ji,jj+1,ikv) 
420               !
421               IF( ze3wu >= 0._wp ) THEN   ;   zhi(ji,jj) = gdept_n(ji  ,jj,iku)    ! i-direction: case 1
422               ELSE                        ;   zhi(ji,jj) = gdept_n(ji+1,jj,iku)    ! -     -      case 2
423               ENDIF
424
425               IF( ze3wv >= 0._wp ) THEN   ;   zhj(ji,jj) = gdept_n(ji,jj  ,ikv)    ! j-direction: case 1
426               ELSE                        ;   zhj(ji,jj) = gdept_n(ji,jj+1,ikv)    ! -     -      case 2
427               ENDIF
428
429            END DO
430         END DO
431         !
432         CALL eos( zti, zhi, zri )        ! interpolated density from zti, ztj
433         CALL eos( ztj, zhj, zrj )        ! at the partial step depth output in  zri, zrj
434         !
435         DO jj = 1, jpjm1                 ! Gradient of density at the last level
436            DO ji = 1, jpim1
437               iku = miku(ji,jj) 
438               ikv = mikv(ji,jj) 
439               ze3wu  =  gdept_n(ji,jj,iku) - gdept_n(ji+1,jj,iku)
440               ze3wv  =  gdept_n(ji,jj,ikv) - gdept_n(ji,jj+1,ikv) 
441
442               IF( ze3wu >= 0._wp ) THEN ; pgrui(ji,jj) = ssumask(ji,jj) * ( zri(ji  ,jj      ) - prd(ji,jj,iku) ) ! i: 1
443               ELSE                      ; pgrui(ji,jj) = ssumask(ji,jj) * ( prd(ji+1,jj  ,iku) - zri(ji,jj    ) ) ! i: 2
444               ENDIF
445               IF( ze3wv >= 0._wp ) THEN ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( zrj(ji  ,jj      ) - prd(ji,jj,ikv) ) ! j: 1
446               ELSE                      ; pgrvi(ji,jj) = ssvmask(ji,jj) * ( prd(ji  ,jj+1,ikv) - zrj(ji,jj    ) ) ! j: 2
447               ENDIF
448
449            END DO
450         END DO
451         CALL lbc_lnk_multi( 'zpshde', pgrui, 'U', -1. , pgrvi, 'V', -1. )   ! Lateral boundary conditions
452         !
453      END IF 
454      !
455      IF( ln_timing )   CALL timing_stop( 'zps_hde_isf')
456      !
457   END SUBROUTINE zps_hde_isf
458
459   !!======================================================================
460END MODULE zpshde
Note: See TracBrowser for help on using the repository browser.