New URL for NEMO forge!   http://forge.nemo-ocean.eu

Since March 2022 along with NEMO 4.2 release, the code development moved to a self-hosted GitLab.
This present forge is now archived and remained online for history.
trcsms_cfc.F90 in NEMO/branches/UKMO/dev_r9950_GO8_package/src/TOP/CFC – NEMO

source: NEMO/branches/UKMO/dev_r9950_GO8_package/src/TOP/CFC/trcsms_cfc.F90 @ 10322

Last change on this file since 10322 was 10322, checked in by davestorkey, 5 years ago

UKMO/dev_r9950_GO8_package: Update to be relative to rev 10321 of NEMO4_beta_mirror branch.

File size: 13.2 KB
Line 
1MODULE trcsms_cfc
2   !!======================================================================
3   !!                      ***  MODULE trcsms_cfc  ***
4   !! TOP : CFC main model
5   !!======================================================================
6   !! History :  OPA  !  1999-10  (JC. Dutay)  original code
7   !!  NEMO      1.0  !  2004-03  (C. Ethe) free form + modularity
8   !!            2.0  !  2007-12  (C. Ethe, G. Madec)  reorganisation
9   !!            4.0  !  2016-11  (T. Lovato) Add SF6, Update Schmidt number
10   !!----------------------------------------------------------------------
11   !!   trc_sms_cfc  :  compute and add CFC suface forcing to CFC trends
12   !!   cfc_init     :  sets constants for CFC surface forcing computation
13   !!----------------------------------------------------------------------
14   USE oce_trc       ! Ocean variables
15   USE par_trc       ! TOP parameters
16   USE trc           ! TOP variables
17   USE trd_oce
18   USE trdtrc
19   USE iom           ! I/O library
20
21   IMPLICIT NONE
22   PRIVATE
23
24   PUBLIC   trc_sms_cfc         ! called in ???   
25   PUBLIC   trc_sms_cfc_alloc   ! called in trcini_cfc.F90
26
27   INTEGER , PUBLIC, PARAMETER ::   jphem  =   2   ! parameter for the 2 hemispheres
28   INTEGER , PUBLIC            ::   jpyear         ! Number of years read in input data file (in trcini_cfc)
29   INTEGER , PUBLIC            ::   ndate_beg      ! initial calendar date (aammjj) for CFC
30   INTEGER , PUBLIC            ::   nyear_res      ! restoring time constant (year)
31   INTEGER , PUBLIC            ::   nyear_beg      ! initial year (aa)
32   
33   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   p_cfc    ! partial hemispheric pressure for all CFC
34   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   xphem    ! spatial interpolation factor for patm
35   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   qtr_cfc  ! flux at surface
36   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   qint_cfc ! cumulative flux
37   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:,:) ::   atm_cfc  ! partial hemispheric pressure for used CFC
38   REAL(wp), PUBLIC, ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   patm     ! atmospheric function
39
40   REAL(wp),         ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   soa      ! coefficient for solubility of CFC [mol/l/atm]
41   REAL(wp),         ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   sob      !    "               "
42   REAL(wp),         ALLOCATABLE, SAVE, DIMENSION(:,:)   ::   sca      ! coefficients for schmidt number in degrees Celsius
43   !                          ! coefficients for conversion
44   REAL(wp) ::   xconv1 = 1.0          ! conversion from to
45   REAL(wp) ::   xconv2 = 0.01/3600.   ! conversion from cm/h to m/s:
46   REAL(wp) ::   xconv3 = 1.0e+3       ! conversion from mol/l/atm to mol/m3/atm
47   REAL(wp) ::   xconv4 = 1.0e-12      ! conversion from mol/m3/atm to mol/m3/pptv
48
49   !!----------------------------------------------------------------------
50   !! NEMO/TOP 4.0 , NEMO Consortium (2018)
51   !! $Id$
52   !! Software governed by the CeCILL license (see ./LICENSE)
53   !!----------------------------------------------------------------------
54CONTAINS
55
56   SUBROUTINE trc_sms_cfc( kt )
57      !!----------------------------------------------------------------------
58      !!                     ***  ROUTINE trc_sms_cfc  ***
59      !!
60      !! ** Purpose :   Compute the surface boundary contition on CFC 11
61      !!             passive tracer associated with air-mer fluxes and add it
62      !!             to the general trend of tracers equations.
63      !!
64      !! ** Method  : - get the atmospheric partial pressure - given in pico -
65      !!              - computation of solubility ( in 1.e-12 mol/l then in 1.e-9 mol/m3)
66      !!              - computation of transfert speed ( given in cm/hour ----> cm/s )
67      !!              - the input function is given by :
68      !!                speed * ( concentration at equilibrium - concentration at surface )
69      !!              - the input function is in pico-mol/m3/s and the
70      !!                CFC concentration in pico-mol/m3
71      !!----------------------------------------------------------------------
72      INTEGER, INTENT(in) ::   kt    ! ocean time-step index
73      !
74      INTEGER  ::   ji, jj, jn, jl, jm
75      INTEGER  ::   iyear_beg, iyear_end
76      INTEGER  ::   im1, im2, ierr
77      REAL(wp) ::   ztap, zdtap       
78      REAL(wp) ::   zt1, zt2, zt3, zt4, zv2
79      REAL(wp) ::   zsol      ! solubility
80      REAL(wp) ::   zsch      ! schmidt number
81      REAL(wp) ::   zpp_cfc   ! atmospheric partial pressure of CFC
82      REAL(wp) ::   zca_cfc   ! concentration at equilibrium
83      REAL(wp) ::   zak_cfc   ! transfert coefficients
84      REAL(wp), ALLOCATABLE, DIMENSION(:,:)  ::   zpatm     ! atmospheric function
85      !!----------------------------------------------------------------------
86      !
87      IF( ln_timing )   CALL timing_start('trc_sms_cfc')
88      !
89      ALLOCATE( zpatm(jphem,jp_cfc), STAT=ierr )
90      IF( ierr > 0 ) THEN
91         CALL ctl_stop( 'trc_sms_cfc: unable to allocate zpatm array' )   ;   RETURN
92      ENDIF
93
94      IF( kt == nittrc000 )   CALL cfc_init
95
96      ! Temporal interpolation
97      ! ----------------------
98      iyear_beg = nyear - 1900
99      IF ( nmonth <= 6 ) THEN
100         iyear_beg = iyear_beg - 1
101         im1       =  6 - nmonth + 1
102         im2       =  6 + nmonth - 1
103      ELSE
104         im1       = 12 - nmonth + 7
105         im2       =      nmonth - 7
106      ENDIF
107      iyear_end = iyear_beg + 1
108
109      !                                                  !------------!
110      DO jl = 1, jp_cfc                                  !  CFC loop  !
111         !                                               !------------!
112         jn = jp_cfc0 + jl - 1
113         ! time interpolation at time kt
114         DO jm = 1, jphem
115            zpatm(jm,jl) = (  atm_cfc(iyear_beg, jm, jl) * REAL(im1, wp)  &
116               &           +  atm_cfc(iyear_end, jm, jl) * REAL(im2, wp) ) / 12.
117         END DO
118         
119         !                                                         !------------!
120         DO jj = 1, jpj                                            !  i-j loop  !
121            DO ji = 1, jpi                                         !------------!
122 
123               ! space interpolation
124               zpp_cfc  =       xphem(ji,jj)   * zpatm(1,jl)   &
125                  &     + ( 1.- xphem(ji,jj) ) * zpatm(2,jl)
126
127               ! Computation of concentration at equilibrium : in picomol/l
128               ! coefficient for solubility for CFC-11/12 in  mol/l/atm
129               IF( tmask(ji,jj,1) .GE. 0.5 ) THEN
130                  ztap  = ( tsn(ji,jj,1,jp_tem) + 273.16 ) * 0.01
131                  zdtap = sob(1,jl) + ztap * ( sob(2,jl) + ztap * sob(3,jl) ) 
132                  zsol  =  EXP( soa(1,jl) + soa(2,jl) / ztap + soa(3,jl) * LOG( ztap )   &
133                     &                    + soa(4,jl) * ztap * ztap + tsn(ji,jj,1,jp_sal) * zdtap ) 
134               ELSE
135                  zsol  = 0.e0
136               ENDIF
137               ! conversion from mol/l/atm to mol/m3/atm and from mol/m3/atm to mol/m3/pptv   
138               zsol = xconv4 * xconv3 * zsol * tmask(ji,jj,1) 
139               ! concentration at equilibrium
140               zca_cfc = xconv1 * zpp_cfc * zsol * tmask(ji,jj,1)             
141 
142               ! Computation of speed transfert
143               !    Schmidt number revised in Wanninkhof (2014)
144               zt1  = tsn(ji,jj,1,jp_tem)
145               zt2  = zt1 * zt1 
146               zt3  = zt1 * zt2
147               zt4  = zt2 * zt2
148               zsch = sca(1,jl) + sca(2,jl) * zt1 + sca(3,jl) * zt2 + sca(4,jl) * zt3 + sca(5,jl) * zt4
149
150               !    speed transfert : formulae revised in Wanninkhof (2014)
151               zv2     = wndm(ji,jj) * wndm(ji,jj)
152               zsch    = zsch / 660.
153               zak_cfc = ( 0.251 * xconv2 * zv2 / SQRT(zsch) ) * tmask(ji,jj,1)
154
155               ! Input function  : speed *( conc. at equil - concen at surface )
156               ! trn in pico-mol/l idem qtr; ak in en m/a
157               qtr_cfc(ji,jj,jl) = -zak_cfc * ( trb(ji,jj,1,jn) - zca_cfc )   &
158                  &                         * tmask(ji,jj,1) * ( 1. - fr_i(ji,jj) )
159               ! Add the surface flux to the trend
160               tra(ji,jj,1,jn) = tra(ji,jj,1,jn) + qtr_cfc(ji,jj,jl) / e3t_n(ji,jj,1) 
161
162               ! cumulation of surface flux at each time step
163               qint_cfc(ji,jj,jl) = qint_cfc(ji,jj,jl) + qtr_cfc(ji,jj,jl) * rdt
164               !                                               !----------------!
165            END DO                                             !  end i-j loop  !
166         END DO                                                !----------------!
167         !                                                  !----------------!
168      END DO                                                !  end CFC loop  !
169      !
170      IF( lrst_trc ) THEN
171         IF(lwp) WRITE(numout,*)
172         IF(lwp) WRITE(numout,*) 'trc_sms_cfc : cumulated input function fields written in ocean restart file ',   &
173            &                    'at it= ', kt,' date= ', ndastp
174         IF(lwp) WRITE(numout,*) '~~~~'
175         jl = 0
176         DO jn = jp_cfc0, jp_cfc1
177             jl = jl + 1
178            CALL iom_rstput( kt, nitrst, numrtw, 'qint_'//ctrcnm(jn), qint_cfc(:,:,jl) )
179         END DO
180      ENDIF                                           
181      !
182      IF( lk_iomput ) THEN
183         jl = 0
184         DO jn = jp_cfc0, jp_cfc1
185            jl = jl + 1
186            CALL iom_put( 'qtr_'//TRIM(ctrcnm(jn)) , qtr_cfc (:,:,jl) )
187            CALL iom_put( 'qint_'//TRIM(ctrcnm(jn)), qint_cfc(:,:,jl) )
188         ENDDO
189      END IF
190      !
191      IF( l_trdtrc ) THEN
192          DO jn = jp_cfc0, jp_cfc1
193            CALL trd_trc( tra(:,:,:,jn), jn, jptra_sms, kt )   ! save trends
194          END DO
195      END IF
196      !
197      IF( ln_timing )   CALL timing_stop('trc_sms_cfc')
198      !
199   END SUBROUTINE trc_sms_cfc
200
201
202   SUBROUTINE cfc_init
203      !!---------------------------------------------------------------------
204      !!                     ***  cfc_init  *** 
205      !!
206      !! ** Purpose : sets constants for CFC model
207      !!---------------------------------------------------------------------
208      INTEGER ::   jn, jl   !
209      !!----------------------------------------------------------------------
210      !
211      jn = 0 
212      ! coefficient for CFC11
213      !----------------------
214      if ( ln_cfc11 ) then
215         jn = jn + 1
216         ! Solubility
217         soa(1,jn) = -229.9261 
218         soa(2,jn) =  319.6552
219         soa(3,jn) =  119.4471
220         soa(4,jn) =  -1.39165
221
222         sob(1,jn) =  -0.142382
223         sob(2,jn) =   0.091459
224         sob(3,jn) =  -0.0157274
225
226         ! Schmidt number
227         sca(1,jn) = 3579.2
228         sca(2,jn) = -222.63
229         sca(3,jn) = 7.5749
230         sca(4,jn) = -0.14595
231         sca(5,jn) = 0.0011874
232
233         ! atm. concentration
234         atm_cfc(:,:,jn) = p_cfc(:,:,1)
235      endif
236
237      ! coefficient for CFC12
238      !----------------------
239      if ( ln_cfc12 ) then
240         jn = jn + 1
241         ! Solubility
242         soa(1,jn) = -218.0971
243         soa(2,jn) =  298.9702
244         soa(3,jn) =  113.8049
245         soa(4,jn) =  -1.39165
246
247         sob(1,jn) =  -0.143566
248         sob(2,jn) =   0.091015
249         sob(3,jn) =  -0.0153924
250
251         ! schmidt number
252         sca(1,jn) = 3828.1
253         sca(2,jn) = -249.86
254         sca(3,jn) = 8.7603
255         sca(4,jn) = -0.1716
256         sca(5,jn) = 0.001408
257
258         ! atm. concentration
259         atm_cfc(:,:,jn) = p_cfc(:,:,2)
260      endif
261
262      ! coefficient for SF6
263      !----------------------
264      if ( ln_sf6 ) then
265         jn = jn + 1
266         ! Solubility
267         soa(1,jn) = -80.0343
268         soa(2,jn) = 117.232
269         soa(3,jn) =  29.5817
270         soa(4,jn) =   0.0
271
272         sob(1,jn) =  0.0335183 
273         sob(2,jn) = -0.0373942 
274         sob(3,jn) =  0.00774862
275
276         ! schmidt number
277         sca(1,jn) = 3177.5
278         sca(2,jn) = -200.57
279         sca(3,jn) = 6.8865
280         sca(4,jn) = -0.13335
281         sca(5,jn) = 0.0010877
282 
283         ! atm. concentration
284         atm_cfc(:,:,jn) = p_cfc(:,:,3)
285       endif
286
287      IF( ln_rsttr ) THEN
288         IF(lwp) WRITE(numout,*)
289         IF(lwp) WRITE(numout,*) ' Read specific variables from CFC model '
290         IF(lwp) WRITE(numout,*) ' ~~~~~~~~~~~~~~'
291         !
292         jl = 0
293         DO jn = jp_cfc0, jp_cfc1
294            jl = jl + 1
295            CALL iom_get( numrtr, jpdom_autoglo, 'qint_'//ctrcnm(jn), qint_cfc(:,:,jl) ) 
296         END DO
297      ENDIF
298      IF(lwp) WRITE(numout,*)
299      !
300   END SUBROUTINE cfc_init
301
302
303   INTEGER FUNCTION trc_sms_cfc_alloc()
304      !!----------------------------------------------------------------------
305      !!                     ***  ROUTINE trc_sms_cfc_alloc  ***
306      !!----------------------------------------------------------------------
307      ALLOCATE( xphem   (jpi,jpj)        , atm_cfc(jpyear,jphem,jp_cfc)  ,    &
308         &      qtr_cfc (jpi,jpj,jp_cfc) , qint_cfc(jpi,jpj,jp_cfc)      ,    &
309         &      soa(4,jp_cfc)    ,  sob(3,jp_cfc)   ,  sca(5,jp_cfc)     ,    &
310         &      STAT=trc_sms_cfc_alloc )
311         !
312      IF( trc_sms_cfc_alloc /= 0 ) CALL ctl_warn('trc_sms_cfc_alloc : failed to allocate arrays.')
313      !
314   END FUNCTION trc_sms_cfc_alloc
315
316   !!======================================================================
317END MODULE trcsms_cfc
Note: See TracBrowser for help on using the repository browser.