New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
traldf_triad.F90 in NEMO/branches/UKMO/dev_r9950_GO8_package/src/OCE/TRA – NEMO

source: NEMO/branches/UKMO/dev_r9950_GO8_package/src/OCE/TRA/traldf_triad.F90 @ 10322

Last change on this file since 10322 was 10322, checked in by davestorkey, 5 years ago

UKMO/dev_r9950_GO8_package: Update to be relative to rev 10321 of NEMO4_beta_mirror branch.

File size: 23.5 KB
Line 
1MODULE traldf_triad
2   !!======================================================================
3   !!                   ***  MODULE  traldf_triad  ***
4   !! Ocean  tracers:  horizontal component of the lateral tracer mixing trend
5   !!======================================================================
6   !! History :  3.3  ! 2010-10  (G. Nurser, C. Harris, G. Madec)  Griffies operator (original code)
7   !!            3.7  ! 2013-12  (F. Lemarie, G. Madec)  triad operator (Griffies) + Method of Stabilizing Correction
8   !!----------------------------------------------------------------------
9
10   !!----------------------------------------------------------------------
11   !!   tra_ldf_triad : update the tracer trend with the iso-neutral laplacian triad-operator
12   !!----------------------------------------------------------------------
13   USE oce            ! ocean dynamics and active tracers
14   USE dom_oce        ! ocean space and time domain
15   USE phycst         ! physical constants
16   USE trc_oce        ! share passive tracers/Ocean variables
17   USE zdf_oce        ! ocean vertical physics
18   USE ldftra         ! lateral physics: eddy diffusivity
19   USE ldfslp         ! lateral physics: iso-neutral slopes
20   USE traldf_iso     ! lateral diffusion (Madec operator)         (tra_ldf_iso routine)
21   USE diaptr         ! poleward transport diagnostics
22   USE diaar5         ! AR5 diagnostics
23   USE zpshde         ! partial step: hor. derivative     (zps_hde routine)
24   !
25   USE in_out_manager ! I/O manager
26   USE iom            ! I/O library
27   USE lbclnk         ! ocean lateral boundary conditions (or mpp link)
28   USE lib_mpp        ! MPP library
29
30   IMPLICIT NONE
31   PRIVATE
32
33   PUBLIC   tra_ldf_triad   ! routine called by traldf.F90
34
35   REAL(wp), DIMENSION(:,:,:), ALLOCATABLE, SAVE ::   zdkt3d   !: vertical tracer gradient at 2 levels
36
37   LOGICAL  ::   l_ptr   ! flag to compute poleward transport
38   LOGICAL  ::   l_hst   ! flag to compute heat transport
39
40
41   !! * Substitutions
42#  include "vectopt_loop_substitute.h90"
43   !!----------------------------------------------------------------------
44   !! NEMO/OCE 4.0 , NEMO Consortium (2018)
45   !! $Id$
46   !! Software governed by the CeCILL license (see ./LICENSE)
47   !!----------------------------------------------------------------------
48CONTAINS
49
50  SUBROUTINE tra_ldf_triad( kt, kit000, cdtype, pahu, pahv, pgu , pgv ,   &
51      &                                                     pgui, pgvi,   &
52      &                                         ptb , ptbb, pta , kjpt, kpass )
53      !!----------------------------------------------------------------------
54      !!                  ***  ROUTINE tra_ldf_triad  ***
55      !!
56      !! ** Purpose :   Compute the before horizontal tracer (t & s) diffusive
57      !!      trend for a laplacian tensor (ezxcept the dz[ dz[.] ] term) and
58      !!      add it to the general trend of tracer equation.
59      !!
60      !! ** Method  :   The horizontal component of the lateral diffusive trends
61      !!      is provided by a 2nd order operator rotated along neural or geopo-
62      !!      tential surfaces to which an eddy induced advection can be added
63      !!      It is computed using before fields (forward in time) and isopyc-
64      !!      nal or geopotential slopes computed in routine ldfslp.
65      !!
66      !!      see documentation for the desciption
67      !!
68      !! ** Action :   pta   updated with the before rotated diffusion
69      !!               ah_wslp2 ....
70      !!               akz   stabilizing vertical diffusivity coefficient (used in trazdf_imp)
71      !!----------------------------------------------------------------------
72      INTEGER                              , INTENT(in   ) ::   kt         ! ocean time-step index
73      INTEGER                              , INTENT(in   ) ::   kit000     ! first time step index
74      CHARACTER(len=3)                     , INTENT(in   ) ::   cdtype     ! =TRA or TRC (tracer indicator)
75      INTEGER                              , INTENT(in   ) ::   kjpt       ! number of tracers
76      INTEGER                              , INTENT(in   ) ::   kpass      ! =1/2 first or second passage
77      REAL(wp), DIMENSION(jpi,jpj,jpk)     , INTENT(in   ) ::   pahu, pahv ! eddy diffusivity at u- and v-points  [m2/s]
78      REAL(wp), DIMENSION(jpi,jpj    ,kjpt), INTENT(in   ) ::   pgu , pgv  ! tracer gradient at pstep levels
79      REAL(wp), DIMENSION(jpi,jpj,    kjpt), INTENT(in   ) ::   pgui, pgvi ! tracer gradient at top   levels
80      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptb        ! tracer (kpass=1) or laplacian of tracer (kpass=2)
81      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(in   ) ::   ptbb       ! tracer (only used in kpass=2)
82      REAL(wp), DIMENSION(jpi,jpj,jpk,kjpt), INTENT(inout) ::   pta        ! tracer trend
83      !
84      INTEGER  ::  ji, jj, jk, jn   ! dummy loop indices
85      INTEGER  ::  ip,jp,kp         ! dummy loop indices
86      INTEGER  ::  ierr            ! local integer
87      REAL(wp) ::  zmsku, zabe1, zcof1, zcoef3          ! local scalars
88      REAL(wp) ::  zmskv, zabe2, zcof2, zcoef4          !   -      -
89      REAL(wp) ::  zcoef0, ze3w_2, zsign, z2dt, z1_2dt  !   -      -
90      !
91      REAL(wp) ::   zslope_skew, zslope_iso, zslope2, zbu, zbv
92      REAL(wp) ::   ze1ur, ze2vr, ze3wr, zdxt, zdyt, zdzt
93      REAL(wp) ::   zah, zah_slp, zaei_slp
94      REAL(wp), DIMENSION(jpi,jpj    ) ::   z2d                                              ! 2D workspace
95      REAL(wp), DIMENSION(jpi,jpj,jpk) ::   zdit, zdjt, zftu, zftv, ztfw, zpsi_uw, zpsi_vw   ! 3D     -
96      !!----------------------------------------------------------------------
97      !
98      IF( .NOT.ALLOCATED(zdkt3d) )  THEN
99         ALLOCATE( zdkt3d(jpi,jpj,0:1) , STAT=ierr )
100         IF( lk_mpp   )   CALL mpp_sum ( ierr )
101         IF( ierr > 0 )   CALL ctl_stop('STOP', 'tra_ldf_triad: unable to allocate arrays')
102      ENDIF
103     !
104      IF( kpass == 1 .AND. kt == kit000 )  THEN
105         IF(lwp) WRITE(numout,*)
106         IF(lwp) WRITE(numout,*) 'tra_ldf_triad : rotated laplacian diffusion operator on ', cdtype
107         IF(lwp) WRITE(numout,*) '~~~~~~~~~~~~~'
108      ENDIF
109      !   
110      l_hst = .FALSE.
111      l_ptr = .FALSE.
112      IF( cdtype == 'TRA' .AND. ln_diaptr )                                                 l_ptr = .TRUE. 
113      IF( cdtype == 'TRA' .AND. ( iom_use("uadv_heattr") .OR. iom_use("vadv_heattr") .OR. &
114         &                        iom_use("uadv_salttr") .OR. iom_use("vadv_salttr")  ) )   l_hst = .TRUE.
115      !
116      !                                                        ! set time step size (Euler/Leapfrog)
117      IF( neuler == 0 .AND. kt == kit000 ) THEN   ;   z2dt =     rdt      ! at nit000   (Euler)
118      ELSE                                        ;   z2dt = 2.* rdt      !             (Leapfrog)
119      ENDIF
120      z1_2dt = 1._wp / z2dt
121      !
122      IF( kpass == 1 ) THEN   ;   zsign =  1._wp      ! bilaplacian operator require a minus sign (eddy diffusivity >0)
123      ELSE                    ;   zsign = -1._wp
124      ENDIF
125      !   
126      !!----------------------------------------------------------------------
127      !!   0 - calculate  ah_wslp2, akz, and optionally zpsi_uw, zpsi_vw
128      !!----------------------------------------------------------------------
129      !
130      IF( kpass == 1 ) THEN         !==  first pass only  and whatever the tracer is  ==!
131         !
132         akz     (:,:,:) = 0._wp     
133         ah_wslp2(:,:,:) = 0._wp
134         IF( ln_ldfeiv_dia ) THEN
135            zpsi_uw(:,:,:) = 0._wp
136            zpsi_vw(:,:,:) = 0._wp
137         ENDIF
138         !
139         DO ip = 0, 1                            ! i-k triads
140            DO kp = 0, 1
141               DO jk = 1, jpkm1
142                  DO jj = 1, jpjm1
143                     DO ji = 1, fs_jpim1
144                        ze3wr = 1._wp / e3w_n(ji+ip,jj,jk+kp)
145                        zbu   = e1e2u(ji,jj) * e3u_n(ji,jj,jk)
146                        zah   = 0.25_wp * pahu(ji,jj,jk)
147                        zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
148                        ! Subtract s-coordinate slope at t-points to give slope rel to s-surfaces (do this by *adding* gradient of depth)
149                        zslope2 = zslope_skew + ( gdept_n(ji+1,jj,jk) - gdept_n(ji,jj,jk) ) * r1_e1u(ji,jj) * umask(ji,jj,jk+kp)
150                        zslope2 = zslope2 *zslope2
151                        ah_wslp2(ji+ip,jj,jk+kp) = ah_wslp2(ji+ip,jj,jk+kp) + zah * zbu * ze3wr * r1_e1e2t(ji+ip,jj) * zslope2
152                        akz     (ji+ip,jj,jk+kp) = akz     (ji+ip,jj,jk+kp) + zah * r1_e1u(ji,jj)       &
153                           &                                                      * r1_e1u(ji,jj) * umask(ji,jj,jk+kp)
154                           !
155                       IF( ln_ldfeiv_dia )   zpsi_uw(ji,jj,jk+kp) = zpsi_uw(ji,jj,jk+kp)   &
156                           &                                       + 0.25_wp * aeiu(ji,jj,jk) * e2u(ji,jj) * zslope_skew
157                     END DO
158                  END DO
159               END DO
160            END DO
161         END DO
162         !
163         DO jp = 0, 1                            ! j-k triads
164            DO kp = 0, 1
165               DO jk = 1, jpkm1
166                  DO jj = 1, jpjm1
167                     DO ji = 1, fs_jpim1
168                        ze3wr = 1.0_wp / e3w_n(ji,jj+jp,jk+kp)
169                        zbv   = e1e2v(ji,jj) * e3v_n(ji,jj,jk)
170                        zah   = 0.25_wp * pahv(ji,jj,jk)
171                        zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
172                        ! Subtract s-coordinate slope at t-points to give slope rel to s surfaces
173                        !    (do this by *adding* gradient of depth)
174                        zslope2 = zslope_skew + ( gdept_n(ji,jj+1,jk) - gdept_n(ji,jj,jk) ) * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp)
175                        zslope2 = zslope2 * zslope2
176                        ah_wslp2(ji,jj+jp,jk+kp) = ah_wslp2(ji,jj+jp,jk+kp) + zah * zbv * ze3wr * r1_e1e2t(ji,jj+jp) * zslope2
177                        akz     (ji,jj+jp,jk+kp) = akz     (ji,jj+jp,jk+kp) + zah * r1_e2v(ji,jj)     &
178                           &                                                      * r1_e2v(ji,jj) * vmask(ji,jj,jk+kp)
179                        !
180                        IF( ln_ldfeiv_dia )   zpsi_vw(ji,jj,jk+kp) = zpsi_vw(ji,jj,jk+kp)   &
181                           &                                       + 0.25 * aeiv(ji,jj,jk) * e1v(ji,jj) * zslope_skew
182                     END DO
183                  END DO
184               END DO
185            END DO
186         END DO
187         !
188         IF( ln_traldf_msc ) THEN                ! stabilizing vertical diffusivity coefficient
189            !
190            IF( ln_traldf_blp ) THEN                ! bilaplacian operator
191               DO jk = 2, jpkm1
192                  DO jj = 1, jpjm1
193                     DO ji = 1, fs_jpim1
194                        akz(ji,jj,jk) = 16._wp * ah_wslp2(ji,jj,jk)   &
195                           &          * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ( e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk) )  )
196                     END DO
197                  END DO
198               END DO
199            ELSEIF( ln_traldf_lap ) THEN              ! laplacian operator
200               DO jk = 2, jpkm1
201                  DO jj = 1, jpjm1
202                     DO ji = 1, fs_jpim1
203                        ze3w_2 = e3w_n(ji,jj,jk) * e3w_n(ji,jj,jk)
204                        zcoef0 = z2dt * (  akz(ji,jj,jk) + ah_wslp2(ji,jj,jk) / ze3w_2  )
205                        akz(ji,jj,jk) = MAX( zcoef0 - 0.5_wp , 0._wp ) * ze3w_2 * z1_2dt
206                     END DO
207                  END DO
208               END DO
209           ENDIF
210           !
211         ELSE                                    ! 33 flux set to zero with akz=ah_wslp2 ==>> computed in full implicit
212            akz(:,:,:) = ah_wslp2(:,:,:)     
213         ENDIF
214         !
215         IF( ln_ldfeiv_dia .AND. cdtype == 'TRA' )   CALL ldf_eiv_dia( zpsi_uw, zpsi_vw )
216         !
217      ENDIF                                  !==  end 1st pass only  ==!
218      !
219      !                                                           ! ===========
220      DO jn = 1, kjpt                                             ! tracer loop
221         !                                                        ! ===========
222         ! Zero fluxes for each tracer
223!!gm  this should probably be done outside the jn loop
224         ztfw(:,:,:) = 0._wp
225         zftu(:,:,:) = 0._wp
226         zftv(:,:,:) = 0._wp
227         !
228         DO jk = 1, jpkm1        !==  before lateral T & S gradients at T-level jk  ==!
229            DO jj = 1, jpjm1
230               DO ji = 1, fs_jpim1   ! vector opt.
231                  zdit(ji,jj,jk) = ( ptb(ji+1,jj  ,jk,jn) - ptb(ji,jj,jk,jn) ) * umask(ji,jj,jk)
232                  zdjt(ji,jj,jk) = ( ptb(ji  ,jj+1,jk,jn) - ptb(ji,jj,jk,jn) ) * vmask(ji,jj,jk)
233               END DO
234            END DO
235         END DO
236         IF( ln_zps .AND. l_grad_zps ) THEN    ! partial steps: correction at top/bottom ocean level
237            DO jj = 1, jpjm1                       ! bottom level
238               DO ji = 1, fs_jpim1   ! vector opt.
239                  zdit(ji,jj,mbku(ji,jj)) = pgu(ji,jj,jn)
240                  zdjt(ji,jj,mbkv(ji,jj)) = pgv(ji,jj,jn)
241               END DO
242            END DO
243            IF( ln_isfcav ) THEN                   ! top level (ocean cavities only)
244               DO jj = 1, jpjm1
245                  DO ji = 1, fs_jpim1   ! vector opt.
246                     IF( miku(ji,jj)  > 1 )   zdit(ji,jj,miku(ji,jj) ) = pgui(ji,jj,jn) 
247                     IF( mikv(ji,jj)  > 1 )   zdjt(ji,jj,mikv(ji,jj) ) = pgvi(ji,jj,jn) 
248                  END DO
249               END DO
250            ENDIF
251         ENDIF
252         !
253         !!----------------------------------------------------------------------
254         !!   II - horizontal trend  (full)
255         !!----------------------------------------------------------------------
256         !
257         DO jk = 1, jpkm1
258            !                    !==  Vertical tracer gradient at level jk and jk+1
259            zdkt3d(:,:,1) = ( ptb(:,:,jk,jn) - ptb(:,:,jk+1,jn) ) * tmask(:,:,jk+1)
260            !
261            !                    ! surface boundary condition: zdkt3d(jk=0)=zdkt3d(jk=1)
262            IF( jk == 1 ) THEN   ;   zdkt3d(:,:,0) = zdkt3d(:,:,1)
263            ELSE                 ;   zdkt3d(:,:,0) = ( ptb(:,:,jk-1,jn) - ptb(:,:,jk,jn) ) * tmask(:,:,jk)
264            ENDIF
265            !
266            zaei_slp = 0._wp
267            !
268            IF( ln_botmix_triad ) THEN
269               DO ip = 0, 1              !==  Horizontal & vertical fluxes
270                  DO kp = 0, 1
271                     DO jj = 1, jpjm1
272                        DO ji = 1, fs_jpim1
273                           ze1ur = r1_e1u(ji,jj)
274                           zdxt  = zdit(ji,jj,jk) * ze1ur
275                           ze3wr = 1._wp / e3w_n(ji+ip,jj,jk+kp)
276                           zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
277                           zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
278                           zslope_iso  = triadi  (ji+ip,jj,jk,1-ip,kp)
279                           !
280                           zbu = 0.25_wp * e1e2u(ji,jj) * e3u_n(ji,jj,jk)
281                           ! ln_botmix_triad is .T. don't mask zah for bottom half cells    !!gm ?????   ahu is masked....
282                           zah = pahu(ji,jj,jk)
283                           zah_slp  = zah * zslope_iso
284                           IF( ln_ldfeiv )   zaei_slp = aeiu(ji,jj,jk) * zslope_skew
285                           zftu(ji   ,jj,jk   ) = zftu(ji   ,jj,jk   ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
286                           ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - ( zah_slp + zaei_slp) * zdxt                 * zbu * ze3wr
287                        END DO
288                     END DO
289                  END DO
290               END DO
291               !
292               DO jp = 0, 1
293                  DO kp = 0, 1
294                     DO jj = 1, jpjm1
295                        DO ji = 1, fs_jpim1
296                           ze2vr = r1_e2v(ji,jj)
297                           zdyt  = zdjt(ji,jj,jk) * ze2vr
298                           ze3wr = 1._wp / e3w_n(ji,jj+jp,jk+kp)
299                           zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
300                           zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
301                           zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
302                           zbv = 0.25_wp * e1e2v(ji,jj) * e3v_n(ji,jj,jk)
303                           ! ln_botmix_triad is .T. don't mask zah for bottom half cells    !!gm ?????  ahv is masked...
304                           zah = pahv(ji,jj,jk)
305                           zah_slp = zah * zslope_iso
306                           IF( ln_ldfeiv )   zaei_slp = aeiv(ji,jj,jk) * zslope_skew
307                           zftv(ji,jj   ,jk   ) = zftv(ji,jj   ,jk   ) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
308                           ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - ( zah_slp + zaei_slp ) * zdyt                * zbv * ze3wr
309                        END DO
310                     END DO
311                  END DO
312               END DO
313               !
314            ELSE
315               !
316               DO ip = 0, 1               !==  Horizontal & vertical fluxes
317                  DO kp = 0, 1
318                     DO jj = 1, jpjm1
319                        DO ji = 1, fs_jpim1
320                           ze1ur = r1_e1u(ji,jj)
321                           zdxt  = zdit(ji,jj,jk) * ze1ur
322                           ze3wr = 1._wp / e3w_n(ji+ip,jj,jk+kp)
323                           zdzt  = zdkt3d(ji+ip,jj,kp) * ze3wr
324                           zslope_skew = triadi_g(ji+ip,jj,jk,1-ip,kp)
325                           zslope_iso  = triadi(ji+ip,jj,jk,1-ip,kp)
326                           !
327                           zbu = 0.25_wp * e1e2u(ji,jj) * e3u_n(ji,jj,jk)
328                           ! ln_botmix_triad is .F. mask zah for bottom half cells
329                           zah = pahu(ji,jj,jk) * umask(ji,jj,jk+kp)         ! pahu(ji+ip,jj,jk)   ===>>  ????
330                           zah_slp  = zah * zslope_iso
331                           IF( ln_ldfeiv )   zaei_slp = aeiu(ji,jj,jk) * zslope_skew        ! aeit(ji+ip,jj,jk)*zslope_skew
332                           zftu(ji   ,jj,jk   ) = zftu(ji   ,jj,jk   ) - ( zah * zdxt + (zah_slp - zaei_slp) * zdzt ) * zbu * ze1ur
333                           ztfw(ji+ip,jj,jk+kp) = ztfw(ji+ip,jj,jk+kp) - (zah_slp + zaei_slp) * zdxt * zbu * ze3wr
334                        END DO
335                     END DO
336                  END DO
337               END DO
338               !
339               DO jp = 0, 1
340                  DO kp = 0, 1
341                     DO jj = 1, jpjm1
342                        DO ji = 1, fs_jpim1
343                           ze2vr = r1_e2v(ji,jj)
344                           zdyt  = zdjt(ji,jj,jk) * ze2vr
345                           ze3wr = 1._wp / e3w_n(ji,jj+jp,jk+kp)
346                           zdzt  = zdkt3d(ji,jj+jp,kp) * ze3wr
347                           zslope_skew = triadj_g(ji,jj+jp,jk,1-jp,kp)
348                           zslope_iso  = triadj(ji,jj+jp,jk,1-jp,kp)
349                           zbv = 0.25_wp * e1e2v(ji,jj) * e3v_n(ji,jj,jk)
350                           ! ln_botmix_triad is .F. mask zah for bottom half cells
351                           zah = pahv(ji,jj,jk) * vmask(ji,jj,jk+kp)         ! pahv(ji,jj+jp,jk)  ????
352                           zah_slp = zah * zslope_iso
353                           IF( ln_ldfeiv )   zaei_slp = aeiv(ji,jj,jk) * zslope_skew        ! aeit(ji,jj+jp,jk)*zslope_skew
354                           zftv(ji,jj,jk) = zftv(ji,jj,jk) - ( zah * zdyt + (zah_slp - zaei_slp) * zdzt ) * zbv * ze2vr
355                           ztfw(ji,jj+jp,jk+kp) = ztfw(ji,jj+jp,jk+kp) - (zah_slp + zaei_slp) * zdyt * zbv * ze3wr
356                        END DO
357                     END DO
358                  END DO
359               END DO
360            ENDIF
361            !                             !==  horizontal divergence and add to the general trend  ==!
362            DO jj = 2 , jpjm1
363               DO ji = fs_2, fs_jpim1  ! vector opt.
364                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * (  zftu(ji-1,jj,jk) - zftu(ji,jj,jk)       &
365                     &                                           + zftv(ji,jj-1,jk) - zftv(ji,jj,jk)   )   &
366                     &                                        / (  e1e2t(ji,jj) * e3t_n(ji,jj,jk)  )
367               END DO
368            END DO
369            !
370         END DO
371         !
372         !                                !==  add the vertical 33 flux  ==!
373         IF( ln_traldf_lap ) THEN               ! laplacian case: eddy coef = ah_wslp2 - akz
374            DO jk = 2, jpkm1       
375               DO jj = 1, jpjm1
376                  DO ji = fs_2, fs_jpim1
377                     ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk)   &
378                        &                            * ( ah_wslp2(ji,jj,jk) - akz(ji,jj,jk) )             &
379                        &                            * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) )
380                  END DO
381               END DO
382            END DO
383         ELSE                                   ! bilaplacian
384            SELECT CASE( kpass )
385            CASE(  1  )                            ! 1st pass : eddy coef = ah_wslp2
386               DO jk = 2, jpkm1 
387                  DO jj = 1, jpjm1
388                     DO ji = fs_2, fs_jpim1
389                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk)             &
390                           &                            * ah_wslp2(ji,jj,jk) * ( ptb(ji,jj,jk-1,jn) - ptb(ji,jj,jk,jn) )
391                     END DO
392                  END DO
393               END DO
394            CASE(  2  )                            ! 2nd pass : eddy flux = ah_wslp2 and akz applied on ptb  and ptbb gradients, resp.
395               DO jk = 2, jpkm1 
396                  DO jj = 1, jpjm1
397                     DO ji = fs_2, fs_jpim1
398                        ztfw(ji,jj,jk) = ztfw(ji,jj,jk) - e1e2t(ji,jj) / e3w_n(ji,jj,jk) * tmask(ji,jj,jk)                      &
399                           &                            * (  ah_wslp2(ji,jj,jk) * ( ptb (ji,jj,jk-1,jn) - ptb (ji,jj,jk,jn) )   &
400                           &                               + akz     (ji,jj,jk) * ( ptbb(ji,jj,jk-1,jn) - ptbb(ji,jj,jk,jn) )   )
401                     END DO
402                  END DO
403               END DO
404            END SELECT
405         ENDIF
406         !
407         DO jk = 1, jpkm1                 !==  Divergence of vertical fluxes added to pta  ==!
408            DO jj = 2, jpjm1
409               DO ji = fs_2, fs_jpim1  ! vector opt.
410                  pta(ji,jj,jk,jn) = pta(ji,jj,jk,jn) + zsign * (  ztfw(ji,jj,jk+1) - ztfw(ji,jj,jk)  )   &
411                     &                                        / ( e1e2t(ji,jj) * e3t_n(ji,jj,jk) )
412               END DO
413            END DO
414         END DO
415         !
416         IF( ( kpass == 1 .AND. ln_traldf_lap ) .OR.  &     !==  first pass only (  laplacian)  ==!
417             ( kpass == 2 .AND. ln_traldf_blp ) ) THEN      !==  2nd   pass      (bilaplacian)  ==!
418            !
419            !                          ! "Poleward" diffusive heat or salt transports (T-S case only)
420            IF( l_ptr )  CALL dia_ptr_hst( jn, 'ldf', zftv(:,:,:)  )
421            !                          ! Diffusive heat transports
422            IF( l_hst )  CALL dia_ar5_hst( jn, 'ldf', zftu(:,:,:), zftv(:,:,:) )
423            !
424         ENDIF                                                    !== end pass selection  ==!
425         !
426         !                                                        ! ===============
427      END DO                                                      ! end tracer loop
428      !                                                           ! ===============
429   END SUBROUTINE tra_ldf_triad
430
431   !!==============================================================================
432END MODULE traldf_triad
Note: See TracBrowser for help on using the repository browser.