New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
p5zmeso.F90 in NEMO/branches/UKMO/dev_r9888_GO6_mixing/src/TOP/PISCES/P4Z – NEMO

source: NEMO/branches/UKMO/dev_r9888_GO6_mixing/src/TOP/PISCES/P4Z/p5zmeso.F90 @ 9900

Last change on this file since 9900 was 9900, checked in by davestorkey, 6 years ago

UKMO dev_r9888_GO6_mixing branch: clear SVN keywords.

  • Property svn:executable set to *
File size: 25.7 KB
Line 
1MODULE p5zmeso
2   !!======================================================================
3   !!                         ***  MODULE p5zmeso  ***
4   !! TOP :   PISCES Compute the sources/sinks for mesozooplankton
5   !!======================================================================
6   !! History :   1.0  !  2002     (O. Aumont) Original code
7   !!             2.0  !  2007-12  (C. Ethe, G. Madec)  F90
8   !!             3.4  !  2011-06  (O. Aumont, C. Ethe) Quota model for iron
9   !!             3.6  !  2015-05  (O. Aumont) PISCES quota
10   !!----------------------------------------------------------------------
11   !!   p5z_meso       :   Compute the sources/sinks for mesozooplankton
12   !!   p5z_meso_init  :   Initialization of the parameters for mesozooplankton
13   !!----------------------------------------------------------------------
14   USE oce_trc         !  shared variables between ocean and passive tracers
15   USE trc             !  passive tracers common variables
16   USE sms_pisces      !  PISCES Source Minus Sink variables
17   USE prtctl_trc      !  print control for debugging
18   USE iom             !  I/O manager
19
20   IMPLICIT NONE
21   PRIVATE
22
23   PUBLIC   p5z_meso              ! called in p5zbio.F90
24   PUBLIC   p5z_meso_init         ! called in trcsms_pisces.F90
25
26   !! * Shared module variables
27   REAL(wp), PUBLIC ::  part2        !: part of calcite not dissolved in mesozoo guts
28   REAL(wp), PUBLIC ::  xpref2c      !: mesozoo preference for POC
29   REAL(wp), PUBLIC ::  xpref2p      !: mesozoo preference for nanophyto
30   REAL(wp), PUBLIC ::  xpref2z      !: mesozoo preference for zooplankton
31   REAL(wp), PUBLIC ::  xpref2d      !: mesozoo preference for Diatoms
32   REAL(wp), PUBLIC ::  xpref2m      !: mesozoo preference for mesozoo
33   REAL(wp), PUBLIC ::  xthresh2zoo  !: zoo feeding threshold for mesozooplankton
34   REAL(wp), PUBLIC ::  xthresh2dia  !: diatoms feeding threshold for mesozooplankton
35   REAL(wp), PUBLIC ::  xthresh2phy  !: nanophyto feeding threshold for mesozooplankton
36   REAL(wp), PUBLIC ::  xthresh2poc  !: poc feeding threshold for mesozooplankton
37   REAL(wp), PUBLIC ::  xthresh2mes  !: mesozoo feeding threshold for mesozooplankton
38   REAL(wp), PUBLIC ::  xthresh2     !: feeding threshold for mesozooplankton
39   REAL(wp), PUBLIC ::  resrat2      !: exsudation rate of mesozooplankton
40   REAL(wp), PUBLIC ::  mzrat2       !: microzooplankton mortality rate
41   REAL(wp), PUBLIC ::  grazrat2     !: maximal mesozoo grazing rate
42   REAL(wp), PUBLIC ::  xkgraz2      !: non assimilated fraction of P by mesozoo
43   REAL(wp), PUBLIC ::  unass2c      !: Efficicency of mesozoo growth
44   REAL(wp), PUBLIC ::  unass2n      !: Efficicency of mesozoo growth
45   REAL(wp), PUBLIC ::  unass2p      !: Efficicency of mesozoo growth
46   REAL(wp), PUBLIC ::  epsher2      !: half sturation constant for grazing 2
47   REAL(wp), PUBLIC ::  ssigma2      !: Fraction excreted as semi-labile DOM
48   REAL(wp), PUBLIC ::  srespir2     !: Active respiration
49   REAL(wp), PUBLIC ::  grazflux     !: mesozoo flux feeding rate
50   LOGICAL,  PUBLIC ::  bmetexc2     !: Use of excess carbon for respiration
51
52   !!----------------------------------------------------------------------
53   !! NEMO/TOP 3.3 , NEMO Consortium (2018)
54   !! $Id$
55   !! Software governed by the CeCILL licence (./LICENSE)
56   !!----------------------------------------------------------------------
57
58CONTAINS
59
60   SUBROUTINE p5z_meso( kt, knt )
61      !!---------------------------------------------------------------------
62      !!                     ***  ROUTINE p5z_meso  ***
63      !!
64      !! ** Purpose :   Compute the sources/sinks for mesozooplankton
65      !!
66      !! ** Method  : - ???
67      !!---------------------------------------------------------------------
68      INTEGER, INTENT(in) ::   kt, knt ! ocean time step
69      INTEGER  :: ji, jj, jk
70      REAL(wp) :: zcompadi, zcompaph, zcompapoc, zcompaz, zcompam, zcompames
71      REAL(wp) :: zgraze2, zdenom, zfact, zfood, zfoodlim, zproport
72      REAL(wp) :: zmortzgoc, zfracc, zfracn, zfracp, zfracfe, zratio, zratio2
73      REAL(wp) :: zepsherf, zepshert, zepsherv, zrespirc, zrespirn, zrespirp, zbasresb, zbasresi
74      REAL(wp) :: zgraztotc, zgraztotn, zgraztotp, zgraztotf, zbasresn, zbasresp, zbasresf
75      REAL(wp) :: zgradoc, zgradon, zgradop, zgratmp, zgradoct, zgradont, zgrareft, zgradopt
76      REAL(wp) :: zgrapoc, zgrapon, zgrapop, zgrapof, zprcaca, zmortz
77      REAL(wp) :: zexcess, zgrarem, zgraren, zgrarep, zgraref
78      REAL(wp) :: zbeta, zrespz, ztortz, zgrasratp, zgrasratn, zgrasratf
79      REAL(wp) :: ztmp1, ztmp2, ztmp3, ztmp4, ztmp5, ztmptot
80      REAL(wp) :: zgrazdc, zgrazz, zgrazm, zgrazpof, zgrazcal, zfracal
81      REAL(wp) :: zgraznc, zgrazpoc, zgrazpon, zgrazpop, zgraznf, zgrazdf
82      REAL(wp) :: zgraznp, zgraznn, zgrazdn, zgrazdp
83      REAL(wp) :: zgrazfffp, zgrazfffg, zgrazffep, zgrazffeg
84      REAL(wp) :: zgrazffnp, zgrazffng, zgrazffpp, zgrazffpg
85      CHARACTER (len=25) :: charout
86      REAL(wp) :: zrfact2, zmetexcess
87      REAL(wp), DIMENSION(jpi,jpj,jpk) :: zgrazing
88      REAL(wp), ALLOCATABLE, DIMENSION(:,:,:) :: zw3d
89
90      !!---------------------------------------------------------------------
91      !
92      IF( ln_timing )   CALL timing_start('p5z_meso')
93      !
94      zgrazing(:,:,:) = 0._wp
95
96      zmetexcess = 0.0
97      IF ( bmetexc2 ) zmetexcess = 1.0
98
99      DO jk = 1, jpkm1
100         DO jj = 1, jpj
101            DO ji = 1, jpi
102               zcompam   = MAX( ( trb(ji,jj,jk,jpmes) - 1.e-9 ), 0.e0 )
103               zfact     = xstep * tgfunc2(ji,jj,jk) * zcompam
104
105               !   Michaelis-Menten mortality rates of mesozooplankton
106               !   ---------------------------------------------------
107               zrespz   = resrat2 * zfact * ( trb(ji,jj,jk,jpmes) / ( xkmort + trb(ji,jj,jk,jpmes) )  &
108               &          + 3. * nitrfac(ji,jj,jk) )
109
110               !   Zooplankton mortality. A square function has been selected with
111               !   no real reason except that it seems to be more stable and may mimic predation
112               !   ---------------------------------------------------------------
113               ztortz   = mzrat2 * 1.e6 * zfact * trb(ji,jj,jk,jpmes)
114
115               !   Computation of the abundance of the preys
116               !   A threshold can be specified in the namelist
117               !   --------------------------------------------
118               zcompadi  = MAX( ( trb(ji,jj,jk,jpdia) - xthresh2dia ), 0.e0 )
119               zcompaz   = MAX( ( trb(ji,jj,jk,jpzoo) - xthresh2zoo ), 0.e0 )
120               zcompaph  = MAX( ( trb(ji,jj,jk,jpphy) - xthresh2phy ), 0.e0 )
121               zcompapoc = MAX( ( trb(ji,jj,jk,jppoc) - xthresh2poc ), 0.e0 )
122               zcompames = MAX( ( trb(ji,jj,jk,jpmes) - xthresh2mes ), 0.e0 )
123
124               !   Mesozooplankton grazing
125               !   ------------------------
126               zfood     = xpref2d * zcompadi + xpref2z * zcompaz + xpref2p * zcompaph + xpref2c * zcompapoc   &
127               &           + xpref2m * zcompames 
128               zfoodlim  = MAX( 0., zfood - MIN( 0.5 * zfood, xthresh2 ) )
129               zdenom    = zfoodlim / ( xkgraz2 + zfoodlim )
130               zgraze2   = grazrat2 * xstep * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpmes) 
131
132               !   An active switching parameterization is used here.
133               !   We don't use the KTW parameterization proposed by
134               !   Vallina et al. because it tends to produce to steady biomass
135               !   composition and the variance of Chl is too low as it grazes
136               !   too strongly on winning organisms. Thus, instead of a square
137               !   a 1.5 power value is used which decreases the pressure on the
138               !   most abundant species
139               !   ------------------------------------------------------------ 
140               ztmp1 = xpref2p * zcompaph**1.5
141               ztmp2 = xpref2m * zcompames**1.5
142               ztmp3 = xpref2c * zcompapoc**1.5
143               ztmp4 = xpref2d * zcompadi**1.5
144               ztmp5 = xpref2z * zcompaz**1.5
145               ztmptot = ztmp1 + ztmp2 + ztmp3 + ztmp4 + ztmp5 + rtrn
146               ztmp1 = ztmp1 / ztmptot
147               ztmp2 = ztmp2 / ztmptot
148               ztmp3 = ztmp3 / ztmptot
149               ztmp4 = ztmp4 / ztmptot
150               ztmp5 = ztmp5 / ztmptot
151
152               !   Mesozooplankton regular grazing on the different preys
153               !   ------------------------------------------------------
154               zgrazdc   = zgraze2 * ztmp4 * zdenom
155               zgrazdn   = zgrazdc * trb(ji,jj,jk,jpndi) / ( trb(ji,jj,jk,jpdia) + rtrn)
156               zgrazdp   = zgrazdc * trb(ji,jj,jk,jppdi) / ( trb(ji,jj,jk,jpdia) + rtrn)
157               zgrazdf   = zgrazdc * trb(ji,jj,jk,jpdfe) / ( trb(ji,jj,jk,jpdia) + rtrn)
158               zgrazz    = zgraze2 * ztmp5 * zdenom
159               zgrazm    = zgraze2 * ztmp2 * zdenom
160               zgraznc   = zgraze2 * ztmp1 * zdenom
161               zgraznn   = zgraznc * trb(ji,jj,jk,jpnph) / ( trb(ji,jj,jk,jpphy) + rtrn)
162               zgraznp   = zgraznc * trb(ji,jj,jk,jppph) / ( trb(ji,jj,jk,jpphy) + rtrn)
163               zgraznf   = zgraznc * trb(ji,jj,jk,jpnfe) / ( trb(ji,jj,jk,jpphy) + rtrn)
164               zgrazpoc  = zgraze2 * ztmp3 * zdenom
165               zgrazpon  = zgrazpoc * trb(ji,jj,jk,jppon) / ( trb(ji,jj,jk,jppoc) + rtrn)
166               zgrazpop  = zgrazpoc * trb(ji,jj,jk,jppop) / ( trb(ji,jj,jk,jppoc) + rtrn)
167               zgrazpof  = zgrazpoc * trb(ji,jj,jk,jpsfe) / ( trb(ji,jj,jk,jppoc) + rtrn)
168
169               !   Mesozooplankton flux feeding on GOC
170               !   ----------------------------------
171               zgrazffeg = grazflux  * xstep * wsbio4(ji,jj,jk)      &
172               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes)
173               zgrazfffg = zgrazffeg * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
174               zgrazffng = zgrazffeg * trb(ji,jj,jk,jpgon) / (trb(ji,jj,jk,jpgoc) + rtrn)
175               zgrazffpg = zgrazffeg * trb(ji,jj,jk,jpgop) / (trb(ji,jj,jk,jpgoc) + rtrn)
176               zgrazffep = grazflux  * xstep *  wsbio3(ji,jj,jk)     &
177               &           * tgfunc2(ji,jj,jk) * trb(ji,jj,jk,jppoc) * trb(ji,jj,jk,jpmes)
178               zgrazfffp = zgrazffep * trb(ji,jj,jk,jpsfe) / (trb(ji,jj,jk,jppoc) + rtrn)
179               zgrazffnp = zgrazffep * trb(ji,jj,jk,jppon) / (trb(ji,jj,jk,jppoc) + rtrn)
180               zgrazffpp = zgrazffep * trb(ji,jj,jk,jppop) / (trb(ji,jj,jk,jppoc) + rtrn)
181               !
182               zgraztotc  = zgrazdc + zgrazz + zgraznc + zgrazm + zgrazpoc + zgrazffep + zgrazffeg
183
184               !   Compute the proportion of filter feeders
185               !   ---------------------------------------- 
186               zproport  = (zgrazffep + zgrazffeg)/(rtrn + zgraztotc)
187
188               !   Compute fractionation of aggregates. It is assumed that
189               !   diatoms based aggregates are more prone to fractionation
190               !   since they are more porous (marine snow instead of fecal pellets)
191               !   ----------------------------------------------------------------
192               zratio    = trb(ji,jj,jk,jpgsi) / ( trb(ji,jj,jk,jpgoc) + rtrn )
193               zratio2   = zratio * zratio
194               zfracc    = zproport * grazflux  * xstep * wsbio4(ji,jj,jk)      &
195               &          * trb(ji,jj,jk,jpgoc) * trb(ji,jj,jk,jpmes)          &
196               &          * ( 0.2 + 3.8 * zratio2 / ( 1.**2 + zratio2 ) )
197               zfracfe   = zfracc * trb(ji,jj,jk,jpbfe) / (trb(ji,jj,jk,jpgoc) + rtrn)
198               zfracn    = zfracc * trb(ji,jj,jk,jpgon) / (trb(ji,jj,jk,jpgoc) + rtrn)
199               zfracp    = zfracc * trb(ji,jj,jk,jpgop) / (trb(ji,jj,jk,jpgoc) + rtrn)
200
201               zgrazffep = zproport * zgrazffep   ;   zgrazffeg = zproport * zgrazffeg
202               zgrazfffp = zproport * zgrazfffp   ;   zgrazfffg = zproport * zgrazfffg
203               zgrazffnp = zproport * zgrazffnp   ;   zgrazffng = zproport * zgrazffng
204               zgrazffpp = zproport * zgrazffpp   ;   zgrazffpg = zproport * zgrazffpg
205
206               zgraztotc  = zgrazdc + zgrazz + zgraznc + zgrazm + zgrazpoc + zgrazffep + zgrazffeg
207               zgraztotf  = zgrazdf + zgraznf + ( zgrazz + zgrazm ) * ferat3 + zgrazpof &
208               &            + zgrazfffp + zgrazfffg
209               zgraztotn  = zgrazdn + (zgrazm + zgrazz) * no3rat3 + zgraznn + zgrazpon  &
210               &            + zgrazffnp + zgrazffng
211               zgraztotp  = zgrazdp + (zgrazz + zgrazm) * po4rat3 + zgraznp + zgrazpop  &
212               &            + zgrazffpp + zgrazffpg
213
214
215               ! Total grazing ( grazing by microzoo is already computed in p5zmicro )
216               zgrazing(ji,jj,jk) = zgraztotc
217
218               !   Stoichiometruc ratios of the food ingested by zooplanton
219               !   --------------------------------------------------------
220               zgrasratf  =  (zgraztotf + rtrn) / ( zgraztotc + rtrn )
221               zgrasratn  =  (zgraztotn + rtrn) / ( zgraztotc + rtrn )
222               zgrasratp  =  (zgraztotp + rtrn) / ( zgraztotc + rtrn )
223
224               !   Growth efficiency is made a function of the quality
225               !   and the quantity of the preys
226               !   ---------------------------------------------------
227               zepshert  = MIN( 1., zgrasratn/ no3rat3, zgrasratp/ po4rat3, zgrasratf / ferat3)
228               zbeta = 1./ (epsher2 - 0.2)
229               zepsherf = 0.2 + 1./ (zbeta + 0.04 * 12. * zfood *1E6 )
230               zepsherv  = zepsherf * zepshert
231
232               !   Respiration of mesozooplankton
233               !   Excess carbon in the food is used preferentially
234               !   ----------------  ------------------------------
235               zexcess  = zgraztotc * zepsherf * (1.0 - zepshert) * zmetexcess 
236               zbasresb = MAX(0., zrespz - zexcess)
237               zbasresi = zexcess + MIN(0., zrespz - zexcess)
238               zrespirc = srespir2 * zepsherv * zgraztotc + zbasresb
239
240               !   When excess carbon is used, the other elements in excess
241               !   are also used proportionally to their abundance
242               !   --------------------------------------------------------
243               zexcess  = ( zgrasratn/ no3rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
244               zbasresn = zbasresi * zexcess * zgrasratn
245               zexcess  = ( zgrasratp/ po4rat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
246               zbasresp = zbasresi * zexcess * zgrasratp
247               zexcess  = ( zgrasratf/ ferat3 - zepshert ) / ( 1.0 - zepshert + rtrn)
248               zbasresf = zbasresi * zexcess * zgrasratf
249
250               !   Voiding of the excessive elements as organic matter
251               !   --------------------------------------------------------
252               zgradoct = (1. - unass2c - zepsherv) * zgraztotc - zbasresi
253               zgradont = (1. - unass2n) * zgraztotn - zepsherv * no3rat3 * zgraztotc - zbasresn
254               zgradopt = (1. - unass2p) * zgraztotp - zepsherv * po4rat3 * zgraztotc - zbasresp
255               zgrareft = (1. - unass2c) * zgraztotf - zepsherv * ferat3 * zgraztotc - zbasresf
256               ztmp1   = ( 1. - epsher2 - unass2c ) /( 1. - 0.8 * epsher2 ) * ztortz
257               zgradoc = (zgradoct + ztmp1) * ssigma2
258               zgradon = (zgradont + no3rat3 * ztmp1) * ssigma2
259               zgradop = (zgradopt + po4rat3 * ztmp1) * ssigma2
260               zgratmp = 0.2 * epsher2 /( 1. - 0.8 * epsher2 ) * ztortz
261
262               !  Since only semilabile DOM is represented in PISCES
263               !  part of DOM is in fact labile and is then released
264               !  as dissolved inorganic compounds (ssigma2)
265               !  --------------------------------------------------
266               zgrarem = zgratmp + ( zgradoct + ztmp1 ) * (1.0 - ssigma2)
267               zgraren = no3rat3 * zgratmp + ( zgradont + no3rat3 * ztmp1 ) * (1.0 - ssigma2)
268               zgrarep = po4rat3 * zgratmp + ( zgradopt + po4rat3 * ztmp1 ) * (1.0 - ssigma2)
269               zgraref = zgrareft + ferat3 * ( ztmp1 + zgratmp )
270
271               !   Defecation as a result of non assimilated products
272               !   --------------------------------------------------
273               zgrapoc  = zgraztotc * unass2c + unass2c / ( 1. - 0.8 * epsher2 ) * ztortz
274               zgrapon  = zgraztotn * unass2n + no3rat3 * unass2n / ( 1. - 0.8 * epsher2 ) * ztortz
275               zgrapop  = zgraztotp * unass2p + po4rat3 * unass2p / ( 1. - 0.8 * epsher2 ) * ztortz
276               zgrapof  = zgraztotf * unass2c + ferat3  * unass2c / ( 1. - 0.8 * epsher2 ) * ztortz
277
278               !  Addition of respiration to the release of inorganic nutrients
279               !  -------------------------------------------------------------
280               zgrarem = zgrarem + zbasresi + zrespirc
281               zgraren = zgraren + zbasresn + zrespirc * no3rat3
282               zgrarep = zgrarep + zbasresp + zrespirc * po4rat3
283               zgraref = zgraref + zbasresf + zrespirc * ferat3
284
285               !   Update the arrays TRA which contain the biological sources and
286               !   sinks
287               !   --------------------------------------------------------------
288               tra(ji,jj,jk,jppo4) = tra(ji,jj,jk,jppo4) + zgrarep 
289               tra(ji,jj,jk,jpnh4) = tra(ji,jj,jk,jpnh4) + zgraren
290               tra(ji,jj,jk,jpdoc) = tra(ji,jj,jk,jpdoc) + zgradoc
291               !
292               IF( ln_ligand ) tra(ji,jj,jk,jplgw) = tra(ji,jj,jk,jplgw) + zgradoc * ldocz
293               !
294               tra(ji,jj,jk,jpdon) = tra(ji,jj,jk,jpdon) + zgradon
295               tra(ji,jj,jk,jpdop) = tra(ji,jj,jk,jpdop) + zgradop
296               tra(ji,jj,jk,jpoxy) = tra(ji,jj,jk,jpoxy) - o2ut * zgrarem
297               tra(ji,jj,jk,jpfer) = tra(ji,jj,jk,jpfer) + zgraref
298               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrarem
299               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + rno3 * zgraren
300               tra(ji,jj,jk,jpmes) = tra(ji,jj,jk,jpmes) + zepsherv * zgraztotc - zrespirc   &
301               &                     - ztortz - zgrazm
302               tra(ji,jj,jk,jpdia) = tra(ji,jj,jk,jpdia) - zgrazdc
303               tra(ji,jj,jk,jpndi) = tra(ji,jj,jk,jpndi) - zgrazdn
304               tra(ji,jj,jk,jppdi) = tra(ji,jj,jk,jppdi) - zgrazdp
305               tra(ji,jj,jk,jpdfe) = tra(ji,jj,jk,jpdfe) - zgrazdf
306               tra(ji,jj,jk,jpzoo) = tra(ji,jj,jk,jpzoo) - zgrazz
307               tra(ji,jj,jk,jpphy) = tra(ji,jj,jk,jpphy) - zgraznc
308               tra(ji,jj,jk,jpnph) = tra(ji,jj,jk,jpnph) - zgraznn
309               tra(ji,jj,jk,jppph) = tra(ji,jj,jk,jppph) - zgraznp
310               tra(ji,jj,jk,jpnfe) = tra(ji,jj,jk,jpnfe) - zgraznf
311               tra(ji,jj,jk,jpnch) = tra(ji,jj,jk,jpnch) - zgraznc * trb(ji,jj,jk,jpnch) / ( trb(ji,jj,jk,jpphy) + rtrn )
312               tra(ji,jj,jk,jpdch) = tra(ji,jj,jk,jpdch) - zgrazdc * trb(ji,jj,jk,jpdch) / ( trb(ji,jj,jk,jpdia) + rtrn )
313               tra(ji,jj,jk,jpdsi) = tra(ji,jj,jk,jpdsi) - zgrazdc * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
314               tra(ji,jj,jk,jpgsi) = tra(ji,jj,jk,jpgsi) + zgrazdc * trb(ji,jj,jk,jpdsi) / ( trb(ji,jj,jk,jpdia) + rtrn )
315
316               tra(ji,jj,jk,jppoc) = tra(ji,jj,jk,jppoc) - zgrazpoc - zgrazffep + zfracc
317               prodpoc(ji,jj,jk) = prodpoc(ji,jj,jk) + zfracc
318               conspoc(ji,jj,jk) = conspoc(ji,jj,jk) - zgrazpoc - zgrazffep
319               tra(ji,jj,jk,jppon) = tra(ji,jj,jk,jppon) - zgrazpon - zgrazffnp + zfracn
320               tra(ji,jj,jk,jppop) = tra(ji,jj,jk,jppop) - zgrazpop - zgrazffpp + zfracp
321               tra(ji,jj,jk,jpgoc) = tra(ji,jj,jk,jpgoc) - zgrazffeg + zgrapoc - zfracc
322               prodgoc(ji,jj,jk) = prodgoc(ji,jj,jk) + zgrapoc
323               consgoc(ji,jj,jk) = consgoc(ji,jj,jk) - zgrazffeg - zfracc
324               tra(ji,jj,jk,jpgon) = tra(ji,jj,jk,jpgon) - zgrazffng + zgrapon - zfracn
325               tra(ji,jj,jk,jpgop) = tra(ji,jj,jk,jpgop) - zgrazffpg + zgrapop - zfracp
326               tra(ji,jj,jk,jpsfe) = tra(ji,jj,jk,jpsfe) - zgrazpof - zgrazfffp + zfracfe
327               tra(ji,jj,jk,jpbfe) = tra(ji,jj,jk,jpbfe) - zgrazfffg + zgrapof - zfracfe
328               zfracal = trb(ji,jj,jk,jpcal) / ( trb(ji,jj,jk,jpgoc) + rtrn )
329               zgrazcal = zgrazffeg * (1. - part2) * zfracal
330
331               !  calcite production
332               !  ------------------
333               zprcaca = xfracal(ji,jj,jk) * zgraznc
334               prodcal(ji,jj,jk) = prodcal(ji,jj,jk) + zprcaca  ! prodcal=prodcal(nanophy)+prodcal(microzoo)+prodcal(mesozoo)
335               zprcaca = part2 * zprcaca
336               tra(ji,jj,jk,jpdic) = tra(ji,jj,jk,jpdic) + zgrazcal - zprcaca
337               tra(ji,jj,jk,jptal) = tra(ji,jj,jk,jptal) + 2. * ( zgrazcal - zprcaca )
338               tra(ji,jj,jk,jpcal) = tra(ji,jj,jk,jpcal) - zgrazcal + zprcaca
339            END DO
340         END DO
341      END DO
342      !
343      IF( lk_iomput .AND. knt == nrdttrc ) THEN
344         ALLOCATE( zw3d(jpi,jpj,jpk) )
345         IF( iom_use( "GRAZ2" ) ) THEN
346            zw3d(:,:,:) = zgrazing(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)  !   Total grazing of phyto by zooplankton
347            CALL iom_put( "GRAZ2", zw3d )
348         ENDIF
349         IF( iom_use( "PCAL" ) ) THEN
350            zw3d(:,:,:) = prodcal(:,:,:) * 1.e+3 * rfact2r * tmask(:,:,:)   !  Calcite production
351            CALL iom_put( "PCAL", zw3d )
352         ENDIF
353         DEALLOCATE( zw3d )
354      ENDIF
355      !
356      IF(ln_ctl)   THEN  ! print mean trends (used for debugging)
357        WRITE(charout, FMT="('meso')")
358        CALL prt_ctl_trc_info(charout)
359        CALL prt_ctl_trc(tab4d=tra, mask=tmask, clinfo=ctrcnm)
360      ENDIF
361      !
362      IF( ln_timing )   CALL timing_stop('p5z_meso')
363      !
364   END SUBROUTINE p5z_meso
365
366
367   SUBROUTINE p5z_meso_init
368      !!----------------------------------------------------------------------
369      !!                  ***  ROUTINE p5z_meso_init  ***
370      !!
371      !! ** Purpose :   Initialization of mesozooplankton parameters
372      !!
373      !! ** Method  :   Read the nampismes namelist and check the parameters
374      !!      called at the first timestep (nittrc000)
375      !!
376      !! ** input   :   Namelist nampismes
377      !!
378      !!----------------------------------------------------------------------
379      INTEGER :: ios                 ! Local integer output status for namelist read
380      !!
381      NAMELIST/namp5zmes/part2, bmetexc2, grazrat2, resrat2, mzrat2, xpref2c, xpref2p, xpref2z, &
382         &                xpref2m, xpref2d, xthresh2dia, xthresh2phy, xthresh2zoo, xthresh2poc, &
383         &                xthresh2mes, xthresh2, xkgraz2, epsher2, ssigma2, unass2c, &
384         &                unass2n, unass2p, srespir2, grazflux
385      !!----------------------------------------------------------------------
386      !
387      REWIND( numnatp_ref )              ! Namelist nampismes in reference namelist : Pisces mesozooplankton
388      READ  ( numnatp_ref, namp5zmes, IOSTAT = ios, ERR = 901)
389901   IF( ios /= 0 ) CALL ctl_nam ( ios , 'nampismes in reference namelist', lwp )
390      !
391      REWIND( numnatp_cfg )              ! Namelist nampismes in configuration namelist : Pisces mesozooplankton
392      READ  ( numnatp_cfg, namp5zmes, IOSTAT = ios, ERR = 902 )
393902   IF( ios >  0 ) CALL ctl_nam ( ios , 'nampismes in configuration namelist', lwp )
394      IF(lwm) WRITE ( numonp, namp5zmes )
395      !
396      IF(lwp) THEN                         ! control print
397         WRITE(numout,*) ' ' 
398         WRITE(numout,*) ' Namelist parameters for mesozooplankton, namp5zmes'
399         WRITE(numout,*) ' ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~'
400         WRITE(numout,*) '    part of calcite not dissolved in mesozoo guts  part2       = ', part2
401         WRITE(numout,*) '    mesozoo preference for nano.                   xpref2p     = ', xpref2p
402         WRITE(numout,*) '    mesozoo preference for diatoms                 xpref2d     = ', xpref2d
403         WRITE(numout,*) '    mesozoo preference for zoo                     xpref2z     = ', xpref2z
404         WRITE(numout,*) '    mesozoo preference for mesozoo                 xpref2m     = ', xpref2m
405         WRITE(numout,*) '    mesozoo preference for poc                     xpref2c     = ', xpref2c
406         WRITE(numout,*) '    microzoo feeding threshold  for mesozoo        xthresh2zoo = ', xthresh2zoo
407         WRITE(numout,*) '    diatoms feeding threshold  for mesozoo         xthresh2dia = ', xthresh2dia
408         WRITE(numout,*) '    nanophyto feeding threshold for mesozoo        xthresh2phy = ', xthresh2phy
409         WRITE(numout,*) '    poc feeding threshold for mesozoo              xthresh2poc = ', xthresh2poc
410         WRITE(numout,*) '    mesozoo feeding threshold for mesozoo          xthresh2mes = ', xthresh2mes
411         WRITE(numout,*) '    feeding threshold for mesozooplankton          xthresh2    = ', xthresh2
412         WRITE(numout,*) '    exsudation rate of mesozooplankton             resrat2     = ', resrat2
413         WRITE(numout,*) '    mesozooplankton mortality rate                 mzrat2      = ', mzrat2
414         WRITE(numout,*) '    maximal mesozoo grazing rate                   grazrat2    = ', grazrat2
415         WRITE(numout,*) '    mesozoo flux feeding rate                      grazflux    = ', grazflux
416         WRITE(numout,*) '    C egested fraction of food by mesozoo          unass2c     = ', unass2c
417         WRITE(numout,*) '    C egested fraction of food by mesozoo          unass2n     = ', unass2n
418         WRITE(numout,*) '    C egested fraction of food by mesozoo          unass2p     = ', unass2p
419         WRITE(numout,*) '    Efficicency of Mesozoo growth                  epsher2     = ', epsher2
420         WRITE(numout,*) '    Fraction excreted as semi-labile DOM           ssigma2     = ', ssigma2
421         WRITE(numout,*) '    Active respiration                             srespir2    = ', srespir2
422         WRITE(numout,*) '    half sturation constant for grazing 2          xkgraz2     = ', xkgraz2
423         WRITE(numout,*) '    Use excess carbon for respiration              bmetexc2    = ', bmetexc2
424      ENDIF
425      !
426   END SUBROUTINE p5z_meso_init
427
428   !!======================================================================
429END MODULE p5zmeso
Note: See TracBrowser for help on using the repository browser.